DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
8914 Commits
11 Branches
314MB
Tree: e05a1549f2
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'e05a1549f2'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

1827 lines
80KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2017 - ROLI Ltd.

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 5 End-User License

  11.    Agreement and JUCE 5 Privacy Policy (both updated and effective as of the

  12.    27th April 2017).

  13. 

  14.    End User License Agreement: www.juce.com/juce-5-licence

  15.    Privacy Policy: www.juce.com/juce-5-privacy-policy

  16. 

  17.    Or: You may also use this code under the terms of the GPL v3 (see

  18.    www.gnu.org/licenses).

  19. 

  20.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  21.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  22.    DISCLAIMED.

  23. 

  24.   ==============================================================================

  25. */

  26. 

  27. #include "../../juce_core/system/juce_TargetPlatform.h"

  28. #include "../utility/juce_CheckSettingMacros.h"

  29. 

  30. #if JucePlugin_Build_AUv3

  31. 

  32. #import <CoreAudioKit/CoreAudioKit.h>

  33. #import <AudioToolbox/AudioToolbox.h>

  34. #import <AVFoundation/AVFoundation.h>

  35. 

  36. #if JUCE_MAC

  37.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  38.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  39.  #endif

  40.  #if (defined MAC_OS_X_VERSION_10_13) && (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_13)

  41.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  42.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  43.  #endif

  44. #endif

  45. 

  46. #if JUCE_IOS

  47.  #if (! defined __IPHONE_OS_VERSION_MIN_REQUIRED) || (! defined __IPHONE_9_0) || (__IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_9_0)

  48.   #error AUv3 needs Deployment Target iOS 9.0 or higher to compile

  49.  #endif

  50.  #if (defined __IPHONE_11_0) && (__IPHONE_OS_VERSION_MIN_REQUIRED >= __IPHONE_11_0)

  51.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  52.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  53.  #endif

  54. #endif

  55. 

  56. #ifndef __OBJC2__

  57.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  58. #endif

  59. 

  60. #define JUCE_CORE_INCLUDE_OBJC_HELPERS 1

  61. 

  62. #include "../utility/juce_IncludeSystemHeaders.h"

  63. #include "../utility/juce_IncludeModuleHeaders.h"

  64. #include "../../juce_graphics/native/juce_mac_CoreGraphicsHelpers.h"

  65. 

  66. #include "../../juce_audio_basics/native/juce_mac_CoreAudioLayouts.h"

  67. #include "../../juce_audio_processors/format_types/juce_LegacyAudioParameter.cpp"

  68. #include "../../juce_audio_processors/format_types/juce_AU_Shared.h"

  69. 

  70. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  71. 

  72. #if JUCE_IOS

  73.  #define JUCE_IOS_MAC_VIEW  UIView

  74. #else

  75.  #define JUCE_IOS_MAC_VIEW  NSView

  76. #endif

  77. 

  78. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  79. 

  80. #pragma clang diagnostic push

  81. #pragma clang diagnostic ignored "-Wnullability-completeness"

  82. 

  83. using namespace juce;

  84. 

  85. // TODO: use SFINAE to automatically generate this for all NSObjects

  86. template <> struct ContainerDeletePolicy<AUAudioUnitBusArray>                   { static void destroy (NSObject* o) { [o release]; } };

  87. template <> struct ContainerDeletePolicy<AUParameterTree>                       { static void destroy (NSObject* o) { [o release]; } };

  88. template <> struct ContainerDeletePolicy<NSMutableArray<AUParameterNode*>>      { static void destroy (NSObject* o) { [o release]; } };

  89. template <> struct ContainerDeletePolicy<AUParameter>                           { static void destroy (NSObject* o) { [o release]; } };

  90. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitBus*>>       { static void destroy (NSObject* o) { [o release]; } };

  91. template <> struct ContainerDeletePolicy<AUAudioUnitBus>                        { static void destroy (NSObject* o) { [o release]; } };

  92. template <> struct ContainerDeletePolicy<AVAudioFormat>                         { static void destroy (NSObject* o) { [o release]; } };

  93. template <> struct ContainerDeletePolicy<AVAudioPCMBuffer>                      { static void destroy (NSObject* o) { [o release]; } };

  94. template <> struct ContainerDeletePolicy<NSMutableArray<NSNumber*>>             { static void destroy (NSObject* o) { [o release]; } };

  95. template <> struct ContainerDeletePolicy<NSNumber>                              { static void destroy (NSObject* o) { [o release]; } };

  96. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitPreset*>>    { static void destroy (NSObject* o) { [o release]; } };

  97. template <> struct ContainerDeletePolicy<AUAudioUnitPreset>                     { static void destroy (NSObject* o) { [o release]; } };

  98. 

  99. //==============================================================================

  100. struct AudioProcessorHolder  : public ReferenceCountedObject

  101. {

  102.     AudioProcessorHolder() {}

  103.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  104.     AudioProcessor& operator*() noexcept        { return *processor; }

  105.     AudioProcessor* operator->() noexcept       { return processor; }

  106.     AudioProcessor* get() noexcept              { return processor; }

  107. 

  108.     struct ViewConfig

  109.     {

  110.         double width;

  111.         double height;

  112.         bool hostHasMIDIController;

  113.     };

  114. 

  115.     ScopedPointer<ViewConfig> viewConfiguration;

  116. 

  117.     typedef ReferenceCountedObjectPtr<AudioProcessorHolder> Ptr;

  118. 

  119. private:

  120.     ScopedPointer<AudioProcessor> processor;

  121. 

  122.     AudioProcessorHolder& operator= (AudioProcessor*) = delete;

  123.     AudioProcessorHolder (AudioProcessorHolder&) = delete;

  124.     AudioProcessorHolder& operator= (AudioProcessorHolder&) = delete;

  125. };

  126. 

  127. //==============================================================================

  128. class JuceAudioUnitv3Base

  129. {

  130. public:

  131.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  132.                          AudioComponentInstantiationOptions options,

  133.                          NSError** error)

  134.        #pragma clang diagnostic push

  135.        #pragma clang diagnostic ignored "-Wobjc-method-access"

  136.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  137.                                                                         options: options

  138.                                                                           error: error

  139.                                                                       juceClass: this])

  140.        #pragma clang diagnostic pop

  141.     {}

  142. 

  143.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  144.     {

  145.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  146.         initialiseJuce_GUI();

  147.     }

  148. 

  149.     virtual ~JuceAudioUnitv3Base() {}

  150. 

  151.     //==============================================================================

  152.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  153. 

  154.     //==============================================================================

  155.     virtual void reset()                                                   = 0;

  156. 

  157.     //==============================================================================

  158.     virtual AUAudioUnitPreset* getCurrentPreset()                          = 0;

  159.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      = 0;

  160.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()               = 0;

  161. 

  162.     virtual NSDictionary<NSString*, id>* getFullState()

  163.     {

  164.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  165.         return ObjCMsgSendSuper<NSDictionary<NSString*, id>*> (&s, @selector (fullState));

  166.     }

  167. 

  168.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  169.     {

  170.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  171.         ObjCMsgSendSuper<void, NSDictionary<NSString*, id>*> (&s, @selector (setFullState:), state);

  172.     }

  173. 

  174.     virtual AUParameterTree* getParameterTree()                            = 0;

  175.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)       = 0;

  176. 

  177.     //==============================================================================

  178.     virtual NSTimeInterval getLatency()                                    = 0;

  179.     virtual NSTimeInterval getTailTime()                                   = 0;

  180. 

  181.     //==============================================================================

  182.     virtual AUAudioUnitBusArray* getInputBusses()                          = 0;

  183.     virtual AUAudioUnitBusArray* getOutputBusses()                         = 0;

  184.     virtual NSArray<NSNumber*>* getChannelCapabilities()                   = 0;

  185.     virtual bool shouldChangeToFormat (AVAudioFormat*, AUAudioUnitBus*)    = 0;

  186. 

  187.     //==============================================================================

  188.     virtual int getVirtualMIDICableCount()                                 = 0;

  189.     virtual bool getSupportsMPE()                                          = 0;

  190.     virtual NSArray<NSString*>* getMIDIOutputNames()                       = 0;

  191. 

  192.     //==============================================================================

  193.     virtual AUInternalRenderBlock getInternalRenderBlock()                 = 0;

  194.     virtual bool getCanProcessInPlace()                                    { return false; }

  195.     virtual bool getRenderingOffline()                                     = 0;

  196.     virtual void setRenderingOffline (bool offline)                        = 0;

  197. 

  198.     //==============================================================================

  199.     virtual NSString* getContextName()      const                          = 0;

  200.     virtual void setContextName (NSString*)                                = 0;

  201. 

  202.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  203.     {

  204.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  205.         return (ObjCMsgSendSuper<BOOL, NSError**> (&s, @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  206.     }

  207. 

  208.     virtual void deallocateRenderResources()

  209.     {

  210.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  211.         ObjCMsgSendSuper<void> (&s, @selector (deallocateRenderResources));

  212.     }

  213. 

  214.     //==============================================================================

  215.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  216.     virtual NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>*) = 0;

  217.     virtual void selectViewConfiguration (AUAudioUnitViewConfiguration*)   = 0;

  218.    #endif

  219. 

  220. private:

  221.     struct Class  : public ObjCClass<AUAudioUnit>

  222.     {

  223.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  224.         {

  225.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  226. 

  227.            #pragma clang diagnostic push

  228.            #pragma clang diagnostic ignored "-Wundeclared-selector"

  229.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  230.                        initWithComponentDescriptionAndJuceClass, "@@:",

  231.                        @encode (AudioComponentDescription),

  232.                        @encode (AudioComponentInstantiationOptions), "^@@");

  233.            #pragma clang diagnostic pop

  234. 

  235.             addMethod (@selector (initWithComponentDescription:options:error:),

  236.                        initWithComponentDescription, "@@:",

  237.                        @encode (AudioComponentDescription),

  238.                        @encode (AudioComponentInstantiationOptions), "^@");

  239. 

  240.             addMethod (@selector (dealloc),                         dealloc,                        "v@:");

  241. 

  242.             //==============================================================================

  243.             addMethod (@selector (reset),                           reset,                          "v@:");

  244. 

  245.             //==============================================================================

  246.             addMethod (@selector (currentPreset),                   getCurrentPreset,               "@@:");

  247.             addMethod (@selector (setCurrentPreset:),               setCurrentPreset,               "v@:@");

  248.             addMethod (@selector (factoryPresets),                  getFactoryPresets,              "@@:");

  249.             addMethod (@selector (fullState),                       getFullState,                   "@@:");

  250.             addMethod (@selector (setFullState:),                   setFullState,                   "v@:@");

  251.             addMethod (@selector (parameterTree),                   getParameterTree,               "@@:");

  252.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  253. 

  254.             //==============================================================================

  255.             addMethod (@selector (latency),                         getLatency,                     @encode (NSTimeInterval), "@:");

  256.             addMethod (@selector (tailTime),                        getTailTime,                    @encode (NSTimeInterval),  "@:");

  257. 

  258.             //==============================================================================

  259.             addMethod (@selector (inputBusses),                     getInputBusses,                 "@@:");

  260.             addMethod (@selector (outputBusses),                    getOutputBusses,                "@@:");

  261.             addMethod (@selector (channelCapabilities),             getChannelCapabilities,         "@@:");

  262.             addMethod (@selector (shouldChangeToFormat:forBus:),    shouldChangeToFormat,           "B@:@@");

  263. 

  264.             //==============================================================================

  265.             addMethod (@selector (virtualMIDICableCount),           getVirtualMIDICableCount,       @encode (NSInteger), "@:");

  266.             addMethod (@selector (supportsMPE),                     getSupportsMPE,                 @encode (BOOL),      "@:");

  267. 

  268.            #if JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  269.             addMethod (@selector (MIDIOutputNames),                 getMIDIOutputNames,             "@@:");

  270.            #endif

  271. 

  272.             //==============================================================================

  273.             addMethod (@selector (internalRenderBlock),             getInternalRenderBlock,         @encode (AUInternalRenderBlock), "@:");

  274.             addMethod (@selector (canProcessInPlace),               getCanProcessInPlace,           @encode (BOOL), "@:");

  275.             addMethod (@selector (isRenderingOffline),              getRenderingOffline,            @encode (BOOL),  "@:");

  276.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  277.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "B@:^@");

  278.             addMethod (@selector (deallocateRenderResources),       deallocateRenderResources,      "v@:");

  279. 

  280.             //==============================================================================

  281.             addMethod (@selector (contextName),                     getContextName,                 "@@:");

  282.             addMethod (@selector (setContextName:),                  setContextName,                 "v@:@");

  283. 

  284.             //==============================================================================

  285.            #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  286.             addMethod (@selector (supportedViewConfigurations:),    getSupportedViewConfigurations, "@@:@");

  287.             addMethod (@selector (selectViewConfiguration:),        selectViewConfiguration,        "v@:@");

  288.            #endif

  289. 

  290.             registerClass();

  291.         }

  292. 

  293.         //==============================================================================

  294.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  295.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  296. 

  297.         //==============================================================================

  298.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  299.         {

  300.             AUAudioUnit* self = _self;

  301. 

  302.             objc_super s = { self, [AUAudioUnit class] };

  303.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  304.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  305. 

  306.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  307. 

  308.             setThis (self, juceAU);

  309.             return self;

  310.         }

  311. 

  312.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  313.         {

  314.             AUAudioUnit* self = _self;

  315. 

  316.             objc_super s = { self, [AUAudioUnit class] };

  317.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  318.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  319. 

  320. 

  321.             setThis (self, juceAU);

  322.             return self;

  323.         }

  324. 

  325.         static void dealloc (id self, SEL)

  326.         {

  327.             if (! MessageManager::getInstance()->isThisTheMessageThread())

  328.             {

  329.                 WaitableEvent deletionEvent;

  330. 

  331.                 struct AUDeleter  : public CallbackMessage

  332.                 {

  333.                     AUDeleter (id selfToDelete, WaitableEvent& event)

  334.                         : parentSelf (selfToDelete), parentDeletionEvent (event)

  335.                     {

  336.                     }

  337. 

  338.                     void messageCallback() override

  339.                     {

  340.                         delete _this (parentSelf);

  341.                         parentDeletionEvent.signal();

  342.                     }

  343. 

  344.                     id parentSelf;

  345.                     WaitableEvent& parentDeletionEvent;

  346.                 };

  347. 

  348.                 (new AUDeleter (self, deletionEvent))->post();

  349.                 deletionEvent.wait (-1);

  350.             }

  351.             else

  352.             {

  353.                 delete _this (self);

  354.             }

  355.         }

  356. 

  357.         //==============================================================================

  358.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  359. 

  360.         //==============================================================================

  361.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  362.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  363.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  364.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  365.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  366.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  367.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  368. 

  369.         //==============================================================================

  370.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  371.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  372. 

  373.         //==============================================================================

  374.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  375.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  376.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  377.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  378. 

  379.         //==============================================================================

  380.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  381.         static BOOL getSupportsMPE (id self, SEL)                                                   { return _this (self)->getSupportsMPE() ? YES : NO; }

  382.         static NSArray<NSString*>* getMIDIOutputNames (id self, SEL)                                { return _this (self)->getMIDIOutputNames(); }

  383. 

  384.         //==============================================================================

  385.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  386.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  387.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  388.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  389.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  390.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  391. 

  392.         //==============================================================================

  393.         static NSString* getContextName (id self, SEL)                                              { return _this (self)->getContextName(); }

  394.         static void setContextName (id self, SEL, NSString* str)                                    { return _this (self)->setContextName (str); }

  395. 

  396.         //==============================================================================

  397.        #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  398.         static NSIndexSet* getSupportedViewConfigurations (id self, SEL, NSArray<AUAudioUnitViewConfiguration*>* configs) { return _this (self)->getSupportedViewConfigurations (configs); }

  399.         static void selectViewConfiguration (id self, SEL, AUAudioUnitViewConfiguration* config)    { _this (self)->selectViewConfiguration (config); }

  400.        #endif

  401.     };

  402. 

  403.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  404. 

  405.     //==============================================================================

  406.     static Class audioUnitObjCClass;

  407. 

  408. protected:

  409.     AUAudioUnit* au;

  410. };

  411. 

  412. //==============================================================================

  413. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  414. 

  415. //==============================================================================

  416. //=========================== The actual AudioUnit =============================

  417. //==============================================================================

  418. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  419.                          public AudioProcessorListener,

  420.                          public AudioPlayHead

  421. {

  422. public:

  423.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  424.                      const AudioComponentDescription& descr,

  425.                      AudioComponentInstantiationOptions options,

  426.                      NSError** error)

  427.         : JuceAudioUnitv3Base (descr, options, error),

  428.           processorHolder (processor),

  429.           mapper (*processorHolder->get())

  430.     {

  431.         init();

  432.     }

  433. 

  434.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  435.         : JuceAudioUnitv3Base (audioUnit),

  436.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  437.           mapper (*processorHolder->get())

  438.     {

  439.         init();

  440.     }

  441. 

  442.     ~JuceAudioUnitv3()

  443.     {

  444.         auto& processor = getAudioProcessor();

  445.         processor.removeListener (this);

  446. 

  447.         removeEditor (processor);

  448. 

  449.         if (editorObserverToken != nullptr)

  450.         {

  451.             [paramTree removeParameterObserver: editorObserverToken];

  452.             editorObserverToken = nullptr;

  453.         }

  454.     }

  455. 

  456.     //==============================================================================

  457.     void init()

  458.     {

  459.         inParameterChangedCallback = false;

  460. 

  461.         AudioProcessor& processor = getAudioProcessor();

  462.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  463. 

  464.        #ifdef JucePlugin_PreferredChannelConfigurations

  465.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  466.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  467. 

  468.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  469.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  470. 

  471.         Array<AUChannelInfo> channelInfos;

  472. 

  473.         for (int i = 0; i < numConfigs; ++i)

  474.         {

  475.             AUChannelInfo channelInfo;

  476. 

  477.             channelInfo.inChannels  = configs[i][0];

  478.             channelInfo.outChannels = configs[i][1];

  479. 

  480.             channelInfos.add (channelInfo);

  481.         }

  482.        #else

  483.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  484.        #endif

  485. 

  486.         processor.setPlayHead (this);

  487. 

  488.         totalInChannels  = processor.getTotalNumInputChannels();

  489.         totalOutChannels = processor.getTotalNumOutputChannels();

  490. 

  491.         {

  492.             channelCapabilities = [[NSMutableArray<NSNumber*> alloc] init];

  493. 

  494. 

  495.             for (int i = 0; i < channelInfos.size(); ++i)

  496.             {

  497.                 AUChannelInfo& info = channelInfos.getReference (i);

  498. 

  499.                 [channelCapabilities addObject: [NSNumber numberWithInteger: info.inChannels]];

  500.                 [channelCapabilities addObject: [NSNumber numberWithInteger: info.outChannels]];

  501.             }

  502.         }

  503. 

  504.         editorObserverToken = nullptr;

  505.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  506. 

  507.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  508.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  509.         processor.addListener (this);

  510. 

  511.         addParameters();

  512.         addPresets();

  513. 

  514.         addAudioUnitBusses (true);

  515.         addAudioUnitBusses (false);

  516.     }

  517. 

  518.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  519. 

  520.     //==============================================================================

  521.     void reset() override

  522.     {

  523.         midiMessages.clear();

  524.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  525.     }

  526. 

  527.     //==============================================================================

  528.     AUAudioUnitPreset* getCurrentPreset() override

  529.     {

  530.         const int n = static_cast<int> ([factoryPresets count]);

  531.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  532. 

  533.         if (idx < n)

  534.             return [factoryPresets objectAtIndex:static_cast<unsigned int> (idx)];

  535. 

  536.         return nullptr;

  537.     }

  538. 

  539.     void setCurrentPreset(AUAudioUnitPreset* preset) override

  540.     {

  541.         const int n = static_cast<int> ([factoryPresets count]);

  542.         const int idx = static_cast<int> ([preset number]);

  543. 

  544.         if (isPositiveAndBelow (idx, n))

  545.             getAudioProcessor().setCurrentProgram (idx);

  546.     }

  547. 

  548.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override

  549.     {

  550.         return factoryPresets;

  551.     }

  552. 

  553.     NSDictionary<NSString*, id>* getFullState() override

  554.     {

  555.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  556. 

  557.         {

  558.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  559. 

  560.             if (superRetval != nullptr)

  561.                 [retval addEntriesFromDictionary:superRetval];

  562.         }

  563. 

  564.         juce::MemoryBlock state;

  565.         getAudioProcessor().getCurrentProgramStateInformation (state);

  566. 

  567.         if (state.getSize() > 0)

  568.         {

  569.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  570.                                                       length: state.getSize()];

  571. 

  572.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  573. 

  574.             [retval setObject: ourState

  575.                        forKey: nsKey];

  576. 

  577.             [nsKey    release];

  578.             [ourState release];

  579.         }

  580. 

  581.         return [retval autorelease];

  582.     }

  583. 

  584.     void setFullState (NSDictionary<NSString*, id>* state) override

  585.     {

  586.         if (state == nullptr)

  587.             return;

  588. 

  589.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  590.         [modifiedState addEntriesFromDictionary: state];

  591. 

  592.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  593.         [modifiedState removeObjectForKey: nsPresetKey];

  594.         [nsPresetKey release];

  595. 

  596.         JuceAudioUnitv3Base::setFullState (modifiedState);

  597. 

  598.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  599.         NSObject* obj = [modifiedState objectForKey: nsKey];

  600.         [nsKey release];

  601. 

  602.         if (obj != nullptr)

  603.         {

  604.             if ([obj isKindOfClass:[NSData class]])

  605.             {

  606.                 NSData* data = reinterpret_cast<NSData*> (obj);

  607.                 const int numBytes = static_cast<int> ([data length]);

  608.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  609. 

  610.                 if (numBytes > 0)

  611.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  612.             }

  613.         }

  614. 

  615.         [modifiedState release];

  616.     }

  617. 

  618.     AUParameterTree* getParameterTree() override

  619.     {

  620.         return paramTree;

  621.     }

  622. 

  623.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  624.     {

  625.         const int n = static_cast<int> ([overviewParams count]);

  626. 

  627.         if (count >= n)

  628.             return overviewParams;

  629. 

  630.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams];

  631.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  632. 

  633.         return [retval autorelease];

  634.     }

  635. 

  636.     //==============================================================================

  637.     NSTimeInterval getLatency() override

  638.     {

  639.         auto& p = getAudioProcessor();

  640.         return p.getLatencySamples() / p.getSampleRate();

  641.     }

  642. 

  643.     NSTimeInterval getTailTime() override

  644.     {

  645.         return getAudioProcessor().getTailLengthSeconds();

  646.     }

  647. 

  648.     //==============================================================================

  649.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses;  }

  650.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses; }

  651.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities; }

  652. 

  653.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  654.     {

  655.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  656.         const int busIdx = static_cast<int> ([auBus index]);

  657.         const int newNumChannels = static_cast<int> ([format channelCount]);

  658. 

  659.         AudioProcessor& processor = getAudioProcessor();

  660. 

  661.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  662.         {

  663.           #ifdef JucePlugin_PreferredChannelConfigurations

  664.             ignoreUnused (bus);

  665. 

  666.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  667. 

  668.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  669.                 return false;

  670.           #else

  671.             const AVAudioChannelLayout* layout    = [format channelLayout];

  672.             const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  673. 

  674.             if (layoutTag != 0)

  675.             {

  676.                 AudioChannelSet newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  677. 

  678.                 if (newLayout.size() != newNumChannels)

  679.                     return false;

  680. 

  681.                 if (! bus->isLayoutSupported (newLayout))

  682.                     return false;

  683.             }

  684.             else

  685.             {

  686.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  687.                     return false;

  688.             }

  689.            #endif

  690. 

  691.             return true;

  692.         }

  693. 

  694.         return false;

  695.     }

  696. 

  697.     //==============================================================================

  698.     int getVirtualMIDICableCount() override

  699.     {

  700.        #if JucePlugin_WantsMidiInput

  701.         return 1;

  702.        #else

  703.         return 0;

  704.        #endif

  705.     }

  706. 

  707.     bool getSupportsMPE() override

  708.     {

  709.         return getAudioProcessor().supportsMPE();

  710.     }

  711. 

  712.     NSArray<NSString*>* getMIDIOutputNames() override

  713.     {

  714.        #if JucePlugin_ProducesMidiOutput

  715.         return @[@"MIDI Out"];

  716.        #else

  717.         return @[];

  718.        #endif

  719.     }

  720. 

  721.     //==============================================================================

  722.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  723.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  724.     void setRenderingOffline (bool offline) override

  725.     {

  726.         auto& processor = getAudioProcessor();

  727.         auto isCurrentlyNonRealtime = processor.isNonRealtime();

  728. 

  729.         if (isCurrentlyNonRealtime != offline)

  730.         {

  731.             ScopedLock callbackLock (processor.getCallbackLock());

  732. 

  733.             processor.setNonRealtime (offline);

  734.             processor.prepareToPlay (processor.getSampleRate(), processor.getBlockSize());

  735.         }

  736.     }

  737. 

  738.     //==============================================================================

  739.     NSString* getContextName() const    override              { return juceStringToNS (contextName); }

  740.     void setContextName (NSString* str) override

  741.     {

  742.         if (str != nullptr)

  743.         {

  744.             AudioProcessor::TrackProperties props;

  745.             props.name = nsStringToJuce (str);

  746. 

  747.             getAudioProcessor().updateTrackProperties (props);

  748.         }

  749.     }

  750. 

  751.     //==============================================================================

  752.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  753.     {

  754.         AudioProcessor& processor = getAudioProcessor();

  755.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  756. 

  757.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  758.             return false;

  759. 

  760.         if (outError != nullptr)

  761.             *outError = nullptr;

  762. 

  763.         AudioProcessor::BusesLayout layouts;

  764.         for (int dir = 0; dir < 2; ++dir)

  765.         {

  766.             const bool isInput = (dir == 0);

  767.             const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  768.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  769. 

  770.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  771.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  772. 

  773.             for (int busIdx = 0; busIdx < n; ++busIdx)

  774.             {

  775.                 AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx);

  776.                 AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  777. 

  778.                 AudioChannelSet newLayout;

  779.                 const AVAudioChannelLayout* layout    = [format channelLayout];

  780.                 const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  781. 

  782.                 if (layoutTag != 0)

  783.                     newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  784.                 else

  785.                     newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  786. 

  787.                 if (newLayout.isDisabled())

  788.                     return false;

  789. 

  790.                 channelSets.add (newLayout);

  791.             }

  792.         }

  793. 

  794.        #ifdef JucePlugin_PreferredChannelConfigurations

  795.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  796. 

  797.         if (! AudioProcessor::containsLayout (layouts, configs))

  798.         {

  799.             if (outError != nullptr)

  800.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  801. 

  802.             return false;

  803.         }

  804.        #endif

  805. 

  806.         if (! AudioUnitHelpers::setBusesLayout (&getAudioProcessor(), layouts))

  807.         {

  808.             if (outError != nullptr)

  809.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  810. 

  811.             return false;

  812.         }

  813. 

  814.         totalInChannels  = processor.getTotalNumInputChannels();

  815.         totalOutChannels = processor.getTotalNumOutputChannels();

  816. 

  817.         allocateBusBuffer (true);

  818.         allocateBusBuffer (false);

  819. 

  820.         mapper.alloc();

  821. 

  822.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  823. 

  824.         double sampleRate = (jmax (AudioUnitHelpers::getBusCount (&processor, true), AudioUnitHelpers::getBusCount (&processor, false)) > 0 ?

  825.                              [[[([inputBusses count] > 0 ? inputBusses : outputBusses) objectAtIndexedSubscript: 0] format] sampleRate] : 44100.0);

  826. 

  827.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  828.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  829. 

  830.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  831.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  832.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  833. 

  834.         reset();

  835. 

  836.         return true;

  837.     }

  838. 

  839.     void deallocateRenderResources() override

  840.     {

  841.         hostMusicalContextCallback = nullptr;

  842.         hostTransportStateCallback = nullptr;

  843. 

  844.         getAudioProcessor().releaseResources();

  845.         audioBuffer.release();

  846. 

  847.         inBusBuffers. clear();

  848.         outBusBuffers.clear();

  849. 

  850.         mapper.release();

  851. 

  852.         JuceAudioUnitv3Base::deallocateRenderResources();

  853.     }

  854. 

  855.     //==============================================================================

  856.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  857.     NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>* configs) override

  858.     {

  859.         auto supportedViewIndecies = [[NSMutableIndexSet alloc] init];

  860.         auto n = [configs count];

  861. 

  862.         if (auto* editor = getAudioProcessor().createEditorIfNeeded())

  863.         {

  864.             // If you hit this assertion then your plug-in's editor is reporting that it doesn't support

  865.             // any host MIDI controller configurations!

  866.             jassert (editor->supportsHostMIDIControllerPresence (true) || editor->supportsHostMIDIControllerPresence (false));

  867. 

  868.             for (auto i = 0u; i < n; ++i)

  869.             {

  870.                 if (auto* viewConfiguration = [configs objectAtIndex:i])

  871.                 {

  872.                     if (editor->supportsHostMIDIControllerPresence ([viewConfiguration hostHasController] == YES))

  873.                     {

  874.                         auto* constrainer = editor->getConstrainer();

  875.                         auto height = (int) [viewConfiguration height];

  876.                         auto width  = (int) [viewConfiguration width];

  877. 

  878.                         if (height <= constrainer->getMaximumHeight() && height >= constrainer->getMinimumHeight()

  879.                          && width  <= constrainer->getMaximumWidth()  && width  >= constrainer->getMinimumWidth())

  880.                             [supportedViewIndecies addIndex: i];

  881.                     }

  882.                 }

  883.             }

  884.         }

  885. 

  886.         return [supportedViewIndecies autorelease];

  887.     }

  888. 

  889.     void selectViewConfiguration (AUAudioUnitViewConfiguration* config) override

  890.     {

  891.         processorHolder->viewConfiguration = new AudioProcessorHolder::ViewConfig { [config width], [config height], [config hostHasController] == YES };

  892.     }

  893.    #endif

  894. 

  895.     //==============================================================================

  896.     void audioProcessorChanged (AudioProcessor* processor) override

  897.     {

  898.         ignoreUnused (processor);

  899. 

  900.         [au willChangeValueForKey: @"allParameterValues"];

  901.         addPresets();

  902.         [au didChangeValueForKey: @"allParameterValues"];

  903.     }

  904. 

  905.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  906.     {

  907.         if (inParameterChangedCallback.get())

  908.         {

  909.             inParameterChangedCallback = false;

  910.             return;

  911.         }

  912. 

  913.         if (isPositiveAndBelow (idx, juceParameters.getNumParameters()))

  914.         {

  915.             if (AUParameter* param = [paramTree parameterWithAddress: getAUParameterAddressForIndex (idx)])

  916.             {

  917.                 if (editorObserverToken != nullptr)

  918.                     [param setValue: newValue  originator: editorObserverToken];

  919.                 else

  920.                     [param setValue: newValue];

  921.             }

  922.         }

  923.     }

  924. 

  925.     //==============================================================================

  926.     bool getCurrentPosition (CurrentPositionInfo& info) override

  927.     {

  928.         bool musicContextCallSucceeded = false;

  929.         bool transportStateCallSucceeded = false;

  930. 

  931.         info = lastAudioHead;

  932.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  933.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  934. 

  935.         switch (lastTimeStamp.mSMPTETime.mType)

  936.         {

  937.             case kSMPTETimeType2398:        info.frameRate = AudioPlayHead::fps23976; break;

  938.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24; break;

  939.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25; break;

  940.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997; break;

  941.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  942.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop; break;

  943.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30; break;

  944.             case kSMPTETimeType60Drop:      info.frameRate = AudioPlayHead::fps60drop; break;

  945.             case kSMPTETimeType60:          info.frameRate = AudioPlayHead::fps60; break;

  946.             default:                        info.frameRate = AudioPlayHead::fpsUnknown; break;

  947.         }

  948. 

  949.         double num;

  950.         NSInteger den;

  951.         NSInteger outDeltaSampleOffsetToNextBeat;

  952.         double outCurrentMeasureDownBeat, bpm;

  953.         double ppqPosition;

  954. 

  955.         if (hostMusicalContextCallback != nullptr)

  956.         {

  957.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  958. 

  959.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  960.             {

  961.                 musicContextCallSucceeded = true;

  962. 

  963.                 info.timeSigNumerator   = (int) num;

  964.                 info.timeSigDenominator = (int) den;

  965.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  966.                 info.bpm = bpm;

  967.                 info.ppqPosition = ppqPosition;

  968.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  969.             }

  970.         }

  971. 

  972.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  973.         AUHostTransportStateFlags flags;

  974. 

  975.         if (hostTransportStateCallback != nullptr)

  976.         {

  977.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  978. 

  979.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  980.             {

  981.                 transportStateCallSucceeded = true;

  982. 

  983.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  984.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  985.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  986.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  987.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  988.                 info.ppqLoopStart   = outCycleStartBeat;

  989.                 info.ppqLoopEnd     = outCycleEndBeat;

  990.             }

  991.         }

  992. 

  993.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  994.             lastAudioHead = info;

  995. 

  996.         return true;

  997.     }

  998. 

  999.     //==============================================================================

  1000.     static void removeEditor (AudioProcessor& processor)

  1001.     {

  1002.         ScopedLock editorLock (processor.getCallbackLock());

  1003. 

  1004.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  1005.         {

  1006.             processor.editorBeingDeleted (editor);

  1007.             delete editor;

  1008.         }

  1009.     }

  1010. 

  1011. private:

  1012.     //==============================================================================

  1013.     struct BusBuffer

  1014.     {

  1015.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  1016.             : auBus (bus),

  1017.               maxFrames (maxFramesPerBuffer),

  1018.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  1019.               isInterleaved ([[auBus format] isInterleaved])

  1020.         {

  1021.             alloc();

  1022.         }

  1023. 

  1024.         //==============================================================================

  1025.         void alloc()

  1026.         {

  1027.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1028.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  1029.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  1030.             jassert (bytes > 0);

  1031. 

  1032.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  1033.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  1034. 

  1035.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  1036.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  1037.         }

  1038. 

  1039.         void dealloc()

  1040.         {

  1041.             bufferList = nullptr;

  1042.             bufferListStorage.free();

  1043.             scratchBuffer.setSize (0, 0);

  1044.         }

  1045. 

  1046.         //==============================================================================

  1047.         int numChannels() const noexcept                { return numberOfChannels; }

  1048.         bool interleaved() const noexcept               { return isInterleaved; }

  1049.         AudioBufferList* get() const noexcept           { return bufferList; }

  1050. 

  1051.         //==============================================================================

  1052.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  1053.         {

  1054.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1055.             const bool isCompatible = isCompatibleWith (other);

  1056. 

  1057.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  1058. 

  1059.             for (int i = 0; i < numBuffers; ++i)

  1060.             {

  1061.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  1062.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  1063.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  1064.                                                               : scratchBuffer.getWritePointer (i));

  1065.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  1066.             }

  1067.         }

  1068. 

  1069.         //==============================================================================

  1070.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  1071.         {

  1072.             if (other == nullptr)

  1073.                 return false;

  1074. 

  1075.             if (other->mNumberBuffers > 0)

  1076.             {

  1077.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  1078.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  1079.                                                                              : other->mNumberBuffers);

  1080. 

  1081.                 return otherInterleaved == isInterleaved

  1082.                     && numberOfChannels == otherChannels;

  1083.             }

  1084. 

  1085.             return numberOfChannels == 0;

  1086.         }

  1087. 

  1088.     private:

  1089.         AUAudioUnitBus* auBus;

  1090.         HeapBlock<char> bufferListStorage;

  1091.         AudioBufferList* bufferList = nullptr;

  1092.         int maxFrames, numberOfChannels;

  1093.         bool isInterleaved;

  1094.         AudioBuffer<float> scratchBuffer;

  1095.     };

  1096. 

  1097.     //==============================================================================

  1098.     void addAudioUnitBusses (bool isInput)

  1099.     {

  1100.         ScopedPointer<NSMutableArray<AUAudioUnitBus*>> array = [[NSMutableArray<AUAudioUnitBus*> alloc] init];

  1101.         AudioProcessor& processor = getAudioProcessor();

  1102.         const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  1103. 

  1104.         for (int i = 0; i < n; ++i)

  1105.         {

  1106.             ScopedPointer<AUAudioUnitBus> audioUnitBus;

  1107. 

  1108.             {

  1109.                 ScopedPointer<AVAudioFormat> defaultFormat = [[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  1110.                                                                                                             channels: static_cast<AVAudioChannelCount> (processor.getChannelCountOfBus (isInput, i))];

  1111. 

  1112.                 audioUnitBus = [[AUAudioUnitBus alloc] initWithFormat: defaultFormat

  1113.                                                                 error: nullptr];

  1114.             }

  1115. 

  1116.             [array addObject: audioUnitBus];

  1117.         }

  1118. 

  1119.         (isInput ? inputBusses : outputBusses) = [[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  1120.                                                                                         busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  1121.                                                                                          busses: array];

  1122.     }

  1123. 

  1124.     // When parameters are discrete we need to use integer values.

  1125.     float getMaximumParameterValue (AudioProcessorParameter* juceParam)

  1126.     {

  1127.        #if JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1128.         ignoreUnused (juceParam);

  1129.         return 1.0f;

  1130.        #else

  1131.         return juceParam->isDiscrete() ? (float) (juceParam->getNumSteps() - 1) : 1.0f;

  1132.        #endif

  1133.     }

  1134. 

  1135.     void addParameters()

  1136.     {

  1137.         ScopedPointer<NSMutableArray<AUParameterNode*>> params = [[NSMutableArray<AUParameterNode*> alloc] init];

  1138. 

  1139.         overviewParams = [[NSMutableArray<NSNumber*> alloc] init];

  1140. 

  1141.         auto& processor = getAudioProcessor();

  1142.         juceParameters.update (processor, forceLegacyParamIDs);

  1143. 

  1144.         const int n = juceParameters.getNumParameters();

  1145. 

  1146.         for (int idx = 0; idx < n; ++idx)

  1147.         {

  1148.             auto* juceParam = juceParameters.getParamForIndex (idx);

  1149. 

  1150.             const String identifier (idx);

  1151.             const String name = juceParam->getName (512);

  1152. 

  1153.             AudioUnitParameterUnit unit = kAudioUnitParameterUnit_Generic;

  1154.             AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  1155.                                                       | kAudioUnitParameterFlag_IsReadable

  1156.                                                       | kAudioUnitParameterFlag_HasCFNameString

  1157.                                                       | kAudioUnitParameterFlag_ValuesHaveStrings);

  1158. 

  1159.             if (! forceLegacyParamIDs)

  1160.                 flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  1161. 

  1162.             // set whether the param is automatable (unnamed parameters aren't allowed to be automated)

  1163.             if (name.isEmpty() || ! juceParam->isAutomatable())

  1164.                 flags |= kAudioUnitParameterFlag_NonRealTime;

  1165. 

  1166.             const bool isParameterDiscrete = juceParam->isDiscrete();

  1167. 

  1168.             if (! isParameterDiscrete)

  1169.                 flags |= kAudioUnitParameterFlag_CanRamp;

  1170. 

  1171.             if (juceParam->isMetaParameter())

  1172.                 flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  1173. 

  1174.             auto deleter = [](NSMutableArray* arr) { [arr release]; };

  1175.             std::unique_ptr<NSMutableArray, decltype (deleter)> valueStrings (nullptr, deleter);

  1176. 

  1177.             // is this a meter?

  1178.             if (((juceParam->getCategory() & 0xffff0000) >> 16) == 2)

  1179.             {

  1180.                 flags &= ~kAudioUnitParameterFlag_IsWritable;

  1181.                 flags |= kAudioUnitParameterFlag_MeterReadOnly | kAudioUnitParameterFlag_DisplayLogarithmic;

  1182.                 unit = kAudioUnitParameterUnit_LinearGain;

  1183.             }

  1184.             else

  1185.             {

  1186.                 if (! forceLegacyParamIDs)

  1187.                 {

  1188.                     if (juceParam->isDiscrete())

  1189.                     {

  1190.                         unit = juceParam->isBoolean() ? kAudioUnitParameterUnit_Boolean : kAudioUnitParameterUnit_Indexed;

  1191.                         auto maxValue = getMaximumParameterValue (juceParam);

  1192.                         auto numSteps = juceParam->getNumSteps();

  1193. 

  1194.                         // Some hosts can't handle the huge numbers of discrete parameter values created when

  1195.                         // using the default number of steps.

  1196.                         jassert (numSteps != AudioProcessor::getDefaultNumParameterSteps());

  1197. 

  1198.                         valueStrings.reset ([NSMutableArray new]);

  1199. 

  1200.                         for (int i = 0; i < numSteps; ++i)

  1201.                             [valueStrings.get() addObject: juceStringToNS (juceParam->getText ((float) i / maxValue, 0))];

  1202.                     }

  1203.                 }

  1204.             }

  1205. 

  1206.             AUParameterAddress address = forceLegacyParamIDs ? static_cast<AUParameterAddress> (idx)

  1207.                                                              : generateAUParameterAddress (juceParam);

  1208. 

  1209.            #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1210.             // Consider yourself very unlucky if you hit this assertion. The hash codes of your

  1211.             // parameter ids are not unique.

  1212.             jassert (! paramMap.contains (static_cast<int64> (address)));

  1213. 

  1214.             paramAddresses.add (address);

  1215.             paramMap.set (static_cast<int64> (address), idx);

  1216.            #endif

  1217. 

  1218.             // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1219. 

  1220.             ScopedPointer<AUParameter> param = [[AUParameterTree createParameterWithIdentifier: juceStringToNS (identifier)

  1221.                                                                                           name: juceStringToNS (name)

  1222.                                                                                        address: address

  1223.                                                                                            min: 0.0f

  1224.                                                                                            max: getMaximumParameterValue (juceParam)

  1225.                                                                                           unit: unit

  1226.                                                                                       unitName: nullptr

  1227.                                                                                          flags: flags

  1228.                                                                                   valueStrings: valueStrings.get()

  1229.                                                                            dependentParameters: nullptr] retain];

  1230. 

  1231.             [param.get() setValue: juceParam->getDefaultValue()];

  1232. 

  1233.             [params addObject: param];

  1234.             [overviewParams addObject: [NSNumber numberWithUnsignedLongLong:address]];

  1235.         }

  1236. 

  1237.         // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1238.         paramTree = [[AUParameterTree createTreeWithChildren: params] retain];

  1239. 

  1240.         paramObserver           = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  1241.         paramProvider           = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  1242.         stringFromValueProvider = CreateObjCBlock (this, &JuceAudioUnitv3::stringFromValue);

  1243.         valueFromStringProvider = CreateObjCBlock (this, &JuceAudioUnitv3::valueFromString);

  1244. 

  1245.         [paramTree setImplementorValueObserver: paramObserver];

  1246.         [paramTree setImplementorValueProvider: paramProvider];

  1247.         [paramTree setImplementorStringFromValueCallback: stringFromValueProvider];

  1248.         [paramTree setImplementorValueFromStringCallback: valueFromStringProvider];

  1249. 

  1250.         if (processor.hasEditor())

  1251.         {

  1252.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  1253.             editorObserverToken = [paramTree tokenByAddingParameterObserver: editorParamObserver];

  1254.         }

  1255.     }

  1256. 

  1257.     void setAudioProcessorParameter (AudioProcessorParameter* juceParam, float value)

  1258.     {

  1259.         if (value != juceParam->getValue())

  1260.         {

  1261.             juceParam->setValue (value);

  1262. 

  1263.             inParameterChangedCallback = true;

  1264.             juceParam->sendValueChangedMessageToListeners (value);

  1265.         }

  1266.     }

  1267. 

  1268.     void addPresets()

  1269.     {

  1270.         factoryPresets = [[NSMutableArray<AUAudioUnitPreset*> alloc] init];

  1271. 

  1272.         const int n = getAudioProcessor().getNumPrograms();

  1273. 

  1274.         for (int idx = 0; idx < n; ++idx)

  1275.         {

  1276.             String name = getAudioProcessor().getProgramName (idx);

  1277. 

  1278.             ScopedPointer<AUAudioUnitPreset> preset = [[AUAudioUnitPreset alloc] init];

  1279.             [preset setName: juceStringToNS (name)];

  1280.             [preset setNumber: static_cast<NSInteger> (idx)];

  1281. 

  1282.             [factoryPresets addObject: preset];

  1283.         }

  1284.     }

  1285. 

  1286.     //==============================================================================

  1287.     void allocateBusBuffer (bool isInput)

  1288.     {

  1289.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  1290.         busBuffers.clear();

  1291. 

  1292.         const int n = AudioUnitHelpers::getBusCount (&getAudioProcessor(), isInput);

  1293.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1294. 

  1295.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1296.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses : outputBusses) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1297.                                            static_cast<int> (maxFrames)));

  1298.     }

  1299. 

  1300.     //==============================================================================

  1301.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1302.     {

  1303.         ignoreUnused (numParams);

  1304. 

  1305.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1306.         {

  1307.             switch (event->head.eventType)

  1308.             {

  1309.                 case AURenderEventMIDI:

  1310.                 {

  1311.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1312.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1313.                 }

  1314.                 break;

  1315. 

  1316.                 case AURenderEventParameter:

  1317.                 case AURenderEventParameterRamp:

  1318.                 {

  1319.                     const AUParameterEvent& paramEvent = event->parameter;

  1320. 

  1321.                     if (auto* p = getJuceParameterForAUAddress (paramEvent.parameterAddress))

  1322.                         setAudioProcessorParameter (p, paramEvent.value);

  1323.                 }

  1324.                 break;

  1325. 

  1326.                 default:

  1327.                     break;

  1328.             }

  1329.         }

  1330.     }

  1331. 

  1332.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1333.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1334.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1335.     {

  1336.         auto& processor = getAudioProcessor();

  1337.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1338. 

  1339.         // process params

  1340.         const int numParams = juceParameters.getNumParameters();

  1341.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1342. 

  1343.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1344.         {

  1345.             lastTimeStamp = *timestamp;

  1346. 

  1347.             const int numInputBuses  = inBusBuffers. size();

  1348.             const int numOutputBuses = outBusBuffers.size();

  1349. 

  1350.             // prepare buffers

  1351.             {

  1352.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1353.                 {

  1354.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1355.                      const bool canUseDirectOutput =

  1356.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1357. 

  1358.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1359.                 }

  1360. 

  1361.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1362.                 {

  1363.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1364.                     busBuffer.prepare (frameCount, busIdx < numOutputBuses ? outBusBuffers[busIdx]->get() : nullptr);

  1365.                 }

  1366. 

  1367.                 audioBuffer.reset();

  1368.             }

  1369. 

  1370.             // pull inputs

  1371.             {

  1372.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1373.                 {

  1374.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1375.                     AudioBufferList* buffer = busBuffer.get();

  1376. 

  1377.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1378.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1379. 

  1380.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1381.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1382.                 }

  1383.             }

  1384. 

  1385.             // set buffer pointer to minimize copying

  1386.             {

  1387.                 int chIdx = 0;

  1388. 

  1389.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1390.                 {

  1391.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1392.                     AudioBufferList* buffer = busBuffer.get();

  1393. 

  1394.                     const bool interleaved = busBuffer.interleaved();

  1395.                     const int numChannels = busBuffer.numChannels();

  1396. 

  1397.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1398. 

  1399.                     for (int ch = 0; ch < numChannels; ++ch)

  1400.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1401.                 }

  1402. 

  1403.                 // use input pointers on remaining channels

  1404. 

  1405.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1406.                 {

  1407.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1408. 

  1409.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1410.                     AudioBufferList* buffer = busBuffer.get();

  1411. 

  1412.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1413.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1414.                 }

  1415.             }

  1416. 

  1417.             // copy input

  1418.             {

  1419.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1420.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1421. 

  1422.                 // clear remaining channels

  1423.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1424.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1425.             }

  1426. 

  1427.             // process audio

  1428.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1429. 

  1430.             // send MIDI

  1431.            #if JucePlugin_ProducesMidiOutput && JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  1432.             auto midiOut = [au MIDIOutputEventBlock];

  1433.             MidiMessage msg;

  1434.             int samplePosition;

  1435. 

  1436.             for (MidiBuffer::Iterator it (midiMessages); it.getNextEvent (msg, samplePosition);)

  1437.                 midiOut (samplePosition, 0, msg.getRawDataSize(), msg.getRawData());

  1438.            #endif

  1439. 

  1440.             midiMessages.clear();

  1441.         }

  1442. 

  1443.         // copy back

  1444.         audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1445.                          mapper.get (false, (int) outputBusNumber));

  1446. 

  1447.         return noErr;

  1448.     }

  1449. 

  1450.     void processBlock (AudioBuffer<float>& buffer, MidiBuffer& midiBuffer) noexcept

  1451.     {

  1452.         auto& processor = getAudioProcessor();

  1453.         const ScopedLock sl (processor.getCallbackLock());

  1454. 

  1455.         if (processor.isSuspended())

  1456.             buffer.clear();

  1457.         else if ([au shouldBypassEffect])

  1458.             processor.processBlockBypassed (buffer, midiBuffer);

  1459.         else

  1460.             processor.processBlock (buffer, midiBuffer);

  1461.     }

  1462. 

  1463.     //==============================================================================

  1464.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1465.     {

  1466.         if (param != nullptr)

  1467.         {

  1468.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1469.             {

  1470.                 auto normalisedValue = value / getMaximumParameterValue (p);

  1471.                 setAudioProcessorParameter (p, normalisedValue);

  1472.             }

  1473.         }

  1474.     }

  1475. 

  1476.     AUValue getValue (AUParameter* param)

  1477.     {

  1478.         if (param != nullptr)

  1479.         {

  1480.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1481.                 return p->getValue() * getMaximumParameterValue (p);

  1482.         }

  1483. 

  1484.         return 0;

  1485.     }

  1486. 

  1487.     void valueChangedForObserver (AUParameterAddress, AUValue)

  1488.     {

  1489.         // this will have already been handled by valueChangedFromHost

  1490.     }

  1491. 

  1492.     NSString* stringFromValue (AUParameter* param, const AUValue* value)

  1493.     {

  1494.         String text;

  1495. 

  1496.         if (param != nullptr && value != nullptr)

  1497.         {

  1498.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1499.             {

  1500.                 if (LegacyAudioParameter::isLegacy (p))

  1501.                     text = String (*value);

  1502.                 else

  1503.                     text = p->getText (*value / getMaximumParameterValue (p), 0);

  1504.             }

  1505.         }

  1506. 

  1507.         return juceStringToNS (text);

  1508.     }

  1509. 

  1510.     AUValue valueFromString (AUParameter* param, NSString* str)

  1511.     {

  1512.         if (param != nullptr && str != nullptr)

  1513.         {

  1514.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1515.             {

  1516.                 const String text (nsStringToJuce (str));

  1517. 

  1518.                 if (LegacyAudioParameter::isLegacy (p))

  1519.                     return text.getFloatValue();

  1520.                 else

  1521.                     return p->getValueForText (text) * getMaximumParameterValue (p);

  1522.             }

  1523.         }

  1524. 

  1525.         return 0;

  1526.     }

  1527. 

  1528.     //==============================================================================

  1529.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1530.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept     { return static_cast<AUParameterAddress> (paramIndex); }

  1531.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept    { return static_cast<int> (address); }

  1532.    #else

  1533.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1534.     {

  1535.         return juceParameters.isUsingManagedParameters() ? paramAddresses.getReference (paramIndex)

  1536.                                                          : static_cast<AUParameterAddress> (paramIndex);

  1537.     }

  1538. 

  1539.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1540.     {

  1541.         return juceParameters.isUsingManagedParameters() ? paramMap[static_cast<int64> (address)]

  1542.                                                          : static_cast<int> (address);

  1543.     }

  1544.    #endif

  1545. 

  1546.     AUParameterAddress generateAUParameterAddress (AudioProcessorParameter* param) const

  1547.     {

  1548.         const String& juceParamID = LegacyAudioParameter::getParamID (param, forceLegacyParamIDs);

  1549. 

  1550.         return juceParameters.isUsingManagedParameters() ? static_cast<AUParameterAddress> (juceParamID.hashCode64())

  1551.                                                          : static_cast<AUParameterAddress> (juceParamID.getIntValue());

  1552.     }

  1553. 

  1554.     AudioProcessorParameter* getJuceParameterForAUAddress (AUParameterAddress address) const noexcept

  1555.     {

  1556.         return juceParameters.getParamForIndex (getJuceParameterIndexForAUAddress (address));

  1557.     }

  1558. 

  1559.     //==============================================================================

  1560.     static const double kDefaultSampleRate;

  1561. 

  1562.     AudioProcessorHolder::Ptr processorHolder;

  1563. 

  1564.     int totalInChannels, totalOutChannels;

  1565. 

  1566.     ScopedPointer<AUAudioUnitBusArray> inputBusses;

  1567.     ScopedPointer<AUAudioUnitBusArray> outputBusses;

  1568. 

  1569.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1570.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1571.     ObjCBlock<AUImplementorStringFromValueCallback> stringFromValueProvider;

  1572.     ObjCBlock<AUImplementorValueFromStringCallback> valueFromStringProvider;

  1573. 

  1574.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1575.     Array<AUParameterAddress> paramAddresses;

  1576.     HashMap<int64, int> paramMap;

  1577.    #endif

  1578.     LegacyAudioParametersWrapper juceParameters;

  1579. 

  1580.     // to avoid recursion on parameter changes, we need to add an

  1581.     // editor observer to do the parameter changes

  1582.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1583.     AUParameterObserverToken editorObserverToken;

  1584. 

  1585.     ScopedPointer<AUParameterTree> paramTree;

  1586.     ScopedPointer<NSMutableArray<NSNumber*>> overviewParams;

  1587.     ScopedPointer<NSMutableArray<NSNumber*>> channelCapabilities;

  1588. 

  1589.     ScopedPointer<NSMutableArray<AUAudioUnitPreset*>> factoryPresets;

  1590. 

  1591.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1592. 

  1593.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1594.     AudioUnitHelpers::ChannelRemapper mapper;

  1595. 

  1596.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1597.     MidiBuffer midiMessages;

  1598. 

  1599.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1600.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1601. 

  1602.     AudioTimeStamp lastTimeStamp;

  1603.     CurrentPositionInfo lastAudioHead;

  1604. 

  1605.     String contextName;

  1606. 

  1607.     ThreadLocalValue<bool> inParameterChangedCallback;

  1608.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1609.     static constexpr bool forceLegacyParamIDs = true;

  1610.    #else

  1611.     static constexpr bool forceLegacyParamIDs = false;

  1612.    #endif

  1613. };

  1614. 

  1615. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1616. 

  1617. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1618. {

  1619.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1620.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1621. }

  1622. 

  1623. //==============================================================================

  1624. class JuceAUViewController

  1625. {

  1626. public:

  1627.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1628.         : myself (p)

  1629.     {

  1630.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1631. 

  1632.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1633.         initialiseJuce_GUI();

  1634.     }

  1635. 

  1636.     ~JuceAUViewController()

  1637.     {

  1638.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1639. 

  1640.         if (processorHolder != nullptr)

  1641.             JuceAudioUnitv3::removeEditor (getAudioProcessor());

  1642.     }

  1643. 

  1644.     //==============================================================================

  1645.     void loadView()

  1646.     {

  1647.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1648. 

  1649.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1650.         {

  1651.             processorHolder = new AudioProcessorHolder (p);

  1652.             auto& processor = getAudioProcessor();

  1653. 

  1654.             if (processor.hasEditor())

  1655.             {

  1656.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1657.                 {

  1658.                     preferredSize = editor->getBounds();

  1659. 

  1660.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1661.                     [myself setView: view];

  1662. 

  1663.                    #if JUCE_IOS

  1664.                     editor->setVisible (false);

  1665.                    #else

  1666.                     editor->setVisible (true);

  1667.                    #endif

  1668. 

  1669.                     editor->addToDesktop (0, view);

  1670. 

  1671.                    #if JUCE_IOS

  1672.                     if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1673.                         [peerView setContentMode: UIViewContentModeTop];

  1674.                    #endif

  1675.                 }

  1676.             }

  1677.         }

  1678.     }

  1679. 

  1680.     void viewDidLayoutSubviews()

  1681.     {

  1682.         if (processorHolder != nullptr && [myself view] != nullptr)

  1683.         {

  1684.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1685.             {

  1686.                 if (processorHolder->viewConfiguration != nullptr)

  1687.                     editor->hostMIDIControllerIsAvailable (processorHolder->viewConfiguration->hostHasMIDIController);

  1688. 

  1689.                 editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1690. 

  1691.                 if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1692.                 {

  1693.                    #if JUCE_IOS

  1694.                     [peerView setNeedsDisplay];

  1695.                    #else

  1696.                     [peerView setNeedsDisplay: YES];

  1697.                    #endif

  1698.                 }

  1699.             }

  1700.         }

  1701.     }

  1702. 

  1703.     void didReceiveMemoryWarning()

  1704.     {

  1705.         if (processorHolder != nullptr)

  1706.             if (auto* processor = processorHolder->get())

  1707.                 processor->memoryWarningReceived();

  1708.     }

  1709. 

  1710.     void viewDidAppear (bool)

  1711.     {

  1712.         if (processorHolder != nullptr)

  1713.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1714.                 editor->setVisible (true);

  1715.     }

  1716. 

  1717.     void viewDidDisappear (bool)

  1718.     {

  1719.         if (processorHolder != nullptr)

  1720.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1721.                 editor->setVisible (false);

  1722.     }

  1723. 

  1724.     CGSize getPreferredContentSize() const

  1725.     {

  1726.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1727.                            static_cast<float> (preferredSize.getHeight()));

  1728.     }

  1729. 

  1730.     //==============================================================================

  1731.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1732.     {

  1733.         AUAudioUnit* retval = nil;

  1734. 

  1735.         if (! MessageManager::getInstance()->isThisTheMessageThread())

  1736.         {

  1737.             WaitableEvent creationEvent;

  1738. 

  1739.             // AUv3 headers say that we may block this thread and that the message thread is guaranteed

  1740.             // to be unblocked

  1741.             struct AUCreator  : public CallbackMessage

  1742.             {

  1743.                 JuceAUViewController& owner;

  1744.                 AudioComponentDescription pDescr;

  1745.                 NSError** pError;

  1746.                 AUAudioUnit*& outAU;

  1747.                 WaitableEvent& e;

  1748. 

  1749.                 AUCreator (JuceAUViewController& parent, const AudioComponentDescription& paramDescr, NSError** paramError,

  1750.                            AUAudioUnit*& outputAU, WaitableEvent& event)

  1751.                     : owner (parent), pDescr (paramDescr), pError (paramError), outAU (outputAU), e (event)

  1752.                 {}

  1753. 

  1754.                 void messageCallback() override

  1755.                 {

  1756.                     outAU = owner.createAudioUnitOnMessageThread (pDescr, pError);

  1757.                     e.signal();

  1758.                 }

  1759.             };

  1760. 

  1761.             (new AUCreator (*this, descr, error, retval, creationEvent))->post();

  1762.             creationEvent.wait (-1);

  1763.         }

  1764.         else

  1765.         {

  1766.             retval = createAudioUnitOnMessageThread (descr, error);

  1767.         }

  1768. 

  1769.         return [retval autorelease];

  1770.     }

  1771. 

  1772. private:

  1773.     //==============================================================================

  1774.     AUViewController<AUAudioUnitFactory>* myself;

  1775.     AudioProcessorHolder::Ptr processorHolder = nullptr;

  1776.     Rectangle<int> preferredSize { 1, 1 };

  1777. 

  1778.     //==============================================================================

  1779.     AUAudioUnit* createAudioUnitOnMessageThread (const AudioComponentDescription& descr, NSError** error)

  1780.     {

  1781.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1782. 

  1783.         [myself view];  // this will call [view load] and ensure that the AudioProcessor has been instantiated

  1784. 

  1785.         if (processorHolder == nullptr)

  1786.             return nullptr;

  1787. 

  1788.         return (new JuceAudioUnitv3 (processorHolder, descr, 0, error))->getAudioUnit();

  1789.     }

  1790. 

  1791.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder; }

  1792. };

  1793. 

  1794. //==============================================================================

  1795. // necessary glue code

  1796. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  1797. @end

  1798. 

  1799. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  1800. {

  1801.     ScopedPointer<JuceAUViewController> cpp;

  1802. }

  1803. 

  1804. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp = new JuceAUViewController (self); return self; }

  1805. - (void) loadView                { cpp->loadView(); }

  1806. - (AUAudioUnit *) createAudioUnitWithComponentDescription: (AudioComponentDescription) desc error: (NSError **) error { return cpp->createAudioUnit (desc, error); }

  1807. - (CGSize) preferredContentSize  { return cpp->getPreferredContentSize(); }

  1808. - (void) viewDidLayoutSubviews   { cpp->viewDidLayoutSubviews(); }

  1809. - (void) didReceiveMemoryWarning { cpp->didReceiveMemoryWarning(); }

  1810. #if JUCE_IOS

  1811. - (void) viewDidAppear: (BOOL) animated { cpp->viewDidAppear (animated); [super viewDidAppear:animated]; }

  1812. - (void) viewDidDisappear: (BOOL) animated { cpp->viewDidDisappear (animated); [super viewDidDisappear:animated]; }

  1813. #endif

  1814. @end

  1815. 

  1816. //==============================================================================

  1817. #if JUCE_IOS

  1818. bool JUCE_CALLTYPE juce_isInterAppAudioConnected() { return false; }

  1819. void JUCE_CALLTYPE juce_switchToHostApplication()  {}

  1820. #if JUCE_MODULE_AVAILABLE_juce_gui_basics

  1821. Image JUCE_CALLTYPE juce_getIAAHostIcon (int)      { return {}; }

  1822. #endif

  1823. #endif

  1824. 

  1825. #pragma clang diagnostic pop

  1826. #endif