DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
13795 Commits
9 Branches
2.8GB
Tree: bcb06af289
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'bcb06af289'
${ noResults }
JUCE/modules/juce_gui_basics/native/accessibility/juce_Accessibility_ios.mm

678 lines
33KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2022 - Raw Material Software Limited

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 7 End-User License

  11.    Agreement and JUCE Privacy Policy.

  12. 

  13.    End User License Agreement: www.juce.com/juce-7-licence

  14.    Privacy Policy: www.juce.com/juce-privacy-policy

  15. 

  16.    Or: You may also use this code under the terms of the GPL v3 (see

  17.    www.gnu.org/licenses).

  18. 

  19.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  20.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  21.    DISCLAIMED.

  22. 

  23.   ==============================================================================

  24. */

  25. 

  26. static void juceFreeAccessibilityPlatformSpecificData (UIAccessibilityElement* element)

  27. {

  28.     if (auto* container = juce::getIvar<UIAccessibilityElement*> (element, "container"))

  29.     {

  30.         object_setInstanceVariable (element, "container", nullptr);

  31.         object_setInstanceVariable (container, "handler", nullptr);

  32. 

  33.         [container release];

  34.     }

  35. }

  36. 

  37. namespace juce

  38. {

  39. 

  40. #define JUCE_NATIVE_ACCESSIBILITY_INCLUDED 1

  41. 

  42. template <typename> struct Signature;

  43. 

  44. template <typename Result, typename... Args>

  45. struct Signature<Result (Args...)> {};

  46. 

  47. // @selector isn't constexpr, so the 'sel' members are functions rather than static constexpr data members

  48. struct SignatureHasText                         : Signature<BOOL()>                                                              { static auto sel() { return @selector (hasText); } };

  49. struct SignatureSetSelectedTextRange            : Signature<void (UITextRange*)>                                                 { static auto sel() { return @selector (setSelectedTextRange:); } };

  50. struct SignatureSelectedTextRange               : Signature<UITextRange*()>                                                      { static auto sel() { return @selector (selectedTextRange); } };

  51. struct SignatureMarkedTextRange                 : Signature<UITextRange*()>                                                      { static auto sel() { return @selector (markedTextRange); } };

  52. struct SignatureSetMarkedTextSelectedRange      : Signature<void (NSString*, NSRange)>                                           { static auto sel() { return @selector (setMarkedText:selectedRange:); } };

  53. struct SignatureUnmarkText                      : Signature<void()>                                                              { static auto sel() { return @selector (unmarkText); } };

  54. struct SignatureMarkedTextStyle                 : Signature<NSDictionary<NSAttributedStringKey, id>*()>                          { static auto sel() { return @selector (markedTextStyle); } };

  55. struct SignatureSetMarkedTextStyle              : Signature<void (NSDictionary<NSAttributedStringKey, id>*)>                     { static auto sel() { return @selector (setMarkedTextStyle:); } };

  56. struct SignatureBeginningOfDocument             : Signature<UITextPosition*()>                                                   { static auto sel() { return @selector (beginningOfDocument); } };

  57. struct SignatureEndOfDocument                   : Signature<UITextPosition*()>                                                   { static auto sel() { return @selector (endOfDocument); } };

  58. struct SignatureTokenizer                       : Signature<id<UITextInputTokenizer>()>                                          { static auto sel() { return @selector (tokenizer); } };

  59. struct SignatureBaseWritingDirection            : Signature<NSWritingDirection (UITextPosition*, UITextStorageDirection)>        { static auto sel() { return @selector (baseWritingDirectionForPosition:inDirection:); } };

  60. struct SignatureCaretRectForPosition            : Signature<CGRect (UITextPosition*)>                                            { static auto sel() { return @selector (caretRectForPosition:); } };

  61. struct SignatureCharacterRangeByExtending       : Signature<UITextRange* (UITextPosition*, UITextLayoutDirection)>               { static auto sel() { return @selector (characterRangeByExtendingPosition:inDirection:); } };

  62. struct SignatureCharacterRangeAtPoint           : Signature<UITextRange* (CGPoint)>                                              { static auto sel() { return @selector (characterRangeAtPoint:); } };

  63. struct SignatureClosestPositionToPoint          : Signature<UITextPosition* (CGPoint)>                                           { static auto sel() { return @selector (closestPositionToPoint:); } };

  64. struct SignatureClosestPositionToPointInRange   : Signature<UITextPosition* (CGPoint, UITextRange*)>                             { static auto sel() { return @selector (closestPositionToPoint:withinRange:); } };

  65. struct SignatureComparePositionToPosition       : Signature<NSComparisonResult (UITextPosition*, UITextPosition*)>               { static auto sel() { return @selector (comparePosition:toPosition:); } };

  66. struct SignatureOffsetFromPositionToPosition    : Signature<NSInteger (UITextPosition*, UITextPosition*)>                        { static auto sel() { return @selector (offsetFromPosition:toPosition:); } };

  67. struct SignaturePositionFromPositionInDirection : Signature<UITextPosition* (UITextPosition*, UITextLayoutDirection, NSInteger)> { static auto sel() { return @selector (positionFromPosition:inDirection:offset:); } };

  68. struct SignaturePositionFromPositionOffset      : Signature<UITextPosition* (UITextPosition*, NSInteger)>                        { static auto sel() { return @selector (positionFromPosition:offset:); } };

  69. struct SignatureFirstRectForRange               : Signature<CGRect (UITextRange*)>                                               { static auto sel() { return @selector (firstRectForRange:); } };

  70. struct SignatureSelectionRectsForRange          : Signature<NSArray<UITextSelectionRect*>* (UITextRange*)>                       { static auto sel() { return @selector (selectionRectsForRange:); } };

  71. struct SignaturePositionWithinRange             : Signature<UITextPosition* (UITextRange*, UITextLayoutDirection)>               { static auto sel() { return @selector (positionWithinRange:farthestInDirection:); } };

  72. struct SignatureReplaceRangeWithText            : Signature<void (UITextRange*, NSString*)>                                      { static auto sel() { return @selector (replaceRange:withText:); } };

  73. struct SignatureSetBaseWritingDirection         : Signature<void (NSWritingDirection, UITextRange*)>                             { static auto sel() { return @selector (setBaseWritingDirection:forRange:); } };

  74. struct SignatureTextInRange                     : Signature<NSString* (UITextRange*)>                                            { static auto sel() { return @selector (textInRange:); } };

  75. struct SignatureTextRangeFromPosition           : Signature<UITextRange* (UITextPosition*, UITextPosition*)>                     { static auto sel() { return @selector (textRangeFromPosition:toPosition:); } };

  76. struct SignatureSetInputDelegate                : Signature<void (id)>                                                           { static auto sel() { return @selector (setInputDelegate:); } };

  77. struct SignatureInputDelegate                   : Signature<id()>                                                                { static auto sel() { return @selector (inputDelegate); } };

  78. struct SignatureKeyboardType                    : Signature<UIKeyboardType()>                                                    { static auto sel() { return @selector (keyboardType); } };

  79. struct SignatureAutocapitalizationType          : Signature<UITextAutocapitalizationType()>                                      { static auto sel() { return @selector (autocapitalizationType); } };

  80. struct SignatureAutocorrectionType              : Signature<UITextAutocorrectionType()>                                          { static auto sel() { return @selector (autocorrectionType); } };

  81. 

  82. //==============================================================================

  83. class AccessibilityHandler::AccessibilityNativeImpl

  84. {

  85. public:

  86.     explicit AccessibilityNativeImpl (AccessibilityHandler& handler)

  87.         : accessibilityElement (AccessibilityElement::create (handler))

  88.     {

  89.     }

  90. 

  91.     UIAccessibilityElement* getAccessibilityElement() const noexcept

  92.     {

  93.         return accessibilityElement.get();

  94.     }

  95. 

  96. private:

  97.     //==============================================================================

  98.     class AccessibilityContainer  : public AccessibleObjCClass<NSObject>

  99.     {

  100.     public:

  101.         AccessibilityContainer()

  102.             : AccessibleObjCClass ("JUCEUIAccessibilityContainer_")

  103.         {

  104.             addMethod (@selector (isAccessibilityElement), [] (id, SEL) { return false; });

  105. 

  106.             addMethod (@selector (accessibilityFrame), [] (id self, SEL)

  107.             {

  108.                 if (auto* handler = getHandler (self))

  109.                     return convertToCGRect (handler->getComponent().getScreenBounds());

  110. 

  111.                 return CGRectZero;

  112.             });

  113. 

  114.             addMethod (@selector (accessibilityElements), [] (id self, SEL) -> NSArray*

  115.             {

  116.                 if (auto* handler = getHandler (self))

  117.                     return getContainerAccessibilityElements (*handler);

  118. 

  119.                 return nil;

  120.             });

  121. 

  122.             if (@available (iOS 11.0, *))

  123.             {

  124.                 addMethod (@selector (accessibilityDataTableCellElementForRow:column:), [] (id self, SEL, NSUInteger row, NSUInteger column) -> id

  125.                 {

  126.                     if (auto* tableHandler = detail::AccessibilityHelpers::getEnclosingHandlerWithInterface (getHandler (self), &AccessibilityHandler::getTableInterface))

  127.                         if (auto* tableInterface = tableHandler->getTableInterface())

  128.                             if (auto* cellHandler = tableInterface->getCellHandler ((int) row, (int) column))

  129.                                 if (auto* parent = getAccessibleParent (cellHandler))

  130.                                     return static_cast<id> (parent->getNativeImplementation());

  131. 

  132.                     return nil;

  133.                 });

  134. 

  135.                 addMethod (@selector (accessibilityRowCount),                           getAccessibilityRowCount);

  136.                 addMethod (@selector (accessibilityColumnCount),                        getAccessibilityColumnCount);

  137. 

  138.                 addMethod (@selector (accessibilityHeaderElementsForColumn:), [] (id self, SEL, NSUInteger column) -> NSArray*

  139.                 {

  140.                     if (auto* tableHandler = detail::AccessibilityHelpers::getEnclosingHandlerWithInterface (getHandler (self), &AccessibilityHandler::getTableInterface))

  141.                     {

  142.                         if (auto* tableInterface = tableHandler->getTableInterface())

  143.                         {

  144.                             if (auto* header = tableInterface->getHeaderHandler())

  145.                             {

  146.                                 if (isPositiveAndBelow (column, header->getChildren().size()))

  147.                                 {

  148.                                     auto* result = [NSMutableArray new];

  149.                                     [result addObject: static_cast<id> (header->getChildren()[(size_t) column]->getNativeImplementation())];

  150.                                     return result;

  151.                                 }

  152.                             }

  153.                         }

  154.                     }

  155. 

  156.                     return nullptr;

  157.                 });

  158. 

  159.                 addProtocol (@protocol (UIAccessibilityContainerDataTable));

  160. 

  161.                 addMethod (@selector (accessibilityContainerType), [] (id self, SEL) -> NSInteger

  162.                 {

  163.                     if (auto* handler = getHandler (self))

  164.                     {

  165.                         if (handler->getTableInterface() != nullptr)

  166.                         {

  167.                             if (@available (iOS 11.0, *))

  168.                                 return UIAccessibilityContainerTypeDataTable;

  169. 

  170.                             return 1; // UIAccessibilityContainerTypeDataTable

  171.                         }

  172. 

  173.                         const auto handlerRole = handler->getRole();

  174. 

  175.                         if (handlerRole == AccessibilityRole::popupMenu

  176.                             || handlerRole == AccessibilityRole::list

  177.                             || handlerRole == AccessibilityRole::tree)

  178.                         {

  179.                             if (@available (iOS 11.0, *))

  180.                                 return UIAccessibilityContainerTypeList;

  181. 

  182.                             return 2; // UIAccessibilityContainerTypeList

  183.                         }

  184.                     }

  185. 

  186.                     if (@available (iOS 11.0, *))

  187.                         return UIAccessibilityContainerTypeNone;

  188. 

  189.                     return 0; // UIAccessibilityContainerTypeNone

  190.                 });

  191.             }

  192. 

  193.             registerClass();

  194.         }

  195. 

  196.     private:

  197.         static const AccessibilityHandler* getAccessibleParent (const AccessibilityHandler* h)

  198.         {

  199.             if (h == nullptr)

  200.                 return nullptr;

  201. 

  202.             if ([static_cast<id> (h->getNativeImplementation()) isAccessibilityElement])

  203.                 return h;

  204. 

  205.             return getAccessibleParent (h->getParent());

  206.         }

  207. 

  208.         static AccessibilityHandler* getHandler (id self)

  209.         {

  210.             return getIvar<AccessibilityHandler*> (self, "handler");

  211.         }

  212.     };

  213. 

  214.     //==============================================================================

  215.     class AccessibilityElement  : public AccessibleObjCClass<UIAccessibilityElement>

  216.     {

  217.         template <typename Func, typename... Items>

  218.         static constexpr void forEach (Func&& func, Items&&... items)

  219.         {

  220.             (func (std::forward<Items> (items)), ...);

  221.         }

  222. 

  223.     public:

  224.         enum class Type  { defaultElement, textElement };

  225. 

  226.         static Holder create (AccessibilityHandler& handler)

  227.         {

  228.             static AccessibilityElement cls     { Type::defaultElement };

  229.             static AccessibilityElement textCls { Type::textElement };

  230. 

  231.             id instance = (hasEditableText (handler) ? textCls : cls).createInstance();

  232. 

  233.             Holder element ([instance initWithAccessibilityContainer: static_cast<id> (handler.getComponent().getWindowHandle())]);

  234.             object_setInstanceVariable (element.get(), "handler", &handler);

  235.             return element;

  236.         }

  237. 

  238.         AccessibilityElement (Type elementType)

  239.         {

  240.             addMethod (@selector (isAccessibilityElement), [] (id self, SEL)

  241.             {

  242.                 auto* handler = getHandler (self);

  243. 

  244.                 const auto hasAccessiblePropertiesOrIsTableCell = [] (auto& handlerRef)

  245.                 {

  246.                     const auto isTableCell = [&]

  247.                     {

  248.                         if (auto* tableHandler = detail::AccessibilityHelpers::getEnclosingHandlerWithInterface (&handlerRef, &AccessibilityHandler::getTableInterface))

  249.                         {

  250.                             if (auto* tableInterface = tableHandler->getTableInterface())

  251.                             {

  252.                                 return tableInterface->getRowSpan    (handlerRef).hasValue()

  253.                                     && tableInterface->getColumnSpan (handlerRef).hasValue();

  254.                             }

  255.                         }

  256. 

  257.                         return false;

  258.                     };

  259. 

  260.                     return handlerRef.getTitle().isNotEmpty()

  261.                         || handlerRef.getHelp().isNotEmpty()

  262.                         || handlerRef.getTextInterface()  != nullptr

  263.                         || handlerRef.getValueInterface() != nullptr

  264.                         || isTableCell();

  265.                 };

  266. 

  267.                 return handler != nullptr

  268.                     && ! handler->isIgnored()

  269.                     && handler->getRole() != AccessibilityRole::window

  270.                     && hasAccessiblePropertiesOrIsTableCell (*handler);

  271.             });

  272. 

  273.             addMethod (@selector (accessibilityContainer), [] (id self, SEL) -> id

  274.             {

  275.                 if (auto* handler = getHandler (self))

  276.                 {

  277.                     if (handler->getComponent().isOnDesktop())

  278.                         return static_cast<id> (handler->getComponent().getWindowHandle());

  279. 

  280.                     if (   ! handler->getChildren().empty()

  281.                         || AccessibilityHandler::getNativeChildForComponent (handler->getComponent()) != nullptr)

  282.                     {

  283.                         if (UIAccessibilityElement* container = getContainer (self))

  284.                             return container;

  285. 

  286.                         static AccessibilityContainer cls;

  287. 

  288.                         id container = cls.createInstance();

  289. 

  290.                         object_setInstanceVariable (container, "handler", handler);

  291.                         object_setInstanceVariable (self, "container", container);

  292. 

  293.                         return container;

  294.                     }

  295. 

  296.                     if (auto* parent = handler->getParent())

  297.                         return [static_cast<id> (parent->getNativeImplementation()) accessibilityContainer];

  298.                 }

  299. 

  300.                 return nil;

  301.             });

  302. 

  303.             addMethod (@selector (accessibilityFrame), [] (id self, SEL)

  304.             {

  305.                 if (auto* handler = getHandler (self))

  306.                     return convertToCGRect (handler->getComponent().getScreenBounds());

  307. 

  308.                 return CGRectZero;

  309.             });

  310. 

  311.             addMethod (@selector (accessibilityTraits), [] (id self, SEL)

  312.             {

  313.                 auto traits = UIAccessibilityTraits{};

  314. 

  315.                 if (auto* handler = getHandler (self))

  316.                 {

  317.                     traits |= [&handler]

  318.                     {

  319.                         switch (handler->getRole())

  320.                         {

  321.                             case AccessibilityRole::button:

  322.                             case AccessibilityRole::toggleButton:

  323.                             case AccessibilityRole::radioButton:

  324.                             case AccessibilityRole::comboBox:      return UIAccessibilityTraitButton;

  325. 

  326.                             case AccessibilityRole::label:

  327.                             case AccessibilityRole::staticText:    return UIAccessibilityTraitStaticText;

  328. 

  329.                             case AccessibilityRole::image:         return UIAccessibilityTraitImage;

  330.                             case AccessibilityRole::tableHeader:   return UIAccessibilityTraitHeader;

  331.                             case AccessibilityRole::hyperlink:     return UIAccessibilityTraitLink;

  332.                             case AccessibilityRole::ignored:       return UIAccessibilityTraitNotEnabled;

  333. 

  334.                             case AccessibilityRole::editableText:  return UIAccessibilityTraitKeyboardKey;

  335. 

  336.                             case AccessibilityRole::slider:

  337.                             case AccessibilityRole::menuItem:

  338.                             case AccessibilityRole::menuBar:

  339.                             case AccessibilityRole::popupMenu:

  340.                             case AccessibilityRole::table:

  341.                             case AccessibilityRole::column:

  342.                             case AccessibilityRole::row:

  343.                             case AccessibilityRole::cell:

  344.                             case AccessibilityRole::list:

  345.                             case AccessibilityRole::listItem:

  346.                             case AccessibilityRole::tree:

  347.                             case AccessibilityRole::treeItem:

  348.                             case AccessibilityRole::progressBar:

  349.                             case AccessibilityRole::group:

  350.                             case AccessibilityRole::dialogWindow:

  351.                             case AccessibilityRole::window:

  352.                             case AccessibilityRole::scrollBar:

  353.                             case AccessibilityRole::tooltip:

  354.                             case AccessibilityRole::splashScreen:

  355.                             case AccessibilityRole::unspecified:   break;

  356.                         }

  357. 

  358.                         return UIAccessibilityTraitNone;

  359.                     }();

  360. 

  361.                     const auto state = handler->getCurrentState();

  362. 

  363.                     if (state.isSelected() || state.isChecked())

  364.                         traits |= UIAccessibilityTraitSelected;

  365. 

  366.                     if (auto* valueInterface = getValueInterface (self))

  367.                         if (! valueInterface->isReadOnly() && valueInterface->getRange().isValid())

  368.                             traits |= UIAccessibilityTraitAdjustable;

  369.                 }

  370. 

  371.                 return traits | sendSuperclassMessage<UIAccessibilityTraits> (self, @selector (accessibilityTraits));

  372.             });

  373. 

  374.             addMethod (@selector (accessibilityLabel), getAccessibilityTitle);

  375.             addMethod (@selector (accessibilityHint),  getAccessibilityHelp);

  376. 

  377.             addMethod (@selector (accessibilityValue), [] (id self, SEL) -> NSString*

  378.             {

  379.                 if (auto* handler = getHandler (self))

  380.                 {

  381.                     if (handler->getCurrentState().isCheckable())

  382.                         return handler->getCurrentState().isChecked() ? @"1" : @"0";

  383. 

  384.                     return (NSString*) getAccessibilityValueFromInterfaces (*handler);

  385.                 }

  386. 

  387.                 return nil;

  388.             });

  389. 

  390.             addMethod (@selector (setAccessibilityValue:), setAccessibilityValue);

  391. 

  392.             addMethod (@selector (accessibilityElementDidBecomeFocused), [] (id self, SEL)

  393.             {

  394.                 if (auto* handler = getHandler (self))

  395.                 {

  396.                     const WeakReference<Component> safeComponent (&handler->getComponent());

  397. 

  398.                     performActionIfSupported (self, AccessibilityActionType::focus);

  399. 

  400.                     if (safeComponent != nullptr)

  401.                         handler->grabFocus();

  402.                 }

  403.             });

  404. 

  405.             addMethod (@selector (accessibilityElementDidLoseFocus), [] (id self, SEL)

  406.             {

  407.                 if (auto* handler = getHandler (self))

  408.                     handler->giveAwayFocus();

  409.             });

  410. 

  411.             addMethod (@selector (accessibilityElementIsFocused), [] (id self, SEL) -> BOOL

  412.             {

  413.                 if (auto* handler = getHandler (self))

  414.                     return handler->hasFocus (false);

  415. 

  416.                 return NO;

  417.             });

  418. 

  419.             addMethod (@selector (accessibilityViewIsModal), getIsAccessibilityModal);

  420. 

  421.             addMethod (@selector (accessibilityActivate), [] (id self, SEL)

  422.             {

  423.                 if (auto* handler = getHandler (self))

  424.                 {

  425.                     // Occasionally VoiceOver sends accessibilityActivate to the wrong element, so we first query

  426.                     // which element it thinks has focus and forward the event on to that element if it differs

  427.                     id focusedElement = UIAccessibilityFocusedElement (UIAccessibilityNotificationVoiceOverIdentifier);

  428. 

  429.                     if (focusedElement != nullptr && ! [static_cast<id> (handler->getNativeImplementation()) isEqual: focusedElement])

  430.                         return [focusedElement accessibilityActivate];

  431. 

  432.                     if (handler->hasFocus (false))

  433.                         return accessibilityPerformPress (self, {});

  434.                 }

  435. 

  436.                 return NO;

  437.             });

  438. 

  439.             addMethod (@selector (accessibilityIncrement), accessibilityPerformIncrement);

  440.             addMethod (@selector (accessibilityDecrement), accessibilityPerformDecrement);

  441. 

  442.             addMethod (@selector (accessibilityPerformEscape), [] (id self, SEL)

  443.             {

  444.                 if (auto* handler = getHandler (self))

  445.                 {

  446.                     if (auto* modal = Component::getCurrentlyModalComponent())

  447.                     {

  448.                         if (auto* modalHandler = modal->getAccessibilityHandler())

  449.                         {

  450.                             if (modalHandler == handler || modalHandler->isParentOf (handler))

  451.                             {

  452.                                 modal->exitModalState (0);

  453.                                 return YES;

  454.                             }

  455.                         }

  456.                     }

  457.                 }

  458. 

  459.                 return NO;

  460.             });

  461. 

  462.             if (elementType == Type::textElement)

  463.             {

  464.                 addMethod (@selector (deleteBackward), [] (id, SEL) {});

  465.                 addMethod (@selector (insertText:), [] (id, SEL, NSString*) {});

  466. 

  467.                 forEach ([this] (auto signature) { addPassthroughMethodWithSignature (signature); },

  468.                          SignatureHasText{},

  469.                          SignatureSetSelectedTextRange{},

  470.                          SignatureSelectedTextRange{},

  471.                          SignatureMarkedTextRange{},

  472.                          SignatureSetMarkedTextSelectedRange{},

  473.                          SignatureUnmarkText{},

  474.                          SignatureMarkedTextStyle{},

  475.                          SignatureSetMarkedTextStyle{},

  476.                          SignatureBeginningOfDocument{},

  477.                          SignatureEndOfDocument{},

  478.                          SignatureTokenizer{},

  479.                          SignatureBaseWritingDirection{},

  480.                          SignatureCaretRectForPosition{},

  481.                          SignatureCharacterRangeByExtending{},

  482.                          SignatureCharacterRangeAtPoint{},

  483.                          SignatureClosestPositionToPoint{},

  484.                          SignatureClosestPositionToPointInRange{},

  485.                          SignatureComparePositionToPosition{},

  486.                          SignatureOffsetFromPositionToPosition{},

  487.                          SignaturePositionFromPositionInDirection{},

  488.                          SignaturePositionFromPositionOffset{},

  489.                          SignatureFirstRectForRange{},

  490.                          SignatureSelectionRectsForRange{},

  491.                          SignaturePositionWithinRange{},

  492.                          SignatureReplaceRangeWithText{},

  493.                          SignatureSetBaseWritingDirection{},

  494.                          SignatureTextInRange{},

  495.                          SignatureTextRangeFromPosition{},

  496.                          SignatureSetInputDelegate{},

  497.                          SignatureInputDelegate{},

  498.                          SignatureKeyboardType{},

  499.                          SignatureAutocapitalizationType{},

  500.                          SignatureAutocorrectionType{});

  501. 

  502.                 addProtocol (@protocol (UITextInput));

  503.             }

  504. 

  505.             if (@available (iOS 11.0, *))

  506.             {

  507.                 addMethod (@selector (accessibilityRowRange),                           getAccessibilityRowIndexRange);

  508.                 addMethod (@selector (accessibilityColumnRange),                        getAccessibilityColumnIndexRange);

  509.                 addProtocol (@protocol (UIAccessibilityContainerDataTableCell));

  510.             }

  511. 

  512.             addIvar<UIAccessibilityElement*> ("container");

  513. 

  514.             registerClass();

  515.         }

  516. 

  517.     private:

  518.         template <typename Result>

  519.         static auto getResult (NSInvocation* invocation, detail::Tag<Result>)

  520.         {

  521.             Result result{};

  522.             [invocation getReturnValue: &result];

  523.             return result;

  524.         }

  525. 

  526.         static void getResult (NSInvocation*, detail::Tag<void>) {}

  527. 

  528.         template <typename HasSelector, typename Result, typename... Args>

  529.         auto makePassthroughCallback (HasSelector, Signature<Result (Args...)>)

  530.         {

  531.             return [] (id self, SEL, Args... args) -> Result

  532.             {

  533.                 if (auto* input = getPeerTextInput (self))

  534.                 {

  535.                     const auto s = detail::makeCompileTimeStr (@encode (Result), @encode (id), @encode (SEL), @encode (Args)...);

  536.                     const auto signature = [NSMethodSignature signatureWithObjCTypes: s.data()];

  537. 

  538.                     if (signature == nullptr)

  539.                     {

  540.                         jassertfalse;

  541.                         return {};

  542.                     }

  543. 

  544.                     JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wnullable-to-nonnull-conversion")

  545.                     const auto invocation = [NSInvocation invocationWithMethodSignature: signature];

  546.                     JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  547. 

  548.                     invocation.selector = HasSelector::sel();

  549. 

  550.                     // Indices 0 and 1 are 'id self' and 'SEL _cmd' respectively

  551.                     auto counter = 2;

  552.                     forEach ([&] (auto& arg) { [invocation setArgument: &arg atIndex: counter++]; }, args...);

  553. 

  554.                     [invocation invokeWithTarget: input];

  555. 

  556.                     return getResult (invocation, detail::Tag<Result>{});

  557.                 }

  558. 

  559.                 jassertfalse;

  560.                 return {};

  561.             };

  562.         }

  563. 

  564.         template <typename Signature>

  565.         void addPassthroughMethodWithSignature (Signature signature)

  566.         {

  567.             addMethod (Signature::sel(), makePassthroughCallback (signature, signature));

  568.         }

  569. 

  570.         static UIAccessibilityElement* getContainer (id self)

  571.         {

  572.             return getIvar<UIAccessibilityElement*> (self, "container");

  573.         }

  574. 

  575.         static UIViewComponentPeer* getPeer (id self)

  576.         {

  577.             if (auto* handler = getHandler (self))

  578.                 return static_cast<UIViewComponentPeer*> (handler->getComponent().getPeer());

  579. 

  580.             return nil;

  581.         }

  582. 

  583.         static JuceTextView* getPeerTextInput (id self)

  584.         {

  585.             if (auto* peer = getPeer (self))

  586.                 return peer->hiddenTextInput.get();

  587. 

  588.             return nil;

  589.         }

  590. 

  591.         //==============================================================================

  592.         JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityElement)

  593.     };

  594. 

  595.     //==============================================================================

  596.     AccessibilityElement::Holder accessibilityElement;

  597. 

  598.     //==============================================================================

  599.     JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityNativeImpl)

  600. };

  601. 

  602. //==============================================================================

  603. AccessibilityNativeHandle* AccessibilityHandler::getNativeImplementation() const

  604. {

  605.     return (AccessibilityNativeHandle*) nativeImpl->getAccessibilityElement();

  606. }

  607. 

  608. static bool areAnyAccessibilityClientsActive()

  609. {

  610.     return UIAccessibilityIsVoiceOverRunning();

  611. }

  612. 

  613. static void sendAccessibilityEvent (UIAccessibilityNotifications notification, id argument)

  614. {

  615.     if (! areAnyAccessibilityClientsActive())

  616.         return;

  617. 

  618.     jassert (notification != UIAccessibilityNotifications{});

  619. 

  620.     UIAccessibilityPostNotification (notification, argument);

  621. }

  622. 

  623. void detail::AccessibilityHelpers::notifyAccessibilityEvent (const AccessibilityHandler& handler, Event eventType)

  624. {

  625.     auto notification = [eventType]

  626.     {

  627.         switch (eventType)

  628.         {

  629.             case Event::elementCreated:

  630.             case Event::elementDestroyed:

  631.             case Event::elementMovedOrResized:

  632.             case Event::focusChanged:            return UIAccessibilityLayoutChangedNotification;

  633. 

  634.             case Event::windowOpened:

  635.             case Event::windowClosed:            return UIAccessibilityScreenChangedNotification;

  636.         }

  637. 

  638.         return UIAccessibilityNotifications{};

  639.     }();

  640. 

  641.     if (notification != UIAccessibilityNotifications{})

  642.     {

  643.         const bool moveToHandler = (eventType == Event::focusChanged && handler.hasFocus (false));

  644. 

  645.         sendAccessibilityEvent (notification,

  646.                                 moveToHandler ? static_cast<id> (handler.getNativeImplementation()) : nil);

  647.     }

  648. }

  649. 

  650. void AccessibilityHandler::notifyAccessibilityEvent (AccessibilityEvent eventType) const

  651. {

  652.     auto notification = [eventType]

  653.     {

  654.         switch (eventType)

  655.         {

  656.             case AccessibilityEvent::textSelectionChanged:

  657.             case AccessibilityEvent::rowSelectionChanged:

  658.             case AccessibilityEvent::textChanged:

  659.             case AccessibilityEvent::valueChanged:

  660.             case AccessibilityEvent::titleChanged:          break;

  661. 

  662.             case AccessibilityEvent::structureChanged:      return UIAccessibilityLayoutChangedNotification;

  663.         }

  664. 

  665.         return UIAccessibilityNotifications{};

  666.     }();

  667. 

  668.     if (notification != UIAccessibilityNotifications{})

  669.         sendAccessibilityEvent (notification, static_cast<id> (getNativeImplementation()));

  670. }

  671. 

  672. void AccessibilityHandler::postAnnouncement (const String& announcementString, AnnouncementPriority)

  673. {

  674.     sendAccessibilityEvent (UIAccessibilityAnnouncementNotification, juceStringToNS (announcementString));

  675. }

  676. 

  677. } // namespace juce