DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
11976 Commits
11 Branches
347MB
Tree: fa17310dd1
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'fa17310dd1'
${ noResults }
JUCE/modules/juce_gui_basics/native/accessibility/juce_mac_Accessibility.mm

1149 lines
52KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2020 - Raw Material Software Limited

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 6 End-User License

  11.    Agreement and JUCE Privacy Policy (both effective as of the 16th June 2020).

  12. 

  13.    End User License Agreement: www.juce.com/juce-6-licence

  14.    Privacy Policy: www.juce.com/juce-privacy-policy

  15. 

  16.    Or: You may also use this code under the terms of the GPL v3 (see

  17.    www.gnu.org/licenses).

  18. 

  19.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  20.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  21.    DISCLAIMED.

  22. 

  23.   ==============================================================================

  24. */

  25. 

  26. namespace juce

  27. {

  28. 

  29. #if (defined (MAC_OS_X_VERSION_10_10) && MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_10)

  30. 

  31. #if (! defined MAC_OS_X_VERSION_10_13) || MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_13

  32.  using NSAccessibilityRole = NSString*;

  33.  using NSAccessibilityNotificationName = NSString*;

  34. #endif

  35. 

  36. //==============================================================================

  37. class AccessibilityHandler::AccessibilityNativeImpl

  38. {

  39. public:

  40.     explicit AccessibilityNativeImpl (AccessibilityHandler& handler)

  41.         : accessibilityElement (AccessibilityElement::create (handler))

  42.     {}

  43. 

  44.     NSAccessibilityElement<NSAccessibility>* getAccessibilityElement() const noexcept

  45.     {

  46.         return accessibilityElement.get();

  47.     }

  48. 

  49. private:

  50.     //==============================================================================

  51.     class AccessibilityElement  : public ObjCClass<NSAccessibilityElement<NSAccessibility>>

  52.     {

  53.     private:

  54.         struct Deleter

  55.         {

  56.             void operator() (NSAccessibilityElement<NSAccessibility>* element) const

  57.             {

  58.                 object_setInstanceVariable (element, "handler", nullptr);

  59.                 [element release];

  60.             }

  61.         };

  62. 

  63.     public:

  64.         using Holder = std::unique_ptr<NSAccessibilityElement<NSAccessibility>, Deleter>;

  65. 

  66.         static Holder create (AccessibilityHandler& handler)

  67.         {

  68.             static AccessibilityElement cls;

  69.             Holder element ([cls.createInstance() init]);

  70.             object_setInstanceVariable (element.get(), "handler", &handler);

  71.             return element;

  72.         }

  73. 

  74.     private:

  75.         AccessibilityElement()  : ObjCClass<NSAccessibilityElement<NSAccessibility>> ("JUCEAccessibilityElement_")

  76.         {

  77.             addIvar<AccessibilityHandler*> ("handler");

  78. 

  79.             addMethod (@selector (accessibilityNotifiesWhenDestroyed),     getAccessibilityNotifiesWhenDestroyed, "c@:");

  80.             addMethod (@selector (isAccessibilityElement),                 getIsAccessibilityElement,             "c@:");

  81.             addMethod (@selector (isAccessibilityEnabled),                 getIsAccessibilityEnabled,             "c@:");

  82.             addMethod (@selector (accessibilityWindow),                    getAccessibilityWindow,                "@@:");

  83.             addMethod (@selector (accessibilityTopLevelUIElement),         getAccessibilityWindow,                "@@:");

  84.             addMethod (@selector (accessibilityFocusedUIElement),          getAccessibilityFocusedUIElement,      "@@:");

  85.             addMethod (@selector (accessibilityHitTest:),                  accessibilityHitTest,                  "@@:", @encode (NSPoint));

  86.             addMethod (@selector (accessibilityParent),                    getAccessibilityParent,                "@@:");

  87.             addMethod (@selector (accessibilityChildren),                  getAccessibilityChildren,              "@@:");

  88.             addMethod (@selector (isAccessibilityFocused),                 getIsAccessibilityFocused,             "c@:");

  89.             addMethod (@selector (setAccessibilityFocused:),               setAccessibilityFocused,               "v@:c");

  90.             addMethod (@selector (isAccessibilityModal),                   getIsAccessibilityModal,               "c@:");

  91.             addMethod (@selector (accessibilityFrame),                     getAccessibilityFrame,                 @encode (NSRect), "@:");

  92.             addMethod (@selector (accessibilityRole),                      getAccessibilityRole,                  "@@:");

  93.             addMethod (@selector (accessibilitySubrole),                   getAccessibilitySubrole,               "@@:");

  94.             addMethod (@selector (accessibilityTitle),                     getAccessibilityTitle,                 "@@:");

  95.             addMethod (@selector (accessibilityLabel),                     getAccessibilityLabel,                 "@@:");

  96.             addMethod (@selector (accessibilityHelp),                      getAccessibilityHelp,                  "@@:");

  97.             addMethod (@selector (accessibilityValue),                     getAccessibilityValue,                 "@@:");

  98.             addMethod (@selector (setAccessibilityValue:),                 setAccessibilityValue,                 "v@:@");

  99.             addMethod (@selector (accessibilitySelectedChildren),          getAccessibilitySelectedChildren,      "@@:");

  100.             addMethod (@selector (setAccessibilitySelectedChildren:),      setAccessibilitySelectedChildren,      "v@:@");

  101.             addMethod (@selector (accessibilityOrientation),               getAccessibilityOrientation,           "i@:@");

  102. 

  103.             addMethod (@selector (accessibilityInsertionPointLineNumber),  getAccessibilityInsertionPointLineNumber, "i@:");

  104.             addMethod (@selector (accessibilitySharedCharacterRange),      getAccessibilitySharedCharacterRange,     @encode (NSRange), "@:");

  105.             addMethod (@selector (accessibilitySharedTextUIElements),      getAccessibilitySharedTextUIElements,     "@@:");

  106.             addMethod (@selector (accessibilityVisibleCharacterRange),     getAccessibilityVisibleCharacterRange,    @encode (NSRange), "@:");

  107.             addMethod (@selector (accessibilityNumberOfCharacters),        getAccessibilityNumberOfCharacters,       "i@:");

  108.             addMethod (@selector (accessibilitySelectedText),              getAccessibilitySelectedText,             "@@:");

  109.             addMethod (@selector (accessibilitySelectedTextRange),         getAccessibilitySelectedTextRange,        @encode (NSRange), "@:");

  110.             addMethod (@selector (accessibilitySelectedTextRanges),        getAccessibilitySelectedTextRanges,       "@@:");

  111.             addMethod (@selector (accessibilityAttributedStringForRange:), getAccessibilityAttributedStringForRange, "@@:", @encode (NSRange));

  112.             addMethod (@selector (accessibilityRangeForLine:),             getAccessibilityRangeForLine,             @encode (NSRange), "@:i");

  113.             addMethod (@selector (accessibilityStringForRange:),           getAccessibilityStringForRange,           "@@:", @encode (NSRange));

  114.             addMethod (@selector (accessibilityRangeForPosition:),         getAccessibilityRangeForPosition,         @encode (NSRange), "@:", @encode (NSPoint));

  115.             addMethod (@selector (accessibilityRangeForIndex:),            getAccessibilityRangeForIndex,            @encode (NSRange), "@:i");

  116.             addMethod (@selector (accessibilityFrameForRange:),            getAccessibilityFrameForRange,            @encode (NSRect), "@:", @encode (NSRange));

  117.             addMethod (@selector (accessibilityRTFForRange:),              getAccessibilityRTFForRange,              "@@:", @encode (NSRange));

  118.             addMethod (@selector (accessibilityStyleRangeForIndex:),       getAccessibilityStyleRangeForIndex,       @encode (NSRange), "@:i");

  119.             addMethod (@selector (accessibilityLineForIndex:),             getAccessibilityLineForIndex,             "i@:i");

  120.             addMethod (@selector (setAccessibilitySelectedTextRange:),     setAccessibilitySelectedTextRange,        "v@:", @encode (NSRange));

  121. 

  122.             addMethod (@selector (accessibilityRowCount),            getAccessibilityRowCount,         "i@:");

  123.             addMethod (@selector (accessibilityRows),                getAccessibilityRows,             "@@:");

  124.             addMethod (@selector (accessibilitySelectedRows),        getAccessibilitySelectedRows,     "@@:");

  125.             addMethod (@selector (setAccessibilitySelectedRows:),    setAccessibilitySelectedRows,     "v@:@");

  126.             addMethod (@selector (accessibilityColumnCount),         getAccessibilityColumnCount,      "i@:");

  127.             addMethod (@selector (accessibilityColumns),             getAccessibilityColumns,          "@@:");

  128.             addMethod (@selector (accessibilitySelectedColumns),     getAccessibilitySelectedColumns,  "@@:");

  129.             addMethod (@selector (setAccessibilitySelectedColumns:), setAccessibilitySelectedColumns,  "v@:@");

  130. 

  131.             addMethod (@selector (accessibilityRowIndexRange),    getAccessibilityRowIndexRange,    @encode (NSRange), "@:");

  132.             addMethod (@selector (accessibilityColumnIndexRange), getAccessibilityColumnIndexRange, @encode (NSRange), "@:");

  133.             addMethod (@selector (accessibilityIndex),            getAccessibilityIndex,            "i@:");

  134.             addMethod (@selector (accessibilityDisclosureLevel),  getAccessibilityDisclosureLevel,  "i@:");

  135.             addMethod (@selector (isAccessibilityExpanded),       getIsAccessibilityExpanded,       "c@:");

  136. 

  137.             addMethod (@selector (accessibilityPerformIncrement), accessibilityPerformIncrement, "c@:");

  138.             addMethod (@selector (accessibilityPerformDecrement), accessibilityPerformDecrement, "c@:");

  139.             addMethod (@selector (accessibilityPerformDelete),    accessibilityPerformDelete,    "c@:");

  140.             addMethod (@selector (accessibilityPerformPress),     accessibilityPerformPress,     "c@:");

  141.             addMethod (@selector (accessibilityPerformShowMenu),  accessibilityPerformShowMenu,  "c@:");

  142.             addMethod (@selector (accessibilityPerformRaise),     accessibilityPerformRaise,     "c@:");

  143. 

  144.             addMethod (@selector (isAccessibilitySelectorAllowed:), getIsAccessibilitySelectorAllowed, "c@:@");

  145. 

  146.            #if defined (MAC_OS_X_VERSION_10_13) && MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_13

  147.             addMethod (@selector (accessibilityChildrenInNavigationOrder), getAccessibilityChildren, "@@:");

  148.            #endif

  149. 

  150.             registerClass();

  151.         }

  152. 

  153.     private:

  154.         static AccessibilityHandler* getHandler (id self)            { return getIvar<AccessibilityHandler*> (self, "handler"); }

  155. 

  156.         template <typename MemberFn>

  157.         static auto getInterface (id self, MemberFn fn) noexcept -> decltype ((std::declval<AccessibilityHandler>().*fn)())

  158.         {

  159.             if (auto* handler = getHandler (self))

  160.                 return (handler->*fn)();

  161. 

  162.             return nullptr;

  163.         }

  164. 

  165.         static AccessibilityTextInterface*  getTextInterface  (id self) noexcept  { return getInterface (self, &AccessibilityHandler::getTextInterface); }

  166.         static AccessibilityValueInterface* getValueInterface (id self) noexcept  { return getInterface (self, &AccessibilityHandler::getValueInterface); }

  167.         static AccessibilityTableInterface* getTableInterface (id self) noexcept  { return getInterface (self, &AccessibilityHandler::getTableInterface); }

  168.         static AccessibilityCellInterface*  getCellInterface  (id self) noexcept  { return getInterface (self, &AccessibilityHandler::getCellInterface); }

  169. 

  170.         static bool hasEditableText (AccessibilityHandler& handler) noexcept

  171.         {

  172.             return handler.getRole() == AccessibilityRole::editableText

  173.                 && handler.getTextInterface() != nullptr;

  174.         }

  175. 

  176.         static bool nameIsAccessibilityValue (AccessibilityRole role) noexcept

  177.         {

  178.             return role == AccessibilityRole::staticText;

  179.         }

  180. 

  181.         static bool isSelectable (AccessibleState state) noexcept

  182.         {

  183.             return state.isSelectable() || state.isMultiSelectable();

  184.         }

  185. 

  186.         static NSArray* getSelectedChildren (NSArray* children)

  187.         {

  188.             NSMutableArray* selected = [[NSMutableArray new] autorelease];

  189. 

  190.             for (id child in children)

  191.             {

  192.                 if (auto* handler = getHandler (child))

  193.                 {

  194.                     const auto currentState = handler->getCurrentState();

  195. 

  196.                     if (isSelectable (currentState) && currentState.isSelected())

  197.                         [selected addObject: child];

  198.                 }

  199.             }

  200. 

  201.             return selected;

  202.         }

  203. 

  204.         static void setSelectedChildren (NSArray* children, NSArray* selected)

  205.         {

  206.             for (id child in children)

  207.             {

  208.                 if (auto* handler = getHandler (child))

  209.                 {

  210.                     const auto currentState = handler->getCurrentState();

  211.                     const BOOL isSelected = [selected containsObject: child];

  212. 

  213.                     if (isSelectable (currentState))

  214.                     {

  215.                         if (currentState.isSelected() != isSelected)

  216.                             handler->getActions().invoke (AccessibilityActionType::toggle);

  217.                     }

  218.                     else if (currentState.isFocusable())

  219.                     {

  220.                         [child setAccessibilityFocused: isSelected];

  221.                     }

  222.                 }

  223.             }

  224.         }

  225. 

  226.         static BOOL performActionIfSupported (id self, AccessibilityActionType actionType)

  227.         {

  228.             if (auto* handler = getHandler (self))

  229.                 if (handler->getActions().invoke (actionType))

  230.                     return YES;

  231. 

  232.             return NO;

  233.         }

  234. 

  235.         //==============================================================================

  236.         static BOOL getAccessibilityNotifiesWhenDestroyed (id, SEL)  { return YES; }

  237. 

  238.         static BOOL getIsAccessibilityElement (id self, SEL)

  239.         {

  240.             if (auto* handler = getHandler (self))

  241.                 return ! handler->isIgnored()

  242.                       && handler->getRole() != AccessibilityRole::window;

  243. 

  244.             return NO;

  245.         }

  246. 

  247.         static BOOL getIsAccessibilityEnabled (id self, SEL)

  248.         {

  249.             if (auto* handler = getHandler (self))

  250.                 return handler->getComponent().isEnabled();

  251. 

  252.             return NO;

  253.         }

  254. 

  255.         static id getAccessibilityWindow (id self, SEL)

  256.         {

  257.             return [[self accessibilityParent] accessibilityWindow];

  258.         }

  259. 

  260.         static id getAccessibilityFocusedUIElement (id self, SEL)

  261.         {

  262.             if (auto* handler = getHandler (self))

  263.             {

  264.                 if (auto* modal = Component::getCurrentlyModalComponent())

  265.                 {

  266.                     const auto& component = handler->getComponent();

  267. 

  268.                     if (! component.isParentOf (modal)

  269.                          && component.isCurrentlyBlockedByAnotherModalComponent())

  270.                     {

  271.                         if (auto* modalHandler = modal->getAccessibilityHandler())

  272.                         {

  273.                             if (auto* focusChild = modalHandler->getChildFocus())

  274.                                 return (id) focusChild->getNativeImplementation();

  275. 

  276.                             return (id) modalHandler->getNativeImplementation();

  277.                         }

  278.                     }

  279.                 }

  280. 

  281.                 if (auto* focusChild = handler->getChildFocus())

  282.                     return (id) focusChild->getNativeImplementation();

  283.             }

  284. 

  285.             return nil;

  286.         }

  287. 

  288.         static id accessibilityHitTest (id self, SEL, NSPoint point)

  289.         {

  290.             if (auto* handler = getHandler (self))

  291.             {

  292.                 if (auto* child = handler->getChildAt (convertToIntPoint (flippedScreenPoint (point))))

  293.                     return (id) child->getNativeImplementation();

  294. 

  295.                 return self;

  296.             }

  297. 

  298.             return nil;

  299.         }

  300. 

  301.         static id getAccessibilityParent (id self, SEL)

  302.         {

  303.             if (auto* handler = getHandler (self))

  304.             {

  305.                 if (auto* parentHandler = handler->getParent())

  306.                     return NSAccessibilityUnignoredAncestor ((id) parentHandler->getNativeImplementation());

  307. 

  308.                 return NSAccessibilityUnignoredAncestor ((id) handler->getComponent().getWindowHandle());

  309.             }

  310. 

  311.             return nil;

  312.         }

  313. 

  314.         static NSArray* getAccessibilityChildren (id self, SEL)

  315.         {

  316.             if (auto* handler = getHandler (self))

  317.             {

  318.                 auto children = handler->getChildren();

  319. 

  320.                 NSMutableArray* accessibleChildren = [NSMutableArray arrayWithCapacity: (NSUInteger) children.size()];

  321. 

  322.                 for (auto* childHandler : children)

  323.                     [accessibleChildren addObject: (id) childHandler->getNativeImplementation()];

  324. 

  325.                 return accessibleChildren;

  326.             }

  327. 

  328.             return nil;

  329.         }

  330. 

  331.         static NSArray* getAccessibilitySelectedChildren (id self, SEL)

  332.         {

  333.             return getSelectedChildren ([self accessibilityChildren]);

  334.         }

  335. 

  336.         static void setAccessibilitySelectedChildren (id self, SEL, NSArray* selected)

  337.         {

  338.             setSelectedChildren ([self accessibilityChildren], selected);

  339.         }

  340. 

  341.         static NSAccessibilityOrientation getAccessibilityOrientation (id self, SEL)

  342.         {

  343.             if (auto* handler = getHandler (self))

  344.                 return handler->getComponent().getBounds().toFloat().getAspectRatio() > 1.0f

  345.                            ? NSAccessibilityOrientationHorizontal

  346.                            : NSAccessibilityOrientationVertical;

  347. 

  348.             return NSAccessibilityOrientationUnknown;

  349.         }

  350. 

  351.         static BOOL getIsAccessibilityFocused (id self, SEL)

  352.         {

  353.             return [[self accessibilityWindow] accessibilityFocusedUIElement] == self;

  354.         }

  355. 

  356.         static void setAccessibilityFocused (id self, SEL, BOOL focused)

  357.         {

  358.             if (auto* handler = getHandler (self))

  359.             {

  360.                 if (focused)

  361.                 {

  362.                     const WeakReference<Component> safeComponent (&handler->getComponent());

  363. 

  364.                     performActionIfSupported (self, AccessibilityActionType::focus);

  365. 

  366.                     if (safeComponent != nullptr)

  367.                         handler->grabFocus();

  368.                 }

  369.                 else

  370.                 {

  371.                     handler->giveAwayFocus();

  372.                 }

  373.             }

  374.         }

  375. 

  376.         static BOOL getIsAccessibilityModal (id self, SEL)

  377.         {

  378.             if (auto* handler = getHandler (self))

  379.                 return handler->getComponent().isCurrentlyModal();

  380. 

  381.             return NO;

  382.         }

  383. 

  384.         static NSRect getAccessibilityFrame (id self, SEL)

  385.         {

  386.             if (auto* handler = getHandler (self))

  387.                 return flippedScreenRect (makeNSRect (handler->getComponent().getScreenBounds()));

  388. 

  389.             return NSZeroRect;

  390.         }

  391. 

  392.         static NSAccessibilityRole getAccessibilityRole (id self, SEL)

  393.         {

  394.             if (auto* handler = getHandler (self))

  395.             {

  396.                 switch (handler->getRole())

  397.                 {

  398.                     case AccessibilityRole::button:       return NSAccessibilityButtonRole;

  399.                     case AccessibilityRole::toggleButton: return NSAccessibilityCheckBoxRole;

  400.                     case AccessibilityRole::radioButton:  return NSAccessibilityRadioButtonRole;

  401.                     case AccessibilityRole::comboBox:     return NSAccessibilityPopUpButtonRole;

  402.                     case AccessibilityRole::image:        return NSAccessibilityImageRole;

  403.                     case AccessibilityRole::slider:       return NSAccessibilitySliderRole;

  404.                     case AccessibilityRole::staticText:   return NSAccessibilityStaticTextRole;

  405.                     case AccessibilityRole::editableText: return NSAccessibilityTextAreaRole;

  406.                     case AccessibilityRole::menuItem:     return NSAccessibilityMenuItemRole;

  407.                     case AccessibilityRole::menuBar:      return NSAccessibilityMenuRole;

  408.                     case AccessibilityRole::popupMenu:    return NSAccessibilityWindowRole;

  409.                     case AccessibilityRole::table:        return NSAccessibilityListRole;

  410.                     case AccessibilityRole::tableHeader:  return NSAccessibilityGroupRole;

  411.                     case AccessibilityRole::column:       return NSAccessibilityColumnRole;

  412.                     case AccessibilityRole::row:          return NSAccessibilityRowRole;

  413.                     case AccessibilityRole::cell:         return NSAccessibilityCellRole;

  414.                     case AccessibilityRole::hyperlink:    return NSAccessibilityLinkRole;

  415.                     case AccessibilityRole::list:         return NSAccessibilityOutlineRole;

  416.                     case AccessibilityRole::listItem:     return NSAccessibilityRowRole;

  417.                     case AccessibilityRole::tree:         return NSAccessibilityOutlineRole;

  418.                     case AccessibilityRole::treeItem:     return NSAccessibilityRowRole;

  419.                     case AccessibilityRole::progressBar:  return NSAccessibilityProgressIndicatorRole;

  420.                     case AccessibilityRole::group:        return NSAccessibilityGroupRole;

  421.                     case AccessibilityRole::dialogWindow: return NSAccessibilityWindowRole;

  422.                     case AccessibilityRole::window:       return NSAccessibilityWindowRole;

  423.                     case AccessibilityRole::scrollBar:    return NSAccessibilityScrollBarRole;

  424.                     case AccessibilityRole::tooltip:      return NSAccessibilityWindowRole;

  425.                     case AccessibilityRole::splashScreen: return NSAccessibilityWindowRole;

  426.                     case AccessibilityRole::ignored:      return NSAccessibilityUnknownRole;

  427.                     case AccessibilityRole::unspecified:  return NSAccessibilityGroupRole;

  428.                     default:                              break;

  429.                 }

  430. 

  431.                 return NSAccessibilityUnknownRole;

  432.             }

  433. 

  434.             return nil;

  435.         }

  436. 

  437.         static NSAccessibilityRole getAccessibilitySubrole (id self, SEL)

  438.         {

  439.             if (auto* handler = getHandler (self))

  440.             {

  441.                 if (auto* textInterface = getTextInterface (self))

  442.                     if (textInterface->isDisplayingProtectedText())

  443.                         return NSAccessibilitySecureTextFieldSubrole;

  444. 

  445.                 const auto role = handler->getRole();

  446. 

  447.                 if (role == AccessibilityRole::window)                                     return NSAccessibilityStandardWindowSubrole;

  448.                 if (role == AccessibilityRole::dialogWindow)                               return NSAccessibilityDialogSubrole;

  449.                 if (role == AccessibilityRole::tooltip

  450.                     || role == AccessibilityRole::splashScreen)                            return NSAccessibilityFloatingWindowSubrole;

  451.                 if (role == AccessibilityRole::toggleButton)                               return NSAccessibilityToggleSubrole;

  452.                 if (role == AccessibilityRole::treeItem

  453.                     || role == AccessibilityRole::listItem)                                return NSAccessibilityOutlineRowSubrole;

  454.                 if (role == AccessibilityRole::row && getCellInterface (self) != nullptr)  return NSAccessibilityTableRowSubrole;

  455. 

  456.                 const auto& component = handler->getComponent();

  457. 

  458.                 if (auto* documentWindow = component.findParentComponentOfClass<DocumentWindow>())

  459.                 {

  460.                     if (role == AccessibilityRole::button)

  461.                     {

  462.                         if (&component == documentWindow->getCloseButton())     return NSAccessibilityCloseButtonSubrole;

  463.                         if (&component == documentWindow->getMinimiseButton())  return NSAccessibilityMinimizeButtonSubrole;

  464.                         if (&component == documentWindow->getMaximiseButton())  return NSAccessibilityFullScreenButtonSubrole;

  465.                     }

  466.                 }

  467.             }

  468. 

  469.             return NSAccessibilityUnknownRole;

  470.         }

  471. 

  472.         static NSString* getAccessibilityTitle (id self, SEL)

  473.         {

  474.             if (auto* handler = getHandler (self))

  475.             {

  476.                 if (nameIsAccessibilityValue (handler->getRole()))

  477.                     return @"";

  478. 

  479.                 auto title = handler->getTitle();

  480. 

  481.                 if (title.isEmpty() && handler->getComponent().isOnDesktop())

  482.                     title = getAccessibleApplicationOrPluginName();

  483. 

  484.                 return juceStringToNS (title);

  485.             }

  486. 

  487.             return nil;

  488.         }

  489. 

  490.         static NSString* getAccessibilityLabel (id self, SEL)

  491.         {

  492.             if (auto* handler = getHandler (self))

  493.                 return juceStringToNS (handler->getDescription());

  494. 

  495.             return nil;

  496.         }

  497. 

  498.         static NSString* getAccessibilityHelp (id self, SEL)

  499.         {

  500.             if (auto* handler = getHandler (self))

  501.                 return juceStringToNS (handler->getHelp());

  502. 

  503.             return nil;

  504.         }

  505. 

  506.         static id getAccessibilityValue (id self, SEL)

  507.         {

  508.             if (auto* handler = getHandler (self))

  509.             {

  510.                 if (nameIsAccessibilityValue (handler->getRole()))

  511.                     return juceStringToNS (handler->getTitle());

  512. 

  513.                 if (hasEditableText (*handler))

  514.                 {

  515.                     auto* textInterface = handler->getTextInterface();

  516.                     return juceStringToNS (textInterface->getText ({ 0, textInterface->getTotalNumCharacters() }));

  517.                 }

  518. 

  519.                 if (handler->getCurrentState().isCheckable())

  520.                     return handler->getCurrentState().isChecked() ? @(1) : @(0);

  521. 

  522.                 if (auto* valueInterface = handler->getValueInterface())

  523.                     return juceStringToNS (valueInterface->getCurrentValueAsString());

  524.             }

  525. 

  526.             return nil;

  527.         }

  528. 

  529.         static void setAccessibilityValue (id self, SEL, NSString* value)

  530.         {

  531.             if (auto* handler = getHandler (self))

  532.             {

  533.                 if (hasEditableText (*handler))

  534.                 {

  535.                     handler->getTextInterface()->setText (nsStringToJuce (value));

  536.                     return;

  537.                 }

  538. 

  539.                 if (auto* valueInterface = handler->getValueInterface())

  540.                     if (! valueInterface->isReadOnly())

  541.                         valueInterface->setValueAsString (nsStringToJuce (value));

  542.             }

  543.         }

  544. 

  545.         //==============================================================================

  546.         static NSInteger getAccessibilityInsertionPointLineNumber (id self, SEL)

  547.         {

  548.             if (auto* textInterface = getTextInterface (self))

  549.                 return [self accessibilityLineForIndex: textInterface->getTextInsertionOffset()];

  550. 

  551.             return 0;

  552.         }

  553. 

  554.         static NSRange getAccessibilitySharedCharacterRange (id self, SEL)

  555.         {

  556.             return [self accessibilityVisibleCharacterRange];

  557.         }

  558. 

  559.         static NSArray* getAccessibilitySharedTextUIElements (id self, SEL)

  560.         {

  561.             return [NSArray arrayWithObject: self];

  562.         }

  563. 

  564.         static NSRange getAccessibilityVisibleCharacterRange (id self, SEL)

  565.         {

  566.             if (auto* textInterface = getTextInterface (self))

  567.                 return juceRangeToNS ({ 0, textInterface->getTotalNumCharacters() });

  568. 

  569.             return NSMakeRange (0, 0);

  570.         }

  571. 

  572.         static NSInteger getAccessibilityNumberOfCharacters (id self, SEL)

  573.         {

  574.             if (auto* textInterface = getTextInterface (self))

  575.                 return textInterface->getTotalNumCharacters();

  576. 

  577.             return 0;

  578.         }

  579. 

  580.         static NSString* getAccessibilitySelectedText (id self, SEL)

  581.         {

  582.             if (auto* textInterface = getTextInterface (self))

  583.                 return juceStringToNS (textInterface->getText (textInterface->getSelection()));

  584. 

  585.             return nil;

  586.         }

  587. 

  588.         static NSRange getAccessibilitySelectedTextRange (id self, SEL)

  589.         {

  590.             if (auto* textInterface = getTextInterface (self))

  591.                 return juceRangeToNS (textInterface->getSelection());

  592. 

  593.             return NSMakeRange (0, 0);

  594.         }

  595. 

  596.         static NSArray* getAccessibilitySelectedTextRanges (id self, SEL)

  597.         {

  598.             return [NSArray arrayWithObject: [NSValue valueWithRange: [self accessibilitySelectedTextRange]]];

  599.         }

  600. 

  601.         static NSAttributedString* getAccessibilityAttributedStringForRange (id self, SEL, NSRange range)

  602.         {

  603.             NSString* string = [self accessibilityStringForRange: range];

  604. 

  605.             if (string != nil)

  606.                 return [[[NSAttributedString alloc] initWithString: string] autorelease];

  607. 

  608.             return nil;

  609.         }

  610. 

  611.         static NSRange getAccessibilityRangeForLine (id self, SEL, NSInteger line)

  612.         {

  613.             if (auto* textInterface = getTextInterface (self))

  614.             {

  615.                 auto text = textInterface->getText ({ 0, textInterface->getTotalNumCharacters() });

  616.                 auto lines = StringArray::fromLines (text);

  617. 

  618.                 if (line < lines.size())

  619.                 {

  620.                     auto lineText = lines[(int) line];

  621.                     auto start = text.indexOf (lineText);

  622. 

  623.                     if (start >= 0)

  624.                         return NSMakeRange ((NSUInteger) start, (NSUInteger) lineText.length());

  625.                 }

  626.             }

  627. 

  628.             return NSMakeRange (0, 0);

  629.         }

  630. 

  631.         static NSString* getAccessibilityStringForRange (id self, SEL, NSRange range)

  632.         {

  633.             if (auto* textInterface = getTextInterface (self))

  634.                 return juceStringToNS (textInterface->getText (nsRangeToJuce (range)));

  635. 

  636.             return nil;

  637.         }

  638. 

  639.         static NSRange getAccessibilityRangeForPosition (id self, SEL, NSPoint position)

  640.         {

  641.             if (auto* handler = getHandler (self))

  642.             {

  643.                 if (auto* textInterface = handler->getTextInterface())

  644.                 {

  645.                     auto screenPoint = convertToIntPoint (flippedScreenPoint (position));

  646. 

  647.                     if (handler->getComponent().getScreenBounds().contains (screenPoint))

  648.                     {

  649.                         auto offset = textInterface->getOffsetAtPoint (screenPoint);

  650. 

  651.                         if (offset >= 0)

  652.                             return NSMakeRange ((NSUInteger) offset, 1);

  653.                     }

  654.                 }

  655.             }

  656. 

  657.             return NSMakeRange (0, 0);

  658.         }

  659. 

  660.         static NSRange getAccessibilityRangeForIndex (id self, SEL, NSInteger index)

  661.         {

  662.             if (auto* textInterface = getTextInterface (self))

  663.                 if (isPositiveAndBelow (index, textInterface->getTotalNumCharacters()))

  664.                     return NSMakeRange ((NSUInteger) index, 1);

  665. 

  666.             return NSMakeRange (0, 0);

  667.         }

  668. 

  669.         static NSRect getAccessibilityFrameForRange (id self, SEL, NSRange range)

  670.         {

  671.             if (auto* textInterface = getTextInterface (self))

  672.                 return flippedScreenRect (makeNSRect (textInterface->getTextBounds (nsRangeToJuce (range)).getBounds()));

  673. 

  674.             return NSZeroRect;

  675.         }

  676. 

  677.         static NSData* getAccessibilityRTFForRange (id, SEL, NSRange)

  678.         {

  679.             return nil;

  680.         }

  681. 

  682.         static NSRange getAccessibilityStyleRangeForIndex (id self, SEL, NSInteger)

  683.         {

  684.             return [self accessibilityVisibleCharacterRange];

  685.         }

  686. 

  687.         static NSInteger getAccessibilityLineForIndex (id self, SEL, NSInteger index)

  688.         {

  689.             if (auto* textInterface = getTextInterface (self))

  690.             {

  691.                 auto text = textInterface->getText ({ 0, (int) index });

  692. 

  693.                 if (! text.isEmpty())

  694.                     return StringArray::fromLines (text).size() - 1;

  695.             }

  696. 

  697.             return 0;

  698.         }

  699. 

  700.         static void setAccessibilitySelectedTextRange (id self, SEL, NSRange selectedRange)

  701.         {

  702.             if (auto* textInterface = getTextInterface (self))

  703.             {

  704.                 textInterface->setSelection ({});

  705.                 textInterface->setSelection (nsRangeToJuce (selectedRange));

  706.             }

  707.         }

  708. 

  709.         //==============================================================================

  710.         static NSInteger getAccessibilityRowCount (id self, SEL)

  711.         {

  712.             if (auto* tableInterface = getTableInterface (self))

  713.                 return tableInterface->getNumRows();

  714. 

  715.             return 0;

  716.         }

  717. 

  718.         static NSArray* getAccessibilityRows (id self, SEL)

  719.         {

  720.             NSMutableArray* rows = [[NSMutableArray new] autorelease];

  721. 

  722.             if (auto* tableInterface = getTableInterface (self))

  723.             {

  724.                 for (int row = 0; row < tableInterface->getNumRows(); ++row)

  725.                 {

  726.                     if (auto* handler = tableInterface->getCellHandler (row, 0))

  727.                     {

  728.                         [rows addObject: (id) handler->getNativeImplementation()];

  729.                     }

  730.                     else

  731.                     {

  732.                         [rows addObject: [NSAccessibilityElement accessibilityElementWithRole: NSAccessibilityRowRole

  733.                                                                                          frame: NSZeroRect

  734.                                                                                          label: @"Offscreen Row"

  735.                                                                                         parent: self]];

  736.                     }

  737.                 }

  738.             }

  739. 

  740.             return rows;

  741.         }

  742. 

  743.         static NSArray* getAccessibilitySelectedRows (id self, SEL)

  744.         {

  745.             return getSelectedChildren ([self accessibilityRows]);

  746.         }

  747. 

  748.         static void setAccessibilitySelectedRows (id self, SEL, NSArray* selected)

  749.         {

  750.             setSelectedChildren ([self accessibilityRows], selected);

  751.         }

  752. 

  753.         static NSInteger getAccessibilityColumnCount (id self, SEL)

  754.         {

  755.             if (auto* tableInterface = getTableInterface (self))

  756.                 return tableInterface->getNumColumns();

  757. 

  758.             return 0;

  759.         }

  760. 

  761.         static NSArray* getAccessibilityColumns (id self, SEL)

  762.         {

  763.             NSMutableArray* columns = [[NSMutableArray new] autorelease];

  764. 

  765.             if (auto* tableInterface = getTableInterface (self))

  766.             {

  767.                 for (int column = 0; column < tableInterface->getNumColumns(); ++column)

  768.                 {

  769.                     if (auto* handler = tableInterface->getCellHandler (0, column))

  770.                     {

  771.                         [columns addObject: (id) handler->getNativeImplementation()];

  772.                     }

  773.                     else

  774.                     {

  775.                         [columns addObject: [NSAccessibilityElement accessibilityElementWithRole: NSAccessibilityColumnRole

  776.                                                                                             frame: NSZeroRect

  777.                                                                                             label: @"Offscreen Column"

  778.                                                                                            parent: self]];

  779.                     }

  780.                 }

  781.             }

  782. 

  783.             return columns;

  784.         }

  785. 

  786.         static NSArray* getAccessibilitySelectedColumns (id self, SEL)

  787.         {

  788.             return getSelectedChildren ([self accessibilityColumns]);

  789.         }

  790. 

  791.         static void setAccessibilitySelectedColumns (id self, SEL, NSArray* selected)

  792.         {

  793.             setSelectedChildren ([self accessibilityColumns], selected);

  794.         }

  795. 

  796.         //==============================================================================

  797.         static NSRange getAccessibilityRowIndexRange (id self, SEL)

  798.         {

  799.             if (auto* cellInterface = getCellInterface (self))

  800.                 return NSMakeRange ((NSUInteger) cellInterface->getRowIndex(),

  801.                                     (NSUInteger) cellInterface->getRowSpan());

  802. 

  803.             return NSMakeRange (0, 0);

  804.         }

  805. 

  806.         static NSRange getAccessibilityColumnIndexRange (id self, SEL)

  807.         {

  808.             if (auto* cellInterface = getCellInterface (self))

  809.                 return NSMakeRange ((NSUInteger) cellInterface->getColumnIndex(),

  810.                                     (NSUInteger) cellInterface->getColumnSpan());

  811. 

  812.             return NSMakeRange (0, 0);

  813.         }

  814. 

  815.         static NSInteger getAccessibilityIndex (id self, SEL)

  816.         {

  817.             if (auto* handler = getHandler (self))

  818.             {

  819.                 if (auto* cellInterface = handler->getCellInterface())

  820.                 {

  821.                     NSAccessibilityRole role = [self accessibilityRole];

  822. 

  823.                     if ([role isEqual: NSAccessibilityRowRole])

  824.                         return cellInterface->getRowIndex();

  825. 

  826.                     if ([role isEqual: NSAccessibilityColumnRole])

  827.                         return cellInterface->getColumnIndex();

  828.                 }

  829.             }

  830. 

  831.             return 0;

  832.         }

  833. 

  834.         static NSInteger getAccessibilityDisclosureLevel (id self, SEL)

  835.         {

  836.             if (auto* handler = getHandler (self))

  837.                 if (auto* cellInterface = handler->getCellInterface())

  838.                     return cellInterface->getDisclosureLevel();

  839. 

  840.             return 0;

  841.         }

  842. 

  843.         static BOOL getIsAccessibilityExpanded (id self, SEL)

  844.         {

  845.             if (auto* handler = getHandler (self))

  846.                 return handler->getCurrentState().isExpanded();

  847. 

  848.             return NO;

  849.         }

  850. 

  851.         //==============================================================================

  852.         static BOOL accessibilityPerformPress (id self, SEL)     { return performActionIfSupported (self, AccessibilityActionType::press); }

  853.         static BOOL accessibilityPerformShowMenu (id self, SEL)  { return performActionIfSupported (self, AccessibilityActionType::showMenu); }

  854. 

  855.         static BOOL accessibilityPerformRaise (id self, SEL)     { [self setAccessibilityFocused: YES]; return YES; }

  856. 

  857.         static BOOL accessibilityPerformIncrement (id self, SEL)

  858.         {

  859.             if (auto* valueInterface = getValueInterface (self))

  860.             {

  861.                 if (! valueInterface->isReadOnly())

  862.                 {

  863.                     auto range = valueInterface->getRange();

  864. 

  865.                     if (range.isValid())

  866.                     {

  867.                         valueInterface->setValue (jlimit (range.getMinimumValue(),

  868.                                                           range.getMaximumValue(),

  869.                                                           valueInterface->getCurrentValue() + range.getInterval()));

  870.                         return YES;

  871.                     }

  872.                 }

  873.             }

  874. 

  875.             return NO;

  876.         }

  877. 

  878.         static BOOL accessibilityPerformDecrement (id self, SEL)

  879.         {

  880.             if (auto* valueInterface = getValueInterface (self))

  881.             {

  882.                 if (! valueInterface->isReadOnly())

  883.                 {

  884.                     auto range = valueInterface->getRange();

  885. 

  886.                     if (range.isValid())

  887.                     {

  888.                         valueInterface->setValue (jlimit (range.getMinimumValue(),

  889.                                                           range.getMaximumValue(),

  890.                                                           valueInterface->getCurrentValue() - range.getInterval()));

  891.                         return YES;

  892.                     }

  893.                 }

  894.             }

  895. 

  896.             return NO;

  897.         }

  898. 

  899.         static BOOL accessibilityPerformDelete (id self, SEL)

  900.         {

  901.             if (auto* handler = getHandler (self))

  902.             {

  903.                 if (hasEditableText (*handler))

  904.                 {

  905.                     handler->getTextInterface()->setText ({});

  906.                     return YES;

  907.                 }

  908. 

  909.                 if (auto* valueInterface = handler->getValueInterface())

  910.                 {

  911.                     if (! valueInterface->isReadOnly())

  912.                     {

  913.                         valueInterface->setValue ({});

  914.                         return YES;

  915.                     }

  916.                 }

  917.             }

  918. 

  919.             return NO;

  920.         }

  921. 

  922.         //==============================================================================

  923.         static BOOL getIsAccessibilitySelectorAllowed (id self, SEL, SEL selector)

  924.         {

  925.             if (auto* handler = getHandler (self))

  926.             {

  927.                 const auto role = handler->getRole();

  928.                 const auto currentState = handler->getCurrentState();

  929. 

  930.                 for (auto textSelector : { @selector (accessibilityInsertionPointLineNumber),

  931.                                            @selector (accessibilitySharedCharacterRange),

  932.                                            @selector (accessibilitySharedTextUIElements),

  933.                                            @selector (accessibilityVisibleCharacterRange),

  934.                                            @selector (accessibilityNumberOfCharacters),

  935.                                            @selector (accessibilitySelectedText),

  936.                                            @selector (accessibilitySelectedTextRange),

  937.                                            @selector (accessibilitySelectedTextRanges),

  938.                                            @selector (accessibilityAttributedStringForRange:),

  939.                                            @selector (accessibilityRangeForLine:),

  940.                                            @selector (accessibilityStringForRange:),

  941.                                            @selector (accessibilityRangeForPosition:),

  942.                                            @selector (accessibilityRangeForIndex:),

  943.                                            @selector (accessibilityFrameForRange:),

  944.                                            @selector (accessibilityRTFForRange:),

  945.                                            @selector (accessibilityStyleRangeForIndex:),

  946.                                            @selector (accessibilityLineForIndex:),

  947.                                            @selector (setAccessibilitySelectedTextRange:) })

  948.                 {

  949.                     if (selector == textSelector)

  950.                         return handler->getTextInterface() != nullptr;

  951.                 }

  952. 

  953.                 for (auto tableSelector : { @selector (accessibilityRowCount),

  954.                                             @selector (accessibilityRows),

  955.                                             @selector (accessibilitySelectedRows),

  956.                                             @selector (accessibilityColumnCount),

  957.                                             @selector (accessibilityColumns),

  958.                                             @selector (accessibilitySelectedColumns) })

  959.                 {

  960.                     if (selector == tableSelector)

  961.                         return handler->getTableInterface() != nullptr;

  962.                 }

  963. 

  964.                 for (auto cellSelector : { @selector (accessibilityRowIndexRange),

  965.                                            @selector (accessibilityColumnIndexRange),

  966.                                            @selector (accessibilityIndex),

  967.                                            @selector (accessibilityDisclosureLevel) })

  968.                 {

  969.                     if (selector == cellSelector)

  970.                         return handler->getCellInterface() != nullptr;

  971.                 }

  972. 

  973.                 for (auto valueSelector : { @selector (accessibilityValue),

  974.                                             @selector (setAccessibilityValue:),

  975.                                             @selector (accessibilityPerformDelete),

  976.                                             @selector (accessibilityPerformIncrement),

  977.                                             @selector (accessibilityPerformDecrement) })

  978.                 {

  979.                     if (selector != valueSelector)

  980.                         continue;

  981. 

  982.                     auto* valueInterface = handler->getValueInterface();

  983. 

  984.                     if (selector == @selector (accessibilityValue))

  985.                         return valueInterface != nullptr

  986.                             || hasEditableText (*handler)

  987.                             || nameIsAccessibilityValue (role)

  988.                             || currentState.isCheckable();

  989. 

  990.                     auto hasEditableValue = [valueInterface] { return valueInterface != nullptr && ! valueInterface->isReadOnly(); };

  991. 

  992.                     if (selector == @selector (setAccessibilityValue:)

  993.                      || selector == @selector (accessibilityPerformDelete))

  994.                         return hasEditableValue() || hasEditableText (*handler);

  995. 

  996.                     auto isRanged = [valueInterface] { return valueInterface != nullptr && valueInterface->getRange().isValid(); };

  997. 

  998.                     if (selector == @selector (accessibilityPerformIncrement)

  999.                      || selector == @selector (accessibilityPerformDecrement))

  1000.                         return hasEditableValue() && isRanged();

  1001. 

  1002.                     return NO;

  1003.                 }

  1004. 

  1005.                 for (auto actionSelector : { @selector (accessibilityPerformPress),

  1006.                                              @selector (accessibilityPerformShowMenu),

  1007.                                              @selector (accessibilityPerformRaise),

  1008.                                              @selector (setAccessibilityFocused:) })

  1009.                 {

  1010.                     if (selector != actionSelector)

  1011.                         continue;

  1012. 

  1013.                     if (selector == @selector (accessibilityPerformPress))

  1014.                         return handler->getActions().contains (AccessibilityActionType::press);

  1015. 

  1016.                     if (selector == @selector (accessibilityPerformShowMenu))

  1017.                         return handler->getActions().contains (AccessibilityActionType::showMenu);

  1018. 

  1019.                     if (selector == @selector (accessibilityPerformRaise))

  1020.                         return [[self accessibilityRole] isEqual: NSAccessibilityWindowRole];

  1021. 

  1022.                     if (selector == @selector (setAccessibilityFocused:))

  1023.                         return currentState.isFocusable();

  1024.                 }

  1025. 

  1026.                 if (selector == @selector (accessibilitySelectedChildren))

  1027.                     return role == AccessibilityRole::popupMenu;

  1028. 

  1029.                 if (selector == @selector (accessibilityOrientation))

  1030.                     return role == AccessibilityRole::scrollBar;

  1031. 

  1032.                 if (selector == @selector (isAccessibilityExpanded))

  1033.                     return currentState.isExpandable();

  1034. 

  1035.                 return sendSuperclassMessage<BOOL> (self, @selector (isAccessibilitySelectorAllowed:), selector);

  1036.             }

  1037. 

  1038.             return NO;

  1039.         }

  1040. 

  1041.         //==============================================================================

  1042.         JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityElement)

  1043.     };

  1044. 

  1045.     //==============================================================================

  1046.     AccessibilityElement::Holder accessibilityElement;

  1047. 

  1048.     //==============================================================================

  1049.     JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityNativeImpl)

  1050. };

  1051. 

  1052. //==============================================================================

  1053. AccessibilityNativeHandle* AccessibilityHandler::getNativeImplementation() const

  1054. {

  1055.     return (AccessibilityNativeHandle*) nativeImpl->getAccessibilityElement();

  1056. }

  1057. 

  1058. static void sendAccessibilityEvent (id accessibilityElement,

  1059.                                     NSAccessibilityNotificationName notification,

  1060.                                     NSDictionary* userInfo)

  1061. {

  1062.     jassert (notification != NSAccessibilityNotificationName{});

  1063. 

  1064.     NSAccessibilityPostNotificationWithUserInfo (accessibilityElement, notification, userInfo);

  1065. }

  1066. 

  1067. void notifyAccessibilityEventInternal (const AccessibilityHandler& handler, InternalAccessibilityEvent eventType)

  1068. {

  1069.     auto notification = [eventType]

  1070.     {

  1071.         switch (eventType)

  1072.         {

  1073.             case InternalAccessibilityEvent::elementCreated:    return NSAccessibilityCreatedNotification;

  1074.             case InternalAccessibilityEvent::elementDestroyed:  return NSAccessibilityUIElementDestroyedNotification;

  1075.             case InternalAccessibilityEvent::focusChanged:      return NSAccessibilityFocusedUIElementChangedNotification;

  1076.             case InternalAccessibilityEvent::windowOpened:      return NSAccessibilityWindowCreatedNotification;

  1077.             case InternalAccessibilityEvent::windowClosed:      break;

  1078.         }

  1079. 

  1080.         return NSAccessibilityNotificationName{};

  1081.     }();

  1082. 

  1083.     if (notification != NSAccessibilityNotificationName{})

  1084.         sendAccessibilityEvent ((id) handler.getNativeImplementation(), notification, nil);

  1085. }

  1086. 

  1087. void AccessibilityHandler::notifyAccessibilityEvent (AccessibilityEvent eventType) const

  1088. {

  1089.     auto notification = [eventType]

  1090.     {

  1091.         switch (eventType)

  1092.         {

  1093.             case AccessibilityEvent::textSelectionChanged:  return NSAccessibilitySelectedTextChangedNotification;

  1094.             case AccessibilityEvent::rowSelectionChanged:   return NSAccessibilitySelectedRowsChangedNotification;

  1095. 

  1096.             case AccessibilityEvent::textChanged:

  1097.             case AccessibilityEvent::valueChanged:          return NSAccessibilityValueChangedNotification;

  1098.             case AccessibilityEvent::structureChanged:      return NSAccessibilityLayoutChangedNotification;

  1099.         }

  1100. 

  1101.         return NSAccessibilityNotificationName{};

  1102.     }();

  1103. 

  1104.     if (notification != NSAccessibilityNotificationName{})

  1105.     {

  1106.         id accessibilityElement = (id) getNativeImplementation();

  1107. 

  1108.         sendAccessibilityEvent (accessibilityElement, notification,

  1109.                                 (notification == NSAccessibilityLayoutChangedNotification

  1110.                                    ? @{ NSAccessibilityUIElementsKey: accessibilityElement }

  1111.                                    : nil));

  1112.     }

  1113. }

  1114. 

  1115. void AccessibilityHandler::postAnnouncement (const String& announcementString, AnnouncementPriority priority)

  1116. {

  1117.     auto nsPriority = [priority]

  1118.     {

  1119.         switch (priority)

  1120.         {

  1121.             case AnnouncementPriority::low:    return NSAccessibilityPriorityLow;

  1122.             case AnnouncementPriority::medium: return NSAccessibilityPriorityMedium;

  1123.             case AnnouncementPriority::high:   return NSAccessibilityPriorityHigh;

  1124.         }

  1125. 

  1126.         jassertfalse;

  1127.         return NSAccessibilityPriorityLow;

  1128.     }();

  1129. 

  1130.     sendAccessibilityEvent ((id) [NSApp mainWindow],

  1131.                             NSAccessibilityAnnouncementRequestedNotification,

  1132.                             @{ NSAccessibilityAnnouncementKey: juceStringToNS (announcementString),

  1133.                                NSAccessibilityPriorityKey:     @(nsPriority) });

  1134. }

  1135. 

  1136. AccessibilityHandler::AccessibilityNativeImpl* AccessibilityHandler::createNativeImpl (AccessibilityHandler& handler)

  1137. {

  1138.     return new AccessibilityHandler::AccessibilityNativeImpl (handler);

  1139. }

  1140. 

  1141. void AccessibilityHandler::DestroyNativeImpl::operator() (AccessibilityHandler::AccessibilityNativeImpl* impl) const noexcept

  1142. {

  1143.     delete impl;

  1144. }

  1145. 

  1146. #endif

  1147. 

  1148. } // namespace juce