DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
13169 Commits
9 Branches
794MB
Tree: b51e835baf
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'b51e835baf'
${ noResults }
JUCE/modules/juce_gui_basics/native/accessibility/juce_ios_Accessibility.mm

675 lines
33KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2022 - Raw Material Software Limited

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 7 End-User License

  11.    Agreement and JUCE Privacy Policy.

  12. 

  13.    End User License Agreement: www.juce.com/juce-7-licence

  14.    Privacy Policy: www.juce.com/juce-privacy-policy

  15. 

  16.    Or: You may also use this code under the terms of the GPL v3 (see

  17.    www.gnu.org/licenses).

  18. 

  19.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  20.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  21.    DISCLAIMED.

  22. 

  23.   ==============================================================================

  24. */

  25. 

  26. static void juceFreeAccessibilityPlatformSpecificData (UIAccessibilityElement* element)

  27. {

  28.     if (auto* container = juce::getIvar<UIAccessibilityElement*> (element, "container"))

  29.     {

  30.         object_setInstanceVariable (element, "container", nullptr);

  31.         object_setInstanceVariable (container, "handler", nullptr);

  32. 

  33.         [container release];

  34.     }

  35. }

  36. 

  37. namespace juce

  38. {

  39. 

  40. #if defined (__IPHONE_11_0) && __IPHONE_OS_VERSION_MAX_ALLOWED >= __IPHONE_11_0

  41.  #define JUCE_IOS_CONTAINER_API_AVAILABLE 1

  42. #endif

  43. 

  44. #define JUCE_NATIVE_ACCESSIBILITY_INCLUDED 1

  45. 

  46. template <typename> struct Signature;

  47. 

  48. template <typename Result, typename... Args>

  49. struct Signature<Result (Args...)> {};

  50. 

  51. // @selector isn't constexpr, so the 'sel' members are functions rather than static constexpr data members

  52. struct SignatureHasText                         : Signature<BOOL()>                                                              { static auto sel() { return @selector (hasText); } };

  53. struct SignatureSetSelectedTextRange            : Signature<void (UITextRange*)>                                                 { static auto sel() { return @selector (setSelectedTextRange:); } };

  54. struct SignatureSelectedTextRange               : Signature<UITextRange*()>                                                      { static auto sel() { return @selector (selectedTextRange); } };

  55. struct SignatureMarkedTextRange                 : Signature<UITextRange*()>                                                      { static auto sel() { return @selector (markedTextRange); } };

  56. struct SignatureSetMarkedTextSelectedRange      : Signature<void (NSString*, NSRange)>                                           { static auto sel() { return @selector (setMarkedText:selectedRange:); } };

  57. struct SignatureUnmarkText                      : Signature<void()>                                                              { static auto sel() { return @selector (unmarkText); } };

  58. struct SignatureMarkedTextStyle                 : Signature<NSDictionary<NSAttributedStringKey, id>*()>                          { static auto sel() { return @selector (markedTextStyle); } };

  59. struct SignatureSetMarkedTextStyle              : Signature<void (NSDictionary<NSAttributedStringKey, id>*)>                     { static auto sel() { return @selector (setMarkedTextStyle:); } };

  60. struct SignatureBeginningOfDocument             : Signature<UITextPosition*()>                                                   { static auto sel() { return @selector (beginningOfDocument); } };

  61. struct SignatureEndOfDocument                   : Signature<UITextPosition*()>                                                   { static auto sel() { return @selector (endOfDocument); } };

  62. struct SignatureTokenizer                       : Signature<id<UITextInputTokenizer>()>                                          { static auto sel() { return @selector (tokenizer); } };

  63. struct SignatureBaseWritingDirection            : Signature<NSWritingDirection (UITextPosition*, UITextStorageDirection)>        { static auto sel() { return @selector (baseWritingDirectionForPosition:inDirection:); } };

  64. struct SignatureCaretRectForPosition            : Signature<CGRect (UITextPosition*)>                                            { static auto sel() { return @selector (caretRectForPosition:); } };

  65. struct SignatureCharacterRangeByExtending       : Signature<UITextRange* (UITextPosition*, UITextLayoutDirection)>               { static auto sel() { return @selector (characterRangeByExtendingPosition:inDirection:); } };

  66. struct SignatureCharacterRangeAtPoint           : Signature<UITextRange* (CGPoint)>                                              { static auto sel() { return @selector (characterRangeAtPoint:); } };

  67. struct SignatureClosestPositionToPoint          : Signature<UITextPosition* (CGPoint)>                                           { static auto sel() { return @selector (closestPositionToPoint:); } };

  68. struct SignatureClosestPositionToPointInRange   : Signature<UITextPosition* (CGPoint, UITextRange*)>                             { static auto sel() { return @selector (closestPositionToPoint:withinRange:); } };

  69. struct SignatureComparePositionToPosition       : Signature<NSComparisonResult (UITextPosition*, UITextPosition*)>               { static auto sel() { return @selector (comparePosition:toPosition:); } };

  70. struct SignatureOffsetFromPositionToPosition    : Signature<NSInteger (UITextPosition*, UITextPosition*)>                        { static auto sel() { return @selector (offsetFromPosition:toPosition:); } };

  71. struct SignaturePositionFromPositionInDirection : Signature<UITextPosition* (UITextPosition*, UITextLayoutDirection, NSInteger)> { static auto sel() { return @selector (positionFromPosition:inDirection:offset:); } };

  72. struct SignaturePositionFromPositionOffset      : Signature<UITextPosition* (UITextPosition*, NSInteger)>                        { static auto sel() { return @selector (positionFromPosition:offset:); } };

  73. struct SignatureFirstRectForRange               : Signature<CGRect (UITextRange*)>                                               { static auto sel() { return @selector (firstRectForRange:); } };

  74. struct SignatureSelectionRectsForRange          : Signature<NSArray<UITextSelectionRect*>* (UITextRange*)>                       { static auto sel() { return @selector (selectionRectsForRange:); } };

  75. struct SignaturePositionWithinRange             : Signature<UITextPosition* (UITextRange*, UITextLayoutDirection)>               { static auto sel() { return @selector (positionWithinRange:farthestInDirection:); } };

  76. struct SignatureReplaceRangeWithText            : Signature<void (UITextRange*, NSString*)>                                      { static auto sel() { return @selector (replaceRange:withText:); } };

  77. struct SignatureSetBaseWritingDirection         : Signature<void (NSWritingDirection, UITextRange*)>                             { static auto sel() { return @selector (setBaseWritingDirection:forRange:); } };

  78. struct SignatureTextInRange                     : Signature<NSString* (UITextRange*)>                                            { static auto sel() { return @selector (textInRange:); } };

  79. struct SignatureTextRangeFromPosition           : Signature<UITextRange* (UITextPosition*, UITextPosition*)>                     { static auto sel() { return @selector (textRangeFromPosition:toPosition:); } };

  80. struct SignatureSetInputDelegate                : Signature<void (id)>                                                           { static auto sel() { return @selector (setInputDelegate:); } };

  81. struct SignatureInputDelegate                   : Signature<id()>                                                                { static auto sel() { return @selector (inputDelegate); } };

  82. struct SignatureKeyboardType                    : Signature<UIKeyboardType()>                                                    { static auto sel() { return @selector (keyboardType); } };

  83. struct SignatureAutocapitalizationType          : Signature<UITextAutocapitalizationType()>                                      { static auto sel() { return @selector (autocapitalizationType); } };

  84. struct SignatureAutocorrectionType              : Signature<UITextAutocorrectionType()>                                          { static auto sel() { return @selector (autocorrectionType); } };

  85. 

  86. //==============================================================================

  87. class AccessibilityHandler::AccessibilityNativeImpl

  88. {

  89. public:

  90.     explicit AccessibilityNativeImpl (AccessibilityHandler& handler)

  91.         : accessibilityElement (AccessibilityElement::create (handler))

  92.     {

  93.     }

  94. 

  95.     UIAccessibilityElement* getAccessibilityElement() const noexcept

  96.     {

  97.         return accessibilityElement.get();

  98.     }

  99. 

  100. private:

  101.     //==============================================================================

  102.     class AccessibilityContainer  : public AccessibleObjCClass<NSObject>

  103.     {

  104.     public:

  105.         AccessibilityContainer()

  106.             : AccessibleObjCClass ("JUCEUIAccessibilityContainer_")

  107.         {

  108.             addMethod (@selector (isAccessibilityElement), [] (id, SEL) { return false; });

  109. 

  110.             addMethod (@selector (accessibilityFrame), [] (id self, SEL)

  111.             {

  112.                 if (auto* handler = getHandler (self))

  113.                     return convertToCGRect (handler->getComponent().getScreenBounds());

  114. 

  115.                 return CGRectZero;

  116.             });

  117. 

  118.             addMethod (@selector (accessibilityElements), [] (id self, SEL) -> NSArray*

  119.             {

  120.                 if (auto* handler = getHandler (self))

  121.                     return getContainerAccessibilityElements (*handler);

  122. 

  123.                 return nil;

  124.             });

  125. 

  126.            #if JUCE_IOS_CONTAINER_API_AVAILABLE

  127.             if (@available (iOS 11.0, *))

  128.             {

  129.                 addMethod (@selector (accessibilityDataTableCellElementForRow:column:), [] (id self, SEL, NSUInteger row, NSUInteger column) -> id

  130.                 {

  131.                     if (auto* tableHandler = getEnclosingHandlerWithInterface (getHandler (self), &AccessibilityHandler::getTableInterface))

  132.                         if (auto* tableInterface = tableHandler->getTableInterface())

  133.                             if (auto* cellHandler = tableInterface->getCellHandler ((int) row, (int) column))

  134.                                 if (auto* parent = getAccessibleParent (cellHandler))

  135.                                     return static_cast<id> (parent->getNativeImplementation());

  136. 

  137.                     return nil;

  138.                 });

  139. 

  140.                 addMethod (@selector (accessibilityRowCount),                           getAccessibilityRowCount);

  141.                 addMethod (@selector (accessibilityColumnCount),                        getAccessibilityColumnCount);

  142. 

  143.                 addMethod (@selector (accessibilityHeaderElementsForColumn:), [] (id self, SEL, NSUInteger column) -> NSArray*

  144.                 {

  145.                     if (auto* tableHandler = getEnclosingHandlerWithInterface (getHandler (self), &AccessibilityHandler::getTableInterface))

  146.                     {

  147.                         if (auto* tableInterface = tableHandler->getTableInterface())

  148.                         {

  149.                             if (auto* header = tableInterface->getHeaderHandler())

  150.                             {

  151.                                 if (isPositiveAndBelow (column, header->getChildren().size()))

  152.                                 {

  153.                                     auto* result = [NSMutableArray new];

  154.                                     [result addObject: static_cast<id> (header->getChildren()[(size_t) column]->getNativeImplementation())];

  155.                                     return result;

  156.                                 }

  157.                             }

  158.                         }

  159.                     }

  160. 

  161.                     return nullptr;

  162.                 });

  163. 

  164.                 addProtocol (@protocol (UIAccessibilityContainerDataTable));

  165. 

  166.                 addMethod (@selector (accessibilityContainerType), [] (id self, SEL) -> NSInteger

  167.                 {

  168.                     if (auto* handler = getHandler (self))

  169.                     {

  170.                         if (handler->getTableInterface() != nullptr)

  171.                         {

  172.                             if (@available (iOS 11.0, *))

  173.                                 return UIAccessibilityContainerTypeDataTable;

  174. 

  175.                             return 1; // UIAccessibilityContainerTypeDataTable

  176.                         }

  177. 

  178.                         const auto handlerRole = handler->getRole();

  179. 

  180.                         if (handlerRole == AccessibilityRole::popupMenu

  181.                             || handlerRole == AccessibilityRole::list

  182.                             || handlerRole == AccessibilityRole::tree)

  183.                         {

  184.                             if (@available (iOS 11.0, *))

  185.                                 return UIAccessibilityContainerTypeList;

  186. 

  187.                             return 2; // UIAccessibilityContainerTypeList

  188.                         }

  189.                     }

  190. 

  191.                     if (@available (iOS 11.0, *))

  192.                         return UIAccessibilityContainerTypeNone;

  193. 

  194.                     return 0; // UIAccessibilityContainerTypeNone

  195.                 });

  196.             }

  197.            #endif

  198. 

  199.             registerClass();

  200.         }

  201. 

  202.     private:

  203.         static const AccessibilityHandler* getAccessibleParent (const AccessibilityHandler* h)

  204.         {

  205.             if (h == nullptr)

  206.                 return nullptr;

  207. 

  208.             if ([static_cast<id> (h->getNativeImplementation()) isAccessibilityElement])

  209.                 return h;

  210. 

  211.             return getAccessibleParent (h->getParent());

  212.         }

  213. 

  214.         static AccessibilityHandler* getHandler (id self)

  215.         {

  216.             return getIvar<AccessibilityHandler*> (self, "handler");

  217.         }

  218.     };

  219. 

  220.     //==============================================================================

  221.     class AccessibilityElement  : public AccessibleObjCClass<UIAccessibilityElement>

  222.     {

  223.         template <typename Func, typename... Items>

  224.         static constexpr void forEach (Func&& func, Items&&... items)

  225.         {

  226.             (void) std::initializer_list<int> { ((void) func (std::forward<Items> (items)), 0)... };

  227.         }

  228. 

  229.     public:

  230.         enum class Type  { defaultElement, textElement };

  231. 

  232.         static Holder create (AccessibilityHandler& handler)

  233.         {

  234.             static AccessibilityElement cls     { Type::defaultElement };

  235.             static AccessibilityElement textCls { Type::textElement };

  236. 

  237.             id instance = (hasEditableText (handler) ? textCls : cls).createInstance();

  238. 

  239.             Holder element ([instance initWithAccessibilityContainer: static_cast<id> (handler.getComponent().getWindowHandle())]);

  240.             object_setInstanceVariable (element.get(), "handler", &handler);

  241.             return element;

  242.         }

  243. 

  244.         AccessibilityElement (Type elementType)

  245.         {

  246.             addMethod (@selector (isAccessibilityElement), [] (id self, SEL)

  247.             {

  248.                 auto* handler = getHandler (self);

  249. 

  250.                 const auto hasAccessiblePropertiesOrIsTableCell = [] (auto& handlerRef)

  251.                 {

  252.                     const auto isTableCell = [&]

  253.                     {

  254.                         if (auto* tableHandler = getEnclosingHandlerWithInterface (&handlerRef, &AccessibilityHandler::getTableInterface))

  255.                         {

  256.                             if (auto* tableInterface = tableHandler->getTableInterface())

  257.                             {

  258.                                 return tableInterface->getRowSpan    (handlerRef).hasValue()

  259.                                     && tableInterface->getColumnSpan (handlerRef).hasValue();

  260.                             }

  261.                         }

  262. 

  263.                         return false;

  264.                     };

  265. 

  266.                     return handlerRef.getTitle().isNotEmpty()

  267.                         || handlerRef.getHelp().isNotEmpty()

  268.                         || handlerRef.getTextInterface()  != nullptr

  269.                         || handlerRef.getValueInterface() != nullptr

  270.                         || isTableCell();

  271.                 };

  272. 

  273.                 return handler != nullptr

  274.                     && ! handler->isIgnored()

  275.                     && handler->getRole() != AccessibilityRole::window

  276.                     && hasAccessiblePropertiesOrIsTableCell (*handler);

  277.             });

  278. 

  279.             addMethod (@selector (accessibilityContainer), [] (id self, SEL) -> id

  280.             {

  281.                 if (auto* handler = getHandler (self))

  282.                 {

  283.                     if (handler->getComponent().isOnDesktop())

  284.                         return static_cast<id> (handler->getComponent().getWindowHandle());

  285. 

  286.                     if (! handler->getChildren().empty())

  287.                     {

  288.                         if (UIAccessibilityElement* container = getContainer (self))

  289.                             return container;

  290. 

  291.                         static AccessibilityContainer cls;

  292. 

  293.                         id container = cls.createInstance();

  294. 

  295.                         object_setInstanceVariable (container, "handler", handler);

  296.                         object_setInstanceVariable (self, "container", container);

  297. 

  298.                         return container;

  299.                     }

  300. 

  301.                     if (auto* parent = handler->getParent())

  302.                         return [static_cast<id> (parent->getNativeImplementation()) accessibilityContainer];

  303.                 }

  304. 

  305.                 return nil;

  306.             });

  307. 

  308.             addMethod (@selector (accessibilityFrame), [] (id self, SEL)

  309.             {

  310.                 if (auto* handler = getHandler (self))

  311.                     return convertToCGRect (handler->getComponent().getScreenBounds());

  312. 

  313.                 return CGRectZero;

  314.             });

  315. 

  316.             addMethod (@selector (accessibilityTraits), [] (id self, SEL)

  317.             {

  318.                 auto traits = UIAccessibilityTraits{};

  319. 

  320.                 if (auto* handler = getHandler (self))

  321.                 {

  322.                     traits |= [&handler]

  323.                     {

  324.                         switch (handler->getRole())

  325.                         {

  326.                             case AccessibilityRole::button:

  327.                             case AccessibilityRole::toggleButton:

  328.                             case AccessibilityRole::radioButton:

  329.                             case AccessibilityRole::comboBox:      return UIAccessibilityTraitButton;

  330. 

  331.                             case AccessibilityRole::label:

  332.                             case AccessibilityRole::staticText:    return UIAccessibilityTraitStaticText;

  333. 

  334.                             case AccessibilityRole::image:         return UIAccessibilityTraitImage;

  335.                             case AccessibilityRole::tableHeader:   return UIAccessibilityTraitHeader;

  336.                             case AccessibilityRole::hyperlink:     return UIAccessibilityTraitLink;

  337.                             case AccessibilityRole::ignored:       return UIAccessibilityTraitNotEnabled;

  338. 

  339.                             case AccessibilityRole::editableText:  return UIAccessibilityTraitKeyboardKey;

  340. 

  341.                             case AccessibilityRole::slider:

  342.                             case AccessibilityRole::menuItem:

  343.                             case AccessibilityRole::menuBar:

  344.                             case AccessibilityRole::popupMenu:

  345.                             case AccessibilityRole::table:

  346.                             case AccessibilityRole::column:

  347.                             case AccessibilityRole::row:

  348.                             case AccessibilityRole::cell:

  349.                             case AccessibilityRole::list:

  350.                             case AccessibilityRole::listItem:

  351.                             case AccessibilityRole::tree:

  352.                             case AccessibilityRole::treeItem:

  353.                             case AccessibilityRole::progressBar:

  354.                             case AccessibilityRole::group:

  355.                             case AccessibilityRole::dialogWindow:

  356.                             case AccessibilityRole::window:

  357.                             case AccessibilityRole::scrollBar:

  358.                             case AccessibilityRole::tooltip:

  359.                             case AccessibilityRole::splashScreen:

  360.                             case AccessibilityRole::unspecified:   break;

  361.                         }

  362. 

  363.                         return UIAccessibilityTraitNone;

  364.                     }();

  365. 

  366.                     const auto state = handler->getCurrentState();

  367. 

  368.                     if (state.isSelected() || state.isChecked())

  369.                         traits |= UIAccessibilityTraitSelected;

  370. 

  371.                     if (auto* valueInterface = getValueInterface (self))

  372.                         if (! valueInterface->isReadOnly() && valueInterface->getRange().isValid())

  373.                             traits |= UIAccessibilityTraitAdjustable;

  374.                 }

  375. 

  376.                 return traits | sendSuperclassMessage<UIAccessibilityTraits> (self, @selector (accessibilityTraits));

  377.             });

  378. 

  379.             addMethod (@selector (accessibilityLabel), getAccessibilityTitle);

  380.             addMethod (@selector (accessibilityHint),  getAccessibilityHelp);

  381. 

  382.             addMethod (@selector (accessibilityValue), [] (id self, SEL) -> NSString*

  383.             {

  384.                 if (auto* handler = getHandler (self))

  385.                 {

  386.                     if (handler->getCurrentState().isCheckable())

  387.                         return handler->getCurrentState().isChecked() ? @"1" : @"0";

  388. 

  389.                     return (NSString*) getAccessibilityValueFromInterfaces (*handler);

  390.                 }

  391. 

  392.                 return nil;

  393.             });

  394. 

  395.             addMethod (@selector (setAccessibilityValue:), setAccessibilityValue);

  396. 

  397.             addMethod (@selector (accessibilityElementDidBecomeFocused), [] (id self, SEL)

  398.             {

  399.                 if (auto* handler = getHandler (self))

  400.                 {

  401.                     const WeakReference<Component> safeComponent (&handler->getComponent());

  402. 

  403.                     performActionIfSupported (self, AccessibilityActionType::focus);

  404. 

  405.                     if (safeComponent != nullptr)

  406.                         handler->grabFocus();

  407.                 }

  408.             });

  409. 

  410.             addMethod (@selector (accessibilityElementDidLoseFocus), [] (id self, SEL)

  411.             {

  412.                 if (auto* handler = getHandler (self))

  413.                     handler->giveAwayFocus();

  414.             });

  415. 

  416.             addMethod (@selector (accessibilityElementIsFocused), [] (id self, SEL) -> BOOL

  417.             {

  418.                 if (auto* handler = getHandler (self))

  419.                     return handler->hasFocus (false);

  420. 

  421.                 return NO;

  422.             });

  423. 

  424.             addMethod (@selector (accessibilityViewIsModal), getIsAccessibilityModal);

  425. 

  426.             addMethod (@selector (accessibilityActivate), [] (id self, SEL)

  427.             {

  428.                 if (auto* handler = getHandler (self))

  429.                 {

  430.                     // Occasionally VoiceOver sends accessibilityActivate to the wrong element, so we first query

  431.                     // which element it thinks has focus and forward the event on to that element if it differs

  432.                     id focusedElement = UIAccessibilityFocusedElement (UIAccessibilityNotificationVoiceOverIdentifier);

  433. 

  434.                     if (focusedElement != nullptr && ! [static_cast<id> (handler->getNativeImplementation()) isEqual: focusedElement])

  435.                         return [focusedElement accessibilityActivate];

  436. 

  437.                     if (handler->hasFocus (false))

  438.                         return accessibilityPerformPress (self, {});

  439.                 }

  440. 

  441.                 return NO;

  442.             });

  443. 

  444.             addMethod (@selector (accessibilityIncrement), accessibilityPerformIncrement);

  445.             addMethod (@selector (accessibilityDecrement), accessibilityPerformDecrement);

  446. 

  447.             addMethod (@selector (accessibilityPerformEscape), [] (id self, SEL)

  448.             {

  449.                 if (auto* handler = getHandler (self))

  450.                 {

  451.                     if (auto* modal = Component::getCurrentlyModalComponent())

  452.                     {

  453.                         if (auto* modalHandler = modal->getAccessibilityHandler())

  454.                         {

  455.                             if (modalHandler == handler || modalHandler->isParentOf (handler))

  456.                             {

  457.                                 modal->exitModalState (0);

  458.                                 return YES;

  459.                             }

  460.                         }

  461.                     }

  462.                 }

  463. 

  464.                 return NO;

  465.             });

  466. 

  467.             if (elementType == Type::textElement)

  468.             {

  469.                 addMethod (@selector (deleteBackward), [] (id, SEL) {});

  470.                 addMethod (@selector (insertText:), [] (id, SEL, NSString*) {});

  471. 

  472.                 forEach ([this] (auto signature) { addPassthroughMethodWithSignature (signature); },

  473.                          SignatureHasText{},

  474.                          SignatureSetSelectedTextRange{},

  475.                          SignatureSelectedTextRange{},

  476.                          SignatureMarkedTextRange{},

  477.                          SignatureSetMarkedTextSelectedRange{},

  478.                          SignatureUnmarkText{},

  479.                          SignatureMarkedTextStyle{},

  480.                          SignatureSetMarkedTextStyle{},

  481.                          SignatureBeginningOfDocument{},

  482.                          SignatureEndOfDocument{},

  483.                          SignatureTokenizer{},

  484.                          SignatureBaseWritingDirection{},

  485.                          SignatureCaretRectForPosition{},

  486.                          SignatureCharacterRangeByExtending{},

  487.                          SignatureCharacterRangeAtPoint{},

  488.                          SignatureClosestPositionToPoint{},

  489.                          SignatureClosestPositionToPointInRange{},

  490.                          SignatureComparePositionToPosition{},

  491.                          SignatureOffsetFromPositionToPosition{},

  492.                          SignaturePositionFromPositionInDirection{},

  493.                          SignaturePositionFromPositionOffset{},

  494.                          SignatureFirstRectForRange{},

  495.                          SignatureSelectionRectsForRange{},

  496.                          SignaturePositionWithinRange{},

  497.                          SignatureReplaceRangeWithText{},

  498.                          SignatureSetBaseWritingDirection{},

  499.                          SignatureTextInRange{},

  500.                          SignatureTextRangeFromPosition{},

  501.                          SignatureSetInputDelegate{},

  502.                          SignatureInputDelegate{},

  503.                          SignatureKeyboardType{},

  504.                          SignatureAutocapitalizationType{},

  505.                          SignatureAutocorrectionType{});

  506. 

  507.                 addProtocol (@protocol (UITextInput));

  508.             }

  509. 

  510.            #if JUCE_IOS_CONTAINER_API_AVAILABLE

  511.             if (@available (iOS 11.0, *))

  512.             {

  513.                 addMethod (@selector (accessibilityRowRange),                           getAccessibilityRowIndexRange);

  514.                 addMethod (@selector (accessibilityColumnRange),                        getAccessibilityColumnIndexRange);

  515.                 addProtocol (@protocol (UIAccessibilityContainerDataTableCell));

  516.             }

  517.            #endif

  518. 

  519.             addIvar<UIAccessibilityElement*> ("container");

  520. 

  521.             registerClass();

  522.         }

  523. 

  524.     private:

  525.         template <typename Result>

  526.         static auto getResult (NSInvocation* invocation, detail::Tag<Result>)

  527.         {

  528.             Result result{};

  529.             [invocation getReturnValue: &result];

  530.             return result;

  531.         }

  532. 

  533.         static void getResult (NSInvocation*, detail::Tag<void>) {}

  534. 

  535.         template <typename HasSelector, typename Result, typename... Args>

  536.         auto makePassthroughCallback (HasSelector, Signature<Result (Args...)>)

  537.         {

  538.             return [] (id self, SEL, Args... args) -> Result

  539.             {

  540.                 if (auto* input = getPeerTextInput (self))

  541.                 {

  542.                     const auto s = detail::makeCompileTimeStr (@encode (Result), @encode (id), @encode (SEL), @encode (Args)...);

  543.                     const auto signature = [NSMethodSignature signatureWithObjCTypes: s.data()];

  544.                     const auto invocation = [NSInvocation invocationWithMethodSignature: signature];

  545.                     invocation.selector = HasSelector::sel();

  546. 

  547.                     // Indices 0 and 1 are 'id self' and 'SEL _cmd' respectively

  548.                     auto counter = 2;

  549.                     forEach ([&] (auto& arg) { [invocation setArgument: &arg atIndex: counter++]; }, args...);

  550. 

  551.                     [invocation invokeWithTarget: input];

  552. 

  553.                     return getResult (invocation, detail::Tag<Result>{});

  554.                 }

  555. 

  556.                 jassertfalse;

  557.                 return {};

  558.             };

  559.         }

  560. 

  561.         template <typename Signature>

  562.         void addPassthroughMethodWithSignature (Signature signature)

  563.         {

  564.             addMethod (Signature::sel(), makePassthroughCallback (signature, signature));

  565.         }

  566. 

  567.         static UIAccessibilityElement* getContainer (id self)

  568.         {

  569.             return getIvar<UIAccessibilityElement*> (self, "container");

  570.         }

  571. 

  572.         static UIViewComponentPeer* getPeer (id self)

  573.         {

  574.             if (auto* handler = getHandler (self))

  575.                 return static_cast<UIViewComponentPeer*> (handler->getComponent().getPeer());

  576. 

  577.             return nil;

  578.         }

  579. 

  580.         static JuceTextView* getPeerTextInput (id self)

  581.         {

  582.             if (auto* peer = getPeer (self))

  583.                 return peer->hiddenTextInput.get();

  584. 

  585.             return nil;

  586.         }

  587. 

  588.         //==============================================================================

  589.         JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityElement)

  590.     };

  591. 

  592.     //==============================================================================

  593.     AccessibilityElement::Holder accessibilityElement;

  594. 

  595.     //==============================================================================

  596.     JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityNativeImpl)

  597. };

  598. 

  599. //==============================================================================

  600. AccessibilityNativeHandle* AccessibilityHandler::getNativeImplementation() const

  601. {

  602.     return (AccessibilityNativeHandle*) nativeImpl->getAccessibilityElement();

  603. }

  604. 

  605. static bool areAnyAccessibilityClientsActive()

  606. {

  607.     return UIAccessibilityIsVoiceOverRunning();

  608. }

  609. 

  610. static void sendAccessibilityEvent (UIAccessibilityNotifications notification, id argument)

  611. {

  612.     if (! areAnyAccessibilityClientsActive())

  613.         return;

  614. 

  615.     jassert (notification != UIAccessibilityNotifications{});

  616. 

  617.     UIAccessibilityPostNotification (notification, argument);

  618. }

  619. 

  620. void notifyAccessibilityEventInternal (const AccessibilityHandler& handler, InternalAccessibilityEvent eventType)

  621. {

  622.     auto notification = [eventType]

  623.     {

  624.         switch (eventType)

  625.         {

  626.             case InternalAccessibilityEvent::elementCreated:

  627.             case InternalAccessibilityEvent::elementDestroyed:

  628.             case InternalAccessibilityEvent::elementMovedOrResized:

  629.             case InternalAccessibilityEvent::focusChanged:           return UIAccessibilityLayoutChangedNotification;

  630. 

  631.             case InternalAccessibilityEvent::windowOpened:

  632.             case InternalAccessibilityEvent::windowClosed:           return UIAccessibilityScreenChangedNotification;

  633.         }

  634. 

  635.         return UIAccessibilityNotifications{};

  636.     }();

  637. 

  638.     if (notification != UIAccessibilityNotifications{})

  639.     {

  640.         const bool moveToHandler = (eventType == InternalAccessibilityEvent::focusChanged && handler.hasFocus (false));

  641. 

  642.         sendAccessibilityEvent (notification,

  643.                                 moveToHandler ? static_cast<id> (handler.getNativeImplementation()) : nil);

  644.     }

  645. }

  646. 

  647. void AccessibilityHandler::notifyAccessibilityEvent (AccessibilityEvent eventType) const

  648. {

  649.     auto notification = [eventType]

  650.     {

  651.         switch (eventType)

  652.         {

  653.             case AccessibilityEvent::textSelectionChanged:

  654.             case AccessibilityEvent::rowSelectionChanged:

  655.             case AccessibilityEvent::textChanged:

  656.             case AccessibilityEvent::valueChanged:

  657.             case AccessibilityEvent::titleChanged:          break;

  658. 

  659.             case AccessibilityEvent::structureChanged:      return UIAccessibilityLayoutChangedNotification;

  660.         }

  661. 

  662.         return UIAccessibilityNotifications{};

  663.     }();

  664. 

  665.     if (notification != UIAccessibilityNotifications{})

  666.         sendAccessibilityEvent (notification, static_cast<id> (getNativeImplementation()));

  667. }

  668. 

  669. void AccessibilityHandler::postAnnouncement (const String& announcementString, AnnouncementPriority)

  670. {

  671.     sendAccessibilityEvent (UIAccessibilityAnnouncementNotification, juceStringToNS (announcementString));

  672. }

  673. 

  674. } // namespace juce