DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
9152 Commits
11 Branches
450MB
Tree: cfb071d52f
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'cfb071d52f'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

1864 lines
80KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2017 - ROLI Ltd.

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 5 End-User License

  11.    Agreement and JUCE 5 Privacy Policy (both updated and effective as of the

  12.    27th April 2017).

  13. 

  14.    End User License Agreement: www.juce.com/juce-5-licence

  15.    Privacy Policy: www.juce.com/juce-5-privacy-policy

  16. 

  17.    Or: You may also use this code under the terms of the GPL v3 (see

  18.    www.gnu.org/licenses).

  19. 

  20.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  21.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  22.    DISCLAIMED.

  23. 

  24.   ==============================================================================

  25. */

  26. 

  27. #include "../../juce_core/system/juce_TargetPlatform.h"

  28. #include "../utility/juce_CheckSettingMacros.h"

  29. 

  30. #if JucePlugin_Build_AUv3

  31. 

  32. #import <CoreAudioKit/CoreAudioKit.h>

  33. #import <AudioToolbox/AudioToolbox.h>

  34. #import <AVFoundation/AVFoundation.h>

  35. 

  36. #if JUCE_MAC

  37.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  38.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  39.  #endif

  40.  #if (defined MAC_OS_X_VERSION_10_13) && (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_13)

  41.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  42.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  43.  #endif

  44. #endif

  45. 

  46. #if JUCE_IOS

  47.  #if (! defined __IPHONE_OS_VERSION_MIN_REQUIRED) || (! defined __IPHONE_9_0) || (__IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_9_0)

  48.   #error AUv3 needs Deployment Target iOS 9.0 or higher to compile

  49.  #endif

  50.  #if (defined __IPHONE_11_0) && (__IPHONE_OS_VERSION_MIN_REQUIRED >= __IPHONE_11_0)

  51.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  52.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  53.  #endif

  54. #endif

  55. 

  56. #ifndef __OBJC2__

  57.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  58. #endif

  59. 

  60. #define JUCE_CORE_INCLUDE_OBJC_HELPERS 1

  61. 

  62. #include "../utility/juce_IncludeSystemHeaders.h"

  63. #include "../utility/juce_IncludeModuleHeaders.h"

  64. #include "../../juce_graphics/native/juce_mac_CoreGraphicsHelpers.h"

  65. 

  66. #include "../../juce_audio_basics/native/juce_mac_CoreAudioLayouts.h"

  67. #include "../../juce_audio_processors/format_types/juce_LegacyAudioParameter.cpp"

  68. #include "../../juce_audio_processors/format_types/juce_AU_Shared.h"

  69. 

  70. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  71. 

  72. #if JUCE_IOS

  73.  #define JUCE_IOS_MAC_VIEW  UIView

  74. #else

  75.  #define JUCE_IOS_MAC_VIEW  NSView

  76. #endif

  77. 

  78. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  79. 

  80. #pragma clang diagnostic push

  81. #pragma clang diagnostic ignored "-Wnullability-completeness"

  82. 

  83. using namespace juce;

  84. 

  85. struct AudioProcessorHolder  : public ReferenceCountedObject

  86. {

  87.     AudioProcessorHolder() {}

  88.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  89.     AudioProcessor& operator*() noexcept        { return *processor; }

  90.     AudioProcessor* operator->() noexcept       { return processor.get(); }

  91.     AudioProcessor* get() noexcept              { return processor.get(); }

  92. 

  93.     struct ViewConfig

  94.     {

  95.         double width;

  96.         double height;

  97.         bool hostHasMIDIController;

  98.     };

  99. 

  100.     std::unique_ptr<ViewConfig> viewConfiguration;

  101. 

  102.     using Ptr = ReferenceCountedObjectPtr<AudioProcessorHolder>;

  103. 

  104. private:

  105.     std::unique_ptr<AudioProcessor> processor;

  106. 

  107.     AudioProcessorHolder& operator= (AudioProcessor*) = delete;

  108.     AudioProcessorHolder (AudioProcessorHolder&) = delete;

  109.     AudioProcessorHolder& operator= (AudioProcessorHolder&) = delete;

  110. };

  111. 

  112. //==============================================================================

  113. class JuceAudioUnitv3Base

  114. {

  115. public:

  116.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  117.                          AudioComponentInstantiationOptions options,

  118.                          NSError** error)

  119.        #pragma clang diagnostic push

  120.        #pragma clang diagnostic ignored "-Wobjc-method-access"

  121.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  122.                                                                         options: options

  123.                                                                           error: error

  124.                                                                       juceClass: this])

  125.        #pragma clang diagnostic pop

  126.     {}

  127. 

  128.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  129.     {

  130.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  131.         initialiseJuce_GUI();

  132.     }

  133. 

  134.     virtual ~JuceAudioUnitv3Base() {}

  135. 

  136.     //==============================================================================

  137.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  138. 

  139.     //==============================================================================

  140.     virtual void reset()                                                   = 0;

  141. 

  142.     //==============================================================================

  143.     virtual AUAudioUnitPreset* getCurrentPreset()                          = 0;

  144.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      = 0;

  145.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()               = 0;

  146. 

  147.     virtual NSDictionary<NSString*, id>* getFullState()

  148.     {

  149.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  150.         return ObjCMsgSendSuper<NSDictionary<NSString*, id>*> (&s, @selector (fullState));

  151.     }

  152. 

  153.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  154.     {

  155.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  156.         ObjCMsgSendSuper<void, NSDictionary<NSString*, id>*> (&s, @selector (setFullState:), state);

  157.     }

  158. 

  159.     virtual AUParameterTree* getParameterTree()                            = 0;

  160.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)       = 0;

  161. 

  162.     //==============================================================================

  163.     virtual NSTimeInterval getLatency()                                    = 0;

  164.     virtual NSTimeInterval getTailTime()                                   = 0;

  165. 

  166.     //==============================================================================

  167.     virtual AUAudioUnitBusArray* getInputBusses()                          = 0;

  168.     virtual AUAudioUnitBusArray* getOutputBusses()                         = 0;

  169.     virtual NSArray<NSNumber*>* getChannelCapabilities()                   = 0;

  170.     virtual bool shouldChangeToFormat (AVAudioFormat*, AUAudioUnitBus*)    = 0;

  171. 

  172.     //==============================================================================

  173.     virtual int getVirtualMIDICableCount()                                 = 0;

  174.     virtual bool getSupportsMPE()                                          = 0;

  175.     virtual NSArray<NSString*>* getMIDIOutputNames()                       = 0;

  176. 

  177.     //==============================================================================

  178.     virtual AUInternalRenderBlock getInternalRenderBlock()                 = 0;

  179.     virtual bool getCanProcessInPlace()                                    { return false; }

  180.     virtual bool getRenderingOffline()                                     = 0;

  181.     virtual void setRenderingOffline (bool offline)                        = 0;

  182. 

  183.     virtual bool getShouldBypassEffect()

  184.     {

  185.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  186.         return (ObjCMsgSendSuper<BOOL> (&s, @selector (shouldBypassEffect)) == YES);

  187.     }

  188. 

  189.     virtual void setShouldBypassEffect (bool shouldBypass)

  190.     {

  191.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  192.         ObjCMsgSendSuper<void, BOOL> (&s, @selector (setShouldBypassEffect:), shouldBypass ? YES : NO);

  193.     }

  194. 

  195.     //==============================================================================

  196.     virtual NSString* getContextName()      const                          = 0;

  197.     virtual void setContextName (NSString*)                                = 0;

  198. 

  199.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  200.     {

  201.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  202.         return (ObjCMsgSendSuper<BOOL, NSError**> (&s, @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  203.     }

  204. 

  205.     virtual void deallocateRenderResources()

  206.     {

  207.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  208.         ObjCMsgSendSuper<void> (&s, @selector (deallocateRenderResources));

  209.     }

  210. 

  211.     //==============================================================================

  212.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  213.     virtual NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>*) = 0;

  214.     virtual void selectViewConfiguration (AUAudioUnitViewConfiguration*)   = 0;

  215.    #endif

  216. 

  217. private:

  218.     struct Class  : public ObjCClass<AUAudioUnit>

  219.     {

  220.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  221.         {

  222.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  223. 

  224.            #pragma clang diagnostic push

  225.            #pragma clang diagnostic ignored "-Wundeclared-selector"

  226.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  227.                        initWithComponentDescriptionAndJuceClass, "@@:",

  228.                        @encode (AudioComponentDescription),

  229.                        @encode (AudioComponentInstantiationOptions), "^@@");

  230.            #pragma clang diagnostic pop

  231. 

  232.             addMethod (@selector (initWithComponentDescription:options:error:),

  233.                        initWithComponentDescription, "@@:",

  234.                        @encode (AudioComponentDescription),

  235.                        @encode (AudioComponentInstantiationOptions), "^@");

  236. 

  237.             addMethod (@selector (dealloc),                         dealloc,                        "v@:");

  238. 

  239.             //==============================================================================

  240.             addMethod (@selector (reset),                           reset,                          "v@:");

  241. 

  242.             //==============================================================================

  243.             addMethod (@selector (currentPreset),                   getCurrentPreset,               "@@:");

  244.             addMethod (@selector (setCurrentPreset:),               setCurrentPreset,               "v@:@");

  245.             addMethod (@selector (factoryPresets),                  getFactoryPresets,              "@@:");

  246.             addMethod (@selector (fullState),                       getFullState,                   "@@:");

  247.             addMethod (@selector (setFullState:),                   setFullState,                   "v@:@");

  248.             addMethod (@selector (parameterTree),                   getParameterTree,               "@@:");

  249.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  250. 

  251.             //==============================================================================

  252.             addMethod (@selector (latency),                         getLatency,                     @encode (NSTimeInterval), "@:");

  253.             addMethod (@selector (tailTime),                        getTailTime,                    @encode (NSTimeInterval),  "@:");

  254. 

  255.             //==============================================================================

  256.             addMethod (@selector (inputBusses),                     getInputBusses,                 "@@:");

  257.             addMethod (@selector (outputBusses),                    getOutputBusses,                "@@:");

  258.             addMethod (@selector (channelCapabilities),             getChannelCapabilities,         "@@:");

  259.             addMethod (@selector (shouldChangeToFormat:forBus:),    shouldChangeToFormat,           "B@:@@");

  260. 

  261.             //==============================================================================

  262.             addMethod (@selector (virtualMIDICableCount),           getVirtualMIDICableCount,       @encode (NSInteger), "@:");

  263.             addMethod (@selector (supportsMPE),                     getSupportsMPE,                 @encode (BOOL),      "@:");

  264. 

  265.            #if JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  266.             addMethod (@selector (MIDIOutputNames),                 getMIDIOutputNames,             "@@:");

  267.            #endif

  268. 

  269.             //==============================================================================

  270.             addMethod (@selector (internalRenderBlock),             getInternalRenderBlock,         @encode (AUInternalRenderBlock), "@:");

  271.             addMethod (@selector (canProcessInPlace),               getCanProcessInPlace,           @encode (BOOL), "@:");

  272.             addMethod (@selector (isRenderingOffline),              getRenderingOffline,            @encode (BOOL),  "@:");

  273.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  274.             addMethod (@selector (shouldBypassEffect),              getShouldBypassEffect,          @encode (BOOL),  "@:");

  275.             addMethod (@selector (setShouldBypassEffect:),          setShouldBypassEffect,          "v@:", @encode (BOOL));

  276.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "B@:^@");

  277.             addMethod (@selector (deallocateRenderResources),       deallocateRenderResources,      "v@:");

  278. 

  279.             //==============================================================================

  280.             addMethod (@selector (contextName),                     getContextName,                 "@@:");

  281.             addMethod (@selector (setContextName:),                  setContextName,                 "v@:@");

  282. 

  283.             //==============================================================================

  284.            #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  285.             addMethod (@selector (supportedViewConfigurations:),    getSupportedViewConfigurations, "@@:@");

  286.             addMethod (@selector (selectViewConfiguration:),        selectViewConfiguration,        "v@:@");

  287.            #endif

  288. 

  289.             registerClass();

  290.         }

  291. 

  292.         //==============================================================================

  293.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  294.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  295. 

  296.         //==============================================================================

  297.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  298.         {

  299.             AUAudioUnit* self = _self;

  300. 

  301.             objc_super s = { self, [AUAudioUnit class] };

  302.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  303.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  304. 

  305.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  306. 

  307.             setThis (self, juceAU);

  308.             return self;

  309.         }

  310. 

  311.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  312.         {

  313.             AUAudioUnit* self = _self;

  314. 

  315.             objc_super s = { self, [AUAudioUnit class] };

  316.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  317.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  318. 

  319. 

  320.             setThis (self, juceAU);

  321.             return self;

  322.         }

  323. 

  324.         static void dealloc (id self, SEL)

  325.         {

  326.             if (! MessageManager::getInstance()->isThisTheMessageThread())

  327.             {

  328.                 WaitableEvent deletionEvent;

  329. 

  330.                 struct AUDeleter  : public CallbackMessage

  331.                 {

  332.                     AUDeleter (id selfToDelete, WaitableEvent& event)

  333.                         : parentSelf (selfToDelete), parentDeletionEvent (event)

  334.                     {

  335.                     }

  336. 

  337.                     void messageCallback() override

  338.                     {

  339.                         delete _this (parentSelf);

  340.                         parentDeletionEvent.signal();

  341.                     }

  342. 

  343.                     id parentSelf;

  344.                     WaitableEvent& parentDeletionEvent;

  345.                 };

  346. 

  347.                 (new AUDeleter (self, deletionEvent))->post();

  348.                 deletionEvent.wait (-1);

  349.             }

  350.             else

  351.             {

  352.                 delete _this (self);

  353.             }

  354.         }

  355. 

  356.         //==============================================================================

  357.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  358. 

  359.         //==============================================================================

  360.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  361.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  362.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  363.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  364.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  365.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  366.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  367. 

  368.         //==============================================================================

  369.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  370.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  371. 

  372.         //==============================================================================

  373.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  374.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  375.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  376.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  377. 

  378.         //==============================================================================

  379.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  380.         static BOOL getSupportsMPE (id self, SEL)                                                   { return _this (self)->getSupportsMPE() ? YES : NO; }

  381.         static NSArray<NSString*>* getMIDIOutputNames (id self, SEL)                                { return _this (self)->getMIDIOutputNames(); }

  382. 

  383.         //==============================================================================

  384.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  385.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  386.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  387.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  388.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  389.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  390.         static BOOL getShouldBypassEffect (id self, SEL)                                            { return _this (self)->getShouldBypassEffect() ? YES : NO; }

  391.         static void setShouldBypassEffect (id self, SEL, BOOL shouldBypass)                         { _this (self)->setShouldBypassEffect (shouldBypass); }

  392. 

  393.         //==============================================================================

  394.         static NSString* getContextName (id self, SEL)                                              { return _this (self)->getContextName(); }

  395.         static void setContextName (id self, SEL, NSString* str)                                    { return _this (self)->setContextName (str); }

  396. 

  397.         //==============================================================================

  398.        #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  399.         static NSIndexSet* getSupportedViewConfigurations (id self, SEL, NSArray<AUAudioUnitViewConfiguration*>* configs) { return _this (self)->getSupportedViewConfigurations (configs); }

  400.         static void selectViewConfiguration (id self, SEL, AUAudioUnitViewConfiguration* config)    { _this (self)->selectViewConfiguration (config); }

  401.        #endif

  402.     };

  403. 

  404.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  405. 

  406.     //==============================================================================

  407.     static Class audioUnitObjCClass;

  408. 

  409. protected:

  410.     AUAudioUnit* au;

  411. };

  412. 

  413. //==============================================================================

  414. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  415. 

  416. //==============================================================================

  417. //=========================== The actual AudioUnit =============================

  418. //==============================================================================

  419. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  420.                          public AudioProcessorListener,

  421.                          public AudioPlayHead,

  422.                          private AudioProcessorParameter::Listener

  423. {

  424. public:

  425.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  426.                      const AudioComponentDescription& descr,

  427.                      AudioComponentInstantiationOptions options,

  428.                      NSError** error)

  429.         : JuceAudioUnitv3Base (descr, options, error),

  430.           processorHolder (processor),

  431.           mapper (*processorHolder->get())

  432.     {

  433.         init();

  434.     }

  435. 

  436.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  437.         : JuceAudioUnitv3Base (audioUnit),

  438.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  439.           mapper (*processorHolder->get())

  440.     {

  441.         init();

  442.     }

  443. 

  444.     ~JuceAudioUnitv3()

  445.     {

  446.         auto& processor = getAudioProcessor();

  447.         processor.removeListener (this);

  448. 

  449.         if (bypassParam != nullptr)

  450.             bypassParam->removeListener (this);

  451. 

  452.         removeEditor (processor);

  453. 

  454.         if (editorObserverToken != nullptr)

  455.         {

  456.             [paramTree.get() removeParameterObserver: editorObserverToken];

  457.             editorObserverToken = nullptr;

  458.         }

  459.     }

  460. 

  461.     //==============================================================================

  462.     void init()

  463.     {

  464.         inParameterChangedCallback = false;

  465. 

  466.         AudioProcessor& processor = getAudioProcessor();

  467.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  468. 

  469.        #ifdef JucePlugin_PreferredChannelConfigurations

  470.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  471.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  472. 

  473.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  474.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  475. 

  476.         Array<AUChannelInfo> channelInfos;

  477. 

  478.         for (int i = 0; i < numConfigs; ++i)

  479.         {

  480.             AUChannelInfo channelInfo;

  481. 

  482.             channelInfo.inChannels  = configs[i][0];

  483.             channelInfo.outChannels = configs[i][1];

  484. 

  485.             channelInfos.add (channelInfo);

  486.         }

  487.        #else

  488.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  489.        #endif

  490. 

  491.         processor.setPlayHead (this);

  492. 

  493.         totalInChannels  = processor.getTotalNumInputChannels();

  494.         totalOutChannels = processor.getTotalNumOutputChannels();

  495. 

  496.         {

  497.             channelCapabilities.reset ([[NSMutableArray<NSNumber*> alloc] init]);

  498. 

  499.             for (int i = 0; i < channelInfos.size(); ++i)

  500.             {

  501.                 AUChannelInfo& info = channelInfos.getReference (i);

  502. 

  503.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.inChannels]];

  504.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.outChannels]];

  505.             }

  506.         }

  507. 

  508.         editorObserverToken = nullptr;

  509.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  510. 

  511.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  512.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  513.         processor.addListener (this);

  514. 

  515.         addParameters();

  516.         addPresets();

  517. 

  518.         addAudioUnitBusses (true);

  519.         addAudioUnitBusses (false);

  520.     }

  521. 

  522.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  523. 

  524.     //==============================================================================

  525.     void reset() override

  526.     {

  527.         midiMessages.clear();

  528.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  529.     }

  530. 

  531.     //==============================================================================

  532.     AUAudioUnitPreset* getCurrentPreset() override

  533.     {

  534.         const int n = static_cast<int> ([factoryPresets.get() count]);

  535.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  536. 

  537.         if (idx < n)

  538.             return [factoryPresets.get() objectAtIndex:static_cast<unsigned int> (idx)];

  539. 

  540.         return nullptr;

  541.     }

  542. 

  543.     void setCurrentPreset(AUAudioUnitPreset* preset) override

  544.     {

  545.         const int n = static_cast<int> ([factoryPresets.get() count]);

  546.         const int idx = static_cast<int> ([preset number]);

  547. 

  548.         if (isPositiveAndBelow (idx, n))

  549.             getAudioProcessor().setCurrentProgram (idx);

  550.     }

  551. 

  552.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override

  553.     {

  554.         return factoryPresets.get();

  555.     }

  556. 

  557.     NSDictionary<NSString*, id>* getFullState() override

  558.     {

  559.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  560. 

  561.         {

  562.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  563. 

  564.             if (superRetval != nullptr)

  565.                 [retval addEntriesFromDictionary:superRetval];

  566.         }

  567. 

  568.         juce::MemoryBlock state;

  569.         getAudioProcessor().getCurrentProgramStateInformation (state);

  570. 

  571.         if (state.getSize() > 0)

  572.         {

  573.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  574.                                                       length: state.getSize()];

  575. 

  576.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  577. 

  578.             [retval setObject: ourState

  579.                        forKey: nsKey];

  580. 

  581.             [nsKey    release];

  582.             [ourState release];

  583.         }

  584. 

  585.         return [retval autorelease];

  586.     }

  587. 

  588.     void setFullState (NSDictionary<NSString*, id>* state) override

  589.     {

  590.         if (state == nullptr)

  591.             return;

  592. 

  593.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  594.         [modifiedState addEntriesFromDictionary: state];

  595. 

  596.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  597.         [modifiedState removeObjectForKey: nsPresetKey];

  598.         [nsPresetKey release];

  599. 

  600.         JuceAudioUnitv3Base::setFullState (modifiedState);

  601. 

  602.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  603.         NSObject* obj = [modifiedState objectForKey: nsKey];

  604.         [nsKey release];

  605. 

  606.         if (obj != nullptr)

  607.         {

  608.             if ([obj isKindOfClass:[NSData class]])

  609.             {

  610.                 NSData* data = reinterpret_cast<NSData*> (obj);

  611.                 const int numBytes = static_cast<int> ([data length]);

  612.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  613. 

  614.                 if (numBytes > 0)

  615.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  616.             }

  617.         }

  618. 

  619.         [modifiedState release];

  620.     }

  621. 

  622.     AUParameterTree* getParameterTree() override

  623.     {

  624.         return paramTree.get();

  625.     }

  626. 

  627.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  628.     {

  629.         const int n = static_cast<int> ([overviewParams.get() count]);

  630. 

  631.         if (count >= n)

  632.             return overviewParams.get();

  633. 

  634.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams.get()];

  635.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  636. 

  637.         return [retval autorelease];

  638.     }

  639. 

  640.     //==============================================================================

  641.     NSTimeInterval getLatency() override

  642.     {

  643.         auto& p = getAudioProcessor();

  644.         return p.getLatencySamples() / p.getSampleRate();

  645.     }

  646. 

  647.     NSTimeInterval getTailTime() override

  648.     {

  649.         return getAudioProcessor().getTailLengthSeconds();

  650.     }

  651. 

  652.     //==============================================================================

  653.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses.get();  }

  654.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses.get(); }

  655.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities.get(); }

  656. 

  657.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  658.     {

  659.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  660.         const int busIdx = static_cast<int> ([auBus index]);

  661.         const int newNumChannels = static_cast<int> ([format channelCount]);

  662. 

  663.         AudioProcessor& processor = getAudioProcessor();

  664. 

  665.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  666.         {

  667.           #ifdef JucePlugin_PreferredChannelConfigurations

  668.             ignoreUnused (bus);

  669. 

  670.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  671. 

  672.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  673.                 return false;

  674.           #else

  675.             const AVAudioChannelLayout* layout    = [format channelLayout];

  676.             const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  677. 

  678.             if (layoutTag != 0)

  679.             {

  680.                 AudioChannelSet newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  681. 

  682.                 if (newLayout.size() != newNumChannels)

  683.                     return false;

  684. 

  685.                 if (! bus->isLayoutSupported (newLayout))

  686.                     return false;

  687.             }

  688.             else

  689.             {

  690.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  691.                     return false;

  692.             }

  693.            #endif

  694. 

  695.             return true;

  696.         }

  697. 

  698.         return false;

  699.     }

  700. 

  701.     //==============================================================================

  702.     int getVirtualMIDICableCount() override

  703.     {

  704.        #if JucePlugin_WantsMidiInput

  705.         return 1;

  706.        #else

  707.         return 0;

  708.        #endif

  709.     }

  710. 

  711.     bool getSupportsMPE() override

  712.     {

  713.         return getAudioProcessor().supportsMPE();

  714.     }

  715. 

  716.     NSArray<NSString*>* getMIDIOutputNames() override

  717.     {

  718.        #if JucePlugin_ProducesMidiOutput

  719.         return @[@"MIDI Out"];

  720.        #else

  721.         return @[];

  722.        #endif

  723.     }

  724. 

  725.     //==============================================================================

  726.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  727.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  728.     void setRenderingOffline (bool offline) override

  729.     {

  730.         auto& processor = getAudioProcessor();

  731.         auto isCurrentlyNonRealtime = processor.isNonRealtime();

  732. 

  733.         if (isCurrentlyNonRealtime != offline)

  734.         {

  735.             ScopedLock callbackLock (processor.getCallbackLock());

  736. 

  737.             processor.setNonRealtime (offline);

  738.             processor.prepareToPlay (processor.getSampleRate(), processor.getBlockSize());

  739.         }

  740.     }

  741. 

  742.     bool getShouldBypassEffect() override

  743.     {

  744.         if (bypassParam != nullptr)

  745.             return (bypassParam->getValue() != 0.0f);

  746. 

  747.         return JuceAudioUnitv3Base::getShouldBypassEffect();

  748.     }

  749. 

  750.     void setShouldBypassEffect (bool shouldBypass) override

  751.     {

  752.         if (bypassParam != nullptr)

  753.             bypassParam->setValue (shouldBypass ? 1.0f : 0.0f);

  754. 

  755.         JuceAudioUnitv3Base::setShouldBypassEffect (shouldBypass);

  756.     }

  757. 

  758.     //==============================================================================

  759.     NSString* getContextName() const    override              { return juceStringToNS (contextName); }

  760.     void setContextName (NSString* str) override

  761.     {

  762.         if (str != nullptr)

  763.         {

  764.             AudioProcessor::TrackProperties props;

  765.             props.name = nsStringToJuce (str);

  766. 

  767.             getAudioProcessor().updateTrackProperties (props);

  768.         }

  769.     }

  770. 

  771.     //==============================================================================

  772.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  773.     {

  774.         AudioProcessor& processor = getAudioProcessor();

  775.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  776. 

  777.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  778.             return false;

  779. 

  780.         if (outError != nullptr)

  781.             *outError = nullptr;

  782. 

  783.         AudioProcessor::BusesLayout layouts;

  784.         for (int dir = 0; dir < 2; ++dir)

  785.         {

  786.             const bool isInput = (dir == 0);

  787.             const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  788.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  789. 

  790.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  791.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  792. 

  793.             for (int busIdx = 0; busIdx < n; ++busIdx)

  794.             {

  795.                 AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx);

  796.                 AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  797. 

  798.                 AudioChannelSet newLayout;

  799.                 const AVAudioChannelLayout* layout    = [format channelLayout];

  800.                 const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  801. 

  802.                 if (layoutTag != 0)

  803.                     newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  804.                 else

  805.                     newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  806. 

  807.                 if (newLayout.isDisabled())

  808.                     return false;

  809. 

  810.                 channelSets.add (newLayout);

  811.             }

  812.         }

  813. 

  814.        #ifdef JucePlugin_PreferredChannelConfigurations

  815.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  816. 

  817.         if (! AudioProcessor::containsLayout (layouts, configs))

  818.         {

  819.             if (outError != nullptr)

  820.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  821. 

  822.             return false;

  823.         }

  824.        #endif

  825. 

  826.         if (! AudioUnitHelpers::setBusesLayout (&getAudioProcessor(), layouts))

  827.         {

  828.             if (outError != nullptr)

  829.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  830. 

  831.             return false;

  832.         }

  833. 

  834.         totalInChannels  = processor.getTotalNumInputChannels();

  835.         totalOutChannels = processor.getTotalNumOutputChannels();

  836. 

  837.         allocateBusBuffer (true);

  838.         allocateBusBuffer (false);

  839. 

  840.         mapper.alloc();

  841. 

  842.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  843. 

  844.         double sampleRate = (jmax (AudioUnitHelpers::getBusCount (&processor, true), AudioUnitHelpers::getBusCount (&processor, false)) > 0 ?

  845.                              [[[([inputBusses.get() count] > 0 ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: 0] format] sampleRate] : 44100.0);

  846. 

  847.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  848.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  849. 

  850.         midiMessages.ensureSize (2048);

  851.         midiMessages.clear();

  852. 

  853.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  854.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  855.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  856. 

  857.         reset();

  858. 

  859.         return true;

  860.     }

  861. 

  862.     void deallocateRenderResources() override

  863.     {

  864.         hostMusicalContextCallback = nullptr;

  865.         hostTransportStateCallback = nullptr;

  866. 

  867.         getAudioProcessor().releaseResources();

  868.         audioBuffer.release();

  869. 

  870.         inBusBuffers. clear();

  871.         outBusBuffers.clear();

  872. 

  873.         mapper.release();

  874. 

  875.         JuceAudioUnitv3Base::deallocateRenderResources();

  876.     }

  877. 

  878.     //==============================================================================

  879.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  880.     NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>* configs) override

  881.     {

  882.         auto supportedViewIndecies = [[NSMutableIndexSet alloc] init];

  883.         auto n = [configs count];

  884. 

  885.         if (auto* editor = getAudioProcessor().createEditorIfNeeded())

  886.         {

  887.             // If you hit this assertion then your plug-in's editor is reporting that it doesn't support

  888.             // any host MIDI controller configurations!

  889.             jassert (editor->supportsHostMIDIControllerPresence (true) || editor->supportsHostMIDIControllerPresence (false));

  890. 

  891.             for (auto i = 0u; i < n; ++i)

  892.             {

  893.                 if (auto* viewConfiguration = [configs objectAtIndex:i])

  894.                 {

  895.                     if (editor->supportsHostMIDIControllerPresence ([viewConfiguration hostHasController] == YES))

  896.                     {

  897.                         auto* constrainer = editor->getConstrainer();

  898.                         auto height = (int) [viewConfiguration height];

  899.                         auto width  = (int) [viewConfiguration width];

  900. 

  901.                         if (height <= constrainer->getMaximumHeight() && height >= constrainer->getMinimumHeight()

  902.                          && width  <= constrainer->getMaximumWidth()  && width  >= constrainer->getMinimumWidth())

  903.                             [supportedViewIndecies addIndex: i];

  904.                     }

  905.                 }

  906.             }

  907.         }

  908. 

  909.         return [supportedViewIndecies autorelease];

  910.     }

  911. 

  912.     void selectViewConfiguration (AUAudioUnitViewConfiguration* config) override

  913.     {

  914.         processorHolder->viewConfiguration.reset (new AudioProcessorHolder::ViewConfig { [config width], [config height], [config hostHasController] == YES });

  915.     }

  916.    #endif

  917. 

  918.     //==============================================================================

  919.     void audioProcessorChanged (AudioProcessor* processor) override

  920.     {

  921.         ignoreUnused (processor);

  922. 

  923.         [au willChangeValueForKey: @"allParameterValues"];

  924.         addPresets();

  925.         [au didChangeValueForKey: @"allParameterValues"];

  926.     }

  927. 

  928.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  929.     {

  930.         if (inParameterChangedCallback.get())

  931.         {

  932.             inParameterChangedCallback = false;

  933.             return;

  934.         }

  935. 

  936.         if (isPositiveAndBelow (idx, juceParameters.getNumParameters()))

  937.         {

  938.             if (AUParameter* param = [paramTree.get() parameterWithAddress: getAUParameterAddressForIndex (idx)])

  939.             {

  940.                 if (editorObserverToken != nullptr)

  941.                     [param setValue: newValue  originator: editorObserverToken];

  942.                 else

  943.                     [param setValue: newValue];

  944.             }

  945.         }

  946.     }

  947. 

  948.     //==============================================================================

  949.     bool getCurrentPosition (CurrentPositionInfo& info) override

  950.     {

  951.         bool musicContextCallSucceeded = false;

  952.         bool transportStateCallSucceeded = false;

  953. 

  954.         info = lastAudioHead;

  955.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  956.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  957. 

  958.         switch (lastTimeStamp.mSMPTETime.mType)

  959.         {

  960.             case kSMPTETimeType2398:        info.frameRate = AudioPlayHead::fps23976; break;

  961.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24; break;

  962.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25; break;

  963.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997; break;

  964.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  965.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop; break;

  966.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30; break;

  967.             case kSMPTETimeType60Drop:      info.frameRate = AudioPlayHead::fps60drop; break;

  968.             case kSMPTETimeType60:          info.frameRate = AudioPlayHead::fps60; break;

  969.             default:                        info.frameRate = AudioPlayHead::fpsUnknown; break;

  970.         }

  971. 

  972.         double num;

  973.         NSInteger den;

  974.         NSInteger outDeltaSampleOffsetToNextBeat;

  975.         double outCurrentMeasureDownBeat, bpm;

  976.         double ppqPosition;

  977. 

  978.         if (hostMusicalContextCallback != nullptr)

  979.         {

  980.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  981. 

  982.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  983.             {

  984.                 musicContextCallSucceeded = true;

  985. 

  986.                 info.timeSigNumerator   = (int) num;

  987.                 info.timeSigDenominator = (int) den;

  988.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  989.                 info.bpm = bpm;

  990.                 info.ppqPosition = ppqPosition;

  991.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  992.             }

  993.         }

  994. 

  995.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  996.         AUHostTransportStateFlags flags;

  997. 

  998.         if (hostTransportStateCallback != nullptr)

  999.         {

  1000.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  1001. 

  1002.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  1003.             {

  1004.                 transportStateCallSucceeded = true;

  1005. 

  1006.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  1007.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  1008.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  1009.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  1010.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  1011.                 info.ppqLoopStart   = outCycleStartBeat;

  1012.                 info.ppqLoopEnd     = outCycleEndBeat;

  1013.             }

  1014.         }

  1015. 

  1016.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  1017.             lastAudioHead = info;

  1018. 

  1019.         return true;

  1020.     }

  1021. 

  1022.     //==============================================================================

  1023.     static void removeEditor (AudioProcessor& processor)

  1024.     {

  1025.         ScopedLock editorLock (processor.getCallbackLock());

  1026. 

  1027.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  1028.         {

  1029.             processor.editorBeingDeleted (editor);

  1030.             delete editor;

  1031.         }

  1032.     }

  1033. 

  1034. private:

  1035.     //==============================================================================

  1036.     struct BusBuffer

  1037.     {

  1038.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  1039.             : auBus (bus),

  1040.               maxFrames (maxFramesPerBuffer),

  1041.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  1042.               isInterleaved ([[auBus format] isInterleaved])

  1043.         {

  1044.             alloc();

  1045.         }

  1046. 

  1047.         //==============================================================================

  1048.         void alloc()

  1049.         {

  1050.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1051.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  1052.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  1053.             jassert (bytes > 0);

  1054. 

  1055.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  1056.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  1057. 

  1058.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  1059.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  1060.         }

  1061. 

  1062.         void dealloc()

  1063.         {

  1064.             bufferList = nullptr;

  1065.             bufferListStorage.free();

  1066.             scratchBuffer.setSize (0, 0);

  1067.         }

  1068. 

  1069.         //==============================================================================

  1070.         int numChannels() const noexcept                { return numberOfChannels; }

  1071.         bool interleaved() const noexcept               { return isInterleaved; }

  1072.         AudioBufferList* get() const noexcept           { return bufferList; }

  1073. 

  1074.         //==============================================================================

  1075.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  1076.         {

  1077.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1078.             const bool isCompatible = isCompatibleWith (other);

  1079. 

  1080.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  1081. 

  1082.             for (int i = 0; i < numBuffers; ++i)

  1083.             {

  1084.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  1085.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  1086.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  1087.                                                               : scratchBuffer.getWritePointer (i));

  1088.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  1089.             }

  1090.         }

  1091. 

  1092.         //==============================================================================

  1093.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  1094.         {

  1095.             if (other == nullptr)

  1096.                 return false;

  1097. 

  1098.             if (other->mNumberBuffers > 0)

  1099.             {

  1100.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  1101.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  1102.                                                                              : other->mNumberBuffers);

  1103. 

  1104.                 return otherInterleaved == isInterleaved

  1105.                     && numberOfChannels == otherChannels;

  1106.             }

  1107. 

  1108.             return numberOfChannels == 0;

  1109.         }

  1110. 

  1111.     private:

  1112.         AUAudioUnitBus* auBus;

  1113.         HeapBlock<char> bufferListStorage;

  1114.         AudioBufferList* bufferList = nullptr;

  1115.         int maxFrames, numberOfChannels;

  1116.         bool isInterleaved;

  1117.         AudioBuffer<float> scratchBuffer;

  1118.     };

  1119. 

  1120.     //==============================================================================

  1121.     void addAudioUnitBusses (bool isInput)

  1122.     {

  1123.         std::unique_ptr<NSMutableArray<AUAudioUnitBus*>, NSObjectDeleter> array ([[NSMutableArray<AUAudioUnitBus*> alloc] init]);

  1124.         AudioProcessor& processor = getAudioProcessor();

  1125.         const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  1126. 

  1127.         for (int i = 0; i < n; ++i)

  1128.         {

  1129.             std::unique_ptr<AUAudioUnitBus, NSObjectDeleter> audioUnitBus;

  1130. 

  1131.             {

  1132.                 std::unique_ptr<AVAudioFormat, NSObjectDeleter> defaultFormat ([[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  1133.                                                                                                                               channels: static_cast<AVAudioChannelCount> (processor.getChannelCountOfBus (isInput, i))]);

  1134. 

  1135.                 audioUnitBus.reset ([[AUAudioUnitBus alloc] initWithFormat: defaultFormat.get()

  1136.                                                                      error: nullptr]);

  1137.             }

  1138. 

  1139.             [array.get() addObject: audioUnitBus.get()];

  1140.         }

  1141. 

  1142.         (isInput ? inputBusses : outputBusses).reset ([[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  1143.                                                                                              busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  1144.                                                                                               busses: array.get()]);

  1145.     }

  1146. 

  1147.     // When parameters are discrete we need to use integer values.

  1148.     float getMaximumParameterValue (AudioProcessorParameter* juceParam)

  1149.     {

  1150.        #if JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1151.         ignoreUnused (juceParam);

  1152.         return 1.0f;

  1153.        #else

  1154.         return juceParam->isDiscrete() ? (float) (juceParam->getNumSteps() - 1) : 1.0f;

  1155.        #endif

  1156.     }

  1157. 

  1158.     void addParameters()

  1159.     {

  1160.         std::unique_ptr<NSMutableArray<AUParameterNode*>, NSObjectDeleter> params ([[NSMutableArray<AUParameterNode*> alloc] init]);

  1161. 

  1162.         overviewParams.reset ([[NSMutableArray<NSNumber*> alloc] init]);

  1163. 

  1164.         auto& processor = getAudioProcessor();

  1165.         juceParameters.update (processor, forceLegacyParamIDs);

  1166. 

  1167.         const int n = juceParameters.getNumParameters();

  1168. 

  1169.         for (int idx = 0; idx < n; ++idx)

  1170.         {

  1171.             auto* juceParam = juceParameters.getParamForIndex (idx);

  1172. 

  1173.             const String identifier (idx);

  1174.             const String name = juceParam->getName (512);

  1175. 

  1176.             AudioUnitParameterUnit unit = kAudioUnitParameterUnit_Generic;

  1177.             AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  1178.                                                       | kAudioUnitParameterFlag_IsReadable

  1179.                                                       | kAudioUnitParameterFlag_HasCFNameString

  1180.                                                       | kAudioUnitParameterFlag_ValuesHaveStrings);

  1181. 

  1182.             if (! forceLegacyParamIDs)

  1183.                 flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  1184. 

  1185.             // set whether the param is automatable (unnamed parameters aren't allowed to be automated)

  1186.             if (name.isEmpty() || ! juceParam->isAutomatable())

  1187.                 flags |= kAudioUnitParameterFlag_NonRealTime;

  1188. 

  1189.             const bool isParameterDiscrete = juceParam->isDiscrete();

  1190. 

  1191.             if (! isParameterDiscrete)

  1192.                 flags |= kAudioUnitParameterFlag_CanRamp;

  1193. 

  1194.             if (juceParam->isMetaParameter())

  1195.                 flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  1196. 

  1197.             std::unique_ptr<NSMutableArray, NSObjectDeleter> valueStrings;

  1198. 

  1199.             // is this a meter?

  1200.             if (((juceParam->getCategory() & 0xffff0000) >> 16) == 2)

  1201.             {

  1202.                 flags &= ~kAudioUnitParameterFlag_IsWritable;

  1203.                 flags |= kAudioUnitParameterFlag_MeterReadOnly | kAudioUnitParameterFlag_DisplayLogarithmic;

  1204.                 unit = kAudioUnitParameterUnit_LinearGain;

  1205.             }

  1206.             else

  1207.             {

  1208.                 if (! forceLegacyParamIDs)

  1209.                 {

  1210.                     if (juceParam->isDiscrete())

  1211.                     {

  1212.                         unit = juceParam->isBoolean() ? kAudioUnitParameterUnit_Boolean : kAudioUnitParameterUnit_Indexed;

  1213.                         auto maxValue = getMaximumParameterValue (juceParam);

  1214.                         auto numSteps = juceParam->getNumSteps();

  1215. 

  1216.                         // Some hosts can't handle the huge numbers of discrete parameter values created when

  1217.                         // using the default number of steps.

  1218.                         jassert (numSteps != AudioProcessor::getDefaultNumParameterSteps());

  1219. 

  1220.                         valueStrings.reset ([NSMutableArray new]);

  1221. 

  1222.                         for (int i = 0; i < numSteps; ++i)

  1223.                             [valueStrings.get() addObject: juceStringToNS (juceParam->getText ((float) i / maxValue, 0))];

  1224.                     }

  1225.                 }

  1226.             }

  1227. 

  1228.             AUParameterAddress address = generateAUParameterAddress (juceParam);

  1229. 

  1230.            #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1231.             // Consider yourself very unlucky if you hit this assertion. The hash codes of your

  1232.             // parameter ids are not unique.

  1233.             jassert (! paramMap.contains (static_cast<int64> (address)));

  1234. 

  1235.             paramAddresses.add (address);

  1236.             paramMap.set (static_cast<int64> (address), idx);

  1237.            #endif

  1238. 

  1239.             // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1240.             std::unique_ptr<AUParameter, NSObjectDeleter> param ([[AUParameterTree createParameterWithIdentifier: juceStringToNS (identifier)

  1241.                                                                                                             name: juceStringToNS (name)

  1242.                                                                                                          address: address

  1243.                                                                                                              min: 0.0f

  1244.                                                                                                              max: getMaximumParameterValue (juceParam)

  1245.                                                                                                             unit: unit

  1246.                                                                                                         unitName: nullptr

  1247.                                                                                                            flags: flags

  1248.                                                                                                     valueStrings: valueStrings.get()

  1249.                                                                                              dependentParameters: nullptr] retain]);

  1250. 

  1251.             [param.get() setValue: juceParam->getDefaultValue()];

  1252. 

  1253.             [params.get() addObject: param.get()];

  1254.             [overviewParams.get() addObject: [NSNumber numberWithUnsignedLongLong:address]];

  1255.         }

  1256. 

  1257.         // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1258.         paramTree.reset ([[AUParameterTree createTreeWithChildren: params.get()] retain]);

  1259. 

  1260.         paramObserver           = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  1261.         paramProvider           = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  1262.         stringFromValueProvider = CreateObjCBlock (this, &JuceAudioUnitv3::stringFromValue);

  1263.         valueFromStringProvider = CreateObjCBlock (this, &JuceAudioUnitv3::valueFromString);

  1264. 

  1265.         [paramTree.get() setImplementorValueObserver: paramObserver];

  1266.         [paramTree.get() setImplementorValueProvider: paramProvider];

  1267.         [paramTree.get() setImplementorStringFromValueCallback: stringFromValueProvider];

  1268.         [paramTree.get() setImplementorValueFromStringCallback: valueFromStringProvider];

  1269. 

  1270.         if (processor.hasEditor())

  1271.         {

  1272.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  1273.             editorObserverToken = [paramTree.get() tokenByAddingParameterObserver: editorParamObserver];

  1274.         }

  1275. 

  1276.         if ((bypassParam = processor.getBypassParameter()) != nullptr)

  1277.             bypassParam->addListener (this);

  1278.     }

  1279. 

  1280.     void setAudioProcessorParameter (AudioProcessorParameter* juceParam, float value)

  1281.     {

  1282.         if (value != juceParam->getValue())

  1283.         {

  1284.             juceParam->setValue (value);

  1285. 

  1286.             inParameterChangedCallback = true;

  1287.             juceParam->sendValueChangedMessageToListeners (value);

  1288.         }

  1289.     }

  1290. 

  1291.     void addPresets()

  1292.     {

  1293.         factoryPresets.reset ([[NSMutableArray<AUAudioUnitPreset*> alloc] init]);

  1294. 

  1295.         const int n = getAudioProcessor().getNumPrograms();

  1296. 

  1297.         for (int idx = 0; idx < n; ++idx)

  1298.         {

  1299.             String name = getAudioProcessor().getProgramName (idx);

  1300. 

  1301.             std::unique_ptr<AUAudioUnitPreset, NSObjectDeleter> preset ([[AUAudioUnitPreset alloc] init]);

  1302.             [preset.get() setName: juceStringToNS (name)];

  1303.             [preset.get() setNumber: static_cast<NSInteger> (idx)];

  1304. 

  1305.             [factoryPresets.get() addObject: preset.get()];

  1306.         }

  1307.     }

  1308. 

  1309.     //==============================================================================

  1310.     void allocateBusBuffer (bool isInput)

  1311.     {

  1312.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  1313.         busBuffers.clear();

  1314. 

  1315.         const int n = AudioUnitHelpers::getBusCount (&getAudioProcessor(), isInput);

  1316.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1317. 

  1318.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1319.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1320.                                            static_cast<int> (maxFrames)));

  1321.     }

  1322. 

  1323.     //==============================================================================

  1324.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1325.     {

  1326.         ignoreUnused (numParams);

  1327. 

  1328.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1329.         {

  1330.             switch (event->head.eventType)

  1331.             {

  1332.                 case AURenderEventMIDI:

  1333.                 {

  1334.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1335.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1336.                 }

  1337.                 break;

  1338. 

  1339.                 case AURenderEventParameter:

  1340.                 case AURenderEventParameterRamp:

  1341.                 {

  1342.                     const AUParameterEvent& paramEvent = event->parameter;

  1343. 

  1344.                     if (auto* p = getJuceParameterForAUAddress (paramEvent.parameterAddress))

  1345.                         setAudioProcessorParameter (p, paramEvent.value);

  1346.                 }

  1347.                 break;

  1348. 

  1349.                 default:

  1350.                     break;

  1351.             }

  1352.         }

  1353.     }

  1354. 

  1355.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1356.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1357.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1358.     {

  1359.         auto& processor = getAudioProcessor();

  1360.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1361. 

  1362.         // process params

  1363.         const int numParams = juceParameters.getNumParameters();

  1364.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1365. 

  1366.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1367.         {

  1368.             lastTimeStamp = *timestamp;

  1369. 

  1370.             const int numInputBuses  = inBusBuffers. size();

  1371.             const int numOutputBuses = outBusBuffers.size();

  1372. 

  1373.             // prepare buffers

  1374.             {

  1375.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1376.                 {

  1377.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1378.                      const bool canUseDirectOutput =

  1379.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1380. 

  1381.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1382.                 }

  1383. 

  1384.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1385.                 {

  1386.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1387.                     busBuffer.prepare (frameCount, busIdx < numOutputBuses ? outBusBuffers[busIdx]->get() : nullptr);

  1388.                 }

  1389. 

  1390.                 audioBuffer.reset();

  1391.             }

  1392. 

  1393.             // pull inputs

  1394.             {

  1395.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1396.                 {

  1397.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1398.                     AudioBufferList* buffer = busBuffer.get();

  1399. 

  1400.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1401.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1402. 

  1403.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1404.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1405.                 }

  1406.             }

  1407. 

  1408.             // set buffer pointer to minimize copying

  1409.             {

  1410.                 int chIdx = 0;

  1411. 

  1412.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1413.                 {

  1414.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1415.                     AudioBufferList* buffer = busBuffer.get();

  1416. 

  1417.                     const bool interleaved = busBuffer.interleaved();

  1418.                     const int numChannels = busBuffer.numChannels();

  1419. 

  1420.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1421. 

  1422.                     for (int ch = 0; ch < numChannels; ++ch)

  1423.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1424.                 }

  1425. 

  1426.                 // use input pointers on remaining channels

  1427. 

  1428.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1429.                 {

  1430.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1431. 

  1432.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1433.                     AudioBufferList* buffer = busBuffer.get();

  1434. 

  1435.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1436.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1437.                 }

  1438.             }

  1439. 

  1440.             // copy input

  1441.             {

  1442.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1443.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1444. 

  1445.                 // clear remaining channels

  1446.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1447.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1448.             }

  1449. 

  1450.             // process audio

  1451.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1452. 

  1453.             // send MIDI

  1454.            #if JucePlugin_ProducesMidiOutput && JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  1455.             auto midiOut = [au MIDIOutputEventBlock];

  1456.             MidiMessage msg;

  1457.             int samplePosition;

  1458. 

  1459.             for (MidiBuffer::Iterator it (midiMessages); it.getNextEvent (msg, samplePosition);)

  1460.                 midiOut (samplePosition, 0, msg.getRawDataSize(), msg.getRawData());

  1461.            #endif

  1462. 

  1463.             midiMessages.clear();

  1464.         }

  1465. 

  1466.         // copy back

  1467.         audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1468.                          mapper.get (false, (int) outputBusNumber));

  1469. 

  1470.         return noErr;

  1471.     }

  1472. 

  1473.     void processBlock (AudioBuffer<float>& buffer, MidiBuffer& midiBuffer) noexcept

  1474.     {

  1475.         auto& processor = getAudioProcessor();

  1476.         const ScopedLock sl (processor.getCallbackLock());

  1477. 

  1478.         if (processor.isSuspended())

  1479.             buffer.clear();

  1480.         else if (bypassParam != nullptr && [au shouldBypassEffect])

  1481.             processor.processBlockBypassed (buffer, midiBuffer);

  1482.         else

  1483.             processor.processBlock (buffer, midiBuffer);

  1484.     }

  1485. 

  1486.     //==============================================================================

  1487.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1488.     {

  1489.         if (param != nullptr)

  1490.         {

  1491.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1492.             {

  1493.                 auto normalisedValue = value / getMaximumParameterValue (p);

  1494.                 setAudioProcessorParameter (p, normalisedValue);

  1495.             }

  1496.         }

  1497.     }

  1498. 

  1499.     AUValue getValue (AUParameter* param)

  1500.     {

  1501.         if (param != nullptr)

  1502.         {

  1503.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1504.                 return p->getValue() * getMaximumParameterValue (p);

  1505.         }

  1506. 

  1507.         return 0;

  1508.     }

  1509. 

  1510.     void valueChangedForObserver (AUParameterAddress, AUValue)

  1511.     {

  1512.         // this will have already been handled by valueChangedFromHost

  1513.     }

  1514. 

  1515.     NSString* stringFromValue (AUParameter* param, const AUValue* value)

  1516.     {

  1517.         String text;

  1518. 

  1519.         if (param != nullptr && value != nullptr)

  1520.         {

  1521.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1522.             {

  1523.                 if (LegacyAudioParameter::isLegacy (p))

  1524.                     text = String (*value);

  1525.                 else

  1526.                     text = p->getText (*value / getMaximumParameterValue (p), 0);

  1527.             }

  1528.         }

  1529. 

  1530.         return juceStringToNS (text);

  1531.     }

  1532. 

  1533.     AUValue valueFromString (AUParameter* param, NSString* str)

  1534.     {

  1535.         if (param != nullptr && str != nullptr)

  1536.         {

  1537.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1538.             {

  1539.                 const String text (nsStringToJuce (str));

  1540. 

  1541.                 if (LegacyAudioParameter::isLegacy (p))

  1542.                     return text.getFloatValue();

  1543.                 else

  1544.                     return p->getValueForText (text) * getMaximumParameterValue (p);

  1545.             }

  1546.         }

  1547. 

  1548.         return 0;

  1549.     }

  1550. 

  1551.     //==============================================================================

  1552.     // this is only ever called for the bypass parameter

  1553.     void parameterValueChanged (int, float newValue) override

  1554.     {

  1555.         JuceAudioUnitv3Base::setShouldBypassEffect (newValue != 0.0f);

  1556.     }

  1557. 

  1558.     void parameterGestureChanged (int, bool) override {}

  1559. 

  1560.     //==============================================================================

  1561.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1562.     {

  1563.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1564.         return static_cast<AUParameterAddress> (paramIndex);

  1565.        #else

  1566.         return paramAddresses.getReference (paramIndex);

  1567.        #endif

  1568.     }

  1569. 

  1570.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1571.     {

  1572.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1573.         return static_cast<int> (address);

  1574.        #else

  1575.         return paramMap[static_cast<int64> (address)];

  1576.        #endif

  1577.     }

  1578. 

  1579.     AUParameterAddress generateAUParameterAddress (AudioProcessorParameter* param) const

  1580.     {

  1581.         const String& juceParamID = LegacyAudioParameter::getParamID (param, forceLegacyParamIDs);

  1582. 

  1583.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1584.         auto result = juceParamID.getIntValue();

  1585.        #else

  1586.         auto result = juceParamID.hashCode64();

  1587.        #endif

  1588. 

  1589.         return static_cast<AUParameterAddress> (result);

  1590.     }

  1591. 

  1592.     AudioProcessorParameter* getJuceParameterForAUAddress (AUParameterAddress address) const noexcept

  1593.     {

  1594.         return juceParameters.getParamForIndex (getJuceParameterIndexForAUAddress (address));

  1595.     }

  1596. 

  1597.     //==============================================================================

  1598.     static const double kDefaultSampleRate;

  1599. 

  1600.     AudioProcessorHolder::Ptr processorHolder;

  1601. 

  1602.     int totalInChannels, totalOutChannels;

  1603. 

  1604.     std::unique_ptr<AUAudioUnitBusArray, NSObjectDeleter> inputBusses, outputBusses;

  1605. 

  1606.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1607.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1608.     ObjCBlock<AUImplementorStringFromValueCallback> stringFromValueProvider;

  1609.     ObjCBlock<AUImplementorValueFromStringCallback> valueFromStringProvider;

  1610. 

  1611.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1612.     Array<AUParameterAddress> paramAddresses;

  1613.     HashMap<int64, int> paramMap;

  1614.    #endif

  1615.     LegacyAudioParametersWrapper juceParameters;

  1616. 

  1617.     // to avoid recursion on parameter changes, we need to add an

  1618.     // editor observer to do the parameter changes

  1619.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1620.     AUParameterObserverToken editorObserverToken;

  1621. 

  1622.     std::unique_ptr<AUParameterTree, NSObjectDeleter> paramTree;

  1623.     std::unique_ptr<NSMutableArray<NSNumber*>, NSObjectDeleter> overviewParams, channelCapabilities;

  1624. 

  1625.     std::unique_ptr<NSMutableArray<AUAudioUnitPreset*>, NSObjectDeleter> factoryPresets;

  1626. 

  1627.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1628. 

  1629.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1630.     AudioUnitHelpers::ChannelRemapper mapper;

  1631. 

  1632.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1633.     MidiBuffer midiMessages;

  1634. 

  1635.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1636.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1637. 

  1638.     AudioTimeStamp lastTimeStamp;

  1639.     CurrentPositionInfo lastAudioHead;

  1640. 

  1641.     String contextName;

  1642. 

  1643.     ThreadLocalValue<bool> inParameterChangedCallback;

  1644.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1645.     static constexpr bool forceLegacyParamIDs = true;

  1646.    #else

  1647.     static constexpr bool forceLegacyParamIDs = false;

  1648.    #endif

  1649.     AudioProcessorParameter* bypassParam = nullptr;

  1650. };

  1651. 

  1652. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1653. 

  1654. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1655. {

  1656.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1657.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1658. }

  1659. 

  1660. //==============================================================================

  1661. class JuceAUViewController

  1662. {

  1663. public:

  1664.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1665.         : myself (p)

  1666.     {

  1667.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1668. 

  1669.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1670.         initialiseJuce_GUI();

  1671.     }

  1672. 

  1673.     ~JuceAUViewController()

  1674.     {

  1675.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1676. 

  1677.         if (processorHolder != nullptr)

  1678.             JuceAudioUnitv3::removeEditor (getAudioProcessor());

  1679.     }

  1680. 

  1681.     //==============================================================================

  1682.     void loadView()

  1683.     {

  1684.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1685. 

  1686.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1687.         {

  1688.             processorHolder = new AudioProcessorHolder (p);

  1689.             auto& processor = getAudioProcessor();

  1690. 

  1691.             if (processor.hasEditor())

  1692.             {

  1693.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1694.                 {

  1695.                     preferredSize = editor->getBounds();

  1696. 

  1697.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1698.                     [myself setView: view];

  1699. 

  1700.                    #if JUCE_IOS

  1701.                     editor->setVisible (false);

  1702.                    #else

  1703.                     editor->setVisible (true);

  1704.                    #endif

  1705. 

  1706.                     editor->addToDesktop (0, view);

  1707. 

  1708.                    #if JUCE_IOS

  1709.                     if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1710.                         [peerView setContentMode: UIViewContentModeTop];

  1711.                    #endif

  1712.                 }

  1713.             }

  1714.         }

  1715.     }

  1716. 

  1717.     void viewDidLayoutSubviews()

  1718.     {

  1719.         if (processorHolder != nullptr && [myself view] != nullptr)

  1720.         {

  1721.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1722.             {

  1723.                 if (processorHolder->viewConfiguration != nullptr)

  1724.                     editor->hostMIDIControllerIsAvailable (processorHolder->viewConfiguration->hostHasMIDIController);

  1725. 

  1726.                 editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1727. 

  1728.                 if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1729.                 {

  1730.                    #if JUCE_IOS

  1731.                     [peerView setNeedsDisplay];

  1732.                    #else

  1733.                     [peerView setNeedsDisplay: YES];

  1734.                    #endif

  1735.                 }

  1736.             }

  1737.         }

  1738.     }

  1739. 

  1740.     void didReceiveMemoryWarning()

  1741.     {

  1742.         if (processorHolder != nullptr)

  1743.             if (auto* processor = processorHolder->get())

  1744.                 processor->memoryWarningReceived();

  1745.     }

  1746. 

  1747.     void viewDidAppear (bool)

  1748.     {

  1749.         if (processorHolder != nullptr)

  1750.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1751.                 editor->setVisible (true);

  1752.     }

  1753. 

  1754.     void viewDidDisappear (bool)

  1755.     {

  1756.         if (processorHolder != nullptr)

  1757.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1758.                 editor->setVisible (false);

  1759.     }

  1760. 

  1761.     CGSize getPreferredContentSize() const

  1762.     {

  1763.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1764.                            static_cast<float> (preferredSize.getHeight()));

  1765.     }

  1766. 

  1767.     //==============================================================================

  1768.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1769.     {

  1770.         AUAudioUnit* retval = nil;

  1771. 

  1772.         if (! MessageManager::getInstance()->isThisTheMessageThread())

  1773.         {

  1774.             WaitableEvent creationEvent;

  1775. 

  1776.             // AUv3 headers say that we may block this thread and that the message thread is guaranteed

  1777.             // to be unblocked

  1778.             struct AUCreator  : public CallbackMessage

  1779.             {

  1780.                 JuceAUViewController& owner;

  1781.                 AudioComponentDescription pDescr;

  1782.                 NSError** pError;

  1783.                 AUAudioUnit*& outAU;

  1784.                 WaitableEvent& e;

  1785. 

  1786.                 AUCreator (JuceAUViewController& parent, const AudioComponentDescription& paramDescr, NSError** paramError,

  1787.                            AUAudioUnit*& outputAU, WaitableEvent& event)

  1788.                     : owner (parent), pDescr (paramDescr), pError (paramError), outAU (outputAU), e (event)

  1789.                 {}

  1790. 

  1791.                 void messageCallback() override

  1792.                 {

  1793.                     outAU = owner.createAudioUnitOnMessageThread (pDescr, pError);

  1794.                     e.signal();

  1795.                 }

  1796.             };

  1797. 

  1798.             (new AUCreator (*this, descr, error, retval, creationEvent))->post();

  1799.             creationEvent.wait (-1);

  1800.         }

  1801.         else

  1802.         {

  1803.             retval = createAudioUnitOnMessageThread (descr, error);

  1804.         }

  1805. 

  1806.         return [retval autorelease];

  1807.     }

  1808. 

  1809. private:

  1810.     //==============================================================================

  1811.     AUViewController<AUAudioUnitFactory>* myself;

  1812.     AudioProcessorHolder::Ptr processorHolder = nullptr;

  1813.     Rectangle<int> preferredSize { 1, 1 };

  1814. 

  1815.     //==============================================================================

  1816.     AUAudioUnit* createAudioUnitOnMessageThread (const AudioComponentDescription& descr, NSError** error)

  1817.     {

  1818.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1819. 

  1820.         [myself view];  // this will call [view load] and ensure that the AudioProcessor has been instantiated

  1821. 

  1822.         if (processorHolder == nullptr)

  1823.             return nullptr;

  1824. 

  1825.         return (new JuceAudioUnitv3 (processorHolder, descr, 0, error))->getAudioUnit();

  1826.     }

  1827. 

  1828.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder; }

  1829. };

  1830. 

  1831. //==============================================================================

  1832. // necessary glue code

  1833. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  1834. @end

  1835. 

  1836. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  1837. {

  1838.     std::unique_ptr<JuceAUViewController> cpp;

  1839. }

  1840. 

  1841. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp.reset (new JuceAUViewController (self)); return self; }

  1842. - (void) loadView                { cpp->loadView(); }

  1843. - (AUAudioUnit *) createAudioUnitWithComponentDescription: (AudioComponentDescription) desc error: (NSError **) error { return cpp->createAudioUnit (desc, error); }

  1844. - (CGSize) preferredContentSize  { return cpp->getPreferredContentSize(); }

  1845. - (void) viewDidLayoutSubviews   { cpp->viewDidLayoutSubviews(); }

  1846. - (void) didReceiveMemoryWarning { cpp->didReceiveMemoryWarning(); }

  1847. #if JUCE_IOS

  1848. - (void) viewDidAppear: (BOOL) animated { cpp->viewDidAppear (animated); [super viewDidAppear:animated]; }

  1849. - (void) viewDidDisappear: (BOOL) animated { cpp->viewDidDisappear (animated); [super viewDidDisappear:animated]; }

  1850. #endif

  1851. @end

  1852. 

  1853. //==============================================================================

  1854. #if JUCE_IOS

  1855. bool JUCE_CALLTYPE juce_isInterAppAudioConnected() { return false; }

  1856. void JUCE_CALLTYPE juce_switchToHostApplication()  {}

  1857. #if JUCE_MODULE_AVAILABLE_juce_gui_basics

  1858. Image JUCE_CALLTYPE juce_getIAAHostIcon (int)      { return {}; }

  1859. #endif

  1860. #endif

  1861. 

  1862. #pragma clang diagnostic pop

  1863. #endif