DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
12503 Commits
9 Branches
890MB
Tree: cdbefa3b51
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'cdbefa3b51'
${ noResults }
JUCE/modules/juce_gui_basics/native/accessibility/juce_mac_Accessibility.mm

964 lines
44KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2020 - Raw Material Software Limited

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 6 End-User License

  11.    Agreement and JUCE Privacy Policy (both effective as of the 16th June 2020).

  12. 

  13.    End User License Agreement: www.juce.com/juce-6-licence

  14.    Privacy Policy: www.juce.com/juce-privacy-policy

  15. 

  16.    Or: You may also use this code under the terms of the GPL v3 (see

  17.    www.gnu.org/licenses).

  18. 

  19.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  20.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  21.    DISCLAIMED.

  22. 

  23.   ==============================================================================

  24. */

  25. 

  26. static void juceFreeAccessibilityPlatformSpecificData (NSAccessibilityElement<NSAccessibility>*)  {}

  27. 

  28. namespace juce

  29. {

  30. 

  31. #if ! defined (MAC_OS_X_VERSION_10_13) || MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_13

  32.  using NSAccessibilityRole = NSString*;

  33.  using NSAccessibilityNotificationName = NSString*;

  34. #endif

  35. 

  36. #define JUCE_NATIVE_ACCESSIBILITY_INCLUDED 1

  37. 

  38. JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wunguarded-availability", "-Wunguarded-availability-new")

  39. 

  40. //==============================================================================

  41. class AccessibilityHandler::AccessibilityNativeImpl

  42. {

  43. public:

  44.     explicit AccessibilityNativeImpl (AccessibilityHandler& handler)

  45.         : accessibilityElement (AccessibilityElement::create (handler))

  46.     {}

  47. 

  48.     NSAccessibilityElement<NSAccessibility>* getAccessibilityElement() const noexcept

  49.     {

  50.         return accessibilityElement.get();

  51.     }

  52. 

  53. private:

  54.     //==============================================================================

  55.     class AccessibilityElement  : public AccessibleObjCClass<NSAccessibilityElement<NSAccessibility>>

  56.     {

  57.     public:

  58.         static Holder create (AccessibilityHandler& handler)

  59.         {

  60.             if (@available (macOS 10.10, *))

  61.             {

  62.                 static AccessibilityElement cls;

  63.                 Holder element ([cls.createInstance() init]);

  64.                 object_setInstanceVariable (element.get(), "handler", &handler);

  65.                 return element;

  66.             }

  67. 

  68.             return {};

  69.         }

  70. 

  71.     private:

  72.         AccessibilityElement()

  73.         {

  74.             addMethod (@selector (accessibilityNotifiesWhenDestroyed),     getAccessibilityNotifiesWhenDestroyed, "c@:");

  75.             addMethod (@selector (isAccessibilityElement),                 getIsAccessibilityElement,             "c@:");

  76.             addMethod (@selector (isAccessibilityEnabled),                 getIsAccessibilityEnabled,             "c@:");

  77.             addMethod (@selector (accessibilityWindow),                    getAccessibilityWindow,                "@@:");

  78.             addMethod (@selector (accessibilityTopLevelUIElement),         getAccessibilityWindow,                "@@:");

  79.             addMethod (@selector (accessibilityFocusedUIElement),          getAccessibilityFocusedUIElement,      "@@:");

  80.             addMethod (@selector (accessibilityHitTest:),                  accessibilityHitTest,                  "@@:", @encode (NSPoint));

  81.             addMethod (@selector (accessibilityParent),                    getAccessibilityParent,                "@@:");

  82.             addMethod (@selector (accessibilityChildren),                  getAccessibilityChildren,              "@@:");

  83.             addMethod (@selector (isAccessibilityFocused),                 getIsAccessibilityFocused,             "c@:");

  84.             addMethod (@selector (setAccessibilityFocused:),               setAccessibilityFocused,               "v@:c");

  85.             addMethod (@selector (isAccessibilityModal),                   getIsAccessibilityModal,               "c@:");

  86.             addMethod (@selector (accessibilityFrame),                     getAccessibilityFrame,                 @encode (NSRect), "@:");

  87.             addMethod (@selector (accessibilityRole),                      getAccessibilityRole,                  "@@:");

  88.             addMethod (@selector (accessibilitySubrole),                   getAccessibilitySubrole,               "@@:");

  89.             addMethod (@selector (accessibilityTitle),                     getAccessibilityTitle,                 "@@:");

  90.             addMethod (@selector (accessibilityLabel),                     getAccessibilityLabel,                 "@@:");

  91.             addMethod (@selector (accessibilityHelp),                      getAccessibilityHelp,                  "@@:");

  92.             addMethod (@selector (accessibilityValue),                     getAccessibilityValue,                 "@@:");

  93.             addMethod (@selector (setAccessibilityValue:),                 setAccessibilityValue,                 "v@:@");

  94.             addMethod (@selector (accessibilitySelectedChildren),          getAccessibilitySelectedChildren,      "@@:");

  95.             addMethod (@selector (setAccessibilitySelectedChildren:),      setAccessibilitySelectedChildren,      "v@:@");

  96.             addMethod (@selector (accessibilityOrientation),               getAccessibilityOrientation,           "i@:@");

  97. 

  98.             addMethod (@selector (accessibilityInsertionPointLineNumber),  getAccessibilityInsertionPointLineNumber, "i@:");

  99.             addMethod (@selector (accessibilityVisibleCharacterRange),     getAccessibilityVisibleCharacterRange,    @encode (NSRange), "@:");

  100.             addMethod (@selector (accessibilityNumberOfCharacters),        getAccessibilityNumberOfCharacters,       "i@:");

  101.             addMethod (@selector (accessibilitySelectedText),              getAccessibilitySelectedText,             "@@:");

  102.             addMethod (@selector (accessibilitySelectedTextRange),         getAccessibilitySelectedTextRange,        @encode (NSRange), "@:");

  103.             addMethod (@selector (accessibilityAttributedStringForRange:), getAccessibilityAttributedStringForRange, "@@:", @encode (NSRange));

  104.             addMethod (@selector (accessibilityRangeForLine:),             getAccessibilityRangeForLine,             @encode (NSRange), "@:i");

  105.             addMethod (@selector (accessibilityStringForRange:),           getAccessibilityStringForRange,           "@@:", @encode (NSRange));

  106.             addMethod (@selector (accessibilityRangeForPosition:),         getAccessibilityRangeForPosition,         @encode (NSRange), "@:", @encode (NSPoint));

  107.             addMethod (@selector (accessibilityRangeForIndex:),            getAccessibilityRangeForIndex,            @encode (NSRange), "@:i");

  108.             addMethod (@selector (accessibilityFrameForRange:),            getAccessibilityFrameForRange,            @encode (NSRect), "@:", @encode (NSRange));

  109.             addMethod (@selector (accessibilityLineForIndex:),             getAccessibilityLineForIndex,             "i@:i");

  110.             addMethod (@selector (setAccessibilitySelectedTextRange:),     setAccessibilitySelectedTextRange,        "v@:", @encode (NSRange));

  111. 

  112.             addMethod (@selector (accessibilityRowCount),            getAccessibilityRowCount,         "i@:");

  113.             addMethod (@selector (accessibilityRows),                getAccessibilityRows,             "@@:");

  114.             addMethod (@selector (accessibilitySelectedRows),        getAccessibilitySelectedRows,     "@@:");

  115.             addMethod (@selector (setAccessibilitySelectedRows:),    setAccessibilitySelectedRows,     "v@:@");

  116.             addMethod (@selector (accessibilityColumnCount),         getAccessibilityColumnCount,      "i@:");

  117.             addMethod (@selector (accessibilityColumns),             getAccessibilityColumns,          "@@:");

  118.             addMethod (@selector (accessibilitySelectedColumns),     getAccessibilitySelectedColumns,  "@@:");

  119.             addMethod (@selector (setAccessibilitySelectedColumns:), setAccessibilitySelectedColumns,  "v@:@");

  120. 

  121.             addMethod (@selector (accessibilityRowIndexRange),    getAccessibilityRowIndexRange,    @encode (NSRange), "@:");

  122.             addMethod (@selector (accessibilityColumnIndexRange), getAccessibilityColumnIndexRange, @encode (NSRange), "@:");

  123.             addMethod (@selector (accessibilityIndex),            getAccessibilityIndex,            "i@:");

  124.             addMethod (@selector (accessibilityDisclosureLevel),  getAccessibilityDisclosureLevel,  "i@:");

  125.             addMethod (@selector (isAccessibilityExpanded),       getIsAccessibilityExpanded,       "c@:");

  126. 

  127.             addMethod (@selector (accessibilityPerformIncrement), accessibilityPerformIncrement, "c@:");

  128.             addMethod (@selector (accessibilityPerformDecrement), accessibilityPerformDecrement, "c@:");

  129.             addMethod (@selector (accessibilityPerformDelete),    accessibilityPerformDelete,    "c@:");

  130.             addMethod (@selector (accessibilityPerformPress),     accessibilityPerformPress,     "c@:");

  131.             addMethod (@selector (accessibilityPerformShowMenu),  accessibilityPerformShowMenu,  "c@:");

  132.             addMethod (@selector (accessibilityPerformRaise),     accessibilityPerformRaise,     "c@:");

  133. 

  134.             addMethod (@selector (isAccessibilitySelectorAllowed:), getIsAccessibilitySelectorAllowed, "c@:@");

  135. 

  136.            #if defined (MAC_OS_X_VERSION_10_13) && MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_13

  137.             addMethod (@selector (accessibilityChildrenInNavigationOrder), getAccessibilityChildren, "@@:");

  138.            #endif

  139. 

  140.             registerClass();

  141.         }

  142. 

  143.         //==============================================================================

  144.         static bool isSelectable (AccessibleState state) noexcept

  145.         {

  146.             return state.isSelectable() || state.isMultiSelectable();

  147.         }

  148. 

  149.         static NSArray* getSelectedChildren (NSArray* children)

  150.         {

  151.             NSMutableArray* selected = [[NSMutableArray new] autorelease];

  152. 

  153.             for (id child in children)

  154.             {

  155.                 if (auto* handler = getHandler (child))

  156.                 {

  157.                     const auto currentState = handler->getCurrentState();

  158. 

  159.                     if (isSelectable (currentState) && currentState.isSelected())

  160.                         [selected addObject: child];

  161.                 }

  162.             }

  163. 

  164.             return selected;

  165.         }

  166. 

  167.         static void setSelectedChildren (NSArray* children, NSArray* selected)

  168.         {

  169.             for (id child in children)

  170.             {

  171.                 if (auto* handler = getHandler (child))

  172.                 {

  173.                     const auto currentState = handler->getCurrentState();

  174.                     const BOOL isSelected = [selected containsObject: child];

  175. 

  176.                     if (isSelectable (currentState))

  177.                     {

  178.                         if (currentState.isSelected() != isSelected)

  179.                             handler->getActions().invoke (AccessibilityActionType::toggle);

  180.                     }

  181.                     else if (currentState.isFocusable())

  182.                     {

  183.                         [child setAccessibilityFocused: isSelected];

  184.                     }

  185.                 }

  186.             }

  187.         }

  188. 

  189.         //==============================================================================

  190.         static BOOL getAccessibilityNotifiesWhenDestroyed (id, SEL)  { return YES; }

  191. 

  192.         static BOOL getIsAccessibilityEnabled (id self, SEL)

  193.         {

  194.             if (auto* handler = getHandler (self))

  195.                 return handler->getComponent().isEnabled();

  196. 

  197.             return NO;

  198.         }

  199. 

  200.         static id getAccessibilityWindow (id self, SEL)

  201.         {

  202.             return [[self accessibilityParent] accessibilityWindow];

  203.         }

  204. 

  205.         static id getAccessibilityFocusedUIElement (id self, SEL)

  206.         {

  207.             if (auto* handler = getHandler (self))

  208.             {

  209.                 if (auto* modal = Component::getCurrentlyModalComponent())

  210.                 {

  211.                     const auto& component = handler->getComponent();

  212. 

  213.                     if (! component.isParentOf (modal)

  214.                          && component.isCurrentlyBlockedByAnotherModalComponent())

  215.                     {

  216.                         if (auto* modalHandler = modal->getAccessibilityHandler())

  217.                         {

  218.                             if (auto* focusChild = modalHandler->getChildFocus())

  219.                                 return (id) focusChild->getNativeImplementation();

  220. 

  221.                             return (id) modalHandler->getNativeImplementation();

  222.                         }

  223.                     }

  224.                 }

  225. 

  226.                 if (auto* focusChild = handler->getChildFocus())

  227.                     return (id) focusChild->getNativeImplementation();

  228.             }

  229. 

  230.             return nil;

  231.         }

  232. 

  233.         static id accessibilityHitTest (id self, SEL, NSPoint point)

  234.         {

  235.             if (auto* handler = getHandler (self))

  236.             {

  237.                 if (auto* child = handler->getChildAt (roundToIntPoint (flippedScreenPoint (point))))

  238.                     return (id) child->getNativeImplementation();

  239. 

  240.                 return self;

  241.             }

  242. 

  243.             return nil;

  244.         }

  245. 

  246.         static id getAccessibilityParent (id self, SEL)

  247.         {

  248.             if (auto* handler = getHandler (self))

  249.             {

  250.                 if (auto* parentHandler = handler->getParent())

  251.                     return NSAccessibilityUnignoredAncestor ((id) parentHandler->getNativeImplementation());

  252. 

  253.                 return NSAccessibilityUnignoredAncestor ((id) handler->getComponent().getWindowHandle());

  254.             }

  255. 

  256.             return nil;

  257.         }

  258. 

  259.         static NSArray* getAccessibilityChildren (id self, SEL)

  260.         {

  261.             if (auto* handler = getHandler (self))

  262.             {

  263.                 auto children = handler->getChildren();

  264. 

  265.                 auto* accessibleChildren = [NSMutableArray arrayWithCapacity: (NSUInteger) children.size()];

  266. 

  267.                 for (auto* childHandler : children)

  268.                     [accessibleChildren addObject: (id) childHandler->getNativeImplementation()];

  269. 

  270.                 return accessibleChildren;

  271.             }

  272. 

  273.             return nil;

  274.         }

  275. 

  276.         static id getAccessibilityValue (id self, SEL)

  277.         {

  278.             if (auto* handler = getHandler (self))

  279.             {

  280.                 if (handler->getCurrentState().isCheckable())

  281.                     return handler->getCurrentState().isChecked() ? @(1) : @(0);

  282. 

  283.                 return getAccessibilityValueFromInterfaces (*handler);

  284.             }

  285. 

  286.             return nil;

  287.         }

  288. 

  289.         static NSArray* getAccessibilitySelectedChildren (id self, SEL)

  290.         {

  291.             return getSelectedChildren ([self accessibilityChildren]);

  292.         }

  293. 

  294.         static void setAccessibilitySelectedChildren (id self, SEL, NSArray* selected)

  295.         {

  296.             setSelectedChildren ([self accessibilityChildren], selected);

  297.         }

  298. 

  299.         static NSAccessibilityOrientation getAccessibilityOrientation (id self, SEL)

  300.         {

  301.             if (auto* handler = getHandler (self))

  302.                 return handler->getComponent().getBounds().toFloat().getAspectRatio() > 1.0f

  303.                            ? NSAccessibilityOrientationHorizontal

  304.                            : NSAccessibilityOrientationVertical;

  305. 

  306.             return NSAccessibilityOrientationUnknown;

  307.         }

  308. 

  309.         static BOOL getIsAccessibilityFocused (id self, SEL)

  310.         {

  311.             return [[self accessibilityWindow] accessibilityFocusedUIElement] == self;

  312.         }

  313. 

  314.         static void setAccessibilityFocused (id self, SEL, BOOL focused)

  315.         {

  316.             if (auto* handler = getHandler (self))

  317.             {

  318.                 if (focused)

  319.                 {

  320.                     const WeakReference<Component> safeComponent (&handler->getComponent());

  321. 

  322.                     performActionIfSupported (self, AccessibilityActionType::focus);

  323. 

  324.                     if (safeComponent != nullptr)

  325.                         handler->grabFocus();

  326.                 }

  327.                 else

  328.                 {

  329.                     handler->giveAwayFocus();

  330.                 }

  331.             }

  332.         }

  333. 

  334.         static NSRect getAccessibilityFrame (id self, SEL)

  335.         {

  336.             if (auto* handler = getHandler (self))

  337.                 return flippedScreenRect (makeNSRect (handler->getComponent().getScreenBounds()));

  338. 

  339.             return NSZeroRect;

  340.         }

  341. 

  342.         static NSAccessibilityRole getAccessibilityRole (id self, SEL)

  343.         {

  344.             if (auto* handler = getHandler (self))

  345.             {

  346.                 switch (handler->getRole())

  347.                 {

  348.                     case AccessibilityRole::popupMenu:

  349.                     case AccessibilityRole::tooltip:

  350.                     case AccessibilityRole::splashScreen:

  351.                     case AccessibilityRole::dialogWindow:

  352.                     case AccessibilityRole::window:        return NSAccessibilityWindowRole;

  353. 

  354.                     case AccessibilityRole::tableHeader:

  355.                     case AccessibilityRole::unspecified:

  356.                     case AccessibilityRole::group:         return NSAccessibilityGroupRole;

  357. 

  358.                     case AccessibilityRole::label:

  359.                     case AccessibilityRole::staticText:    return NSAccessibilityStaticTextRole;

  360. 

  361.                     case AccessibilityRole::tree:

  362.                     case AccessibilityRole::list:          return NSAccessibilityOutlineRole;

  363. 

  364.                     case AccessibilityRole::listItem:

  365.                     case AccessibilityRole::treeItem:      return NSAccessibilityRowRole;

  366. 

  367.                     case AccessibilityRole::button:        return NSAccessibilityButtonRole;

  368.                     case AccessibilityRole::toggleButton:  return NSAccessibilityCheckBoxRole;

  369.                     case AccessibilityRole::radioButton:   return NSAccessibilityRadioButtonRole;

  370.                     case AccessibilityRole::comboBox:      return NSAccessibilityPopUpButtonRole;

  371.                     case AccessibilityRole::image:         return NSAccessibilityImageRole;

  372.                     case AccessibilityRole::slider:        return NSAccessibilitySliderRole;

  373.                     case AccessibilityRole::editableText:  return NSAccessibilityTextAreaRole;

  374.                     case AccessibilityRole::menuItem:      return NSAccessibilityMenuItemRole;

  375.                     case AccessibilityRole::menuBar:       return NSAccessibilityMenuRole;

  376.                     case AccessibilityRole::table:         return NSAccessibilityListRole;

  377.                     case AccessibilityRole::column:        return NSAccessibilityColumnRole;

  378.                     case AccessibilityRole::row:           return NSAccessibilityRowRole;

  379.                     case AccessibilityRole::cell:          return NSAccessibilityCellRole;

  380.                     case AccessibilityRole::hyperlink:     return NSAccessibilityLinkRole;

  381.                     case AccessibilityRole::progressBar:   return NSAccessibilityProgressIndicatorRole;

  382.                     case AccessibilityRole::scrollBar:     return NSAccessibilityScrollBarRole;

  383. 

  384.                     case AccessibilityRole::ignored:       break;

  385.                 }

  386. 

  387.                 return NSAccessibilityUnknownRole;

  388.             }

  389. 

  390.             return nil;

  391.         }

  392. 

  393.         static NSAccessibilityRole getAccessibilitySubrole (id self, SEL)

  394.         {

  395.             if (auto* handler = getHandler (self))

  396.             {

  397.                 if (auto* textInterface = getTextInterface (self))

  398.                     if (textInterface->isDisplayingProtectedText())

  399.                         return NSAccessibilitySecureTextFieldSubrole;

  400. 

  401.                 const auto role = handler->getRole();

  402. 

  403.                 if (role == AccessibilityRole::window)                                     return NSAccessibilityStandardWindowSubrole;

  404.                 if (role == AccessibilityRole::dialogWindow)                               return NSAccessibilityDialogSubrole;

  405.                 if (role == AccessibilityRole::tooltip

  406.                     || role == AccessibilityRole::splashScreen)                            return NSAccessibilityFloatingWindowSubrole;

  407.                 if (role == AccessibilityRole::toggleButton)                               return NSAccessibilityToggleSubrole;

  408.                 if (role == AccessibilityRole::treeItem

  409.                     || role == AccessibilityRole::listItem)                                return NSAccessibilityOutlineRowSubrole;

  410.                 if (role == AccessibilityRole::row && getCellInterface (self) != nullptr)  return NSAccessibilityTableRowSubrole;

  411. 

  412.                 const auto& component = handler->getComponent();

  413. 

  414.                 if (auto* documentWindow = component.findParentComponentOfClass<DocumentWindow>())

  415.                 {

  416.                     if (role == AccessibilityRole::button)

  417.                     {

  418.                         if (&component == documentWindow->getCloseButton())     return NSAccessibilityCloseButtonSubrole;

  419.                         if (&component == documentWindow->getMinimiseButton())  return NSAccessibilityMinimizeButtonSubrole;

  420.                         if (&component == documentWindow->getMaximiseButton())  return NSAccessibilityFullScreenButtonSubrole;

  421.                     }

  422.                 }

  423.             }

  424. 

  425.             return NSAccessibilityUnknownRole;

  426.         }

  427. 

  428.         static NSString* getAccessibilityLabel (id self, SEL)

  429.         {

  430.             if (auto* handler = getHandler (self))

  431.                 return juceStringToNS (handler->getDescription());

  432. 

  433.             return nil;

  434.         }

  435. 

  436.         //==============================================================================

  437.         static NSInteger getAccessibilityInsertionPointLineNumber (id self, SEL)

  438.         {

  439.             if (auto* textInterface = getTextInterface (self))

  440.                 return [self accessibilityLineForIndex: textInterface->getTextInsertionOffset()];

  441. 

  442.             return 0;

  443.         }

  444. 

  445.         static NSRange getAccessibilityVisibleCharacterRange (id self, SEL)

  446.         {

  447.             if (auto* textInterface = getTextInterface (self))

  448.                 return juceRangeToNS ({ 0, textInterface->getTotalNumCharacters() });

  449. 

  450.             return NSMakeRange (0, 0);

  451.         }

  452. 

  453.         static NSInteger getAccessibilityNumberOfCharacters (id self, SEL)

  454.         {

  455.             if (auto* textInterface = getTextInterface (self))

  456.                 return textInterface->getTotalNumCharacters();

  457. 

  458.             return 0;

  459.         }

  460. 

  461.         static NSString* getAccessibilitySelectedText (id self, SEL)

  462.         {

  463.             if (auto* textInterface = getTextInterface (self))

  464.                 return juceStringToNS (textInterface->getText (textInterface->getSelection()));

  465. 

  466.             return nil;

  467.         }

  468. 

  469.         static NSRange getAccessibilitySelectedTextRange (id self, SEL)

  470.         {

  471.             if (auto* textInterface = getTextInterface (self))

  472.             {

  473.                 const auto currentSelection = textInterface->getSelection();

  474. 

  475.                 if (currentSelection.isEmpty())

  476.                     return NSMakeRange ((NSUInteger) textInterface->getTextInsertionOffset(), 0);

  477. 

  478.                 return juceRangeToNS (currentSelection);

  479.             }

  480. 

  481.             return NSMakeRange (0, 0);

  482.         }

  483. 

  484.         static NSAttributedString* getAccessibilityAttributedStringForRange (id self, SEL, NSRange range)

  485.         {

  486.             NSString* string = [self accessibilityStringForRange: range];

  487. 

  488.             if (string != nil)

  489.                 return [[[NSAttributedString alloc] initWithString: string] autorelease];

  490. 

  491.             return nil;

  492.         }

  493. 

  494.         static NSRange getAccessibilityRangeForLine (id self, SEL, NSInteger line)

  495.         {

  496.             if (auto* textInterface = getTextInterface (self))

  497.             {

  498.                 auto text = textInterface->getText ({ 0, textInterface->getTotalNumCharacters() });

  499.                 auto lines = StringArray::fromLines (text);

  500. 

  501.                 if (line < lines.size())

  502.                 {

  503.                     auto lineText = lines[(int) line];

  504.                     auto start = text.indexOf (lineText);

  505. 

  506.                     if (start >= 0)

  507.                         return NSMakeRange ((NSUInteger) start, (NSUInteger) lineText.length());

  508.                 }

  509.             }

  510. 

  511.             return NSMakeRange (0, 0);

  512.         }

  513. 

  514.         static NSString* getAccessibilityStringForRange (id self, SEL, NSRange range)

  515.         {

  516.             if (auto* textInterface = getTextInterface (self))

  517.                 return juceStringToNS (textInterface->getText (nsRangeToJuce (range)));

  518. 

  519.             return nil;

  520.         }

  521. 

  522.         static NSRange getAccessibilityRangeForPosition (id self, SEL, NSPoint position)

  523.         {

  524.             if (auto* handler = getHandler (self))

  525.             {

  526.                 if (auto* textInterface = handler->getTextInterface())

  527.                 {

  528.                     auto screenPoint = roundToIntPoint (flippedScreenPoint (position));

  529. 

  530.                     if (handler->getComponent().getScreenBounds().contains (screenPoint))

  531.                     {

  532.                         auto offset = textInterface->getOffsetAtPoint (screenPoint);

  533. 

  534.                         if (offset >= 0)

  535.                             return NSMakeRange ((NSUInteger) offset, 1);

  536.                     }

  537.                 }

  538.             }

  539. 

  540.             return NSMakeRange (0, 0);

  541.         }

  542. 

  543.         static NSRange getAccessibilityRangeForIndex (id self, SEL, NSInteger index)

  544.         {

  545.             if (auto* textInterface = getTextInterface (self))

  546.                 if (isPositiveAndBelow (index, textInterface->getTotalNumCharacters()))

  547.                     return NSMakeRange ((NSUInteger) index, 1);

  548. 

  549.             return NSMakeRange (0, 0);

  550.         }

  551. 

  552.         static NSRect getAccessibilityFrameForRange (id self, SEL, NSRange range)

  553.         {

  554.             if (auto* textInterface = getTextInterface (self))

  555.                 return flippedScreenRect (makeNSRect (textInterface->getTextBounds (nsRangeToJuce (range)).getBounds()));

  556. 

  557.             return NSZeroRect;

  558.         }

  559. 

  560.         static NSInteger getAccessibilityLineForIndex (id self, SEL, NSInteger index)

  561.         {

  562.             if (auto* textInterface = getTextInterface (self))

  563.             {

  564.                 auto text = textInterface->getText ({ 0, (int) index });

  565. 

  566.                 if (! text.isEmpty())

  567.                     return StringArray::fromLines (text).size() - 1;

  568.             }

  569. 

  570.             return 0;

  571.         }

  572. 

  573.         static void setAccessibilitySelectedTextRange (id self, SEL, NSRange selectedRange)

  574.         {

  575.             if (auto* textInterface = getTextInterface (self))

  576.                 textInterface->setSelection (nsRangeToJuce (selectedRange));

  577.         }

  578. 

  579.         //==============================================================================

  580.         static NSArray* getAccessibilityRows (id self, SEL)

  581.         {

  582.             NSMutableArray* rows = [[NSMutableArray new] autorelease];

  583. 

  584.             if (auto* tableInterface = getTableInterface (self))

  585.             {

  586.                 for (int row = 0; row < tableInterface->getNumRows(); ++row)

  587.                 {

  588.                     if (auto* handler = tableInterface->getCellHandler (row, 0))

  589.                     {

  590.                         [rows addObject: (id) handler->getNativeImplementation()];

  591.                     }

  592.                     else

  593.                     {

  594.                         [rows addObject: [NSAccessibilityElement accessibilityElementWithRole: NSAccessibilityRowRole

  595.                                                                                          frame: NSZeroRect

  596.                                                                                          label: @"Offscreen Row"

  597.                                                                                         parent: self]];

  598.                     }

  599.                 }

  600.             }

  601. 

  602.             return rows;

  603.         }

  604. 

  605.         static NSArray* getAccessibilitySelectedRows (id self, SEL)

  606.         {

  607.             return getSelectedChildren ([self accessibilityRows]);

  608.         }

  609. 

  610.         static void setAccessibilitySelectedRows (id self, SEL, NSArray* selected)

  611.         {

  612.             setSelectedChildren ([self accessibilityRows], selected);

  613.         }

  614. 

  615.         static NSArray* getAccessibilityColumns (id self, SEL)

  616.         {

  617.             NSMutableArray* columns = [[NSMutableArray new] autorelease];

  618. 

  619.             if (auto* tableInterface = getTableInterface (self))

  620.             {

  621.                 for (int column = 0; column < tableInterface->getNumColumns(); ++column)

  622.                 {

  623.                     if (auto* handler = tableInterface->getCellHandler (0, column))

  624.                     {

  625.                         [columns addObject: (id) handler->getNativeImplementation()];

  626.                     }

  627.                     else

  628.                     {

  629.                         [columns addObject: [NSAccessibilityElement accessibilityElementWithRole: NSAccessibilityColumnRole

  630.                                                                                             frame: NSZeroRect

  631.                                                                                             label: @"Offscreen Column"

  632.                                                                                            parent: self]];

  633.                     }

  634.                 }

  635.             }

  636. 

  637.             return columns;

  638.         }

  639. 

  640.         static NSArray* getAccessibilitySelectedColumns (id self, SEL)

  641.         {

  642.             return getSelectedChildren ([self accessibilityColumns]);

  643.         }

  644. 

  645.         static void setAccessibilitySelectedColumns (id self, SEL, NSArray* selected)

  646.         {

  647.             setSelectedChildren ([self accessibilityColumns], selected);

  648.         }

  649. 

  650.         //==============================================================================

  651.         static NSInteger getAccessibilityIndex (id self, SEL)

  652.         {

  653.             if (auto* handler = getHandler (self))

  654.             {

  655.                 if (auto* cellInterface = handler->getCellInterface())

  656.                 {

  657.                     NSAccessibilityRole role = [self accessibilityRole];

  658. 

  659.                     if ([role isEqual: NSAccessibilityRowRole])

  660.                         return cellInterface->getRowIndex();

  661. 

  662.                     if ([role isEqual: NSAccessibilityColumnRole])

  663.                         return cellInterface->getColumnIndex();

  664.                 }

  665.             }

  666. 

  667.             return 0;

  668.         }

  669. 

  670.         static NSInteger getAccessibilityDisclosureLevel (id self, SEL)

  671.         {

  672.             if (auto* handler = getHandler (self))

  673.                 if (auto* cellInterface = handler->getCellInterface())

  674.                     return cellInterface->getDisclosureLevel();

  675. 

  676.             return 0;

  677.         }

  678. 

  679.         static BOOL getIsAccessibilityExpanded (id self, SEL)

  680.         {

  681.             if (auto* handler = getHandler (self))

  682.                 return handler->getCurrentState().isExpanded();

  683. 

  684.             return NO;

  685.         }

  686. 

  687.         //==============================================================================

  688.         static BOOL accessibilityPerformShowMenu (id self, SEL)  { return performActionIfSupported (self, AccessibilityActionType::showMenu); }

  689.         static BOOL accessibilityPerformRaise (id self, SEL)     { [self setAccessibilityFocused: YES]; return YES; }

  690. 

  691.         static BOOL accessibilityPerformDelete (id self, SEL)

  692.         {

  693.             if (auto* handler = getHandler (self))

  694.             {

  695.                 if (hasEditableText (*handler))

  696.                 {

  697.                     handler->getTextInterface()->setText ({});

  698.                     return YES;

  699.                 }

  700. 

  701.                 if (auto* valueInterface = handler->getValueInterface())

  702.                 {

  703.                     if (! valueInterface->isReadOnly())

  704.                     {

  705.                         valueInterface->setValue ({});

  706.                         return YES;

  707.                     }

  708.                 }

  709.             }

  710. 

  711.             return NO;

  712.         }

  713. 

  714.         //==============================================================================

  715.         static BOOL getIsAccessibilitySelectorAllowed (id self, SEL, SEL selector)

  716.         {

  717.             if (auto* handler = getHandler (self))

  718.             {

  719.                 const auto role = handler->getRole();

  720.                 const auto currentState = handler->getCurrentState();

  721. 

  722.                 for (auto textSelector : { @selector (accessibilityInsertionPointLineNumber),

  723.                                            @selector (accessibilityVisibleCharacterRange),

  724.                                            @selector (accessibilityNumberOfCharacters),

  725.                                            @selector (accessibilitySelectedText),

  726.                                            @selector (accessibilitySelectedTextRange),

  727.                                            @selector (accessibilityAttributedStringForRange:),

  728.                                            @selector (accessibilityRangeForLine:),

  729.                                            @selector (accessibilityStringForRange:),

  730.                                            @selector (accessibilityRangeForPosition:),

  731.                                            @selector (accessibilityRangeForIndex:),

  732.                                            @selector (accessibilityFrameForRange:),

  733.                                            @selector (accessibilityLineForIndex:),

  734.                                            @selector (setAccessibilitySelectedTextRange:) })

  735.                 {

  736.                     if (selector == textSelector)

  737.                         return handler->getTextInterface() != nullptr;

  738.                 }

  739. 

  740.                 for (auto tableSelector : { @selector (accessibilityRowCount),

  741.                                             @selector (accessibilityRows),

  742.                                             @selector (accessibilitySelectedRows),

  743.                                             @selector (accessibilityColumnCount),

  744.                                             @selector (accessibilityColumns),

  745.                                             @selector (accessibilitySelectedColumns) })

  746.                 {

  747.                     if (selector == tableSelector)

  748.                         return handler->getTableInterface() != nullptr;

  749.                 }

  750. 

  751.                 for (auto cellSelector : { @selector (accessibilityRowIndexRange),

  752.                                            @selector (accessibilityColumnIndexRange),

  753.                                            @selector (accessibilityIndex),

  754.                                            @selector (accessibilityDisclosureLevel) })

  755.                 {

  756.                     if (selector == cellSelector)

  757.                         return handler->getCellInterface() != nullptr;

  758.                 }

  759. 

  760.                 for (auto valueSelector : { @selector (accessibilityValue),

  761.                                             @selector (setAccessibilityValue:),

  762.                                             @selector (accessibilityPerformDelete),

  763.                                             @selector (accessibilityPerformIncrement),

  764.                                             @selector (accessibilityPerformDecrement) })

  765.                 {

  766.                     if (selector != valueSelector)

  767.                         continue;

  768. 

  769.                     auto* valueInterface = handler->getValueInterface();

  770. 

  771.                     if (selector == @selector (accessibilityValue))

  772.                         return valueInterface != nullptr

  773.                             || hasEditableText (*handler)

  774.                             || currentState.isCheckable();

  775. 

  776.                     auto hasEditableValue = [valueInterface] { return valueInterface != nullptr && ! valueInterface->isReadOnly(); };

  777. 

  778.                     if (selector == @selector (setAccessibilityValue:)

  779.                      || selector == @selector (accessibilityPerformDelete))

  780.                         return hasEditableValue() || hasEditableText (*handler);

  781. 

  782.                     auto isRanged = [valueInterface] { return valueInterface != nullptr && valueInterface->getRange().isValid(); };

  783. 

  784.                     if (selector == @selector (accessibilityPerformIncrement)

  785.                      || selector == @selector (accessibilityPerformDecrement))

  786.                         return hasEditableValue() && isRanged();

  787. 

  788.                     return NO;

  789.                 }

  790. 

  791.                 for (auto actionSelector : { @selector (accessibilityPerformPress),

  792.                                              @selector (accessibilityPerformShowMenu),

  793.                                              @selector (accessibilityPerformRaise),

  794.                                              @selector (setAccessibilityFocused:) })

  795.                 {

  796.                     if (selector != actionSelector)

  797.                         continue;

  798. 

  799.                     if (selector == @selector (accessibilityPerformPress))

  800.                         return handler->getActions().contains (AccessibilityActionType::press);

  801. 

  802.                     if (selector == @selector (accessibilityPerformShowMenu))

  803.                         return handler->getActions().contains (AccessibilityActionType::showMenu);

  804. 

  805.                     if (selector == @selector (accessibilityPerformRaise))

  806.                         return [[self accessibilityRole] isEqual: NSAccessibilityWindowRole];

  807. 

  808.                     if (selector == @selector (setAccessibilityFocused:))

  809.                         return currentState.isFocusable();

  810.                 }

  811. 

  812.                 if (selector == @selector (accessibilitySelectedChildren))

  813.                     return role == AccessibilityRole::popupMenu;

  814. 

  815.                 if (selector == @selector (accessibilityOrientation))

  816.                     return role == AccessibilityRole::scrollBar;

  817. 

  818.                 if (selector == @selector (isAccessibilityExpanded))

  819.                     return currentState.isExpandable();

  820. 

  821.                 return sendSuperclassMessage<BOOL> (self, @selector (isAccessibilitySelectorAllowed:), selector);

  822.             }

  823. 

  824.             return NO;

  825.         }

  826. 

  827.         //==============================================================================

  828.         JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityElement)

  829.     };

  830. 

  831.     //==============================================================================

  832.     AccessibilityElement::Holder accessibilityElement;

  833. 

  834.     //==============================================================================

  835.     JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityNativeImpl)

  836. };

  837. 

  838. //==============================================================================

  839. AccessibilityNativeHandle* AccessibilityHandler::getNativeImplementation() const

  840. {

  841.     return (AccessibilityNativeHandle*) nativeImpl->getAccessibilityElement();

  842. }

  843. 

  844. static bool areAnyAccessibilityClientsActive()

  845. {

  846.     const String voiceOverKeyString ("voiceOverOnOffKey");

  847.     const String applicationIDString ("com.apple.universalaccess");

  848. 

  849.     CFUniquePtr<CFStringRef> cfKey (voiceOverKeyString.toCFString());

  850.     CFUniquePtr<CFStringRef> cfID  (applicationIDString.toCFString());

  851. 

  852.     CFUniquePtr<CFPropertyListRef> value (CFPreferencesCopyAppValue (cfKey.get(), cfID.get()));

  853. 

  854.     if (value != nullptr)

  855.         return CFBooleanGetValue ((CFBooleanRef) value.get());

  856. 

  857.     return false;

  858. }

  859. 

  860. static void sendAccessibilityEvent (id accessibilityElement,

  861.                                     NSAccessibilityNotificationName notification,

  862.                                     NSDictionary* userInfo)

  863. {

  864.     jassert (notification != NSAccessibilityNotificationName{});

  865. 

  866.     NSAccessibilityPostNotificationWithUserInfo (accessibilityElement, notification, userInfo);

  867. }

  868. 

  869. static void sendHandlerNotification (const AccessibilityHandler& handler,

  870.                                      NSAccessibilityNotificationName notification)

  871. {

  872.     if (! areAnyAccessibilityClientsActive() || notification == NSAccessibilityNotificationName{})

  873.         return;

  874. 

  875.     if (id accessibilityElement = (id) handler.getNativeImplementation())

  876.     {

  877.         sendAccessibilityEvent (accessibilityElement, notification,

  878.                                 (notification == NSAccessibilityLayoutChangedNotification

  879.                                    ? @{ NSAccessibilityUIElementsKey: @[ accessibilityElement ] }

  880.                                    : nil));

  881.     }

  882. }

  883. 

  884. static NSAccessibilityNotificationName layoutChangedNotification()

  885. {

  886.     if (@available (macOS 10.9, *))

  887.         return NSAccessibilityLayoutChangedNotification;

  888. 

  889.     static NSString* layoutChangedString = @"AXLayoutChanged";

  890.     return layoutChangedString;

  891. }

  892. 

  893. void notifyAccessibilityEventInternal (const AccessibilityHandler& handler, InternalAccessibilityEvent eventType)

  894. {

  895.     auto notification = [eventType]

  896.     {

  897.         switch (eventType)

  898.         {

  899.             case InternalAccessibilityEvent::elementCreated:         return NSAccessibilityCreatedNotification;

  900.             case InternalAccessibilityEvent::elementDestroyed:       return NSAccessibilityUIElementDestroyedNotification;

  901.             case InternalAccessibilityEvent::elementMovedOrResized:  return layoutChangedNotification();

  902.             case InternalAccessibilityEvent::focusChanged:           return NSAccessibilityFocusedUIElementChangedNotification;

  903.             case InternalAccessibilityEvent::windowOpened:           return NSAccessibilityWindowCreatedNotification;

  904.             case InternalAccessibilityEvent::windowClosed:           break;

  905.         }

  906. 

  907.         return NSAccessibilityNotificationName{};

  908.     }();

  909. 

  910.     sendHandlerNotification (handler, notification);

  911. }

  912. 

  913. void AccessibilityHandler::notifyAccessibilityEvent (AccessibilityEvent eventType) const

  914. {

  915.     auto notification = [eventType]

  916.     {

  917.         switch (eventType)

  918.         {

  919.             case AccessibilityEvent::textSelectionChanged:  return NSAccessibilitySelectedTextChangedNotification;

  920.             case AccessibilityEvent::rowSelectionChanged:   return NSAccessibilitySelectedRowsChangedNotification;

  921. 

  922.             case AccessibilityEvent::textChanged:

  923.             case AccessibilityEvent::valueChanged:          return NSAccessibilityValueChangedNotification;

  924.             case AccessibilityEvent::titleChanged:          return NSAccessibilityTitleChangedNotification;

  925.             case AccessibilityEvent::structureChanged:      return layoutChangedNotification();

  926.         }

  927. 

  928.         return NSAccessibilityNotificationName{};

  929.     }();

  930. 

  931.     sendHandlerNotification (*this, notification);

  932. }

  933. 

  934. void AccessibilityHandler::postAnnouncement (const String& announcementString, AnnouncementPriority priority)

  935. {

  936.     if (! areAnyAccessibilityClientsActive())

  937.         return;

  938. 

  939.      if (@available (macOS 10.10, *))

  940.      {

  941.         auto nsPriority = [priority]

  942.         {

  943.             switch (priority)

  944.             {

  945.                 case AnnouncementPriority::low:    return NSAccessibilityPriorityLow;

  946.                 case AnnouncementPriority::medium: return NSAccessibilityPriorityMedium;

  947.                 case AnnouncementPriority::high:   return NSAccessibilityPriorityHigh;

  948.             }

  949. 

  950.             jassertfalse;

  951.             return NSAccessibilityPriorityLow;

  952.         }();

  953. 

  954.         sendAccessibilityEvent ((id) [NSApp mainWindow],

  955.                                 NSAccessibilityAnnouncementRequestedNotification,

  956.                                 @{ NSAccessibilityAnnouncementKey: juceStringToNS (announcementString),

  957.                                    NSAccessibilityPriorityKey:     @(nsPriority) });

  958.      }

  959. }

  960. 

  961. JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  962. 

  963. } // namespace juce