DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
12016 Commits
11 Branches
2.7GB
Tree: d5175b6e23
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'd5175b6e23'
${ noResults }
JUCE/modules/juce_gui_basics/native/accessibility/juce_mac_Accessibility.mm

1151 lines
52KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2020 - Raw Material Software Limited

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 6 End-User License

  11.    Agreement and JUCE Privacy Policy (both effective as of the 16th June 2020).

  12. 

  13.    End User License Agreement: www.juce.com/juce-6-licence

  14.    Privacy Policy: www.juce.com/juce-privacy-policy

  15. 

  16.    Or: You may also use this code under the terms of the GPL v3 (see

  17.    www.gnu.org/licenses).

  18. 

  19.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  20.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  21.    DISCLAIMED.

  22. 

  23.   ==============================================================================

  24. */

  25. 

  26. namespace juce

  27. {

  28. 

  29. #if (! defined MAC_OS_X_VERSION_10_13) || MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_13

  30.  using NSAccessibilityRole = NSString*;

  31.  using NSAccessibilityNotificationName = NSString*;

  32. #endif

  33. 

  34. #if JUCE_OBJC_HAS_AVAILABLE_FEATURE || (defined (MAC_OS_X_VERSION_10_10) && MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_10)

  35. 

  36. #define JUCE_NATIVE_ACCESSIBILITY_INCLUDED 1

  37. 

  38. //==============================================================================

  39. class AccessibilityHandler::AccessibilityNativeImpl

  40. {

  41. public:

  42.     explicit AccessibilityNativeImpl (AccessibilityHandler& handler)

  43.         : accessibilityElement (AccessibilityElement::create (handler))

  44.     {}

  45. 

  46.     NSAccessibilityElement<NSAccessibility>* getAccessibilityElement() const noexcept

  47.     {

  48.         return accessibilityElement.get();

  49.     }

  50. 

  51. private:

  52.     //==============================================================================

  53.     class AccessibilityElement  : public ObjCClass<NSAccessibilityElement<NSAccessibility>>

  54.     {

  55.     private:

  56.         struct Deleter

  57.         {

  58.             void operator() (NSAccessibilityElement<NSAccessibility>* element) const

  59.             {

  60.                 object_setInstanceVariable (element, "handler", nullptr);

  61.                 [element release];

  62.             }

  63.         };

  64. 

  65.     public:

  66.         using Holder = std::unique_ptr<NSAccessibilityElement<NSAccessibility>, Deleter>;

  67. 

  68.         static Holder create (AccessibilityHandler& handler)

  69.         {

  70.            #if JUCE_OBJC_HAS_AVAILABLE_FEATURE

  71.             if (@available (macOS 10.10, *))

  72.            #endif

  73.             {

  74.                 static AccessibilityElement cls;

  75.                 Holder element ([cls.createInstance() init]);

  76.                 object_setInstanceVariable (element.get(), "handler", &handler);

  77.                 return element;

  78.             }

  79. 

  80.             return {};

  81.         }

  82. 

  83.     private:

  84.         AccessibilityElement()  : ObjCClass<NSAccessibilityElement<NSAccessibility>> ("JUCEAccessibilityElement_")

  85.         {

  86.             addIvar<AccessibilityHandler*> ("handler");

  87. 

  88.             addMethod (@selector (accessibilityNotifiesWhenDestroyed),     getAccessibilityNotifiesWhenDestroyed, "c@:");

  89.             addMethod (@selector (isAccessibilityElement),                 getIsAccessibilityElement,             "c@:");

  90.             addMethod (@selector (isAccessibilityEnabled),                 getIsAccessibilityEnabled,             "c@:");

  91.             addMethod (@selector (accessibilityWindow),                    getAccessibilityWindow,                "@@:");

  92.             addMethod (@selector (accessibilityTopLevelUIElement),         getAccessibilityWindow,                "@@:");

  93.             addMethod (@selector (accessibilityFocusedUIElement),          getAccessibilityFocusedUIElement,      "@@:");

  94.             addMethod (@selector (accessibilityHitTest:),                  accessibilityHitTest,                  "@@:", @encode (NSPoint));

  95.             addMethod (@selector (accessibilityParent),                    getAccessibilityParent,                "@@:");

  96.             addMethod (@selector (accessibilityChildren),                  getAccessibilityChildren,              "@@:");

  97.             addMethod (@selector (isAccessibilityFocused),                 getIsAccessibilityFocused,             "c@:");

  98.             addMethod (@selector (setAccessibilityFocused:),               setAccessibilityFocused,               "v@:c");

  99.             addMethod (@selector (isAccessibilityModal),                   getIsAccessibilityModal,               "c@:");

  100.             addMethod (@selector (accessibilityFrame),                     getAccessibilityFrame,                 @encode (NSRect), "@:");

  101.             addMethod (@selector (accessibilityRole),                      getAccessibilityRole,                  "@@:");

  102.             addMethod (@selector (accessibilitySubrole),                   getAccessibilitySubrole,               "@@:");

  103.             addMethod (@selector (accessibilityTitle),                     getAccessibilityTitle,                 "@@:");

  104.             addMethod (@selector (accessibilityLabel),                     getAccessibilityLabel,                 "@@:");

  105.             addMethod (@selector (accessibilityHelp),                      getAccessibilityHelp,                  "@@:");

  106.             addMethod (@selector (accessibilityValue),                     getAccessibilityValue,                 "@@:");

  107.             addMethod (@selector (setAccessibilityValue:),                 setAccessibilityValue,                 "v@:@");

  108.             addMethod (@selector (accessibilitySelectedChildren),          getAccessibilitySelectedChildren,      "@@:");

  109.             addMethod (@selector (setAccessibilitySelectedChildren:),      setAccessibilitySelectedChildren,      "v@:@");

  110.             addMethod (@selector (accessibilityOrientation),               getAccessibilityOrientation,           "i@:@");

  111. 

  112.             addMethod (@selector (accessibilityInsertionPointLineNumber),  getAccessibilityInsertionPointLineNumber, "i@:");

  113.             addMethod (@selector (accessibilitySharedCharacterRange),      getAccessibilitySharedCharacterRange,     @encode (NSRange), "@:");

  114.             addMethod (@selector (accessibilitySharedTextUIElements),      getAccessibilitySharedTextUIElements,     "@@:");

  115.             addMethod (@selector (accessibilityVisibleCharacterRange),     getAccessibilityVisibleCharacterRange,    @encode (NSRange), "@:");

  116.             addMethod (@selector (accessibilityNumberOfCharacters),        getAccessibilityNumberOfCharacters,       "i@:");

  117.             addMethod (@selector (accessibilitySelectedText),              getAccessibilitySelectedText,             "@@:");

  118.             addMethod (@selector (accessibilitySelectedTextRange),         getAccessibilitySelectedTextRange,        @encode (NSRange), "@:");

  119.             addMethod (@selector (accessibilitySelectedTextRanges),        getAccessibilitySelectedTextRanges,       "@@:");

  120.             addMethod (@selector (accessibilityAttributedStringForRange:), getAccessibilityAttributedStringForRange, "@@:", @encode (NSRange));

  121.             addMethod (@selector (accessibilityRangeForLine:),             getAccessibilityRangeForLine,             @encode (NSRange), "@:i");

  122.             addMethod (@selector (accessibilityStringForRange:),           getAccessibilityStringForRange,           "@@:", @encode (NSRange));

  123.             addMethod (@selector (accessibilityRangeForPosition:),         getAccessibilityRangeForPosition,         @encode (NSRange), "@:", @encode (NSPoint));

  124.             addMethod (@selector (accessibilityRangeForIndex:),            getAccessibilityRangeForIndex,            @encode (NSRange), "@:i");

  125.             addMethod (@selector (accessibilityFrameForRange:),            getAccessibilityFrameForRange,            @encode (NSRect), "@:", @encode (NSRange));

  126.             addMethod (@selector (accessibilityRTFForRange:),              getAccessibilityRTFForRange,              "@@:", @encode (NSRange));

  127.             addMethod (@selector (accessibilityStyleRangeForIndex:),       getAccessibilityStyleRangeForIndex,       @encode (NSRange), "@:i");

  128.             addMethod (@selector (accessibilityLineForIndex:),             getAccessibilityLineForIndex,             "i@:i");

  129.             addMethod (@selector (setAccessibilitySelectedTextRange:),     setAccessibilitySelectedTextRange,        "v@:", @encode (NSRange));

  130. 

  131.             addMethod (@selector (accessibilityRowCount),            getAccessibilityRowCount,         "i@:");

  132.             addMethod (@selector (accessibilityRows),                getAccessibilityRows,             "@@:");

  133.             addMethod (@selector (accessibilitySelectedRows),        getAccessibilitySelectedRows,     "@@:");

  134.             addMethod (@selector (setAccessibilitySelectedRows:),    setAccessibilitySelectedRows,     "v@:@");

  135.             addMethod (@selector (accessibilityColumnCount),         getAccessibilityColumnCount,      "i@:");

  136.             addMethod (@selector (accessibilityColumns),             getAccessibilityColumns,          "@@:");

  137.             addMethod (@selector (accessibilitySelectedColumns),     getAccessibilitySelectedColumns,  "@@:");

  138.             addMethod (@selector (setAccessibilitySelectedColumns:), setAccessibilitySelectedColumns,  "v@:@");

  139. 

  140.             addMethod (@selector (accessibilityRowIndexRange),    getAccessibilityRowIndexRange,    @encode (NSRange), "@:");

  141.             addMethod (@selector (accessibilityColumnIndexRange), getAccessibilityColumnIndexRange, @encode (NSRange), "@:");

  142.             addMethod (@selector (accessibilityIndex),            getAccessibilityIndex,            "i@:");

  143.             addMethod (@selector (accessibilityDisclosureLevel),  getAccessibilityDisclosureLevel,  "i@:");

  144.             addMethod (@selector (isAccessibilityExpanded),       getIsAccessibilityExpanded,       "c@:");

  145. 

  146.             addMethod (@selector (accessibilityPerformIncrement), accessibilityPerformIncrement, "c@:");

  147.             addMethod (@selector (accessibilityPerformDecrement), accessibilityPerformDecrement, "c@:");

  148.             addMethod (@selector (accessibilityPerformDelete),    accessibilityPerformDelete,    "c@:");

  149.             addMethod (@selector (accessibilityPerformPress),     accessibilityPerformPress,     "c@:");

  150.             addMethod (@selector (accessibilityPerformShowMenu),  accessibilityPerformShowMenu,  "c@:");

  151.             addMethod (@selector (accessibilityPerformRaise),     accessibilityPerformRaise,     "c@:");

  152. 

  153.             addMethod (@selector (isAccessibilitySelectorAllowed:), getIsAccessibilitySelectorAllowed, "c@:@");

  154. 

  155.            #if defined (MAC_OS_X_VERSION_10_13) && MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_13

  156.             addMethod (@selector (accessibilityChildrenInNavigationOrder), getAccessibilityChildren, "@@:");

  157.            #endif

  158. 

  159.             registerClass();

  160.         }

  161. 

  162.     private:

  163.         static AccessibilityHandler* getHandler (id self)            { return getIvar<AccessibilityHandler*> (self, "handler"); }

  164. 

  165.         template <typename MemberFn>

  166.         static auto getInterface (id self, MemberFn fn) noexcept -> decltype ((std::declval<AccessibilityHandler>().*fn)())

  167.         {

  168.             if (auto* handler = getHandler (self))

  169.                 return (handler->*fn)();

  170. 

  171.             return nullptr;

  172.         }

  173. 

  174.         static AccessibilityTextInterface*  getTextInterface  (id self) noexcept  { return getInterface (self, &AccessibilityHandler::getTextInterface); }

  175.         static AccessibilityValueInterface* getValueInterface (id self) noexcept  { return getInterface (self, &AccessibilityHandler::getValueInterface); }

  176.         static AccessibilityTableInterface* getTableInterface (id self) noexcept  { return getInterface (self, &AccessibilityHandler::getTableInterface); }

  177.         static AccessibilityCellInterface*  getCellInterface  (id self) noexcept  { return getInterface (self, &AccessibilityHandler::getCellInterface); }

  178. 

  179.         static bool hasEditableText (AccessibilityHandler& handler) noexcept

  180.         {

  181.             return handler.getRole() == AccessibilityRole::editableText

  182.                 && handler.getTextInterface() != nullptr

  183.                 && ! handler.getTextInterface()->isReadOnly();

  184.         }

  185. 

  186.         static bool isSelectable (AccessibleState state) noexcept

  187.         {

  188.             return state.isSelectable() || state.isMultiSelectable();

  189.         }

  190. 

  191.         static NSArray* getSelectedChildren (NSArray* children)

  192.         {

  193.             NSMutableArray* selected = [[NSMutableArray new] autorelease];

  194. 

  195.             for (id child in children)

  196.             {

  197.                 if (auto* handler = getHandler (child))

  198.                 {

  199.                     const auto currentState = handler->getCurrentState();

  200. 

  201.                     if (isSelectable (currentState) && currentState.isSelected())

  202.                         [selected addObject: child];

  203.                 }

  204.             }

  205. 

  206.             return selected;

  207.         }

  208. 

  209.         static void setSelectedChildren (NSArray* children, NSArray* selected)

  210.         {

  211.             for (id child in children)

  212.             {

  213.                 if (auto* handler = getHandler (child))

  214.                 {

  215.                     const auto currentState = handler->getCurrentState();

  216.                     const BOOL isSelected = [selected containsObject: child];

  217. 

  218.                     if (isSelectable (currentState))

  219.                     {

  220.                         if (currentState.isSelected() != isSelected)

  221.                             handler->getActions().invoke (AccessibilityActionType::toggle);

  222.                     }

  223.                     else if (currentState.isFocusable())

  224.                     {

  225.                         [child setAccessibilityFocused: isSelected];

  226.                     }

  227.                 }

  228.             }

  229.         }

  230. 

  231.         static BOOL performActionIfSupported (id self, AccessibilityActionType actionType)

  232.         {

  233.             if (auto* handler = getHandler (self))

  234.                 if (handler->getActions().invoke (actionType))

  235.                     return YES;

  236. 

  237.             return NO;

  238.         }

  239. 

  240.         //==============================================================================

  241.         static BOOL getAccessibilityNotifiesWhenDestroyed (id, SEL)  { return YES; }

  242. 

  243.         static BOOL getIsAccessibilityElement (id self, SEL)

  244.         {

  245.             if (auto* handler = getHandler (self))

  246.                 return ! handler->isIgnored()

  247.                       && handler->getRole() != AccessibilityRole::window;

  248. 

  249.             return NO;

  250.         }

  251. 

  252.         static BOOL getIsAccessibilityEnabled (id self, SEL)

  253.         {

  254.             if (auto* handler = getHandler (self))

  255.                 return handler->getComponent().isEnabled();

  256. 

  257.             return NO;

  258.         }

  259. 

  260.         static id getAccessibilityWindow (id self, SEL)

  261.         {

  262.             return [[self accessibilityParent] accessibilityWindow];

  263.         }

  264. 

  265.         static id getAccessibilityFocusedUIElement (id self, SEL)

  266.         {

  267.             if (auto* handler = getHandler (self))

  268.             {

  269.                 if (auto* modal = Component::getCurrentlyModalComponent())

  270.                 {

  271.                     const auto& component = handler->getComponent();

  272. 

  273.                     if (! component.isParentOf (modal)

  274.                          && component.isCurrentlyBlockedByAnotherModalComponent())

  275.                     {

  276.                         if (auto* modalHandler = modal->getAccessibilityHandler())

  277.                         {

  278.                             if (auto* focusChild = modalHandler->getChildFocus())

  279.                                 return (id) focusChild->getNativeImplementation();

  280. 

  281.                             return (id) modalHandler->getNativeImplementation();

  282.                         }

  283.                     }

  284.                 }

  285. 

  286.                 if (auto* focusChild = handler->getChildFocus())

  287.                     return (id) focusChild->getNativeImplementation();

  288.             }

  289. 

  290.             return nil;

  291.         }

  292. 

  293.         static id accessibilityHitTest (id self, SEL, NSPoint point)

  294.         {

  295.             if (auto* handler = getHandler (self))

  296.             {

  297.                 if (auto* child = handler->getChildAt (convertToIntPoint (flippedScreenPoint (point))))

  298.                     return (id) child->getNativeImplementation();

  299. 

  300.                 return self;

  301.             }

  302. 

  303.             return nil;

  304.         }

  305. 

  306.         static id getAccessibilityParent (id self, SEL)

  307.         {

  308.             if (auto* handler = getHandler (self))

  309.             {

  310.                 if (auto* parentHandler = handler->getParent())

  311.                     return NSAccessibilityUnignoredAncestor ((id) parentHandler->getNativeImplementation());

  312. 

  313.                 return NSAccessibilityUnignoredAncestor ((id) handler->getComponent().getWindowHandle());

  314.             }

  315. 

  316.             return nil;

  317.         }

  318. 

  319.         static NSArray* getAccessibilityChildren (id self, SEL)

  320.         {

  321.             if (auto* handler = getHandler (self))

  322.             {

  323.                 auto children = handler->getChildren();

  324. 

  325.                 NSMutableArray* accessibleChildren = [NSMutableArray arrayWithCapacity: (NSUInteger) children.size()];

  326. 

  327.                 for (auto* childHandler : children)

  328.                     [accessibleChildren addObject: (id) childHandler->getNativeImplementation()];

  329. 

  330.                 return accessibleChildren;

  331.             }

  332. 

  333.             return nil;

  334.         }

  335. 

  336.         static NSArray* getAccessibilitySelectedChildren (id self, SEL)

  337.         {

  338.             return getSelectedChildren ([self accessibilityChildren]);

  339.         }

  340. 

  341.         static void setAccessibilitySelectedChildren (id self, SEL, NSArray* selected)

  342.         {

  343.             setSelectedChildren ([self accessibilityChildren], selected);

  344.         }

  345. 

  346.         static NSAccessibilityOrientation getAccessibilityOrientation (id self, SEL)

  347.         {

  348.             if (auto* handler = getHandler (self))

  349.                 return handler->getComponent().getBounds().toFloat().getAspectRatio() > 1.0f

  350.                            ? NSAccessibilityOrientationHorizontal

  351.                            : NSAccessibilityOrientationVertical;

  352. 

  353.             return NSAccessibilityOrientationUnknown;

  354.         }

  355. 

  356.         static BOOL getIsAccessibilityFocused (id self, SEL)

  357.         {

  358.             return [[self accessibilityWindow] accessibilityFocusedUIElement] == self;

  359.         }

  360. 

  361.         static void setAccessibilityFocused (id self, SEL, BOOL focused)

  362.         {

  363.             if (auto* handler = getHandler (self))

  364.             {

  365.                 if (focused)

  366.                 {

  367.                     const WeakReference<Component> safeComponent (&handler->getComponent());

  368. 

  369.                     performActionIfSupported (self, AccessibilityActionType::focus);

  370. 

  371.                     if (safeComponent != nullptr)

  372.                         handler->grabFocus();

  373.                 }

  374.                 else

  375.                 {

  376.                     handler->giveAwayFocus();

  377.                 }

  378.             }

  379.         }

  380. 

  381.         static BOOL getIsAccessibilityModal (id self, SEL)

  382.         {

  383.             if (auto* handler = getHandler (self))

  384.                 return handler->getComponent().isCurrentlyModal();

  385. 

  386.             return NO;

  387.         }

  388. 

  389.         static NSRect getAccessibilityFrame (id self, SEL)

  390.         {

  391.             if (auto* handler = getHandler (self))

  392.                 return flippedScreenRect (makeNSRect (handler->getComponent().getScreenBounds()));

  393. 

  394.             return NSZeroRect;

  395.         }

  396. 

  397.         static NSAccessibilityRole getAccessibilityRole (id self, SEL)

  398.         {

  399.             if (auto* handler = getHandler (self))

  400.             {

  401.                 switch (handler->getRole())

  402.                 {

  403.                     case AccessibilityRole::button:       return NSAccessibilityButtonRole;

  404.                     case AccessibilityRole::toggleButton: return NSAccessibilityCheckBoxRole;

  405.                     case AccessibilityRole::radioButton:  return NSAccessibilityRadioButtonRole;

  406.                     case AccessibilityRole::comboBox:     return NSAccessibilityPopUpButtonRole;

  407.                     case AccessibilityRole::image:        return NSAccessibilityImageRole;

  408.                     case AccessibilityRole::slider:       return NSAccessibilitySliderRole;

  409.                     case AccessibilityRole::label:        return NSAccessibilityStaticTextRole;

  410.                     case AccessibilityRole::staticText:   return NSAccessibilityStaticTextRole;

  411.                     case AccessibilityRole::editableText: return NSAccessibilityTextAreaRole;

  412.                     case AccessibilityRole::menuItem:     return NSAccessibilityMenuItemRole;

  413.                     case AccessibilityRole::menuBar:      return NSAccessibilityMenuRole;

  414.                     case AccessibilityRole::popupMenu:    return NSAccessibilityWindowRole;

  415.                     case AccessibilityRole::table:        return NSAccessibilityListRole;

  416.                     case AccessibilityRole::tableHeader:  return NSAccessibilityGroupRole;

  417.                     case AccessibilityRole::column:       return NSAccessibilityColumnRole;

  418.                     case AccessibilityRole::row:          return NSAccessibilityRowRole;

  419.                     case AccessibilityRole::cell:         return NSAccessibilityCellRole;

  420.                     case AccessibilityRole::hyperlink:    return NSAccessibilityLinkRole;

  421.                     case AccessibilityRole::list:         return NSAccessibilityOutlineRole;

  422.                     case AccessibilityRole::listItem:     return NSAccessibilityRowRole;

  423.                     case AccessibilityRole::tree:         return NSAccessibilityOutlineRole;

  424.                     case AccessibilityRole::treeItem:     return NSAccessibilityRowRole;

  425.                     case AccessibilityRole::progressBar:  return NSAccessibilityProgressIndicatorRole;

  426.                     case AccessibilityRole::group:        return NSAccessibilityGroupRole;

  427.                     case AccessibilityRole::dialogWindow: return NSAccessibilityWindowRole;

  428.                     case AccessibilityRole::window:       return NSAccessibilityWindowRole;

  429.                     case AccessibilityRole::scrollBar:    return NSAccessibilityScrollBarRole;

  430.                     case AccessibilityRole::tooltip:      return NSAccessibilityWindowRole;

  431.                     case AccessibilityRole::splashScreen: return NSAccessibilityWindowRole;

  432.                     case AccessibilityRole::ignored:      return NSAccessibilityUnknownRole;

  433.                     case AccessibilityRole::unspecified:  return NSAccessibilityGroupRole;

  434.                     default:                              break;

  435.                 }

  436. 

  437.                 return NSAccessibilityUnknownRole;

  438.             }

  439. 

  440.             return nil;

  441.         }

  442. 

  443.         static NSAccessibilityRole getAccessibilitySubrole (id self, SEL)

  444.         {

  445.             if (auto* handler = getHandler (self))

  446.             {

  447.                 if (auto* textInterface = getTextInterface (self))

  448.                     if (textInterface->isDisplayingProtectedText())

  449.                         return NSAccessibilitySecureTextFieldSubrole;

  450. 

  451.                 const auto role = handler->getRole();

  452. 

  453.                 if (role == AccessibilityRole::window)                                     return NSAccessibilityStandardWindowSubrole;

  454.                 if (role == AccessibilityRole::dialogWindow)                               return NSAccessibilityDialogSubrole;

  455.                 if (role == AccessibilityRole::tooltip

  456.                     || role == AccessibilityRole::splashScreen)                            return NSAccessibilityFloatingWindowSubrole;

  457.                 if (role == AccessibilityRole::toggleButton)                               return NSAccessibilityToggleSubrole;

  458.                 if (role == AccessibilityRole::treeItem

  459.                     || role == AccessibilityRole::listItem)                                return NSAccessibilityOutlineRowSubrole;

  460.                 if (role == AccessibilityRole::row && getCellInterface (self) != nullptr)  return NSAccessibilityTableRowSubrole;

  461. 

  462.                 const auto& component = handler->getComponent();

  463. 

  464.                 if (auto* documentWindow = component.findParentComponentOfClass<DocumentWindow>())

  465.                 {

  466.                     if (role == AccessibilityRole::button)

  467.                     {

  468.                         if (&component == documentWindow->getCloseButton())     return NSAccessibilityCloseButtonSubrole;

  469.                         if (&component == documentWindow->getMinimiseButton())  return NSAccessibilityMinimizeButtonSubrole;

  470.                         if (&component == documentWindow->getMaximiseButton())  return NSAccessibilityFullScreenButtonSubrole;

  471.                     }

  472.                 }

  473.             }

  474. 

  475.             return NSAccessibilityUnknownRole;

  476.         }

  477. 

  478.         static NSString* getAccessibilityTitle (id self, SEL)

  479.         {

  480.             if (auto* handler = getHandler (self))

  481.             {

  482.                 auto title = handler->getTitle();

  483. 

  484.                 if (title.isEmpty() && handler->getComponent().isOnDesktop())

  485.                     title = getAccessibleApplicationOrPluginName();

  486. 

  487.                 NSString* nsString = juceStringToNS (title);

  488. 

  489.                 if (nsString != nil && [[self accessibilityValue] isEqual: nsString])

  490.                     return @"";

  491. 

  492.                 return nsString;

  493.             }

  494. 

  495.             return nil;

  496.         }

  497. 

  498.         static NSString* getAccessibilityLabel (id self, SEL)

  499.         {

  500.             if (auto* handler = getHandler (self))

  501.                 return juceStringToNS (handler->getDescription());

  502. 

  503.             return nil;

  504.         }

  505. 

  506.         static NSString* getAccessibilityHelp (id self, SEL)

  507.         {

  508.             if (auto* handler = getHandler (self))

  509.                 return juceStringToNS (handler->getHelp());

  510. 

  511.             return nil;

  512.         }

  513. 

  514.         static id getAccessibilityValue (id self, SEL)

  515.         {

  516.             if (auto* handler = getHandler (self))

  517.             {

  518.                 if (auto* textInterface = handler->getTextInterface())

  519.                     return juceStringToNS (textInterface->getText ({ 0, textInterface->getTotalNumCharacters() }));

  520. 

  521.                 if (handler->getCurrentState().isCheckable())

  522.                     return handler->getCurrentState().isChecked() ? @(1) : @(0);

  523. 

  524.                 if (auto* valueInterface = handler->getValueInterface())

  525.                     return juceStringToNS (valueInterface->getCurrentValueAsString());

  526.             }

  527. 

  528.             return nil;

  529.         }

  530. 

  531.         static void setAccessibilityValue (id self, SEL, NSString* value)

  532.         {

  533.             if (auto* handler = getHandler (self))

  534.             {

  535.                 if (hasEditableText (*handler))

  536.                 {

  537.                     handler->getTextInterface()->setText (nsStringToJuce (value));

  538.                     return;

  539.                 }

  540. 

  541.                 if (auto* valueInterface = handler->getValueInterface())

  542.                     if (! valueInterface->isReadOnly())

  543.                         valueInterface->setValueAsString (nsStringToJuce (value));

  544.             }

  545.         }

  546. 

  547.         //==============================================================================

  548.         static NSInteger getAccessibilityInsertionPointLineNumber (id self, SEL)

  549.         {

  550.             if (auto* textInterface = getTextInterface (self))

  551.                 return [self accessibilityLineForIndex: textInterface->getTextInsertionOffset()];

  552. 

  553.             return 0;

  554.         }

  555. 

  556.         static NSRange getAccessibilitySharedCharacterRange (id self, SEL)

  557.         {

  558.             return [self accessibilityVisibleCharacterRange];

  559.         }

  560. 

  561.         static NSArray* getAccessibilitySharedTextUIElements (id self, SEL)

  562.         {

  563.             return [NSArray arrayWithObject: self];

  564.         }

  565. 

  566.         static NSRange getAccessibilityVisibleCharacterRange (id self, SEL)

  567.         {

  568.             if (auto* textInterface = getTextInterface (self))

  569.                 return juceRangeToNS ({ 0, textInterface->getTotalNumCharacters() });

  570. 

  571.             return NSMakeRange (0, 0);

  572.         }

  573. 

  574.         static NSInteger getAccessibilityNumberOfCharacters (id self, SEL)

  575.         {

  576.             if (auto* textInterface = getTextInterface (self))

  577.                 return textInterface->getTotalNumCharacters();

  578. 

  579.             return 0;

  580.         }

  581. 

  582.         static NSString* getAccessibilitySelectedText (id self, SEL)

  583.         {

  584.             if (auto* textInterface = getTextInterface (self))

  585.                 return juceStringToNS (textInterface->getText (textInterface->getSelection()));

  586. 

  587.             return nil;

  588.         }

  589. 

  590.         static NSRange getAccessibilitySelectedTextRange (id self, SEL)

  591.         {

  592.             if (auto* textInterface = getTextInterface (self))

  593.                 return juceRangeToNS (textInterface->getSelection());

  594. 

  595.             return NSMakeRange (0, 0);

  596.         }

  597. 

  598.         static NSArray* getAccessibilitySelectedTextRanges (id self, SEL)

  599.         {

  600.             return [NSArray arrayWithObject: [NSValue valueWithRange: [self accessibilitySelectedTextRange]]];

  601.         }

  602. 

  603.         static NSAttributedString* getAccessibilityAttributedStringForRange (id self, SEL, NSRange range)

  604.         {

  605.             NSString* string = [self accessibilityStringForRange: range];

  606. 

  607.             if (string != nil)

  608.                 return [[[NSAttributedString alloc] initWithString: string] autorelease];

  609. 

  610.             return nil;

  611.         }

  612. 

  613.         static NSRange getAccessibilityRangeForLine (id self, SEL, NSInteger line)

  614.         {

  615.             if (auto* textInterface = getTextInterface (self))

  616.             {

  617.                 auto text = textInterface->getText ({ 0, textInterface->getTotalNumCharacters() });

  618.                 auto lines = StringArray::fromLines (text);

  619. 

  620.                 if (line < lines.size())

  621.                 {

  622.                     auto lineText = lines[(int) line];

  623.                     auto start = text.indexOf (lineText);

  624. 

  625.                     if (start >= 0)

  626.                         return NSMakeRange ((NSUInteger) start, (NSUInteger) lineText.length());

  627.                 }

  628.             }

  629. 

  630.             return NSMakeRange (0, 0);

  631.         }

  632. 

  633.         static NSString* getAccessibilityStringForRange (id self, SEL, NSRange range)

  634.         {

  635.             if (auto* textInterface = getTextInterface (self))

  636.                 return juceStringToNS (textInterface->getText (nsRangeToJuce (range)));

  637. 

  638.             return nil;

  639.         }

  640. 

  641.         static NSRange getAccessibilityRangeForPosition (id self, SEL, NSPoint position)

  642.         {

  643.             if (auto* handler = getHandler (self))

  644.             {

  645.                 if (auto* textInterface = handler->getTextInterface())

  646.                 {

  647.                     auto screenPoint = convertToIntPoint (flippedScreenPoint (position));

  648. 

  649.                     if (handler->getComponent().getScreenBounds().contains (screenPoint))

  650.                     {

  651.                         auto offset = textInterface->getOffsetAtPoint (screenPoint);

  652. 

  653.                         if (offset >= 0)

  654.                             return NSMakeRange ((NSUInteger) offset, 1);

  655.                     }

  656.                 }

  657.             }

  658. 

  659.             return NSMakeRange (0, 0);

  660.         }

  661. 

  662.         static NSRange getAccessibilityRangeForIndex (id self, SEL, NSInteger index)

  663.         {

  664.             if (auto* textInterface = getTextInterface (self))

  665.                 if (isPositiveAndBelow (index, textInterface->getTotalNumCharacters()))

  666.                     return NSMakeRange ((NSUInteger) index, 1);

  667. 

  668.             return NSMakeRange (0, 0);

  669.         }

  670. 

  671.         static NSRect getAccessibilityFrameForRange (id self, SEL, NSRange range)

  672.         {

  673.             if (auto* textInterface = getTextInterface (self))

  674.                 return flippedScreenRect (makeNSRect (textInterface->getTextBounds (nsRangeToJuce (range)).getBounds()));

  675. 

  676.             return NSZeroRect;

  677.         }

  678. 

  679.         static NSData* getAccessibilityRTFForRange (id, SEL, NSRange)

  680.         {

  681.             return nil;

  682.         }

  683. 

  684.         static NSRange getAccessibilityStyleRangeForIndex (id self, SEL, NSInteger)

  685.         {

  686.             return [self accessibilityVisibleCharacterRange];

  687.         }

  688. 

  689.         static NSInteger getAccessibilityLineForIndex (id self, SEL, NSInteger index)

  690.         {

  691.             if (auto* textInterface = getTextInterface (self))

  692.             {

  693.                 auto text = textInterface->getText ({ 0, (int) index });

  694. 

  695.                 if (! text.isEmpty())

  696.                     return StringArray::fromLines (text).size() - 1;

  697.             }

  698. 

  699.             return 0;

  700.         }

  701. 

  702.         static void setAccessibilitySelectedTextRange (id self, SEL, NSRange selectedRange)

  703.         {

  704.             if (auto* textInterface = getTextInterface (self))

  705.             {

  706.                 textInterface->setSelection ({});

  707.                 textInterface->setSelection (nsRangeToJuce (selectedRange));

  708.             }

  709.         }

  710. 

  711.         //==============================================================================

  712.         static NSInteger getAccessibilityRowCount (id self, SEL)

  713.         {

  714.             if (auto* tableInterface = getTableInterface (self))

  715.                 return tableInterface->getNumRows();

  716. 

  717.             return 0;

  718.         }

  719. 

  720.         static NSArray* getAccessibilityRows (id self, SEL)

  721.         {

  722.             NSMutableArray* rows = [[NSMutableArray new] autorelease];

  723. 

  724.             if (auto* tableInterface = getTableInterface (self))

  725.             {

  726.                 for (int row = 0; row < tableInterface->getNumRows(); ++row)

  727.                 {

  728.                     if (auto* handler = tableInterface->getCellHandler (row, 0))

  729.                     {

  730.                         [rows addObject: (id) handler->getNativeImplementation()];

  731.                     }

  732.                     else

  733.                     {

  734.                         [rows addObject: [NSAccessibilityElement accessibilityElementWithRole: NSAccessibilityRowRole

  735.                                                                                          frame: NSZeroRect

  736.                                                                                          label: @"Offscreen Row"

  737.                                                                                         parent: self]];

  738.                     }

  739.                 }

  740.             }

  741. 

  742.             return rows;

  743.         }

  744. 

  745.         static NSArray* getAccessibilitySelectedRows (id self, SEL)

  746.         {

  747.             return getSelectedChildren ([self accessibilityRows]);

  748.         }

  749. 

  750.         static void setAccessibilitySelectedRows (id self, SEL, NSArray* selected)

  751.         {

  752.             setSelectedChildren ([self accessibilityRows], selected);

  753.         }

  754. 

  755.         static NSInteger getAccessibilityColumnCount (id self, SEL)

  756.         {

  757.             if (auto* tableInterface = getTableInterface (self))

  758.                 return tableInterface->getNumColumns();

  759. 

  760.             return 0;

  761.         }

  762. 

  763.         static NSArray* getAccessibilityColumns (id self, SEL)

  764.         {

  765.             NSMutableArray* columns = [[NSMutableArray new] autorelease];

  766. 

  767.             if (auto* tableInterface = getTableInterface (self))

  768.             {

  769.                 for (int column = 0; column < tableInterface->getNumColumns(); ++column)

  770.                 {

  771.                     if (auto* handler = tableInterface->getCellHandler (0, column))

  772.                     {

  773.                         [columns addObject: (id) handler->getNativeImplementation()];

  774.                     }

  775.                     else

  776.                     {

  777.                         [columns addObject: [NSAccessibilityElement accessibilityElementWithRole: NSAccessibilityColumnRole

  778.                                                                                             frame: NSZeroRect

  779.                                                                                             label: @"Offscreen Column"

  780.                                                                                            parent: self]];

  781.                     }

  782.                 }

  783.             }

  784. 

  785.             return columns;

  786.         }

  787. 

  788.         static NSArray* getAccessibilitySelectedColumns (id self, SEL)

  789.         {

  790.             return getSelectedChildren ([self accessibilityColumns]);

  791.         }

  792. 

  793.         static void setAccessibilitySelectedColumns (id self, SEL, NSArray* selected)

  794.         {

  795.             setSelectedChildren ([self accessibilityColumns], selected);

  796.         }

  797. 

  798.         //==============================================================================

  799.         static NSRange getAccessibilityRowIndexRange (id self, SEL)

  800.         {

  801.             if (auto* cellInterface = getCellInterface (self))

  802.                 return NSMakeRange ((NSUInteger) cellInterface->getRowIndex(),

  803.                                     (NSUInteger) cellInterface->getRowSpan());

  804. 

  805.             return NSMakeRange (0, 0);

  806.         }

  807. 

  808.         static NSRange getAccessibilityColumnIndexRange (id self, SEL)

  809.         {

  810.             if (auto* cellInterface = getCellInterface (self))

  811.                 return NSMakeRange ((NSUInteger) cellInterface->getColumnIndex(),

  812.                                     (NSUInteger) cellInterface->getColumnSpan());

  813. 

  814.             return NSMakeRange (0, 0);

  815.         }

  816. 

  817.         static NSInteger getAccessibilityIndex (id self, SEL)

  818.         {

  819.             if (auto* handler = getHandler (self))

  820.             {

  821.                 if (auto* cellInterface = handler->getCellInterface())

  822.                 {

  823.                     NSAccessibilityRole role = [self accessibilityRole];

  824. 

  825.                     if ([role isEqual: NSAccessibilityRowRole])

  826.                         return cellInterface->getRowIndex();

  827. 

  828.                     if ([role isEqual: NSAccessibilityColumnRole])

  829.                         return cellInterface->getColumnIndex();

  830.                 }

  831.             }

  832. 

  833.             return 0;

  834.         }

  835. 

  836.         static NSInteger getAccessibilityDisclosureLevel (id self, SEL)

  837.         {

  838.             if (auto* handler = getHandler (self))

  839.                 if (auto* cellInterface = handler->getCellInterface())

  840.                     return cellInterface->getDisclosureLevel();

  841. 

  842.             return 0;

  843.         }

  844. 

  845.         static BOOL getIsAccessibilityExpanded (id self, SEL)

  846.         {

  847.             if (auto* handler = getHandler (self))

  848.                 return handler->getCurrentState().isExpanded();

  849. 

  850.             return NO;

  851.         }

  852. 

  853.         //==============================================================================

  854.         static BOOL accessibilityPerformPress (id self, SEL)     { return performActionIfSupported (self, AccessibilityActionType::press); }

  855.         static BOOL accessibilityPerformShowMenu (id self, SEL)  { return performActionIfSupported (self, AccessibilityActionType::showMenu); }

  856. 

  857.         static BOOL accessibilityPerformRaise (id self, SEL)     { [self setAccessibilityFocused: YES]; return YES; }

  858. 

  859.         static BOOL accessibilityPerformIncrement (id self, SEL)

  860.         {

  861.             if (auto* valueInterface = getValueInterface (self))

  862.             {

  863.                 if (! valueInterface->isReadOnly())

  864.                 {

  865.                     auto range = valueInterface->getRange();

  866. 

  867.                     if (range.isValid())

  868.                     {

  869.                         valueInterface->setValue (jlimit (range.getMinimumValue(),

  870.                                                           range.getMaximumValue(),

  871.                                                           valueInterface->getCurrentValue() + range.getInterval()));

  872.                         return YES;

  873.                     }

  874.                 }

  875.             }

  876. 

  877.             return NO;

  878.         }

  879. 

  880.         static BOOL accessibilityPerformDecrement (id self, SEL)

  881.         {

  882.             if (auto* valueInterface = getValueInterface (self))

  883.             {

  884.                 if (! valueInterface->isReadOnly())

  885.                 {

  886.                     auto range = valueInterface->getRange();

  887. 

  888.                     if (range.isValid())

  889.                     {

  890.                         valueInterface->setValue (jlimit (range.getMinimumValue(),

  891.                                                           range.getMaximumValue(),

  892.                                                           valueInterface->getCurrentValue() - range.getInterval()));

  893.                         return YES;

  894.                     }

  895.                 }

  896.             }

  897. 

  898.             return NO;

  899.         }

  900. 

  901.         static BOOL accessibilityPerformDelete (id self, SEL)

  902.         {

  903.             if (auto* handler = getHandler (self))

  904.             {

  905.                 if (hasEditableText (*handler))

  906.                 {

  907.                     handler->getTextInterface()->setText ({});

  908.                     return YES;

  909.                 }

  910. 

  911.                 if (auto* valueInterface = handler->getValueInterface())

  912.                 {

  913.                     if (! valueInterface->isReadOnly())

  914.                     {

  915.                         valueInterface->setValue ({});

  916.                         return YES;

  917.                     }

  918.                 }

  919.             }

  920. 

  921.             return NO;

  922.         }

  923. 

  924.         //==============================================================================

  925.         static BOOL getIsAccessibilitySelectorAllowed (id self, SEL, SEL selector)

  926.         {

  927.             if (auto* handler = getHandler (self))

  928.             {

  929.                 const auto role = handler->getRole();

  930.                 const auto currentState = handler->getCurrentState();

  931. 

  932.                 for (auto textSelector : { @selector (accessibilityInsertionPointLineNumber),

  933.                                            @selector (accessibilitySharedCharacterRange),

  934.                                            @selector (accessibilitySharedTextUIElements),

  935.                                            @selector (accessibilityVisibleCharacterRange),

  936.                                            @selector (accessibilityNumberOfCharacters),

  937.                                            @selector (accessibilitySelectedText),

  938.                                            @selector (accessibilitySelectedTextRange),

  939.                                            @selector (accessibilitySelectedTextRanges),

  940.                                            @selector (accessibilityAttributedStringForRange:),

  941.                                            @selector (accessibilityRangeForLine:),

  942.                                            @selector (accessibilityStringForRange:),

  943.                                            @selector (accessibilityRangeForPosition:),

  944.                                            @selector (accessibilityRangeForIndex:),

  945.                                            @selector (accessibilityFrameForRange:),

  946.                                            @selector (accessibilityRTFForRange:),

  947.                                            @selector (accessibilityStyleRangeForIndex:),

  948.                                            @selector (accessibilityLineForIndex:),

  949.                                            @selector (setAccessibilitySelectedTextRange:) })

  950.                 {

  951.                     if (selector == textSelector)

  952.                         return handler->getTextInterface() != nullptr;

  953.                 }

  954. 

  955.                 for (auto tableSelector : { @selector (accessibilityRowCount),

  956.                                             @selector (accessibilityRows),

  957.                                             @selector (accessibilitySelectedRows),

  958.                                             @selector (accessibilityColumnCount),

  959.                                             @selector (accessibilityColumns),

  960.                                             @selector (accessibilitySelectedColumns) })

  961.                 {

  962.                     if (selector == tableSelector)

  963.                         return handler->getTableInterface() != nullptr;

  964.                 }

  965. 

  966.                 for (auto cellSelector : { @selector (accessibilityRowIndexRange),

  967.                                            @selector (accessibilityColumnIndexRange),

  968.                                            @selector (accessibilityIndex),

  969.                                            @selector (accessibilityDisclosureLevel) })

  970.                 {

  971.                     if (selector == cellSelector)

  972.                         return handler->getCellInterface() != nullptr;

  973.                 }

  974. 

  975.                 for (auto valueSelector : { @selector (accessibilityValue),

  976.                                             @selector (setAccessibilityValue:),

  977.                                             @selector (accessibilityPerformDelete),

  978.                                             @selector (accessibilityPerformIncrement),

  979.                                             @selector (accessibilityPerformDecrement) })

  980.                 {

  981.                     if (selector != valueSelector)

  982.                         continue;

  983. 

  984.                     auto* valueInterface = handler->getValueInterface();

  985. 

  986.                     if (selector == @selector (accessibilityValue))

  987.                         return valueInterface != nullptr

  988.                             || hasEditableText (*handler)

  989.                             || currentState.isCheckable();

  990. 

  991.                     auto hasEditableValue = [valueInterface] { return valueInterface != nullptr && ! valueInterface->isReadOnly(); };

  992. 

  993.                     if (selector == @selector (setAccessibilityValue:)

  994.                      || selector == @selector (accessibilityPerformDelete))

  995.                         return hasEditableValue() || hasEditableText (*handler);

  996. 

  997.                     auto isRanged = [valueInterface] { return valueInterface != nullptr && valueInterface->getRange().isValid(); };

  998. 

  999.                     if (selector == @selector (accessibilityPerformIncrement)

  1000.                      || selector == @selector (accessibilityPerformDecrement))

  1001.                         return hasEditableValue() && isRanged();

  1002. 

  1003.                     return NO;

  1004.                 }

  1005. 

  1006.                 for (auto actionSelector : { @selector (accessibilityPerformPress),

  1007.                                              @selector (accessibilityPerformShowMenu),

  1008.                                              @selector (accessibilityPerformRaise),

  1009.                                              @selector (setAccessibilityFocused:) })

  1010.                 {

  1011.                     if (selector != actionSelector)

  1012.                         continue;

  1013. 

  1014.                     if (selector == @selector (accessibilityPerformPress))

  1015.                         return handler->getActions().contains (AccessibilityActionType::press);

  1016. 

  1017.                     if (selector == @selector (accessibilityPerformShowMenu))

  1018.                         return handler->getActions().contains (AccessibilityActionType::showMenu);

  1019. 

  1020.                     if (selector == @selector (accessibilityPerformRaise))

  1021.                         return [[self accessibilityRole] isEqual: NSAccessibilityWindowRole];

  1022. 

  1023.                     if (selector == @selector (setAccessibilityFocused:))

  1024.                         return currentState.isFocusable();

  1025.                 }

  1026. 

  1027.                 if (selector == @selector (accessibilitySelectedChildren))

  1028.                     return role == AccessibilityRole::popupMenu;

  1029. 

  1030.                 if (selector == @selector (accessibilityOrientation))

  1031.                     return role == AccessibilityRole::scrollBar;

  1032. 

  1033.                 if (selector == @selector (isAccessibilityExpanded))

  1034.                     return currentState.isExpandable();

  1035. 

  1036.                 return sendSuperclassMessage<BOOL> (self, @selector (isAccessibilitySelectorAllowed:), selector);

  1037.             }

  1038. 

  1039.             return NO;

  1040.         }

  1041. 

  1042.         //==============================================================================

  1043.         JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityElement)

  1044.     };

  1045. 

  1046.     //==============================================================================

  1047.     AccessibilityElement::Holder accessibilityElement;

  1048. 

  1049.     //==============================================================================

  1050.     JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityNativeImpl)

  1051. };

  1052. 

  1053. //==============================================================================

  1054. AccessibilityNativeHandle* AccessibilityHandler::getNativeImplementation() const

  1055. {

  1056.     return (AccessibilityNativeHandle*) nativeImpl->getAccessibilityElement();

  1057. }

  1058. 

  1059. static void sendAccessibilityEvent (id accessibilityElement,

  1060.                                     NSAccessibilityNotificationName notification,

  1061.                                     NSDictionary* userInfo)

  1062. {

  1063.     jassert (notification != NSAccessibilityNotificationName{});

  1064. 

  1065.     NSAccessibilityPostNotificationWithUserInfo (accessibilityElement, notification, userInfo);

  1066. }

  1067. 

  1068. void notifyAccessibilityEventInternal (const AccessibilityHandler& handler, InternalAccessibilityEvent eventType)

  1069. {

  1070.     auto notification = [eventType]

  1071.     {

  1072.         switch (eventType)

  1073.         {

  1074.             case InternalAccessibilityEvent::elementCreated:    return NSAccessibilityCreatedNotification;

  1075.             case InternalAccessibilityEvent::elementDestroyed:  return NSAccessibilityUIElementDestroyedNotification;

  1076.             case InternalAccessibilityEvent::focusChanged:      return NSAccessibilityFocusedUIElementChangedNotification;

  1077.             case InternalAccessibilityEvent::windowOpened:      return NSAccessibilityWindowCreatedNotification;

  1078.             case InternalAccessibilityEvent::windowClosed:      break;

  1079.         }

  1080. 

  1081.         return NSAccessibilityNotificationName{};

  1082.     }();

  1083. 

  1084.     if (notification != NSAccessibilityNotificationName{})

  1085.         sendAccessibilityEvent ((id) handler.getNativeImplementation(), notification, nil);

  1086. }

  1087. 

  1088. void AccessibilityHandler::notifyAccessibilityEvent (AccessibilityEvent eventType) const

  1089. {

  1090.     auto notification = [eventType]

  1091.     {

  1092.         switch (eventType)

  1093.         {

  1094.             case AccessibilityEvent::textSelectionChanged:  return NSAccessibilitySelectedTextChangedNotification;

  1095.             case AccessibilityEvent::rowSelectionChanged:   return NSAccessibilitySelectedRowsChangedNotification;

  1096. 

  1097.             case AccessibilityEvent::textChanged:

  1098.             case AccessibilityEvent::valueChanged:          return NSAccessibilityValueChangedNotification;

  1099.             case AccessibilityEvent::titleChanged:          return NSAccessibilityTitleChangedNotification;

  1100.             case AccessibilityEvent::structureChanged:      return NSAccessibilityLayoutChangedNotification;

  1101.         }

  1102. 

  1103.         return NSAccessibilityNotificationName{};

  1104.     }();

  1105. 

  1106.     if (notification != NSAccessibilityNotificationName{})

  1107.     {

  1108.         id accessibilityElement = (id) getNativeImplementation();

  1109. 

  1110.         sendAccessibilityEvent (accessibilityElement, notification,

  1111.                                 (notification == NSAccessibilityLayoutChangedNotification

  1112.                                    ? @{ NSAccessibilityUIElementsKey: @[ accessibilityElement ] }

  1113.                                    : nil));

  1114.     }

  1115. }

  1116. 

  1117. void AccessibilityHandler::postAnnouncement (const String& announcementString, AnnouncementPriority priority)

  1118. {

  1119.     auto nsPriority = [priority]

  1120.     {

  1121.         switch (priority)

  1122.         {

  1123.             case AnnouncementPriority::low:    return NSAccessibilityPriorityLow;

  1124.             case AnnouncementPriority::medium: return NSAccessibilityPriorityMedium;

  1125.             case AnnouncementPriority::high:   return NSAccessibilityPriorityHigh;

  1126.         }

  1127. 

  1128.         jassertfalse;

  1129.         return NSAccessibilityPriorityLow;

  1130.     }();

  1131. 

  1132.     sendAccessibilityEvent ((id) [NSApp mainWindow],

  1133.                             NSAccessibilityAnnouncementRequestedNotification,

  1134.                             @{ NSAccessibilityAnnouncementKey: juceStringToNS (announcementString),

  1135.                                NSAccessibilityPriorityKey:     @(nsPriority) });

  1136. }

  1137. 

  1138. AccessibilityHandler::AccessibilityNativeImpl* AccessibilityHandler::createNativeImpl (AccessibilityHandler& handler)

  1139. {

  1140.     return new AccessibilityHandler::AccessibilityNativeImpl (handler);

  1141. }

  1142. 

  1143. void AccessibilityHandler::DestroyNativeImpl::operator() (AccessibilityHandler::AccessibilityNativeImpl* impl) const noexcept

  1144. {

  1145.     delete impl;

  1146. }

  1147. 

  1148. #endif

  1149. 

  1150. } // namespace juce