DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
11016 Commits
9 Branches
519MB
Tree: bf51d2c076
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'bf51d2c076'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

1944 lines
82KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE 6 technical preview.

  5.    Copyright (c) 2020 - Raw Material Software Limited

  6. 

  7.    You may use this code under the terms of the GPL v3

  8.    (see www.gnu.org/licenses).

  9. 

  10.    For this technical preview, this file is not subject to commercial licensing.

  11. 

  12.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  13.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  14.    DISCLAIMED.

  15. 

  16.   ==============================================================================

  17. */

  18. 

  19. #include "../../juce_core/system/juce_TargetPlatform.h"

  20. #include "../utility/juce_CheckSettingMacros.h"

  21. 

  22. #if JucePlugin_Build_AUv3

  23. 

  24. #if JUCE_MAC

  25.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  26.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  27.  #endif

  28.  #if (defined MAC_OS_X_VERSION_10_13) && (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_13)

  29.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  30.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  31.  #endif

  32. #endif

  33. 

  34. #if JUCE_IOS

  35.  #if (! defined __IPHONE_OS_VERSION_MIN_REQUIRED) || (! defined __IPHONE_9_0) || (__IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_9_0)

  36.   #error AUv3 needs Deployment Target iOS 9.0 or higher to compile

  37.  #endif

  38.  #if (defined __IPHONE_11_0) && (__IPHONE_OS_VERSION_MIN_REQUIRED >= __IPHONE_11_0)

  39.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  40.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  41.  #endif

  42. #endif

  43. 

  44. #ifndef __OBJC2__

  45.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  46. #endif

  47. 

  48. #define JUCE_CORE_INCLUDE_OBJC_HELPERS 1

  49. 

  50. #include "../utility/juce_IncludeSystemHeaders.h"

  51. #include "../utility/juce_IncludeModuleHeaders.h"

  52. 

  53. #import <CoreAudioKit/CoreAudioKit.h>

  54. #import <AudioToolbox/AudioToolbox.h>

  55. #import <AVFoundation/AVFoundation.h>

  56. 

  57. #include "../../juce_graphics/native/juce_mac_CoreGraphicsHelpers.h"

  58. #include "../../juce_audio_basics/native/juce_mac_CoreAudioLayouts.h"

  59. #include "../../juce_audio_processors/format_types/juce_LegacyAudioParameter.cpp"

  60. #include "../../juce_audio_processors/format_types/juce_AU_Shared.h"

  61. 

  62. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  63. 

  64. #if JUCE_IOS

  65.  #define JUCE_IOS_MAC_VIEW  UIView

  66. #else

  67.  #define JUCE_IOS_MAC_VIEW  NSView

  68. #endif

  69. 

  70. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  71. 

  72. JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wnullability-completeness")

  73. 

  74. using namespace juce;

  75. 

  76. struct AudioProcessorHolder  : public ReferenceCountedObject

  77. {

  78.     AudioProcessorHolder() {}

  79.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  80.     AudioProcessor& operator*() noexcept        { return *processor; }

  81.     AudioProcessor* operator->() noexcept       { return processor.get(); }

  82.     AudioProcessor* get() noexcept              { return processor.get(); }

  83. 

  84.     struct ViewConfig

  85.     {

  86.         double width;

  87.         double height;

  88.         bool hostHasMIDIController;

  89.     };

  90. 

  91.     std::unique_ptr<ViewConfig> viewConfiguration;

  92. 

  93.     using Ptr = ReferenceCountedObjectPtr<AudioProcessorHolder>;

  94. 

  95. private:

  96.     std::unique_ptr<AudioProcessor> processor;

  97. 

  98.     AudioProcessorHolder& operator= (AudioProcessor*) = delete;

  99.     AudioProcessorHolder (AudioProcessorHolder&) = delete;

  100.     AudioProcessorHolder& operator= (AudioProcessorHolder&) = delete;

  101. };

  102. 

  103. //==============================================================================

  104. class JuceAudioUnitv3Base

  105. {

  106. public:

  107.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  108.                          AudioComponentInstantiationOptions options,

  109.                          NSError** error)

  110.         JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wobjc-method-access")

  111.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  112.                                                                         options: options

  113.                                                                           error: error

  114.                                                                       juceClass: this])

  115.         JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  116.     {}

  117. 

  118.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  119.     {

  120.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  121.         initialiseJuce_GUI();

  122.     }

  123. 

  124.     virtual ~JuceAudioUnitv3Base() = default;

  125. 

  126.     //==============================================================================

  127.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  128. 

  129.     //==============================================================================

  130.     virtual void reset()                                                   = 0;

  131. 

  132.     //==============================================================================

  133.     virtual AUAudioUnitPreset* getCurrentPreset()                          = 0;

  134.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      = 0;

  135.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()               = 0;

  136. 

  137.     virtual NSDictionary<NSString*, id>* getFullState()

  138.     {

  139.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  140.         return ObjCMsgSendSuper<NSDictionary<NSString*, id>*> (&s, @selector (fullState));

  141.     }

  142. 

  143.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  144.     {

  145.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  146.         ObjCMsgSendSuper<void, NSDictionary<NSString*, id>*> (&s, @selector (setFullState:), state);

  147.     }

  148. 

  149.     virtual AUParameterTree* getParameterTree()                            = 0;

  150.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)       = 0;

  151. 

  152.     //==============================================================================

  153.     virtual NSTimeInterval getLatency()                                    = 0;

  154.     virtual NSTimeInterval getTailTime()                                   = 0;

  155. 

  156.     //==============================================================================

  157.     virtual AUAudioUnitBusArray* getInputBusses()                          = 0;

  158.     virtual AUAudioUnitBusArray* getOutputBusses()                         = 0;

  159.     virtual NSArray<NSNumber*>* getChannelCapabilities()                   = 0;

  160.     virtual bool shouldChangeToFormat (AVAudioFormat*, AUAudioUnitBus*)    = 0;

  161. 

  162.     //==============================================================================

  163.     virtual int getVirtualMIDICableCount()                                 = 0;

  164.     virtual bool getSupportsMPE()                                          = 0;

  165.     virtual NSArray<NSString*>* getMIDIOutputNames()                       = 0;

  166. 

  167.     //==============================================================================

  168.     virtual AUInternalRenderBlock getInternalRenderBlock()                 = 0;

  169.     virtual bool getCanProcessInPlace()                                    { return false; }

  170.     virtual bool getRenderingOffline()                                     = 0;

  171.     virtual void setRenderingOffline (bool offline)                        = 0;

  172. 

  173.     virtual bool getShouldBypassEffect()

  174.     {

  175.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  176.         return (ObjCMsgSendSuper<BOOL> (&s, @selector (shouldBypassEffect)) == YES);

  177.     }

  178. 

  179.     virtual void setShouldBypassEffect (bool shouldBypass)

  180.     {

  181.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  182.         ObjCMsgSendSuper<void, BOOL> (&s, @selector (setShouldBypassEffect:), shouldBypass ? YES : NO);

  183.     }

  184. 

  185.     //==============================================================================

  186.     virtual NSString* getContextName()      const                          = 0;

  187.     virtual void setContextName (NSString*)                                = 0;

  188. 

  189.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  190.     {

  191.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  192.         return (ObjCMsgSendSuper<BOOL, NSError**> (&s, @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  193.     }

  194. 

  195.     virtual void deallocateRenderResources()

  196.     {

  197.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  198.         ObjCMsgSendSuper<void> (&s, @selector (deallocateRenderResources));

  199.     }

  200. 

  201.     //==============================================================================

  202.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  203.     virtual NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>*) = 0;

  204.     virtual void selectViewConfiguration (AUAudioUnitViewConfiguration*)   = 0;

  205.    #endif

  206. 

  207. private:

  208.     struct Class  : public ObjCClass<AUAudioUnit>

  209.     {

  210.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  211.         {

  212.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  213. 

  214.             JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wundeclared-selector")

  215.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  216.                        initWithComponentDescriptionAndJuceClass, "@@:",

  217.                        @encode (AudioComponentDescription),

  218.                        @encode (AudioComponentInstantiationOptions), "^@@");

  219.             JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  220. 

  221.             addMethod (@selector (initWithComponentDescription:options:error:),

  222.                        initWithComponentDescription, "@@:",

  223.                        @encode (AudioComponentDescription),

  224.                        @encode (AudioComponentInstantiationOptions), "^@");

  225. 

  226.             addMethod (@selector (dealloc),                         dealloc,                        "v@:");

  227. 

  228.             //==============================================================================

  229.             addMethod (@selector (reset),                           reset,                          "v@:");

  230. 

  231.             //==============================================================================

  232.             addMethod (@selector (currentPreset),                   getCurrentPreset,               "@@:");

  233.             addMethod (@selector (setCurrentPreset:),               setCurrentPreset,               "v@:@");

  234.             addMethod (@selector (factoryPresets),                  getFactoryPresets,              "@@:");

  235.             addMethod (@selector (fullState),                       getFullState,                   "@@:");

  236.             addMethod (@selector (setFullState:),                   setFullState,                   "v@:@");

  237.             addMethod (@selector (parameterTree),                   getParameterTree,               "@@:");

  238.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  239. 

  240.             //==============================================================================

  241.             addMethod (@selector (latency),                         getLatency,                     @encode (NSTimeInterval), "@:");

  242.             addMethod (@selector (tailTime),                        getTailTime,                    @encode (NSTimeInterval),  "@:");

  243. 

  244.             //==============================================================================

  245.             addMethod (@selector (inputBusses),                     getInputBusses,                 "@@:");

  246.             addMethod (@selector (outputBusses),                    getOutputBusses,                "@@:");

  247.             addMethod (@selector (channelCapabilities),             getChannelCapabilities,         "@@:");

  248.             addMethod (@selector (shouldChangeToFormat:forBus:),    shouldChangeToFormat,           "B@:@@");

  249. 

  250.             //==============================================================================

  251.             addMethod (@selector (virtualMIDICableCount),           getVirtualMIDICableCount,       @encode (NSInteger), "@:");

  252.             addMethod (@selector (supportsMPE),                     getSupportsMPE,                 @encode (BOOL),      "@:");

  253. 

  254.            #if JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  255.             addMethod (@selector (MIDIOutputNames),                 getMIDIOutputNames,             "@@:");

  256.            #endif

  257. 

  258.             //==============================================================================

  259.             addMethod (@selector (internalRenderBlock),             getInternalRenderBlock,         @encode (AUInternalRenderBlock), "@:");

  260.             addMethod (@selector (canProcessInPlace),               getCanProcessInPlace,           @encode (BOOL), "@:");

  261.             addMethod (@selector (isRenderingOffline),              getRenderingOffline,            @encode (BOOL),  "@:");

  262.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  263.             addMethod (@selector (shouldBypassEffect),              getShouldBypassEffect,          @encode (BOOL),  "@:");

  264.             addMethod (@selector (setShouldBypassEffect:),          setShouldBypassEffect,          "v@:", @encode (BOOL));

  265.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "B@:^@");

  266.             addMethod (@selector (deallocateRenderResources),       deallocateRenderResources,      "v@:");

  267. 

  268.             //==============================================================================

  269.             addMethod (@selector (contextName),                     getContextName,                 "@@:");

  270.             addMethod (@selector (setContextName:),                  setContextName,                 "v@:@");

  271. 

  272.             //==============================================================================

  273.            #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  274.             addMethod (@selector (supportedViewConfigurations:),    getSupportedViewConfigurations, "@@:@");

  275.             addMethod (@selector (selectViewConfiguration:),        selectViewConfiguration,        "v@:@");

  276.            #endif

  277. 

  278.             registerClass();

  279.         }

  280. 

  281.         //==============================================================================

  282.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  283.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  284. 

  285.         //==============================================================================

  286.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  287.         {

  288.             AUAudioUnit* self = _self;

  289. 

  290.             objc_super s = { self, [AUAudioUnit class] };

  291.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  292.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  293. 

  294.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  295. 

  296.             setThis (self, juceAU);

  297.             return self;

  298.         }

  299. 

  300.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  301.         {

  302.             AUAudioUnit* self = _self;

  303. 

  304.             objc_super s = { self, [AUAudioUnit class] };

  305.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  306.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  307. 

  308. 

  309.             setThis (self, juceAU);

  310.             return self;

  311.         }

  312. 

  313.         static void dealloc (id self, SEL)

  314.         {

  315.             if (! MessageManager::getInstance()->isThisTheMessageThread())

  316.             {

  317.                 WaitableEvent deletionEvent;

  318. 

  319.                 struct AUDeleter  : public CallbackMessage

  320.                 {

  321.                     AUDeleter (id selfToDelete, WaitableEvent& event)

  322.                         : parentSelf (selfToDelete), parentDeletionEvent (event)

  323.                     {

  324.                     }

  325. 

  326.                     void messageCallback() override

  327.                     {

  328.                         delete _this (parentSelf);

  329.                         parentDeletionEvent.signal();

  330.                     }

  331. 

  332.                     id parentSelf;

  333.                     WaitableEvent& parentDeletionEvent;

  334.                 };

  335. 

  336.                 (new AUDeleter (self, deletionEvent))->post();

  337.                 deletionEvent.wait (-1);

  338.             }

  339.             else

  340.             {

  341.                 delete _this (self);

  342.             }

  343.         }

  344. 

  345.         //==============================================================================

  346.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  347. 

  348.         //==============================================================================

  349.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  350.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  351.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  352.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  353.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  354.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  355.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  356. 

  357.         //==============================================================================

  358.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  359.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  360. 

  361.         //==============================================================================

  362.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  363.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  364.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  365.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  366. 

  367.         //==============================================================================

  368.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  369.         static BOOL getSupportsMPE (id self, SEL)                                                   { return _this (self)->getSupportsMPE() ? YES : NO; }

  370.         static NSArray<NSString*>* getMIDIOutputNames (id self, SEL)                                { return _this (self)->getMIDIOutputNames(); }

  371. 

  372.         //==============================================================================

  373.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  374.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  375.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  376.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  377.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  378.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  379.         static BOOL getShouldBypassEffect (id self, SEL)                                            { return _this (self)->getShouldBypassEffect() ? YES : NO; }

  380.         static void setShouldBypassEffect (id self, SEL, BOOL shouldBypass)                         { _this (self)->setShouldBypassEffect (shouldBypass); }

  381. 

  382.         //==============================================================================

  383.         static NSString* getContextName (id self, SEL)                                              { return _this (self)->getContextName(); }

  384.         static void setContextName (id self, SEL, NSString* str)                                    { return _this (self)->setContextName (str); }

  385. 

  386.         //==============================================================================

  387.        #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  388.         static NSIndexSet* getSupportedViewConfigurations (id self, SEL, NSArray<AUAudioUnitViewConfiguration*>* configs) { return _this (self)->getSupportedViewConfigurations (configs); }

  389.         static void selectViewConfiguration (id self, SEL, AUAudioUnitViewConfiguration* config)    { _this (self)->selectViewConfiguration (config); }

  390.        #endif

  391.     };

  392. 

  393.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  394. 

  395.     //==============================================================================

  396.     static Class audioUnitObjCClass;

  397. 

  398. protected:

  399.     AUAudioUnit* au;

  400. };

  401. 

  402. //==============================================================================

  403. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  404. 

  405. //==============================================================================

  406. //=========================== The actual AudioUnit =============================

  407. //==============================================================================

  408. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  409.                          public AudioProcessorListener,

  410.                          public AudioPlayHead,

  411.                          private AudioProcessorParameter::Listener

  412. {

  413. public:

  414.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  415.                      const AudioComponentDescription& descr,

  416.                      AudioComponentInstantiationOptions options,

  417.                      NSError** error)

  418.         : JuceAudioUnitv3Base (descr, options, error),

  419.           processorHolder (processor),

  420.           mapper (*processorHolder->get())

  421.     {

  422.         init();

  423.     }

  424. 

  425.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  426.         : JuceAudioUnitv3Base (audioUnit),

  427.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  428.           mapper (*processorHolder->get())

  429.     {

  430.         init();

  431.     }

  432. 

  433.     ~JuceAudioUnitv3() override

  434.     {

  435.         auto& processor = getAudioProcessor();

  436.         processor.removeListener (this);

  437. 

  438.         if (bypassParam != nullptr)

  439.             bypassParam->removeListener (this);

  440. 

  441.         removeEditor (processor);

  442. 

  443.         if (editorObserverToken != nullptr)

  444.         {

  445.             [paramTree.get() removeParameterObserver: editorObserverToken];

  446.             editorObserverToken = nullptr;

  447.         }

  448.     }

  449. 

  450.     //==============================================================================

  451.     void init()

  452.     {

  453.         inParameterChangedCallback = false;

  454. 

  455.         AudioProcessor& processor = getAudioProcessor();

  456.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  457. 

  458.        #ifdef JucePlugin_PreferredChannelConfigurations

  459.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  460.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  461. 

  462.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  463.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  464. 

  465.         Array<AUChannelInfo> channelInfos;

  466. 

  467.         for (int i = 0; i < numConfigs; ++i)

  468.         {

  469.             AUChannelInfo channelInfo;

  470. 

  471.             channelInfo.inChannels  = configs[i][0];

  472.             channelInfo.outChannels = configs[i][1];

  473. 

  474.             channelInfos.add (channelInfo);

  475.         }

  476.        #else

  477.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  478.        #endif

  479. 

  480.         processor.setPlayHead (this);

  481. 

  482.         totalInChannels  = processor.getTotalNumInputChannels();

  483.         totalOutChannels = processor.getTotalNumOutputChannels();

  484. 

  485.         {

  486.             channelCapabilities.reset ([[NSMutableArray<NSNumber*> alloc] init]);

  487. 

  488.             for (int i = 0; i < channelInfos.size(); ++i)

  489.             {

  490.                 AUChannelInfo& info = channelInfos.getReference (i);

  491. 

  492.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.inChannels]];

  493.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.outChannels]];

  494.             }

  495.         }

  496. 

  497.         editorObserverToken = nullptr;

  498.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  499. 

  500.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  501.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  502.         processor.addListener (this);

  503. 

  504.         addParameters();

  505.         addPresets();

  506. 

  507.         addAudioUnitBusses (true);

  508.         addAudioUnitBusses (false);

  509.     }

  510. 

  511.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  512. 

  513.     //==============================================================================

  514.     void reset() override

  515.     {

  516.         midiMessages.clear();

  517.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  518.     }

  519. 

  520.     //==============================================================================

  521.     AUAudioUnitPreset* getCurrentPreset() override

  522.     {

  523.         const int n = static_cast<int> ([factoryPresets.get() count]);

  524.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  525. 

  526.         if (idx < n)

  527.             return [factoryPresets.get() objectAtIndex:static_cast<unsigned int> (idx)];

  528. 

  529.         return nullptr;

  530.     }

  531. 

  532.     void setCurrentPreset(AUAudioUnitPreset* preset) override

  533.     {

  534.         const int n = static_cast<int> ([factoryPresets.get() count]);

  535.         const int idx = static_cast<int> ([preset number]);

  536. 

  537.         if (isPositiveAndBelow (idx, n))

  538.             getAudioProcessor().setCurrentProgram (idx);

  539.     }

  540. 

  541.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override

  542.     {

  543.         return factoryPresets.get();

  544.     }

  545. 

  546.     NSDictionary<NSString*, id>* getFullState() override

  547.     {

  548.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  549. 

  550.         {

  551.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  552. 

  553.             if (superRetval != nullptr)

  554.                 [retval addEntriesFromDictionary:superRetval];

  555.         }

  556. 

  557.         juce::MemoryBlock state;

  558. 

  559.        #if JUCE_AU_WRAPPERS_SAVE_PROGRAM_STATES

  560.         getAudioProcessor().getCurrentProgramStateInformation (state);

  561.        #else

  562.         getAudioProcessor().getStateInformation (state);

  563.        #endif

  564. 

  565.         if (state.getSize() > 0)

  566.         {

  567.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  568.                                                       length: state.getSize()];

  569. 

  570.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  571. 

  572.             [retval setObject: ourState

  573.                        forKey: nsKey];

  574. 

  575.             [nsKey    release];

  576.             [ourState release];

  577.         }

  578. 

  579.         return [retval autorelease];

  580.     }

  581. 

  582.     void setFullState (NSDictionary<NSString*, id>* state) override

  583.     {

  584.         if (state == nullptr)

  585.             return;

  586. 

  587.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  588.         [modifiedState addEntriesFromDictionary: state];

  589. 

  590.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  591.         [modifiedState removeObjectForKey: nsPresetKey];

  592.         [nsPresetKey release];

  593. 

  594.         JuceAudioUnitv3Base::setFullState (modifiedState);

  595. 

  596.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  597.         NSObject* obj = [modifiedState objectForKey: nsKey];

  598.         [nsKey release];

  599. 

  600.         if (obj != nullptr)

  601.         {

  602.             if ([obj isKindOfClass:[NSData class]])

  603.             {

  604.                 NSData* data = reinterpret_cast<NSData*> (obj);

  605.                 const int numBytes = static_cast<int> ([data length]);

  606.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  607. 

  608.                 if (numBytes > 0)

  609.                 {

  610.                    #if JUCE_AU_WRAPPERS_SAVE_PROGRAM_STATES

  611.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  612.                    #else

  613.                     getAudioProcessor().setStateInformation (rawBytes, numBytes);

  614.                    #endif

  615.                 }

  616.             }

  617.         }

  618. 

  619.         [modifiedState release];

  620.     }

  621. 

  622.     AUParameterTree* getParameterTree() override

  623.     {

  624.         return paramTree.get();

  625.     }

  626. 

  627.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  628.     {

  629.         const int n = static_cast<int> ([overviewParams.get() count]);

  630. 

  631.         if (count >= n)

  632.             return overviewParams.get();

  633. 

  634.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams.get()];

  635.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  636. 

  637.         return [retval autorelease];

  638.     }

  639. 

  640.     //==============================================================================

  641.     NSTimeInterval getLatency() override

  642.     {

  643.         auto& p = getAudioProcessor();

  644.         return p.getLatencySamples() / p.getSampleRate();

  645.     }

  646. 

  647.     NSTimeInterval getTailTime() override

  648.     {

  649.         return getAudioProcessor().getTailLengthSeconds();

  650.     }

  651. 

  652.     //==============================================================================

  653.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses.get();  }

  654.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses.get(); }

  655.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities.get(); }

  656. 

  657.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  658.     {

  659.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  660.         const int busIdx = static_cast<int> ([auBus index]);

  661.         const int newNumChannels = static_cast<int> ([format channelCount]);

  662. 

  663.         AudioProcessor& processor = getAudioProcessor();

  664. 

  665.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  666.         {

  667.           #ifdef JucePlugin_PreferredChannelConfigurations

  668.             ignoreUnused (bus);

  669. 

  670.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  671. 

  672.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  673.                 return false;

  674.           #else

  675.             const AVAudioChannelLayout* layout    = [format channelLayout];

  676.             const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  677. 

  678.             if (layoutTag != 0)

  679.             {

  680.                 AudioChannelSet newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  681. 

  682.                 if (newLayout.size() != newNumChannels)

  683.                     return false;

  684. 

  685.                 if (! bus->isLayoutSupported (newLayout))

  686.                     return false;

  687.             }

  688.             else

  689.             {

  690.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  691.                     return false;

  692.             }

  693.            #endif

  694. 

  695.             return true;

  696.         }

  697. 

  698.         return false;

  699.     }

  700. 

  701.     //==============================================================================

  702.     int getVirtualMIDICableCount() override

  703.     {

  704.        #if JucePlugin_WantsMidiInput

  705.         return 1;

  706.        #else

  707.         return 0;

  708.        #endif

  709.     }

  710. 

  711.     bool getSupportsMPE() override

  712.     {

  713.         return getAudioProcessor().supportsMPE();

  714.     }

  715. 

  716.     NSArray<NSString*>* getMIDIOutputNames() override

  717.     {

  718.        #if JucePlugin_ProducesMidiOutput

  719.         return @[@"MIDI Out"];

  720.        #else

  721.         return @[];

  722.        #endif

  723.     }

  724. 

  725.     //==============================================================================

  726.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  727.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  728.     void setRenderingOffline (bool offline) override

  729.     {

  730.         auto& processor = getAudioProcessor();

  731.         auto isCurrentlyNonRealtime = processor.isNonRealtime();

  732. 

  733.         if (isCurrentlyNonRealtime != offline)

  734.         {

  735.             ScopedLock callbackLock (processor.getCallbackLock());

  736. 

  737.             processor.setNonRealtime (offline);

  738.             processor.prepareToPlay (processor.getSampleRate(), processor.getBlockSize());

  739.         }

  740.     }

  741. 

  742.     bool getShouldBypassEffect() override

  743.     {

  744.         if (bypassParam != nullptr)

  745.             return (bypassParam->getValue() != 0.0f);

  746. 

  747.         return JuceAudioUnitv3Base::getShouldBypassEffect();

  748.     }

  749. 

  750.     void setShouldBypassEffect (bool shouldBypass) override

  751.     {

  752.         if (bypassParam != nullptr)

  753.             bypassParam->setValue (shouldBypass ? 1.0f : 0.0f);

  754. 

  755.         JuceAudioUnitv3Base::setShouldBypassEffect (shouldBypass);

  756.     }

  757. 

  758.     //==============================================================================

  759.     NSString* getContextName() const    override              { return juceStringToNS (contextName); }

  760.     void setContextName (NSString* str) override

  761.     {

  762.         if (str != nullptr)

  763.         {

  764.             AudioProcessor::TrackProperties props;

  765.             props.name = nsStringToJuce (str);

  766. 

  767.             getAudioProcessor().updateTrackProperties (props);

  768.         }

  769.     }

  770. 

  771.     //==============================================================================

  772.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  773.     {

  774.         AudioProcessor& processor = getAudioProcessor();

  775.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  776. 

  777.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  778.             return false;

  779. 

  780.         if (outError != nullptr)

  781.             *outError = nullptr;

  782. 

  783.         AudioProcessor::BusesLayout layouts;

  784.         for (int dir = 0; dir < 2; ++dir)

  785.         {

  786.             const bool isInput = (dir == 0);

  787.             const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  788.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  789. 

  790.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  791.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  792. 

  793.             for (int busIdx = 0; busIdx < n; ++busIdx)

  794.             {

  795.                 AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx);

  796.                 AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  797. 

  798.                 AudioChannelSet newLayout;

  799.                 const AVAudioChannelLayout* layout    = [format channelLayout];

  800.                 const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  801. 

  802.                 if (layoutTag != 0)

  803.                     newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  804.                 else

  805.                     newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  806. 

  807.                 if (newLayout.isDisabled())

  808.                     return false;

  809. 

  810.                 channelSets.add (newLayout);

  811.             }

  812.         }

  813. 

  814.        #ifdef JucePlugin_PreferredChannelConfigurations

  815.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  816. 

  817.         if (! AudioProcessor::containsLayout (layouts, configs))

  818.         {

  819.             if (outError != nullptr)

  820.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  821. 

  822.             return false;

  823.         }

  824.        #endif

  825. 

  826.         if (! AudioUnitHelpers::setBusesLayout (&getAudioProcessor(), layouts))

  827.         {

  828.             if (outError != nullptr)

  829.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  830. 

  831.             return false;

  832.         }

  833. 

  834.         totalInChannels  = processor.getTotalNumInputChannels();

  835.         totalOutChannels = processor.getTotalNumOutputChannels();

  836. 

  837.         allocateBusBuffer (true);

  838.         allocateBusBuffer (false);

  839. 

  840.         mapper.alloc();

  841. 

  842.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  843. 

  844.         double sampleRate = (jmax (AudioUnitHelpers::getBusCount (&processor, true), AudioUnitHelpers::getBusCount (&processor, false)) > 0 ?

  845.                              [[[([inputBusses.get() count] > 0 ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: 0] format] sampleRate] : 44100.0);

  846. 

  847.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  848.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  849. 

  850.         midiMessages.ensureSize (2048);

  851.         midiMessages.clear();

  852. 

  853.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  854.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  855.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  856. 

  857.         reset();

  858. 

  859.         return true;

  860.     }

  861. 

  862.     void deallocateRenderResources() override

  863.     {

  864.         hostMusicalContextCallback = nullptr;

  865.         hostTransportStateCallback = nullptr;

  866. 

  867.         getAudioProcessor().releaseResources();

  868.         audioBuffer.release();

  869. 

  870.         inBusBuffers. clear();

  871.         outBusBuffers.clear();

  872. 

  873.         mapper.release();

  874. 

  875.         JuceAudioUnitv3Base::deallocateRenderResources();

  876.     }

  877. 

  878.     //==============================================================================

  879.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  880.     NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>* configs) override

  881.     {

  882.         auto supportedViewIndecies = [[NSMutableIndexSet alloc] init];

  883.         auto n = [configs count];

  884. 

  885.         if (auto* editor = getAudioProcessor().createEditorIfNeeded())

  886.         {

  887.             // If you hit this assertion then your plug-in's editor is reporting that it doesn't support

  888.             // any host MIDI controller configurations!

  889.             jassert (editor->supportsHostMIDIControllerPresence (true) || editor->supportsHostMIDIControllerPresence (false));

  890. 

  891.             for (auto i = 0u; i < n; ++i)

  892.             {

  893.                 if (auto viewConfiguration = [configs objectAtIndex: i])

  894.                 {

  895.                     if (editor->supportsHostMIDIControllerPresence ([viewConfiguration hostHasController] == YES))

  896.                     {

  897.                         auto* constrainer = editor->getConstrainer();

  898.                         auto height = (int) [viewConfiguration height];

  899.                         auto width  = (int) [viewConfiguration width];

  900. 

  901.                         if (height <= constrainer->getMaximumHeight() && height >= constrainer->getMinimumHeight()

  902.                          && width  <= constrainer->getMaximumWidth()  && width  >= constrainer->getMinimumWidth())

  903.                             [supportedViewIndecies addIndex: i];

  904.                     }

  905.                 }

  906.             }

  907.         }

  908. 

  909.         return [supportedViewIndecies autorelease];

  910.     }

  911. 

  912.     void selectViewConfiguration (AUAudioUnitViewConfiguration* config) override

  913.     {

  914.         processorHolder->viewConfiguration.reset (new AudioProcessorHolder::ViewConfig { [config width], [config height], [config hostHasController] == YES });

  915.     }

  916.    #endif

  917. 

  918.     //==============================================================================

  919.     void audioProcessorChanged (AudioProcessor* processor) override

  920.     {

  921.         ignoreUnused (processor);

  922. 

  923.         [au willChangeValueForKey: @"allParameterValues"];

  924.         addPresets();

  925.         [au didChangeValueForKey: @"allParameterValues"];

  926.     }

  927. 

  928.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  929.     {

  930.         if (inParameterChangedCallback.get())

  931.         {

  932.             inParameterChangedCallback = false;

  933.             return;

  934.         }

  935. 

  936.         if (auto* juceParam = juceParameters.getParamForIndex (idx))

  937.         {

  938.             if (AUParameter* param = [paramTree.get() parameterWithAddress: getAUParameterAddressForIndex (idx)])

  939.             {

  940.                 newValue *= getMaximumParameterValue (juceParam);

  941. 

  942.                 if (editorObserverToken != nullptr)

  943.                     [param setValue: newValue  originator: editorObserverToken];

  944.                 else

  945.                     [param setValue: newValue];

  946.             }

  947.         }

  948.     }

  949. 

  950.     //==============================================================================

  951.     bool getCurrentPosition (CurrentPositionInfo& info) override

  952.     {

  953.         bool musicContextCallSucceeded = false;

  954.         bool transportStateCallSucceeded = false;

  955. 

  956.         info = lastAudioHead;

  957.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  958.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  959. 

  960.         switch (lastTimeStamp.mSMPTETime.mType)

  961.         {

  962.             case kSMPTETimeType2398:        info.frameRate = AudioPlayHead::fps23976;    break;

  963.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24;       break;

  964.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25;       break;

  965.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997;     break;

  966.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  967.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop;   break;

  968.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30;       break;

  969.             case kSMPTETimeType60Drop:      info.frameRate = AudioPlayHead::fps60drop;   break;

  970.             case kSMPTETimeType60:          info.frameRate = AudioPlayHead::fps60;       break;

  971.             case kSMPTETimeType5994:

  972.             case kSMPTETimeType5994Drop:

  973.             case kSMPTETimeType50:

  974.             default:                        info.frameRate = AudioPlayHead::fpsUnknown;  break;

  975.         }

  976. 

  977.         double num;

  978.         NSInteger den;

  979.         NSInteger outDeltaSampleOffsetToNextBeat;

  980.         double outCurrentMeasureDownBeat, bpm;

  981.         double ppqPosition;

  982. 

  983.         if (hostMusicalContextCallback != nullptr)

  984.         {

  985.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  986. 

  987.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  988.             {

  989.                 musicContextCallSucceeded = true;

  990. 

  991.                 info.timeSigNumerator   = (int) num;

  992.                 info.timeSigDenominator = (int) den;

  993.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  994.                 info.bpm = bpm;

  995.                 info.ppqPosition = ppqPosition;

  996.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  997.             }

  998.         }

  999. 

  1000.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  1001.         AUHostTransportStateFlags flags;

  1002. 

  1003.         if (hostTransportStateCallback != nullptr)

  1004.         {

  1005.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  1006. 

  1007.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  1008.             {

  1009.                 transportStateCallSucceeded = true;

  1010. 

  1011.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  1012.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  1013.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  1014.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  1015.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  1016.                 info.ppqLoopStart   = outCycleStartBeat;

  1017.                 info.ppqLoopEnd     = outCycleEndBeat;

  1018.             }

  1019.         }

  1020. 

  1021.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  1022.             lastAudioHead = info;

  1023. 

  1024.         return true;

  1025.     }

  1026. 

  1027.     //==============================================================================

  1028.     static void removeEditor (AudioProcessor& processor)

  1029.     {

  1030.         ScopedLock editorLock (processor.getCallbackLock());

  1031. 

  1032.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  1033.         {

  1034.             processor.editorBeingDeleted (editor);

  1035.             delete editor;

  1036.         }

  1037.     }

  1038. 

  1039. private:

  1040.     //==============================================================================

  1041.     struct BusBuffer

  1042.     {

  1043.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  1044.             : auBus (bus),

  1045.               maxFrames (maxFramesPerBuffer),

  1046.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  1047.               isInterleaved ([[auBus format] isInterleaved])

  1048.         {

  1049.             alloc();

  1050.         }

  1051. 

  1052.         //==============================================================================

  1053.         void alloc()

  1054.         {

  1055.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1056.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  1057.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  1058.             jassert (bytes > 0);

  1059. 

  1060.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  1061.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  1062. 

  1063.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  1064.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  1065.         }

  1066. 

  1067.         void dealloc()

  1068.         {

  1069.             bufferList = nullptr;

  1070.             bufferListStorage.free();

  1071.             scratchBuffer.setSize (0, 0);

  1072.         }

  1073. 

  1074.         //==============================================================================

  1075.         int numChannels() const noexcept                { return numberOfChannels; }

  1076.         bool interleaved() const noexcept               { return isInterleaved; }

  1077.         AudioBufferList* get() const noexcept           { return bufferList; }

  1078. 

  1079.         //==============================================================================

  1080.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  1081.         {

  1082.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1083.             const bool isCompatible = isCompatibleWith (other);

  1084. 

  1085.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  1086. 

  1087.             for (int i = 0; i < numBuffers; ++i)

  1088.             {

  1089.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  1090.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  1091.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  1092.                                                               : scratchBuffer.getWritePointer (i));

  1093.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  1094.             }

  1095.         }

  1096. 

  1097.         //==============================================================================

  1098.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  1099.         {

  1100.             if (other == nullptr)

  1101.                 return false;

  1102. 

  1103.             if (other->mNumberBuffers > 0)

  1104.             {

  1105.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  1106.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  1107.                                                                              : other->mNumberBuffers);

  1108. 

  1109.                 return otherInterleaved == isInterleaved

  1110.                     && numberOfChannels == otherChannels;

  1111.             }

  1112. 

  1113.             return numberOfChannels == 0;

  1114.         }

  1115. 

  1116.     private:

  1117.         AUAudioUnitBus* auBus;

  1118.         HeapBlock<char> bufferListStorage;

  1119.         AudioBufferList* bufferList = nullptr;

  1120.         int maxFrames, numberOfChannels;

  1121.         bool isInterleaved;

  1122.         juce::AudioBuffer<float> scratchBuffer;

  1123.     };

  1124. 

  1125.     //==============================================================================

  1126.     void addAudioUnitBusses (bool isInput)

  1127.     {

  1128.         std::unique_ptr<NSMutableArray<AUAudioUnitBus*>, NSObjectDeleter> array ([[NSMutableArray<AUAudioUnitBus*> alloc] init]);

  1129.         AudioProcessor& processor = getAudioProcessor();

  1130.         const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  1131. 

  1132.         for (int i = 0; i < n; ++i)

  1133.         {

  1134.             std::unique_ptr<AUAudioUnitBus, NSObjectDeleter> audioUnitBus;

  1135. 

  1136.             {

  1137.                 std::unique_ptr<AVAudioFormat, NSObjectDeleter> defaultFormat ([[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  1138.                                                                                                                               channels: static_cast<AVAudioChannelCount> (processor.getChannelCountOfBus (isInput, i))]);

  1139. 

  1140.                 audioUnitBus.reset ([[AUAudioUnitBus alloc] initWithFormat: defaultFormat.get()

  1141.                                                                      error: nullptr]);

  1142.             }

  1143. 

  1144.             [array.get() addObject: audioUnitBus.get()];

  1145.         }

  1146. 

  1147.         (isInput ? inputBusses : outputBusses).reset ([[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  1148.                                                                                              busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  1149.                                                                                               busses: array.get()]);

  1150.     }

  1151. 

  1152.     // When parameters are discrete we need to use integer values.

  1153.     float getMaximumParameterValue (AudioProcessorParameter* juceParam)

  1154.     {

  1155.        #if JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1156.         ignoreUnused (juceParam);

  1157.         return 1.0f;

  1158.        #else

  1159.         return juceParam->isDiscrete() ? (float) (juceParam->getNumSteps() - 1) : 1.0f;

  1160.        #endif

  1161.     }

  1162. 

  1163.     std::unique_ptr<AUParameter, NSObjectDeleter> createParameter (AudioProcessorParameter* parameter)

  1164.     {

  1165.         const String name (parameter->getName (512));

  1166. 

  1167.         AudioUnitParameterUnit unit = kAudioUnitParameterUnit_Generic;

  1168.         AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  1169.                                                   | kAudioUnitParameterFlag_IsReadable

  1170.                                                   | kAudioUnitParameterFlag_HasCFNameString

  1171.                                                   | kAudioUnitParameterFlag_ValuesHaveStrings);

  1172. 

  1173.        #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1174.         flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  1175.        #endif

  1176. 

  1177.         // Set whether the param is automatable (unnamed parameters aren't allowed to be automated).

  1178.         if (name.isEmpty() || ! parameter->isAutomatable())

  1179.             flags |= kAudioUnitParameterFlag_NonRealTime;

  1180. 

  1181.         const bool isParameterDiscrete = parameter->isDiscrete();

  1182. 

  1183.         if (! isParameterDiscrete)

  1184.             flags |= kAudioUnitParameterFlag_CanRamp;

  1185. 

  1186.         if (parameter->isMetaParameter())

  1187.             flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  1188. 

  1189.         std::unique_ptr<NSMutableArray, NSObjectDeleter> valueStrings;

  1190. 

  1191.         // Is this a meter?

  1192.         if (((parameter->getCategory() & 0xffff0000) >> 16) == 2)

  1193.         {

  1194.             flags &= ~kAudioUnitParameterFlag_IsWritable;

  1195.             flags |= kAudioUnitParameterFlag_MeterReadOnly | kAudioUnitParameterFlag_DisplayLogarithmic;

  1196.             unit = kAudioUnitParameterUnit_LinearGain;

  1197.         }

  1198.         else

  1199.         {

  1200.            #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1201.             if (parameter->isDiscrete())

  1202.             {

  1203.                 unit = parameter->isBoolean() ? kAudioUnitParameterUnit_Boolean : kAudioUnitParameterUnit_Indexed;

  1204.                 auto maxValue = getMaximumParameterValue (parameter);

  1205.                 auto numSteps = parameter->getNumSteps();

  1206. 

  1207.                 // Some hosts can't handle the huge numbers of discrete parameter values created when

  1208.                 // using the default number of steps.

  1209.                 jassert (numSteps != AudioProcessor::getDefaultNumParameterSteps());

  1210. 

  1211.                 valueStrings.reset ([NSMutableArray new]);

  1212. 

  1213.                 for (int i = 0; i < numSteps; ++i)

  1214.                     [valueStrings.get() addObject: juceStringToNS (parameter->getText ((float) i / maxValue, 0))];

  1215.             }

  1216.            #endif

  1217.         }

  1218. 

  1219.         AUParameterAddress address = generateAUParameterAddress (parameter);

  1220. 

  1221.        #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1222.         // If you hit this assertion then you have either put a parameter in two groups or you are

  1223.         // very unlucky and the hash codes of your parameter ids are not unique.

  1224.         jassert (! paramMap.contains (static_cast<int64> (address)));

  1225. 

  1226.         paramAddresses.add (address);

  1227.         paramMap.set (static_cast<int64> (address), parameter->getParameterIndex());

  1228.        #endif

  1229. 

  1230.         auto getParameterIdentifier = [parameter]

  1231.         {

  1232.             if (auto* paramWithID = dynamic_cast<AudioProcessorParameterWithID*> (parameter))

  1233.                 return paramWithID->paramID;

  1234. 

  1235.             // This could clash if any groups have been given integer IDs!

  1236.             return String (parameter->getParameterIndex());

  1237.         };

  1238. 

  1239.         std::unique_ptr<AUParameter, NSObjectDeleter> param;

  1240. 

  1241.         @try

  1242.         {

  1243.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1244.             param.reset([[AUParameterTree createParameterWithIdentifier: juceStringToNS (getParameterIdentifier())

  1245.                                                                    name: juceStringToNS (name)

  1246.                                                                 address: address

  1247.                                                                     min: 0.0f

  1248.                                                                     max: getMaximumParameterValue (parameter)

  1249.                                                                    unit: unit

  1250.                                                                unitName: nullptr

  1251.                                                                   flags: flags

  1252.                                                            valueStrings: valueStrings.get()

  1253.                                                     dependentParameters: nullptr]

  1254.                          retain]);

  1255.         }

  1256. 

  1257.         @catch (NSException* exception)

  1258.         {

  1259.             // Do you have duplicate identifiers in any of your groups or parameters,

  1260.             // or do your identifiers have unusual characters in them?

  1261.             jassertfalse;

  1262.         }

  1263. 

  1264.         [param.get() setValue: parameter->getDefaultValue()];

  1265. 

  1266.         [overviewParams.get() addObject: [NSNumber numberWithUnsignedLongLong: address]];

  1267. 

  1268.         return param;

  1269.     }

  1270. 

  1271.     std::unique_ptr<AUParameterGroup, NSObjectDeleter> createParameterGroup (AudioProcessorParameterGroup* group)

  1272.     {

  1273.         std::unique_ptr<NSMutableArray<AUParameterNode*>, NSObjectDeleter> children ([NSMutableArray<AUParameterNode*> new]);

  1274. 

  1275.         for (auto* node : *group)

  1276.         {

  1277.             if (auto* childGroup = node->getGroup())

  1278.                 [children.get() addObject: createParameterGroup (childGroup).get()];

  1279.             else

  1280.                 [children.get() addObject: createParameter (node->getParameter()).get()];

  1281.         }

  1282. 

  1283.         std::unique_ptr<AUParameterGroup, NSObjectDeleter> result;

  1284. 

  1285.         @try

  1286.         {

  1287.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1288.             result.reset ([[AUParameterTree createGroupWithIdentifier: juceStringToNS (group->getID())

  1289.                                                                  name: juceStringToNS (group->getName())

  1290.                                                              children: children.get()]

  1291.                            retain]);

  1292.         }

  1293. 

  1294.         @catch (NSException* exception)

  1295.         {

  1296.             // Do you have duplicate identifiers in any of your groups or parameters,

  1297.             // or do your identifiers have unusual characters in them?

  1298.             jassertfalse;

  1299.         }

  1300. 

  1301.         return result;

  1302.     }

  1303. 

  1304.     void addParameters()

  1305.     {

  1306.         auto& processor = getAudioProcessor();

  1307.         juceParameters.update (processor, forceLegacyParamIDs);

  1308. 

  1309.         // This is updated when we build the tree.

  1310.         overviewParams.reset ([NSMutableArray<NSNumber*> new]);

  1311. 

  1312.         std::unique_ptr<NSMutableArray<AUParameterNode*>, NSObjectDeleter> topLevelNodes ([NSMutableArray<AUParameterNode*> new]);

  1313. 

  1314.         for (auto* node : processor.getParameterTree())

  1315.             if (auto* childGroup = node->getGroup())

  1316.                 [topLevelNodes.get() addObject: createParameterGroup (childGroup).get()];

  1317.             else

  1318.                 [topLevelNodes.get() addObject: createParameter (node->getParameter()).get()];

  1319. 

  1320.         @try

  1321.         {

  1322.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1323.             paramTree.reset ([[AUParameterTree createTreeWithChildren: topLevelNodes.get()] retain]);

  1324.         }

  1325. 

  1326.         @catch (NSException* exception)

  1327.         {

  1328.             // Do you have duplicate identifiers in any of your groups or parameters,

  1329.             // or do your identifiers have unusual characters in them?

  1330.             jassertfalse;

  1331.         }

  1332. 

  1333.         paramObserver           = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  1334.         paramProvider           = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  1335.         stringFromValueProvider = CreateObjCBlock (this, &JuceAudioUnitv3::stringFromValue);

  1336.         valueFromStringProvider = CreateObjCBlock (this, &JuceAudioUnitv3::valueFromString);

  1337. 

  1338.         [paramTree.get() setImplementorValueObserver: paramObserver];

  1339.         [paramTree.get() setImplementorValueProvider: paramProvider];

  1340.         [paramTree.get() setImplementorStringFromValueCallback: stringFromValueProvider];

  1341.         [paramTree.get() setImplementorValueFromStringCallback: valueFromStringProvider];

  1342. 

  1343.         if (processor.hasEditor())

  1344.         {

  1345.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  1346.             editorObserverToken = [paramTree.get() tokenByAddingParameterObserver: editorParamObserver];

  1347.         }

  1348. 

  1349.         if ((bypassParam = processor.getBypassParameter()) != nullptr)

  1350.             bypassParam->addListener (this);

  1351.     }

  1352. 

  1353.     void setAudioProcessorParameter (AudioProcessorParameter* juceParam, float value)

  1354.     {

  1355.         if (value != juceParam->getValue())

  1356.         {

  1357.             juceParam->setValue (value);

  1358. 

  1359.             inParameterChangedCallback = true;

  1360.             juceParam->sendValueChangedMessageToListeners (value);

  1361.         }

  1362.     }

  1363. 

  1364.     void addPresets()

  1365.     {

  1366.         factoryPresets.reset ([[NSMutableArray<AUAudioUnitPreset*> alloc] init]);

  1367. 

  1368.         const int n = getAudioProcessor().getNumPrograms();

  1369. 

  1370.         for (int idx = 0; idx < n; ++idx)

  1371.         {

  1372.             String name = getAudioProcessor().getProgramName (idx);

  1373. 

  1374.             std::unique_ptr<AUAudioUnitPreset, NSObjectDeleter> preset ([[AUAudioUnitPreset alloc] init]);

  1375.             [preset.get() setName: juceStringToNS (name)];

  1376.             [preset.get() setNumber: static_cast<NSInteger> (idx)];

  1377. 

  1378.             [factoryPresets.get() addObject: preset.get()];

  1379.         }

  1380.     }

  1381. 

  1382.     //==============================================================================

  1383.     void allocateBusBuffer (bool isInput)

  1384.     {

  1385.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  1386.         busBuffers.clear();

  1387. 

  1388.         const int n = AudioUnitHelpers::getBusCount (&getAudioProcessor(), isInput);

  1389.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1390. 

  1391.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1392.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1393.                                            static_cast<int> (maxFrames)));

  1394.     }

  1395. 

  1396.     //==============================================================================

  1397.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1398.     {

  1399.         ignoreUnused (numParams);

  1400. 

  1401.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1402.         {

  1403.             switch (event->head.eventType)

  1404.             {

  1405.                 case AURenderEventMIDI:

  1406.                 {

  1407.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1408.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1409.                 }

  1410.                 break;

  1411. 

  1412.                 case AURenderEventParameter:

  1413.                 case AURenderEventParameterRamp:

  1414.                 {

  1415.                     const AUParameterEvent& paramEvent = event->parameter;

  1416. 

  1417.                     if (auto* p = getJuceParameterForAUAddress (paramEvent.parameterAddress))

  1418.                         setAudioProcessorParameter (p, paramEvent.value);

  1419.                 }

  1420.                 break;

  1421. 

  1422.                 case AURenderEventMIDISysEx:

  1423.                 default:

  1424.                     break;

  1425.             }

  1426.         }

  1427.     }

  1428. 

  1429.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1430.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1431.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1432.     {

  1433.         auto& processor = getAudioProcessor();

  1434.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1435. 

  1436.         // process params

  1437.         const int numParams = juceParameters.getNumParameters();

  1438.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1439. 

  1440.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1441.         {

  1442.             lastTimeStamp = *timestamp;

  1443. 

  1444.             const int numInputBuses  = inBusBuffers. size();

  1445.             const int numOutputBuses = outBusBuffers.size();

  1446. 

  1447.             // prepare buffers

  1448.             {

  1449.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1450.                 {

  1451.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1452.                      const bool canUseDirectOutput =

  1453.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1454. 

  1455.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1456.                 }

  1457. 

  1458.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1459.                 {

  1460.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1461.                     busBuffer.prepare (frameCount, busIdx < numOutputBuses ? outBusBuffers[busIdx]->get() : nullptr);

  1462.                 }

  1463. 

  1464.                 audioBuffer.reset();

  1465.             }

  1466. 

  1467.             // pull inputs

  1468.             {

  1469.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1470.                 {

  1471.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1472.                     AudioBufferList* buffer = busBuffer.get();

  1473. 

  1474.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1475.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1476. 

  1477.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1478.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1479.                 }

  1480.             }

  1481. 

  1482.             // set buffer pointer to minimize copying

  1483.             {

  1484.                 int chIdx = 0;

  1485. 

  1486.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1487.                 {

  1488.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1489.                     AudioBufferList* buffer = busBuffer.get();

  1490. 

  1491.                     const bool interleaved = busBuffer.interleaved();

  1492.                     const int numChannels = busBuffer.numChannels();

  1493. 

  1494.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1495. 

  1496.                     for (int ch = 0; ch < numChannels; ++ch)

  1497.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1498.                 }

  1499. 

  1500.                 // use input pointers on remaining channels

  1501. 

  1502.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1503.                 {

  1504.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1505. 

  1506.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1507.                     AudioBufferList* buffer = busBuffer.get();

  1508. 

  1509.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1510.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1511.                 }

  1512.             }

  1513. 

  1514.             // copy input

  1515.             {

  1516.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1517.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1518. 

  1519.                 // clear remaining channels

  1520.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1521.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1522.             }

  1523. 

  1524.             // process audio

  1525.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1526. 

  1527.             // send MIDI

  1528.            #if JucePlugin_ProducesMidiOutput && JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  1529.             if (auto midiOut = [au MIDIOutputEventBlock])

  1530.             {

  1531.                 for (const auto metadata : midiMessages)

  1532.                     midiOut (metadata.samplePosition, 0, metadata.numBytes, metadata.data);

  1533.             }

  1534.            #endif

  1535. 

  1536.             midiMessages.clear();

  1537. 

  1538.             // copy back

  1539.             audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1540.                              mapper.get (false, (int) outputBusNumber));

  1541.         }

  1542. 

  1543.         return noErr;

  1544.     }

  1545. 

  1546.     void processBlock (juce::AudioBuffer<float>& buffer, MidiBuffer& midiBuffer) noexcept

  1547.     {

  1548.         auto& processor = getAudioProcessor();

  1549.         const ScopedLock sl (processor.getCallbackLock());

  1550. 

  1551.         if (processor.isSuspended())

  1552.             buffer.clear();

  1553.         else if (bypassParam != nullptr && [au shouldBypassEffect])

  1554.             processor.processBlockBypassed (buffer, midiBuffer);

  1555.         else

  1556.             processor.processBlock (buffer, midiBuffer);

  1557.     }

  1558. 

  1559.     //==============================================================================

  1560.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1561.     {

  1562.         if (param != nullptr)

  1563.         {

  1564.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1565.             {

  1566.                 auto normalisedValue = value / getMaximumParameterValue (p);

  1567.                 setAudioProcessorParameter (p, normalisedValue);

  1568.             }

  1569.         }

  1570.     }

  1571. 

  1572.     AUValue getValue (AUParameter* param)

  1573.     {

  1574.         if (param != nullptr)

  1575.         {

  1576.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1577.                 return p->getValue() * getMaximumParameterValue (p);

  1578.         }

  1579. 

  1580.         return 0;

  1581.     }

  1582. 

  1583.     void valueChangedForObserver (AUParameterAddress, AUValue)

  1584.     {

  1585.         // this will have already been handled by valueChangedFromHost

  1586.     }

  1587. 

  1588.     NSString* stringFromValue (AUParameter* param, const AUValue* value)

  1589.     {

  1590.         String text;

  1591. 

  1592.         if (param != nullptr && value != nullptr)

  1593.         {

  1594.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1595.             {

  1596.                 if (LegacyAudioParameter::isLegacy (p))

  1597.                     text = String (*value);

  1598.                 else

  1599.                     text = p->getText (*value / getMaximumParameterValue (p), 0);

  1600.             }

  1601.         }

  1602. 

  1603.         return juceStringToNS (text);

  1604.     }

  1605. 

  1606.     AUValue valueFromString (AUParameter* param, NSString* str)

  1607.     {

  1608.         if (param != nullptr && str != nullptr)

  1609.         {

  1610.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1611.             {

  1612.                 const String text (nsStringToJuce (str));

  1613. 

  1614.                 if (LegacyAudioParameter::isLegacy (p))

  1615.                     return text.getFloatValue();

  1616.                 else

  1617.                     return p->getValueForText (text) * getMaximumParameterValue (p);

  1618.             }

  1619.         }

  1620. 

  1621.         return 0;

  1622.     }

  1623. 

  1624.     //==============================================================================

  1625.     // this is only ever called for the bypass parameter

  1626.     void parameterValueChanged (int, float newValue) override

  1627.     {

  1628.         JuceAudioUnitv3Base::setShouldBypassEffect (newValue != 0.0f);

  1629.     }

  1630. 

  1631.     void parameterGestureChanged (int, bool) override {}

  1632. 

  1633.     //==============================================================================

  1634.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1635.     {

  1636.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1637.         return static_cast<AUParameterAddress> (paramIndex);

  1638.        #else

  1639.         return paramAddresses.getReference (paramIndex);

  1640.        #endif

  1641.     }

  1642. 

  1643.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1644.     {

  1645.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1646.         return static_cast<int> (address);

  1647.        #else

  1648.         return paramMap[static_cast<int64> (address)];

  1649.        #endif

  1650.     }

  1651. 

  1652.     AUParameterAddress generateAUParameterAddress (AudioProcessorParameter* param) const

  1653.     {

  1654.         const String& juceParamID = LegacyAudioParameter::getParamID (param, forceLegacyParamIDs);

  1655. 

  1656.         return static_cast<AUParameterAddress> (forceLegacyParamIDs ? juceParamID.getIntValue()

  1657.                                                                     : juceParamID.hashCode64());

  1658.     }

  1659. 

  1660.     AudioProcessorParameter* getJuceParameterForAUAddress (AUParameterAddress address) const noexcept

  1661.     {

  1662.         return juceParameters.getParamForIndex (getJuceParameterIndexForAUAddress (address));

  1663.     }

  1664. 

  1665.     //==============================================================================

  1666.     static const double kDefaultSampleRate;

  1667. 

  1668.     AudioProcessorHolder::Ptr processorHolder;

  1669. 

  1670.     int totalInChannels, totalOutChannels;

  1671. 

  1672.     std::unique_ptr<AUAudioUnitBusArray, NSObjectDeleter> inputBusses, outputBusses;

  1673. 

  1674.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1675.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1676.     ObjCBlock<AUImplementorStringFromValueCallback> stringFromValueProvider;

  1677.     ObjCBlock<AUImplementorValueFromStringCallback> valueFromStringProvider;

  1678. 

  1679.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1680.     Array<AUParameterAddress> paramAddresses;

  1681.     HashMap<int64, int> paramMap;

  1682.    #endif

  1683.     LegacyAudioParametersWrapper juceParameters;

  1684. 

  1685.     // to avoid recursion on parameter changes, we need to add an

  1686.     // editor observer to do the parameter changes

  1687.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1688.     AUParameterObserverToken editorObserverToken;

  1689. 

  1690.     std::unique_ptr<AUParameterTree, NSObjectDeleter> paramTree;

  1691.     std::unique_ptr<NSMutableArray<NSNumber*>, NSObjectDeleter> overviewParams, channelCapabilities;

  1692. 

  1693.     std::unique_ptr<NSMutableArray<AUAudioUnitPreset*>, NSObjectDeleter> factoryPresets;

  1694. 

  1695.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1696. 

  1697.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1698.     AudioUnitHelpers::ChannelRemapper mapper;

  1699. 

  1700.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1701.     MidiBuffer midiMessages;

  1702. 

  1703.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1704.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1705. 

  1706.     AudioTimeStamp lastTimeStamp;

  1707.     CurrentPositionInfo lastAudioHead;

  1708. 

  1709.     String contextName;

  1710. 

  1711.     ThreadLocalValue<bool> inParameterChangedCallback;

  1712.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1713.     static constexpr bool forceLegacyParamIDs = true;

  1714.    #else

  1715.     static constexpr bool forceLegacyParamIDs = false;

  1716.    #endif

  1717.     AudioProcessorParameter* bypassParam = nullptr;

  1718. };

  1719. 

  1720. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1721. 

  1722. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1723. {

  1724.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1725.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1726. }

  1727. 

  1728. #if JUCE_IOS

  1729. namespace juce

  1730. {

  1731. struct UIViewPeerControllerReceiver

  1732. {

  1733.     virtual ~UIViewPeerControllerReceiver();

  1734.     virtual void setViewController (UIViewController*) = 0;

  1735. };

  1736. }

  1737. #endif

  1738. 

  1739. //==============================================================================

  1740. class JuceAUViewController

  1741. {

  1742. public:

  1743.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1744.         : myself (p)

  1745.     {

  1746.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1747.         initialiseJuce_GUI();

  1748.     }

  1749. 

  1750.     ~JuceAUViewController()

  1751.     {

  1752.         JUCE_ASSERT_MESSAGE_THREAD

  1753. 

  1754.         if (processorHolder != nullptr)

  1755.             JuceAudioUnitv3::removeEditor (getAudioProcessor());

  1756.     }

  1757. 

  1758.     //==============================================================================

  1759.     void loadView()

  1760.     {

  1761.         JUCE_ASSERT_MESSAGE_THREAD

  1762. 

  1763.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1764.         {

  1765.             processorHolder = new AudioProcessorHolder (p);

  1766.             auto& processor = getAudioProcessor();

  1767. 

  1768.             if (processor.hasEditor())

  1769.             {

  1770.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1771.                 {

  1772.                     preferredSize = editor->getBounds();

  1773. 

  1774.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1775.                     [myself setView: view];

  1776. 

  1777.                    #if JUCE_IOS

  1778.                     editor->setVisible (false);

  1779.                    #else

  1780.                     editor->setVisible (true);

  1781.                    #endif

  1782. 

  1783.                     editor->addToDesktop (0, view);

  1784. 

  1785.                    #if JUCE_IOS

  1786.                     if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1787.                         [peerView setContentMode: UIViewContentModeTop];

  1788. 

  1789.                     if (auto* peer = dynamic_cast<UIViewPeerControllerReceiver*> (editor->getPeer()))

  1790.                         peer->setViewController (myself);

  1791.                    #endif

  1792.                 }

  1793.             }

  1794.         }

  1795.     }

  1796. 

  1797.     void viewDidLayoutSubviews()

  1798.     {

  1799.         if (processorHolder != nullptr && [myself view] != nullptr)

  1800.         {

  1801.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1802.             {

  1803.                 if (processorHolder->viewConfiguration != nullptr)

  1804.                     editor->hostMIDIControllerIsAvailable (processorHolder->viewConfiguration->hostHasMIDIController);

  1805. 

  1806.                 editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1807. 

  1808.                 if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1809.                 {

  1810.                    #if JUCE_IOS

  1811.                     [peerView setNeedsDisplay];

  1812.                    #else

  1813.                     [peerView setNeedsDisplay: YES];

  1814.                    #endif

  1815.                 }

  1816.             }

  1817.         }

  1818.     }

  1819. 

  1820.     void didReceiveMemoryWarning()

  1821.     {

  1822.         if (processorHolder != nullptr)

  1823.             if (auto* processor = processorHolder->get())

  1824.                 processor->memoryWarningReceived();

  1825.     }

  1826. 

  1827.     void viewDidAppear (bool)

  1828.     {

  1829.         if (processorHolder != nullptr)

  1830.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1831.                 editor->setVisible (true);

  1832.     }

  1833. 

  1834.     void viewDidDisappear (bool)

  1835.     {

  1836.         if (processorHolder != nullptr)

  1837.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1838.                 editor->setVisible (false);

  1839.     }

  1840. 

  1841.     CGSize getPreferredContentSize() const

  1842.     {

  1843.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1844.                            static_cast<float> (preferredSize.getHeight()));

  1845.     }

  1846. 

  1847.     //==============================================================================

  1848.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1849.     {

  1850.         AUAudioUnit* retval = nil;

  1851. 

  1852.         if (! MessageManager::getInstance()->isThisTheMessageThread())

  1853.         {

  1854.             WaitableEvent creationEvent;

  1855. 

  1856.             // AUv3 headers say that we may block this thread and that the message thread is guaranteed

  1857.             // to be unblocked

  1858.             struct AUCreator  : public CallbackMessage

  1859.             {

  1860.                 JuceAUViewController& owner;

  1861.                 AudioComponentDescription pDescr;

  1862.                 NSError** pError;

  1863.                 AUAudioUnit*& outAU;

  1864.                 WaitableEvent& e;

  1865. 

  1866.                 AUCreator (JuceAUViewController& parent, const AudioComponentDescription& paramDescr, NSError** paramError,

  1867.                            AUAudioUnit*& outputAU, WaitableEvent& event)

  1868.                     : owner (parent), pDescr (paramDescr), pError (paramError), outAU (outputAU), e (event)

  1869.                 {}

  1870. 

  1871.                 void messageCallback() override

  1872.                 {

  1873.                     outAU = owner.createAudioUnitOnMessageThread (pDescr, pError);

  1874.                     e.signal();

  1875.                 }

  1876.             };

  1877. 

  1878.             (new AUCreator (*this, descr, error, retval, creationEvent))->post();

  1879.             creationEvent.wait (-1);

  1880.         }

  1881.         else

  1882.         {

  1883.             retval = createAudioUnitOnMessageThread (descr, error);

  1884.         }

  1885. 

  1886.         return [retval autorelease];

  1887.     }

  1888. 

  1889. private:

  1890.     //==============================================================================

  1891.     AUViewController<AUAudioUnitFactory>* myself;

  1892.     AudioProcessorHolder::Ptr processorHolder = nullptr;

  1893.     Rectangle<int> preferredSize { 1, 1 };

  1894. 

  1895.     //==============================================================================

  1896.     AUAudioUnit* createAudioUnitOnMessageThread (const AudioComponentDescription& descr, NSError** error)

  1897.     {

  1898.         JUCE_ASSERT_MESSAGE_THREAD

  1899. 

  1900.         [myself view];  // this will call [view load] and ensure that the AudioProcessor has been instantiated

  1901. 

  1902.         if (processorHolder == nullptr)

  1903.             return nullptr;

  1904. 

  1905.         return (new JuceAudioUnitv3 (processorHolder, descr, 0, error))->getAudioUnit();

  1906.     }

  1907. 

  1908.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder; }

  1909. };

  1910. 

  1911. //==============================================================================

  1912. // necessary glue code

  1913. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  1914. @end

  1915. 

  1916. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  1917. {

  1918.     std::unique_ptr<JuceAUViewController> cpp;

  1919. }

  1920. 

  1921. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp.reset (new JuceAUViewController (self)); return self; }

  1922. - (void) loadView                { cpp->loadView(); }

  1923. - (AUAudioUnit *) createAudioUnitWithComponentDescription: (AudioComponentDescription) desc error: (NSError **) error { return cpp->createAudioUnit (desc, error); }

  1924. - (CGSize) preferredContentSize  { return cpp->getPreferredContentSize(); }

  1925. - (void) viewDidLayoutSubviews   { cpp->viewDidLayoutSubviews(); }

  1926. - (void) didReceiveMemoryWarning { cpp->didReceiveMemoryWarning(); }

  1927. #if JUCE_IOS

  1928. - (void) viewDidAppear: (BOOL) animated { cpp->viewDidAppear (animated); [super viewDidAppear:animated]; }

  1929. - (void) viewDidDisappear: (BOOL) animated { cpp->viewDidDisappear (animated); [super viewDidDisappear:animated]; }

  1930. #endif

  1931. @end

  1932. 

  1933. //==============================================================================

  1934. #if JUCE_IOS

  1935. bool JUCE_CALLTYPE juce_isInterAppAudioConnected() { return false; }

  1936. void JUCE_CALLTYPE juce_switchToHostApplication()  {}

  1937. #if JUCE_MODULE_AVAILABLE_juce_gui_basics

  1938. Image JUCE_CALLTYPE juce_getIAAHostIcon (int)      { return {}; }

  1939. #endif

  1940. #endif

  1941. 

  1942. JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  1943. #endif