DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
11460 Commits
9 Branches
3.6GB
Tree: b51da7dec0
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'b51da7dec0'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

1941 lines
82KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2020 - Raw Material Software Limited

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 6 End-User License

  11.    Agreement and JUCE Privacy Policy (both effective as of the 16th June 2020).

  12. 

  13.    End User License Agreement: www.juce.com/juce-6-licence

  14.    Privacy Policy: www.juce.com/juce-privacy-policy

  15. 

  16.    Or: You may also use this code under the terms of the GPL v3 (see

  17.    www.gnu.org/licenses).

  18. 

  19.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  20.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  21.    DISCLAIMED.

  22. 

  23.   ==============================================================================

  24. */

  25. 

  26. #include <juce_core/system/juce_TargetPlatform.h>

  27. #include "../utility/juce_CheckSettingMacros.h"

  28. 

  29. #if JucePlugin_Build_AUv3

  30. 

  31. #if JUCE_MAC

  32.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  33.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  34.  #endif

  35.  #if (defined MAC_OS_X_VERSION_10_13) && (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_13)

  36.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  37.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  38.  #endif

  39. #endif

  40. 

  41. #if JUCE_IOS

  42.  #if (defined __IPHONE_11_0) && (__IPHONE_OS_VERSION_MIN_REQUIRED >= __IPHONE_11_0)

  43.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  44.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  45.  #endif

  46. #endif

  47. 

  48. #ifndef __OBJC2__

  49.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  50. #endif

  51. 

  52. #define JUCE_CORE_INCLUDE_OBJC_HELPERS 1

  53. 

  54. #include "../utility/juce_IncludeSystemHeaders.h"

  55. #include "../utility/juce_IncludeModuleHeaders.h"

  56. 

  57. #import <CoreAudioKit/CoreAudioKit.h>

  58. #import <AudioToolbox/AudioToolbox.h>

  59. #import <AVFoundation/AVFoundation.h>

  60. 

  61. #include <juce_graphics/native/juce_mac_CoreGraphicsHelpers.h>

  62. #include <juce_audio_basics/native/juce_mac_CoreAudioLayouts.h>

  63. #include <juce_audio_processors/format_types/juce_LegacyAudioParameter.cpp>

  64. #include <juce_audio_processors/format_types/juce_AU_Shared.h>

  65. 

  66. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  67. 

  68. #if JUCE_IOS

  69.  #define JUCE_IOS_MAC_VIEW  UIView

  70. #else

  71.  #define JUCE_IOS_MAC_VIEW  NSView

  72. #endif

  73. 

  74. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  75. 

  76. JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wnullability-completeness")

  77. 

  78. using namespace juce;

  79. 

  80. struct AudioProcessorHolder  : public ReferenceCountedObject

  81. {

  82.     AudioProcessorHolder() {}

  83.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  84.     AudioProcessor& operator*() noexcept        { return *processor; }

  85.     AudioProcessor* operator->() noexcept       { return processor.get(); }

  86.     AudioProcessor* get() noexcept              { return processor.get(); }

  87. 

  88.     struct ViewConfig

  89.     {

  90.         double width;

  91.         double height;

  92.         bool hostHasMIDIController;

  93.     };

  94. 

  95.     std::unique_ptr<ViewConfig> viewConfiguration;

  96. 

  97.     using Ptr = ReferenceCountedObjectPtr<AudioProcessorHolder>;

  98. 

  99. private:

  100.     std::unique_ptr<AudioProcessor> processor;

  101. 

  102.     AudioProcessorHolder& operator= (AudioProcessor*) = delete;

  103.     AudioProcessorHolder (AudioProcessorHolder&) = delete;

  104.     AudioProcessorHolder& operator= (AudioProcessorHolder&) = delete;

  105. };

  106. 

  107. //==============================================================================

  108. class JuceAudioUnitv3Base

  109. {

  110. public:

  111.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  112.                          AudioComponentInstantiationOptions options,

  113.                          NSError** error)

  114.         JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wobjc-method-access")

  115.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  116.                                                                         options: options

  117.                                                                           error: error

  118.                                                                       juceClass: this])

  119.         JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  120.     {}

  121. 

  122.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  123.     {

  124.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  125.         initialiseJuce_GUI();

  126.     }

  127. 

  128.     virtual ~JuceAudioUnitv3Base() = default;

  129. 

  130.     //==============================================================================

  131.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  132. 

  133.     //==============================================================================

  134.     virtual void reset()                                                   = 0;

  135. 

  136.     //==============================================================================

  137.     virtual AUAudioUnitPreset* getCurrentPreset()                          = 0;

  138.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      = 0;

  139.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()               = 0;

  140. 

  141.     virtual NSDictionary<NSString*, id>* getFullState()

  142.     {

  143.         return ObjCMsgSendSuper<AUAudioUnit, NSDictionary<NSString*, id>*> (getAudioUnit(), @selector (fullState));

  144.     }

  145. 

  146.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  147.     {

  148.         ObjCMsgSendSuper<AUAudioUnit, void> (getAudioUnit(), @selector (setFullState:), state);

  149.     }

  150. 

  151.     virtual AUParameterTree* getParameterTree()                            = 0;

  152.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)       = 0;

  153. 

  154.     //==============================================================================

  155.     virtual NSTimeInterval getLatency()                                    = 0;

  156.     virtual NSTimeInterval getTailTime()                                   = 0;

  157. 

  158.     //==============================================================================

  159.     virtual AUAudioUnitBusArray* getInputBusses()                          = 0;

  160.     virtual AUAudioUnitBusArray* getOutputBusses()                         = 0;

  161.     virtual NSArray<NSNumber*>* getChannelCapabilities()                   = 0;

  162.     virtual bool shouldChangeToFormat (AVAudioFormat*, AUAudioUnitBus*)    = 0;

  163. 

  164.     //==============================================================================

  165.     virtual int getVirtualMIDICableCount()                                 = 0;

  166.     virtual bool getSupportsMPE()                                          = 0;

  167.     virtual NSArray<NSString*>* getMIDIOutputNames()                       = 0;

  168. 

  169.     //==============================================================================

  170.     virtual AUInternalRenderBlock getInternalRenderBlock()                 = 0;

  171.     virtual bool getCanProcessInPlace()                                    { return false; }

  172.     virtual bool getRenderingOffline()                                     = 0;

  173.     virtual void setRenderingOffline (bool offline)                        = 0;

  174. 

  175.     virtual bool getShouldBypassEffect()

  176.     {

  177.         return (ObjCMsgSendSuper<AUAudioUnit, BOOL> (getAudioUnit(), @selector (shouldBypassEffect)) == YES);

  178.     }

  179. 

  180.     virtual void setShouldBypassEffect (bool shouldBypass)

  181.     {

  182.         ObjCMsgSendSuper<AUAudioUnit, void> (getAudioUnit(), @selector (setShouldBypassEffect:), shouldBypass ? YES : NO);

  183.     }

  184. 

  185.     //==============================================================================

  186.     virtual NSString* getContextName()      const                          = 0;

  187.     virtual void setContextName (NSString*)                                = 0;

  188. 

  189.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  190.     {

  191.         return (ObjCMsgSendSuper<AUAudioUnit, BOOL, NSError**> (getAudioUnit(), @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  192.     }

  193. 

  194.     virtual void deallocateRenderResources()

  195.     {

  196.         ObjCMsgSendSuper<AUAudioUnit, void> (getAudioUnit(), @selector (deallocateRenderResources));

  197.     }

  198. 

  199.     //==============================================================================

  200.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  201.     virtual NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>*) = 0;

  202.     virtual void selectViewConfiguration (AUAudioUnitViewConfiguration*)   = 0;

  203.    #endif

  204. 

  205. private:

  206.     struct Class  : public ObjCClass<AUAudioUnit>

  207.     {

  208.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  209.         {

  210.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  211. 

  212.             JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wundeclared-selector")

  213.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  214.                        initWithComponentDescriptionAndJuceClass, "@@:",

  215.                        @encode (AudioComponentDescription),

  216.                        @encode (AudioComponentInstantiationOptions), "^@@");

  217.             JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  218. 

  219.             addMethod (@selector (initWithComponentDescription:options:error:),

  220.                        initWithComponentDescription, "@@:",

  221.                        @encode (AudioComponentDescription),

  222.                        @encode (AudioComponentInstantiationOptions), "^@");

  223. 

  224.             addMethod (@selector (dealloc),                         dealloc,                        "v@:");

  225. 

  226.             //==============================================================================

  227.             addMethod (@selector (reset),                           reset,                          "v@:");

  228. 

  229.             //==============================================================================

  230.             addMethod (@selector (currentPreset),                   getCurrentPreset,               "@@:");

  231.             addMethod (@selector (setCurrentPreset:),               setCurrentPreset,               "v@:@");

  232.             addMethod (@selector (factoryPresets),                  getFactoryPresets,              "@@:");

  233.             addMethod (@selector (fullState),                       getFullState,                   "@@:");

  234.             addMethod (@selector (setFullState:),                   setFullState,                   "v@:@");

  235.             addMethod (@selector (parameterTree),                   getParameterTree,               "@@:");

  236.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  237. 

  238.             //==============================================================================

  239.             addMethod (@selector (latency),                         getLatency,                     @encode (NSTimeInterval), "@:");

  240.             addMethod (@selector (tailTime),                        getTailTime,                    @encode (NSTimeInterval),  "@:");

  241. 

  242.             //==============================================================================

  243.             addMethod (@selector (inputBusses),                     getInputBusses,                 "@@:");

  244.             addMethod (@selector (outputBusses),                    getOutputBusses,                "@@:");

  245.             addMethod (@selector (channelCapabilities),             getChannelCapabilities,         "@@:");

  246.             addMethod (@selector (shouldChangeToFormat:forBus:),    shouldChangeToFormat,           "B@:@@");

  247. 

  248.             //==============================================================================

  249.             addMethod (@selector (virtualMIDICableCount),           getVirtualMIDICableCount,       @encode (NSInteger), "@:");

  250.             addMethod (@selector (supportsMPE),                     getSupportsMPE,                 @encode (BOOL),      "@:");

  251. 

  252.            #if JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  253.             addMethod (@selector (MIDIOutputNames),                 getMIDIOutputNames,             "@@:");

  254.            #endif

  255. 

  256.             //==============================================================================

  257.             addMethod (@selector (internalRenderBlock),             getInternalRenderBlock,         @encode (AUInternalRenderBlock), "@:");

  258.             addMethod (@selector (canProcessInPlace),               getCanProcessInPlace,           @encode (BOOL), "@:");

  259.             addMethod (@selector (isRenderingOffline),              getRenderingOffline,            @encode (BOOL),  "@:");

  260.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  261.             addMethod (@selector (shouldBypassEffect),              getShouldBypassEffect,          @encode (BOOL),  "@:");

  262.             addMethod (@selector (setShouldBypassEffect:),          setShouldBypassEffect,          "v@:", @encode (BOOL));

  263.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "B@:^@");

  264.             addMethod (@selector (deallocateRenderResources),       deallocateRenderResources,      "v@:");

  265. 

  266.             //==============================================================================

  267.             addMethod (@selector (contextName),                     getContextName,                 "@@:");

  268.             addMethod (@selector (setContextName:),                  setContextName,                 "v@:@");

  269. 

  270.             //==============================================================================

  271.            #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  272.             addMethod (@selector (supportedViewConfigurations:),    getSupportedViewConfigurations, "@@:@");

  273.             addMethod (@selector (selectViewConfiguration:),        selectViewConfiguration,        "v@:@");

  274.            #endif

  275. 

  276.             registerClass();

  277.         }

  278. 

  279.         //==============================================================================

  280.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  281.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  282. 

  283.         //==============================================================================

  284.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  285.         {

  286.             AUAudioUnit* self = _self;

  287. 

  288.             self = ObjCMsgSendSuper<AUAudioUnit, AUAudioUnit*, AudioComponentDescription,

  289.                                     AudioComponentInstantiationOptions, NSError**> (self, @selector (initWithComponentDescription:options:error:), descr, options, error);

  290. 

  291.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  292. 

  293.             setThis (self, juceAU);

  294.             return self;

  295.         }

  296. 

  297.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  298.         {

  299.             AUAudioUnit* self = _self;

  300. 

  301.             self = ObjCMsgSendSuper<AUAudioUnit, AUAudioUnit*, AudioComponentDescription,

  302.                                     AudioComponentInstantiationOptions, NSError**> (self, @selector(initWithComponentDescription:options:error:), descr, options, error);

  303. 

  304. 

  305.             setThis (self, juceAU);

  306.             return self;

  307.         }

  308. 

  309.         static void dealloc (id self, SEL)

  310.         {

  311.             if (! MessageManager::getInstance()->isThisTheMessageThread())

  312.             {

  313.                 WaitableEvent deletionEvent;

  314. 

  315.                 struct AUDeleter  : public CallbackMessage

  316.                 {

  317.                     AUDeleter (id selfToDelete, WaitableEvent& event)

  318.                         : parentSelf (selfToDelete), parentDeletionEvent (event)

  319.                     {

  320.                     }

  321. 

  322.                     void messageCallback() override

  323.                     {

  324.                         delete _this (parentSelf);

  325.                         parentDeletionEvent.signal();

  326.                     }

  327. 

  328.                     id parentSelf;

  329.                     WaitableEvent& parentDeletionEvent;

  330.                 };

  331. 

  332.                 (new AUDeleter (self, deletionEvent))->post();

  333.                 deletionEvent.wait (-1);

  334.             }

  335.             else

  336.             {

  337.                 delete _this (self);

  338.             }

  339.         }

  340. 

  341.         //==============================================================================

  342.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  343. 

  344.         //==============================================================================

  345.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  346.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  347.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  348.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  349.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  350.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  351.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  352. 

  353.         //==============================================================================

  354.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  355.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  356. 

  357.         //==============================================================================

  358.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  359.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  360.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  361.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  362. 

  363.         //==============================================================================

  364.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  365.         static BOOL getSupportsMPE (id self, SEL)                                                   { return _this (self)->getSupportsMPE() ? YES : NO; }

  366.         static NSArray<NSString*>* getMIDIOutputNames (id self, SEL)                                { return _this (self)->getMIDIOutputNames(); }

  367. 

  368.         //==============================================================================

  369.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  370.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  371.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  372.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  373.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  374.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  375.         static BOOL getShouldBypassEffect (id self, SEL)                                            { return _this (self)->getShouldBypassEffect() ? YES : NO; }

  376.         static void setShouldBypassEffect (id self, SEL, BOOL shouldBypass)                         { _this (self)->setShouldBypassEffect (shouldBypass); }

  377. 

  378.         //==============================================================================

  379.         static NSString* getContextName (id self, SEL)                                              { return _this (self)->getContextName(); }

  380.         static void setContextName (id self, SEL, NSString* str)                                    { return _this (self)->setContextName (str); }

  381. 

  382.         //==============================================================================

  383.        #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  384.         static NSIndexSet* getSupportedViewConfigurations (id self, SEL, NSArray<AUAudioUnitViewConfiguration*>* configs) { return _this (self)->getSupportedViewConfigurations (configs); }

  385.         static void selectViewConfiguration (id self, SEL, AUAudioUnitViewConfiguration* config)    { _this (self)->selectViewConfiguration (config); }

  386.        #endif

  387.     };

  388. 

  389.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  390. 

  391.     //==============================================================================

  392.     static Class audioUnitObjCClass;

  393. 

  394. protected:

  395.     AUAudioUnit* au;

  396. };

  397. 

  398. //==============================================================================

  399. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  400. 

  401. //==============================================================================

  402. //=========================== The actual AudioUnit =============================

  403. //==============================================================================

  404. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  405.                          public AudioProcessorListener,

  406.                          public AudioPlayHead,

  407.                          private AudioProcessorParameter::Listener

  408. {

  409. public:

  410.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  411.                      const AudioComponentDescription& descr,

  412.                      AudioComponentInstantiationOptions options,

  413.                      NSError** error)

  414.         : JuceAudioUnitv3Base (descr, options, error),

  415.           processorHolder (processor),

  416.           mapper (*processorHolder->get())

  417.     {

  418.         init();

  419.     }

  420. 

  421.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  422.         : JuceAudioUnitv3Base (audioUnit),

  423.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  424.           mapper (*processorHolder->get())

  425.     {

  426.         init();

  427.     }

  428. 

  429.     ~JuceAudioUnitv3() override

  430.     {

  431.         auto& processor = getAudioProcessor();

  432.         processor.removeListener (this);

  433. 

  434.         if (bypassParam != nullptr)

  435.             bypassParam->removeListener (this);

  436. 

  437.         removeEditor (processor);

  438. 

  439.         if (editorObserverToken != nullptr)

  440.         {

  441.             [paramTree.get() removeParameterObserver: editorObserverToken];

  442.             editorObserverToken = nullptr;

  443.         }

  444.     }

  445. 

  446.     //==============================================================================

  447.     void init()

  448.     {

  449.         inParameterChangedCallback = false;

  450. 

  451.         AudioProcessor& processor = getAudioProcessor();

  452.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  453. 

  454.        #ifdef JucePlugin_PreferredChannelConfigurations

  455.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  456.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  457. 

  458.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  459.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  460. 

  461.         Array<AUChannelInfo> channelInfos;

  462. 

  463.         for (int i = 0; i < numConfigs; ++i)

  464.         {

  465.             AUChannelInfo channelInfo;

  466. 

  467.             channelInfo.inChannels  = configs[i][0];

  468.             channelInfo.outChannels = configs[i][1];

  469. 

  470.             channelInfos.add (channelInfo);

  471.         }

  472.        #else

  473.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  474.        #endif

  475. 

  476.         processor.setPlayHead (this);

  477. 

  478.         totalInChannels  = processor.getTotalNumInputChannels();

  479.         totalOutChannels = processor.getTotalNumOutputChannels();

  480. 

  481.         {

  482.             channelCapabilities.reset ([[NSMutableArray<NSNumber*> alloc] init]);

  483. 

  484.             for (int i = 0; i < channelInfos.size(); ++i)

  485.             {

  486.                 AUChannelInfo& info = channelInfos.getReference (i);

  487. 

  488.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.inChannels]];

  489.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.outChannels]];

  490.             }

  491.         }

  492. 

  493.         editorObserverToken = nullptr;

  494.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  495. 

  496.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  497.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  498.         processor.addListener (this);

  499. 

  500.         addParameters();

  501.         addPresets();

  502. 

  503.         addAudioUnitBusses (true);

  504.         addAudioUnitBusses (false);

  505.     }

  506. 

  507.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  508. 

  509.     //==============================================================================

  510.     void reset() override

  511.     {

  512.         midiMessages.clear();

  513.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  514.     }

  515. 

  516.     //==============================================================================

  517.     AUAudioUnitPreset* getCurrentPreset() override

  518.     {

  519.         const int n = static_cast<int> ([factoryPresets.get() count]);

  520.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  521. 

  522.         if (idx < n)

  523.             return [factoryPresets.get() objectAtIndex:static_cast<unsigned int> (idx)];

  524. 

  525.         return nullptr;

  526.     }

  527. 

  528.     void setCurrentPreset(AUAudioUnitPreset* preset) override

  529.     {

  530.         const int n = static_cast<int> ([factoryPresets.get() count]);

  531.         const int idx = static_cast<int> ([preset number]);

  532. 

  533.         if (isPositiveAndBelow (idx, n))

  534.             getAudioProcessor().setCurrentProgram (idx);

  535.     }

  536. 

  537.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override

  538.     {

  539.         return factoryPresets.get();

  540.     }

  541. 

  542.     NSDictionary<NSString*, id>* getFullState() override

  543.     {

  544.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  545. 

  546.         {

  547.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  548. 

  549.             if (superRetval != nullptr)

  550.                 [retval addEntriesFromDictionary:superRetval];

  551.         }

  552. 

  553.         juce::MemoryBlock state;

  554. 

  555.        #if JUCE_AU_WRAPPERS_SAVE_PROGRAM_STATES

  556.         getAudioProcessor().getCurrentProgramStateInformation (state);

  557.        #else

  558.         getAudioProcessor().getStateInformation (state);

  559.        #endif

  560. 

  561.         if (state.getSize() > 0)

  562.         {

  563.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  564.                                                       length: state.getSize()];

  565. 

  566.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  567. 

  568.             [retval setObject: ourState

  569.                        forKey: nsKey];

  570. 

  571.             [nsKey    release];

  572.             [ourState release];

  573.         }

  574. 

  575.         return [retval autorelease];

  576.     }

  577. 

  578.     void setFullState (NSDictionary<NSString*, id>* state) override

  579.     {

  580.         if (state == nullptr)

  581.             return;

  582. 

  583.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  584.         [modifiedState addEntriesFromDictionary: state];

  585. 

  586.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  587.         [modifiedState removeObjectForKey: nsPresetKey];

  588.         [nsPresetKey release];

  589. 

  590.         JuceAudioUnitv3Base::setFullState (modifiedState);

  591. 

  592.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  593.         NSObject* obj = [modifiedState objectForKey: nsKey];

  594.         [nsKey release];

  595. 

  596.         if (obj != nullptr)

  597.         {

  598.             if ([obj isKindOfClass:[NSData class]])

  599.             {

  600.                 NSData* data = reinterpret_cast<NSData*> (obj);

  601.                 const int numBytes = static_cast<int> ([data length]);

  602.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  603. 

  604.                 if (numBytes > 0)

  605.                 {

  606.                    #if JUCE_AU_WRAPPERS_SAVE_PROGRAM_STATES

  607.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  608.                    #else

  609.                     getAudioProcessor().setStateInformation (rawBytes, numBytes);

  610.                    #endif

  611.                 }

  612.             }

  613.         }

  614. 

  615.         [modifiedState release];

  616.     }

  617. 

  618.     AUParameterTree* getParameterTree() override

  619.     {

  620.         return paramTree.get();

  621.     }

  622. 

  623.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  624.     {

  625.         const int n = static_cast<int> ([overviewParams.get() count]);

  626. 

  627.         if (count >= n)

  628.             return overviewParams.get();

  629. 

  630.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams.get()];

  631.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  632. 

  633.         return [retval autorelease];

  634.     }

  635. 

  636.     //==============================================================================

  637.     NSTimeInterval getLatency() override

  638.     {

  639.         auto& p = getAudioProcessor();

  640.         return p.getLatencySamples() / p.getSampleRate();

  641.     }

  642. 

  643.     NSTimeInterval getTailTime() override

  644.     {

  645.         return getAudioProcessor().getTailLengthSeconds();

  646.     }

  647. 

  648.     //==============================================================================

  649.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses.get();  }

  650.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses.get(); }

  651.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities.get(); }

  652. 

  653.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  654.     {

  655.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  656.         const int busIdx = static_cast<int> ([auBus index]);

  657.         const int newNumChannels = static_cast<int> ([format channelCount]);

  658. 

  659.         AudioProcessor& processor = getAudioProcessor();

  660. 

  661.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  662.         {

  663.           #ifdef JucePlugin_PreferredChannelConfigurations

  664.             ignoreUnused (bus);

  665. 

  666.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  667. 

  668.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  669.                 return false;

  670.           #else

  671.             const AVAudioChannelLayout* layout    = [format channelLayout];

  672.             const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  673. 

  674.             if (layoutTag != 0)

  675.             {

  676.                 AudioChannelSet newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  677. 

  678.                 if (newLayout.size() != newNumChannels)

  679.                     return false;

  680. 

  681.                 if (! bus->isLayoutSupported (newLayout))

  682.                     return false;

  683.             }

  684.             else

  685.             {

  686.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  687.                     return false;

  688.             }

  689.            #endif

  690. 

  691.             return true;

  692.         }

  693. 

  694.         return false;

  695.     }

  696. 

  697.     //==============================================================================

  698.     int getVirtualMIDICableCount() override

  699.     {

  700.        #if JucePlugin_WantsMidiInput

  701.         return 1;

  702.        #else

  703.         return 0;

  704.        #endif

  705.     }

  706. 

  707.     bool getSupportsMPE() override

  708.     {

  709.         return getAudioProcessor().supportsMPE();

  710.     }

  711. 

  712.     NSArray<NSString*>* getMIDIOutputNames() override

  713.     {

  714.        #if JucePlugin_ProducesMidiOutput

  715.         return @[@"MIDI Out"];

  716.        #else

  717.         return @[];

  718.        #endif

  719.     }

  720. 

  721.     //==============================================================================

  722.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  723.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  724.     void setRenderingOffline (bool offline) override

  725.     {

  726.         auto& processor = getAudioProcessor();

  727.         auto isCurrentlyNonRealtime = processor.isNonRealtime();

  728. 

  729.         if (isCurrentlyNonRealtime != offline)

  730.         {

  731.             ScopedLock callbackLock (processor.getCallbackLock());

  732. 

  733.             processor.setNonRealtime (offline);

  734.             processor.prepareToPlay (processor.getSampleRate(), processor.getBlockSize());

  735.         }

  736.     }

  737. 

  738.     bool getShouldBypassEffect() override

  739.     {

  740.         if (bypassParam != nullptr)

  741.             return (bypassParam->getValue() != 0.0f);

  742. 

  743.         return JuceAudioUnitv3Base::getShouldBypassEffect();

  744.     }

  745. 

  746.     void setShouldBypassEffect (bool shouldBypass) override

  747.     {

  748.         if (bypassParam != nullptr)

  749.             bypassParam->setValue (shouldBypass ? 1.0f : 0.0f);

  750. 

  751.         JuceAudioUnitv3Base::setShouldBypassEffect (shouldBypass);

  752.     }

  753. 

  754.     //==============================================================================

  755.     NSString* getContextName() const    override              { return juceStringToNS (contextName); }

  756.     void setContextName (NSString* str) override

  757.     {

  758.         if (str != nullptr)

  759.         {

  760.             AudioProcessor::TrackProperties props;

  761.             props.name = nsStringToJuce (str);

  762. 

  763.             getAudioProcessor().updateTrackProperties (props);

  764.         }

  765.     }

  766. 

  767.     //==============================================================================

  768.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  769.     {

  770.         AudioProcessor& processor = getAudioProcessor();

  771.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  772. 

  773.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  774.             return false;

  775. 

  776.         if (outError != nullptr)

  777.             *outError = nullptr;

  778. 

  779.         AudioProcessor::BusesLayout layouts;

  780.         for (int dir = 0; dir < 2; ++dir)

  781.         {

  782.             const bool isInput = (dir == 0);

  783.             const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  784.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  785. 

  786.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  787.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  788. 

  789.             for (int busIdx = 0; busIdx < n; ++busIdx)

  790.             {

  791.                 AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx);

  792.                 AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  793. 

  794.                 AudioChannelSet newLayout;

  795.                 const AVAudioChannelLayout* layout    = [format channelLayout];

  796.                 const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  797. 

  798.                 if (layoutTag != 0)

  799.                     newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  800.                 else

  801.                     newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  802. 

  803.                 if (newLayout.isDisabled())

  804.                     return false;

  805. 

  806.                 channelSets.add (newLayout);

  807.             }

  808.         }

  809. 

  810.        #ifdef JucePlugin_PreferredChannelConfigurations

  811.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  812. 

  813.         if (! AudioProcessor::containsLayout (layouts, configs))

  814.         {

  815.             if (outError != nullptr)

  816.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  817. 

  818.             return false;

  819.         }

  820.        #endif

  821. 

  822.         if (! AudioUnitHelpers::setBusesLayout (&getAudioProcessor(), layouts))

  823.         {

  824.             if (outError != nullptr)

  825.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  826. 

  827.             return false;

  828.         }

  829. 

  830.         totalInChannels  = processor.getTotalNumInputChannels();

  831.         totalOutChannels = processor.getTotalNumOutputChannels();

  832. 

  833.         allocateBusBuffer (true);

  834.         allocateBusBuffer (false);

  835. 

  836.         mapper.alloc();

  837. 

  838.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  839. 

  840.         double sampleRate = (jmax (AudioUnitHelpers::getBusCount (&processor, true), AudioUnitHelpers::getBusCount (&processor, false)) > 0 ?

  841.                              [[[([inputBusses.get() count] > 0 ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: 0] format] sampleRate] : 44100.0);

  842. 

  843.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  844.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  845. 

  846.         midiMessages.ensureSize (2048);

  847.         midiMessages.clear();

  848. 

  849.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  850.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  851.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  852. 

  853.         reset();

  854. 

  855.         return true;

  856.     }

  857. 

  858.     void deallocateRenderResources() override

  859.     {

  860.         hostMusicalContextCallback = nullptr;

  861.         hostTransportStateCallback = nullptr;

  862. 

  863.         getAudioProcessor().releaseResources();

  864.         audioBuffer.release();

  865. 

  866.         inBusBuffers. clear();

  867.         outBusBuffers.clear();

  868. 

  869.         mapper.release();

  870. 

  871.         JuceAudioUnitv3Base::deallocateRenderResources();

  872.     }

  873. 

  874.     //==============================================================================

  875.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  876.     NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>* configs) override

  877.     {

  878.         auto supportedViewIndecies = [[NSMutableIndexSet alloc] init];

  879.         auto n = [configs count];

  880. 

  881.         if (auto* editor = getAudioProcessor().createEditorIfNeeded())

  882.         {

  883.             // If you hit this assertion then your plug-in's editor is reporting that it doesn't support

  884.             // any host MIDI controller configurations!

  885.             jassert (editor->supportsHostMIDIControllerPresence (true) || editor->supportsHostMIDIControllerPresence (false));

  886. 

  887.             for (auto i = 0u; i < n; ++i)

  888.             {

  889.                 if (auto viewConfiguration = [configs objectAtIndex: i])

  890.                 {

  891.                     if (editor->supportsHostMIDIControllerPresence ([viewConfiguration hostHasController] == YES))

  892.                     {

  893.                         auto* constrainer = editor->getConstrainer();

  894.                         auto height = (int) [viewConfiguration height];

  895.                         auto width  = (int) [viewConfiguration width];

  896. 

  897.                         if (height <= constrainer->getMaximumHeight() && height >= constrainer->getMinimumHeight()

  898.                          && width  <= constrainer->getMaximumWidth()  && width  >= constrainer->getMinimumWidth())

  899.                             [supportedViewIndecies addIndex: i];

  900.                     }

  901.                 }

  902.             }

  903.         }

  904. 

  905.         return [supportedViewIndecies autorelease];

  906.     }

  907. 

  908.     void selectViewConfiguration (AUAudioUnitViewConfiguration* config) override

  909.     {

  910.         processorHolder->viewConfiguration.reset (new AudioProcessorHolder::ViewConfig { [config width], [config height], [config hostHasController] == YES });

  911.     }

  912.    #endif

  913. 

  914.     //==============================================================================

  915.     void audioProcessorChanged (AudioProcessor* processor) override

  916.     {

  917.         ignoreUnused (processor);

  918. 

  919.         [au willChangeValueForKey: @"allParameterValues"];

  920.         addPresets();

  921.         [au didChangeValueForKey: @"allParameterValues"];

  922.     }

  923. 

  924.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  925.     {

  926.         if (inParameterChangedCallback.get())

  927.         {

  928.             inParameterChangedCallback = false;

  929.             return;

  930.         }

  931. 

  932.         if (auto* juceParam = juceParameters.getParamForIndex (idx))

  933.         {

  934.             if (AUParameter* param = [paramTree.get() parameterWithAddress: getAUParameterAddressForIndex (idx)])

  935.             {

  936.                 newValue *= getMaximumParameterValue (juceParam);

  937. 

  938.                 if (editorObserverToken != nullptr)

  939.                     [param setValue: newValue  originator: editorObserverToken];

  940.                 else

  941.                     [param setValue: newValue];

  942.             }

  943.         }

  944.     }

  945. 

  946.     //==============================================================================

  947.     bool getCurrentPosition (CurrentPositionInfo& info) override

  948.     {

  949.         bool musicContextCallSucceeded = false;

  950.         bool transportStateCallSucceeded = false;

  951. 

  952.         info = lastAudioHead;

  953.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  954.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  955. 

  956.         switch (lastTimeStamp.mSMPTETime.mType)

  957.         {

  958.             case kSMPTETimeType2398:        info.frameRate = AudioPlayHead::fps23976;    break;

  959.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24;       break;

  960.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25;       break;

  961.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997;     break;

  962.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  963.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop;   break;

  964.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30;       break;

  965.             case kSMPTETimeType60Drop:      info.frameRate = AudioPlayHead::fps60drop;   break;

  966.             case kSMPTETimeType60:          info.frameRate = AudioPlayHead::fps60;       break;

  967.             case kSMPTETimeType5994:

  968.             case kSMPTETimeType5994Drop:

  969.             case kSMPTETimeType50:

  970.             default:                        info.frameRate = AudioPlayHead::fpsUnknown;  break;

  971.         }

  972. 

  973.         double num;

  974.         NSInteger den;

  975.         NSInteger outDeltaSampleOffsetToNextBeat;

  976.         double outCurrentMeasureDownBeat, bpm;

  977.         double ppqPosition;

  978. 

  979.         if (hostMusicalContextCallback != nullptr)

  980.         {

  981.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  982. 

  983.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  984.             {

  985.                 musicContextCallSucceeded = true;

  986. 

  987.                 info.timeSigNumerator   = (int) num;

  988.                 info.timeSigDenominator = (int) den;

  989.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  990.                 info.bpm = bpm;

  991.                 info.ppqPosition = ppqPosition;

  992.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  993.             }

  994.         }

  995. 

  996.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  997.         AUHostTransportStateFlags flags;

  998. 

  999.         if (hostTransportStateCallback != nullptr)

  1000.         {

  1001.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  1002. 

  1003.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  1004.             {

  1005.                 transportStateCallSucceeded = true;

  1006. 

  1007.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  1008.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  1009.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  1010.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  1011.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  1012.                 info.ppqLoopStart   = outCycleStartBeat;

  1013.                 info.ppqLoopEnd     = outCycleEndBeat;

  1014.             }

  1015.         }

  1016. 

  1017.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  1018.             lastAudioHead = info;

  1019. 

  1020.         return true;

  1021.     }

  1022. 

  1023.     //==============================================================================

  1024.     static void removeEditor (AudioProcessor& processor)

  1025.     {

  1026.         ScopedLock editorLock (processor.getCallbackLock());

  1027. 

  1028.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  1029.         {

  1030.             processor.editorBeingDeleted (editor);

  1031.             delete editor;

  1032.         }

  1033.     }

  1034. 

  1035. private:

  1036.     //==============================================================================

  1037.     struct BusBuffer

  1038.     {

  1039.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  1040.             : auBus (bus),

  1041.               maxFrames (maxFramesPerBuffer),

  1042.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  1043.               isInterleaved ([[auBus format] isInterleaved])

  1044.         {

  1045.             alloc();

  1046.         }

  1047. 

  1048.         //==============================================================================

  1049.         void alloc()

  1050.         {

  1051.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1052.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  1053.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  1054.             jassert (bytes > 0);

  1055. 

  1056.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  1057.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  1058. 

  1059.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  1060.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  1061.         }

  1062. 

  1063.         void dealloc()

  1064.         {

  1065.             bufferList = nullptr;

  1066.             bufferListStorage.free();

  1067.             scratchBuffer.setSize (0, 0);

  1068.         }

  1069. 

  1070.         //==============================================================================

  1071.         int numChannels() const noexcept                { return numberOfChannels; }

  1072.         bool interleaved() const noexcept               { return isInterleaved; }

  1073.         AudioBufferList* get() const noexcept           { return bufferList; }

  1074. 

  1075.         //==============================================================================

  1076.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  1077.         {

  1078.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1079.             const bool isCompatible = isCompatibleWith (other);

  1080. 

  1081.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  1082. 

  1083.             for (int i = 0; i < numBuffers; ++i)

  1084.             {

  1085.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  1086.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  1087.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  1088.                                                               : scratchBuffer.getWritePointer (i));

  1089.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  1090.             }

  1091.         }

  1092. 

  1093.         //==============================================================================

  1094.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  1095.         {

  1096.             if (other == nullptr)

  1097.                 return false;

  1098. 

  1099.             if (other->mNumberBuffers > 0)

  1100.             {

  1101.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  1102.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  1103.                                                                              : other->mNumberBuffers);

  1104. 

  1105.                 return otherInterleaved == isInterleaved

  1106.                     && numberOfChannels == otherChannels;

  1107.             }

  1108. 

  1109.             return numberOfChannels == 0;

  1110.         }

  1111. 

  1112.     private:

  1113.         AUAudioUnitBus* auBus;

  1114.         HeapBlock<char> bufferListStorage;

  1115.         AudioBufferList* bufferList = nullptr;

  1116.         int maxFrames, numberOfChannels;

  1117.         bool isInterleaved;

  1118.         juce::AudioBuffer<float> scratchBuffer;

  1119.     };

  1120. 

  1121.     //==============================================================================

  1122.     void addAudioUnitBusses (bool isInput)

  1123.     {

  1124.         std::unique_ptr<NSMutableArray<AUAudioUnitBus*>, NSObjectDeleter> array ([[NSMutableArray<AUAudioUnitBus*> alloc] init]);

  1125.         AudioProcessor& processor = getAudioProcessor();

  1126.         const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  1127. 

  1128.         for (int i = 0; i < n; ++i)

  1129.         {

  1130.             std::unique_ptr<AUAudioUnitBus, NSObjectDeleter> audioUnitBus;

  1131. 

  1132.             {

  1133.                 std::unique_ptr<AVAudioFormat, NSObjectDeleter> defaultFormat ([[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  1134.                                                                                                                               channels: static_cast<AVAudioChannelCount> (processor.getChannelCountOfBus (isInput, i))]);

  1135. 

  1136.                 audioUnitBus.reset ([[AUAudioUnitBus alloc] initWithFormat: defaultFormat.get()

  1137.                                                                      error: nullptr]);

  1138.             }

  1139. 

  1140.             [array.get() addObject: audioUnitBus.get()];

  1141.         }

  1142. 

  1143.         (isInput ? inputBusses : outputBusses).reset ([[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  1144.                                                                                              busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  1145.                                                                                               busses: array.get()]);

  1146.     }

  1147. 

  1148.     // When parameters are discrete we need to use integer values.

  1149.     float getMaximumParameterValue (AudioProcessorParameter* juceParam)

  1150.     {

  1151.        #if JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1152.         ignoreUnused (juceParam);

  1153.         return 1.0f;

  1154.        #else

  1155.         return juceParam->isDiscrete() ? (float) (juceParam->getNumSteps() - 1) : 1.0f;

  1156.        #endif

  1157.     }

  1158. 

  1159.     std::unique_ptr<AUParameter, NSObjectDeleter> createParameter (AudioProcessorParameter* parameter)

  1160.     {

  1161.         const String name (parameter->getName (512));

  1162. 

  1163.         AudioUnitParameterUnit unit = kAudioUnitParameterUnit_Generic;

  1164.         AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  1165.                                                   | kAudioUnitParameterFlag_IsReadable

  1166.                                                   | kAudioUnitParameterFlag_HasCFNameString

  1167.                                                   | kAudioUnitParameterFlag_ValuesHaveStrings);

  1168. 

  1169.        #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1170.         flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  1171.        #endif

  1172. 

  1173.         // Set whether the param is automatable (unnamed parameters aren't allowed to be automated).

  1174.         if (name.isEmpty() || ! parameter->isAutomatable())

  1175.             flags |= kAudioUnitParameterFlag_NonRealTime;

  1176. 

  1177.         const bool isParameterDiscrete = parameter->isDiscrete();

  1178. 

  1179.         if (! isParameterDiscrete)

  1180.             flags |= kAudioUnitParameterFlag_CanRamp;

  1181. 

  1182.         if (parameter->isMetaParameter())

  1183.             flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  1184. 

  1185.         std::unique_ptr<NSMutableArray, NSObjectDeleter> valueStrings;

  1186. 

  1187.         // Is this a meter?

  1188.         if (((parameter->getCategory() & 0xffff0000) >> 16) == 2)

  1189.         {

  1190.             flags &= ~kAudioUnitParameterFlag_IsWritable;

  1191.             flags |= kAudioUnitParameterFlag_MeterReadOnly | kAudioUnitParameterFlag_DisplayLogarithmic;

  1192.             unit = kAudioUnitParameterUnit_LinearGain;

  1193.         }

  1194.         else

  1195.         {

  1196.            #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1197.             if (parameter->isDiscrete())

  1198.             {

  1199.                 unit = parameter->isBoolean() ? kAudioUnitParameterUnit_Boolean : kAudioUnitParameterUnit_Indexed;

  1200.                 auto maxValue = getMaximumParameterValue (parameter);

  1201.                 auto numSteps = parameter->getNumSteps();

  1202. 

  1203.                 // Some hosts can't handle the huge numbers of discrete parameter values created when

  1204.                 // using the default number of steps.

  1205.                 jassert (numSteps != AudioProcessor::getDefaultNumParameterSteps());

  1206. 

  1207.                 valueStrings.reset ([NSMutableArray new]);

  1208. 

  1209.                 for (int i = 0; i < numSteps; ++i)

  1210.                     [valueStrings.get() addObject: juceStringToNS (parameter->getText ((float) i / maxValue, 0))];

  1211.             }

  1212.            #endif

  1213.         }

  1214. 

  1215.         AUParameterAddress address = generateAUParameterAddress (parameter);

  1216. 

  1217.        #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1218.         // If you hit this assertion then you have either put a parameter in two groups or you are

  1219.         // very unlucky and the hash codes of your parameter ids are not unique.

  1220.         jassert (! paramMap.contains (static_cast<int64> (address)));

  1221. 

  1222.         paramAddresses.add (address);

  1223.         paramMap.set (static_cast<int64> (address), parameter->getParameterIndex());

  1224.        #endif

  1225. 

  1226.         auto getParameterIdentifier = [parameter]

  1227.         {

  1228.             if (auto* paramWithID = dynamic_cast<AudioProcessorParameterWithID*> (parameter))

  1229.                 return paramWithID->paramID;

  1230. 

  1231.             // This could clash if any groups have been given integer IDs!

  1232.             return String (parameter->getParameterIndex());

  1233.         };

  1234. 

  1235.         std::unique_ptr<AUParameter, NSObjectDeleter> param;

  1236. 

  1237.         @try

  1238.         {

  1239.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1240.             param.reset([[AUParameterTree createParameterWithIdentifier: juceStringToNS (getParameterIdentifier())

  1241.                                                                    name: juceStringToNS (name)

  1242.                                                                 address: address

  1243.                                                                     min: 0.0f

  1244.                                                                     max: getMaximumParameterValue (parameter)

  1245.                                                                    unit: unit

  1246.                                                                unitName: nullptr

  1247.                                                                   flags: flags

  1248.                                                            valueStrings: valueStrings.get()

  1249.                                                     dependentParameters: nullptr]

  1250.                          retain]);

  1251.         }

  1252. 

  1253.         @catch (NSException* exception)

  1254.         {

  1255.             // Do you have duplicate identifiers in any of your groups or parameters,

  1256.             // or do your identifiers have unusual characters in them?

  1257.             jassertfalse;

  1258.         }

  1259. 

  1260.         [param.get() setValue: parameter->getDefaultValue()];

  1261. 

  1262.         [overviewParams.get() addObject: [NSNumber numberWithUnsignedLongLong: address]];

  1263. 

  1264.         return param;

  1265.     }

  1266. 

  1267.     std::unique_ptr<AUParameterGroup, NSObjectDeleter> createParameterGroup (AudioProcessorParameterGroup* group)

  1268.     {

  1269.         std::unique_ptr<NSMutableArray<AUParameterNode*>, NSObjectDeleter> children ([NSMutableArray<AUParameterNode*> new]);

  1270. 

  1271.         for (auto* node : *group)

  1272.         {

  1273.             if (auto* childGroup = node->getGroup())

  1274.                 [children.get() addObject: createParameterGroup (childGroup).get()];

  1275.             else

  1276.                 [children.get() addObject: createParameter (node->getParameter()).get()];

  1277.         }

  1278. 

  1279.         std::unique_ptr<AUParameterGroup, NSObjectDeleter> result;

  1280. 

  1281.         @try

  1282.         {

  1283.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1284.             result.reset ([[AUParameterTree createGroupWithIdentifier: juceStringToNS (group->getID())

  1285.                                                                  name: juceStringToNS (group->getName())

  1286.                                                              children: children.get()]

  1287.                            retain]);

  1288.         }

  1289. 

  1290.         @catch (NSException* exception)

  1291.         {

  1292.             // Do you have duplicate identifiers in any of your groups or parameters,

  1293.             // or do your identifiers have unusual characters in them?

  1294.             jassertfalse;

  1295.         }

  1296. 

  1297.         return result;

  1298.     }

  1299. 

  1300.     void addParameters()

  1301.     {

  1302.         auto& processor = getAudioProcessor();

  1303.         juceParameters.update (processor, forceLegacyParamIDs);

  1304. 

  1305.         // This is updated when we build the tree.

  1306.         overviewParams.reset ([NSMutableArray<NSNumber*> new]);

  1307. 

  1308.         std::unique_ptr<NSMutableArray<AUParameterNode*>, NSObjectDeleter> topLevelNodes ([NSMutableArray<AUParameterNode*> new]);

  1309. 

  1310.         for (auto* node : processor.getParameterTree())

  1311.             if (auto* childGroup = node->getGroup())

  1312.                 [topLevelNodes.get() addObject: createParameterGroup (childGroup).get()];

  1313.             else

  1314.                 [topLevelNodes.get() addObject: createParameter (node->getParameter()).get()];

  1315. 

  1316.         @try

  1317.         {

  1318.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1319.             paramTree.reset ([[AUParameterTree createTreeWithChildren: topLevelNodes.get()] retain]);

  1320.         }

  1321. 

  1322.         @catch (NSException* exception)

  1323.         {

  1324.             // Do you have duplicate identifiers in any of your groups or parameters,

  1325.             // or do your identifiers have unusual characters in them?

  1326.             jassertfalse;

  1327.         }

  1328. 

  1329.         paramObserver           = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  1330.         paramProvider           = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  1331.         stringFromValueProvider = CreateObjCBlock (this, &JuceAudioUnitv3::stringFromValue);

  1332.         valueFromStringProvider = CreateObjCBlock (this, &JuceAudioUnitv3::valueFromString);

  1333. 

  1334.         [paramTree.get() setImplementorValueObserver: paramObserver];

  1335.         [paramTree.get() setImplementorValueProvider: paramProvider];

  1336.         [paramTree.get() setImplementorStringFromValueCallback: stringFromValueProvider];

  1337.         [paramTree.get() setImplementorValueFromStringCallback: valueFromStringProvider];

  1338. 

  1339.         if (processor.hasEditor())

  1340.         {

  1341.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  1342.             editorObserverToken = [paramTree.get() tokenByAddingParameterObserver: editorParamObserver];

  1343.         }

  1344. 

  1345.         if ((bypassParam = processor.getBypassParameter()) != nullptr)

  1346.             bypassParam->addListener (this);

  1347.     }

  1348. 

  1349.     void setAudioProcessorParameter (AudioProcessorParameter* juceParam, float value)

  1350.     {

  1351.         if (value != juceParam->getValue())

  1352.         {

  1353.             juceParam->setValue (value);

  1354. 

  1355.             inParameterChangedCallback = true;

  1356.             juceParam->sendValueChangedMessageToListeners (value);

  1357.         }

  1358.     }

  1359. 

  1360.     void addPresets()

  1361.     {

  1362.         factoryPresets.reset ([[NSMutableArray<AUAudioUnitPreset*> alloc] init]);

  1363. 

  1364.         const int n = getAudioProcessor().getNumPrograms();

  1365. 

  1366.         for (int idx = 0; idx < n; ++idx)

  1367.         {

  1368.             String name = getAudioProcessor().getProgramName (idx);

  1369. 

  1370.             std::unique_ptr<AUAudioUnitPreset, NSObjectDeleter> preset ([[AUAudioUnitPreset alloc] init]);

  1371.             [preset.get() setName: juceStringToNS (name)];

  1372.             [preset.get() setNumber: static_cast<NSInteger> (idx)];

  1373. 

  1374.             [factoryPresets.get() addObject: preset.get()];

  1375.         }

  1376.     }

  1377. 

  1378.     //==============================================================================

  1379.     void allocateBusBuffer (bool isInput)

  1380.     {

  1381.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  1382.         busBuffers.clear();

  1383. 

  1384.         const int n = AudioUnitHelpers::getBusCount (&getAudioProcessor(), isInput);

  1385.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1386. 

  1387.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1388.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1389.                                            static_cast<int> (maxFrames)));

  1390.     }

  1391. 

  1392.     //==============================================================================

  1393.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1394.     {

  1395.         ignoreUnused (numParams);

  1396. 

  1397.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1398.         {

  1399.             switch (event->head.eventType)

  1400.             {

  1401.                 case AURenderEventMIDI:

  1402.                 {

  1403.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1404.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1405.                 }

  1406.                 break;

  1407. 

  1408.                 case AURenderEventParameter:

  1409.                 case AURenderEventParameterRamp:

  1410.                 {

  1411.                     const AUParameterEvent& paramEvent = event->parameter;

  1412. 

  1413.                     if (auto* p = getJuceParameterForAUAddress (paramEvent.parameterAddress))

  1414.                     {

  1415.                         auto normalisedValue = paramEvent.value / getMaximumParameterValue (p);

  1416.                         setAudioProcessorParameter (p, normalisedValue);

  1417.                     }

  1418.                 }

  1419.                 break;

  1420. 

  1421.                 case AURenderEventMIDISysEx:

  1422.                 default:

  1423.                     break;

  1424.             }

  1425.         }

  1426.     }

  1427. 

  1428.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1429.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1430.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1431.     {

  1432.         auto& processor = getAudioProcessor();

  1433.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1434. 

  1435.         // process params

  1436.         const int numParams = juceParameters.getNumParameters();

  1437.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1438. 

  1439.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1440.         {

  1441.             lastTimeStamp = *timestamp;

  1442. 

  1443.             const int numInputBuses  = inBusBuffers. size();

  1444.             const int numOutputBuses = outBusBuffers.size();

  1445. 

  1446.             // prepare buffers

  1447.             {

  1448.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1449.                 {

  1450.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1451.                      const bool canUseDirectOutput =

  1452.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1453. 

  1454.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1455.                 }

  1456. 

  1457.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1458.                 {

  1459.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1460.                     busBuffer.prepare (frameCount, busIdx < numOutputBuses ? outBusBuffers[busIdx]->get() : nullptr);

  1461.                 }

  1462. 

  1463.                 audioBuffer.reset();

  1464.             }

  1465. 

  1466.             // pull inputs

  1467.             {

  1468.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1469.                 {

  1470.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1471.                     AudioBufferList* buffer = busBuffer.get();

  1472. 

  1473.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1474.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1475. 

  1476.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1477.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1478.                 }

  1479.             }

  1480. 

  1481.             // set buffer pointer to minimize copying

  1482.             {

  1483.                 int chIdx = 0;

  1484. 

  1485.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1486.                 {

  1487.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1488.                     AudioBufferList* buffer = busBuffer.get();

  1489. 

  1490.                     const bool interleaved = busBuffer.interleaved();

  1491.                     const int numChannels = busBuffer.numChannels();

  1492. 

  1493.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1494. 

  1495.                     for (int ch = 0; ch < numChannels; ++ch)

  1496.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1497.                 }

  1498. 

  1499.                 // use input pointers on remaining channels

  1500. 

  1501.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1502.                 {

  1503.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1504. 

  1505.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1506.                     AudioBufferList* buffer = busBuffer.get();

  1507. 

  1508.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1509.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1510.                 }

  1511.             }

  1512. 

  1513.             // copy input

  1514.             {

  1515.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1516.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1517. 

  1518.                 // clear remaining channels

  1519.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1520.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1521.             }

  1522. 

  1523.             // process audio

  1524.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1525. 

  1526.             // send MIDI

  1527.            #if JucePlugin_ProducesMidiOutput && JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  1528.             if (auto midiOut = [au MIDIOutputEventBlock])

  1529.             {

  1530.                 for (const auto metadata : midiMessages)

  1531.                     midiOut (metadata.samplePosition, 0, metadata.numBytes, metadata.data);

  1532.             }

  1533.            #endif

  1534. 

  1535.             midiMessages.clear();

  1536. 

  1537.             // copy back

  1538.             audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1539.                              mapper.get (false, (int) outputBusNumber));

  1540.         }

  1541. 

  1542.         return noErr;

  1543.     }

  1544. 

  1545.     void processBlock (juce::AudioBuffer<float>& buffer, MidiBuffer& midiBuffer) noexcept

  1546.     {

  1547.         auto& processor = getAudioProcessor();

  1548.         const ScopedLock sl (processor.getCallbackLock());

  1549. 

  1550.         if (processor.isSuspended())

  1551.             buffer.clear();

  1552.         else if (bypassParam != nullptr && [au shouldBypassEffect])

  1553.             processor.processBlockBypassed (buffer, midiBuffer);

  1554.         else

  1555.             processor.processBlock (buffer, midiBuffer);

  1556.     }

  1557. 

  1558.     //==============================================================================

  1559.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1560.     {

  1561.         if (param != nullptr)

  1562.         {

  1563.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1564.             {

  1565.                 auto normalisedValue = value / getMaximumParameterValue (p);

  1566.                 setAudioProcessorParameter (p, normalisedValue);

  1567.             }

  1568.         }

  1569.     }

  1570. 

  1571.     AUValue getValue (AUParameter* param)

  1572.     {

  1573.         if (param != nullptr)

  1574.         {

  1575.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1576.                 return p->getValue() * getMaximumParameterValue (p);

  1577.         }

  1578. 

  1579.         return 0;

  1580.     }

  1581. 

  1582.     void valueChangedForObserver (AUParameterAddress, AUValue)

  1583.     {

  1584.         // this will have already been handled by valueChangedFromHost

  1585.     }

  1586. 

  1587.     NSString* stringFromValue (AUParameter* param, const AUValue* value)

  1588.     {

  1589.         String text;

  1590. 

  1591.         if (param != nullptr && value != nullptr)

  1592.         {

  1593.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1594.             {

  1595.                 if (LegacyAudioParameter::isLegacy (p))

  1596.                     text = String (*value);

  1597.                 else

  1598.                     text = p->getText (*value / getMaximumParameterValue (p), 0);

  1599.             }

  1600.         }

  1601. 

  1602.         return juceStringToNS (text);

  1603.     }

  1604. 

  1605.     AUValue valueFromString (AUParameter* param, NSString* str)

  1606.     {

  1607.         if (param != nullptr && str != nullptr)

  1608.         {

  1609.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1610.             {

  1611.                 const String text (nsStringToJuce (str));

  1612. 

  1613.                 if (LegacyAudioParameter::isLegacy (p))

  1614.                     return text.getFloatValue();

  1615.                 else

  1616.                     return p->getValueForText (text) * getMaximumParameterValue (p);

  1617.             }

  1618.         }

  1619. 

  1620.         return 0;

  1621.     }

  1622. 

  1623.     //==============================================================================

  1624.     // this is only ever called for the bypass parameter

  1625.     void parameterValueChanged (int, float newValue) override

  1626.     {

  1627.         JuceAudioUnitv3Base::setShouldBypassEffect (newValue != 0.0f);

  1628.     }

  1629. 

  1630.     void parameterGestureChanged (int, bool) override {}

  1631. 

  1632.     //==============================================================================

  1633.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1634.     {

  1635.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1636.         return static_cast<AUParameterAddress> (paramIndex);

  1637.        #else

  1638.         return paramAddresses.getReference (paramIndex);

  1639.        #endif

  1640.     }

  1641. 

  1642.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1643.     {

  1644.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1645.         return static_cast<int> (address);

  1646.        #else

  1647.         return paramMap[static_cast<int64> (address)];

  1648.        #endif

  1649.     }

  1650. 

  1651.     AUParameterAddress generateAUParameterAddress (AudioProcessorParameter* param) const

  1652.     {

  1653.         const String& juceParamID = LegacyAudioParameter::getParamID (param, forceLegacyParamIDs);

  1654. 

  1655.         return static_cast<AUParameterAddress> (forceLegacyParamIDs ? juceParamID.getIntValue()

  1656.                                                                     : juceParamID.hashCode64());

  1657.     }

  1658. 

  1659.     AudioProcessorParameter* getJuceParameterForAUAddress (AUParameterAddress address) const noexcept

  1660.     {

  1661.         return juceParameters.getParamForIndex (getJuceParameterIndexForAUAddress (address));

  1662.     }

  1663. 

  1664.     //==============================================================================

  1665.     static const double kDefaultSampleRate;

  1666. 

  1667.     AudioProcessorHolder::Ptr processorHolder;

  1668. 

  1669.     int totalInChannels, totalOutChannels;

  1670. 

  1671.     std::unique_ptr<AUAudioUnitBusArray, NSObjectDeleter> inputBusses, outputBusses;

  1672. 

  1673.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1674.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1675.     ObjCBlock<AUImplementorStringFromValueCallback> stringFromValueProvider;

  1676.     ObjCBlock<AUImplementorValueFromStringCallback> valueFromStringProvider;

  1677. 

  1678.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1679.     Array<AUParameterAddress> paramAddresses;

  1680.     HashMap<int64, int> paramMap;

  1681.    #endif

  1682.     LegacyAudioParametersWrapper juceParameters;

  1683. 

  1684.     // to avoid recursion on parameter changes, we need to add an

  1685.     // editor observer to do the parameter changes

  1686.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1687.     AUParameterObserverToken editorObserverToken;

  1688. 

  1689.     std::unique_ptr<AUParameterTree, NSObjectDeleter> paramTree;

  1690.     std::unique_ptr<NSMutableArray<NSNumber*>, NSObjectDeleter> overviewParams, channelCapabilities;

  1691. 

  1692.     std::unique_ptr<NSMutableArray<AUAudioUnitPreset*>, NSObjectDeleter> factoryPresets;

  1693. 

  1694.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1695. 

  1696.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1697.     AudioUnitHelpers::ChannelRemapper mapper;

  1698. 

  1699.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1700.     MidiBuffer midiMessages;

  1701. 

  1702.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1703.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1704. 

  1705.     AudioTimeStamp lastTimeStamp;

  1706.     CurrentPositionInfo lastAudioHead;

  1707. 

  1708.     String contextName;

  1709. 

  1710.     ThreadLocalValue<bool> inParameterChangedCallback;

  1711.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1712.     static constexpr bool forceLegacyParamIDs = true;

  1713.    #else

  1714.     static constexpr bool forceLegacyParamIDs = false;

  1715.    #endif

  1716.     AudioProcessorParameter* bypassParam = nullptr;

  1717. };

  1718. 

  1719. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1720. 

  1721. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1722. {

  1723.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1724.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1725. }

  1726. 

  1727. #if JUCE_IOS

  1728. namespace juce

  1729. {

  1730. struct UIViewPeerControllerReceiver

  1731. {

  1732.     virtual ~UIViewPeerControllerReceiver();

  1733.     virtual void setViewController (UIViewController*) = 0;

  1734. };

  1735. }

  1736. #endif

  1737. 

  1738. //==============================================================================

  1739. class JuceAUViewController

  1740. {

  1741. public:

  1742.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1743.         : myself (p)

  1744.     {

  1745.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1746.         initialiseJuce_GUI();

  1747.     }

  1748. 

  1749.     ~JuceAUViewController()

  1750.     {

  1751.         JUCE_ASSERT_MESSAGE_THREAD

  1752. 

  1753.         if (processorHolder != nullptr)

  1754.             JuceAudioUnitv3::removeEditor (getAudioProcessor());

  1755.     }

  1756. 

  1757.     //==============================================================================

  1758.     void loadView()

  1759.     {

  1760.         JUCE_ASSERT_MESSAGE_THREAD

  1761. 

  1762.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1763.         {

  1764.             processorHolder = new AudioProcessorHolder (p);

  1765.             auto& processor = getAudioProcessor();

  1766. 

  1767.             if (processor.hasEditor())

  1768.             {

  1769.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1770.                 {

  1771.                     preferredSize = editor->getBounds();

  1772. 

  1773.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1774.                     [myself setView: view];

  1775. 

  1776.                    #if JUCE_IOS

  1777.                     editor->setVisible (false);

  1778.                    #else

  1779.                     editor->setVisible (true);

  1780.                    #endif

  1781. 

  1782.                     editor->addToDesktop (0, view);

  1783. 

  1784.                    #if JUCE_IOS

  1785.                     if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1786.                         [peerView setContentMode: UIViewContentModeTop];

  1787. 

  1788.                     if (auto* peer = dynamic_cast<UIViewPeerControllerReceiver*> (editor->getPeer()))

  1789.                         peer->setViewController (myself);

  1790.                    #endif

  1791.                 }

  1792.             }

  1793.         }

  1794.     }

  1795. 

  1796.     void viewDidLayoutSubviews()

  1797.     {

  1798.         if (processorHolder != nullptr && [myself view] != nullptr)

  1799.         {

  1800.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1801.             {

  1802.                 if (processorHolder->viewConfiguration != nullptr)

  1803.                     editor->hostMIDIControllerIsAvailable (processorHolder->viewConfiguration->hostHasMIDIController);

  1804. 

  1805.                 editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1806. 

  1807.                 if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1808.                 {

  1809.                    #if JUCE_IOS

  1810.                     [peerView setNeedsDisplay];

  1811.                    #else

  1812.                     [peerView setNeedsDisplay: YES];

  1813.                    #endif

  1814.                 }

  1815.             }

  1816.         }

  1817.     }

  1818. 

  1819.     void didReceiveMemoryWarning()

  1820.     {

  1821.         if (processorHolder != nullptr)

  1822.             if (auto* processor = processorHolder->get())

  1823.                 processor->memoryWarningReceived();

  1824.     }

  1825. 

  1826.     void viewDidAppear (bool)

  1827.     {

  1828.         if (processorHolder != nullptr)

  1829.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1830.                 editor->setVisible (true);

  1831.     }

  1832. 

  1833.     void viewDidDisappear (bool)

  1834.     {

  1835.         if (processorHolder != nullptr)

  1836.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1837.                 editor->setVisible (false);

  1838.     }

  1839. 

  1840.     CGSize getPreferredContentSize() const

  1841.     {

  1842.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1843.                            static_cast<float> (preferredSize.getHeight()));

  1844.     }

  1845. 

  1846.     //==============================================================================

  1847.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1848.     {

  1849.         AUAudioUnit* retval = nil;

  1850. 

  1851.         if (! MessageManager::getInstance()->isThisTheMessageThread())

  1852.         {

  1853.             WaitableEvent creationEvent;

  1854. 

  1855.             // AUv3 headers say that we may block this thread and that the message thread is guaranteed

  1856.             // to be unblocked

  1857.             struct AUCreator  : public CallbackMessage

  1858.             {

  1859.                 JuceAUViewController& owner;

  1860.                 AudioComponentDescription pDescr;

  1861.                 NSError** pError;

  1862.                 AUAudioUnit*& outAU;

  1863.                 WaitableEvent& e;

  1864. 

  1865.                 AUCreator (JuceAUViewController& parent, const AudioComponentDescription& paramDescr, NSError** paramError,

  1866.                            AUAudioUnit*& outputAU, WaitableEvent& event)

  1867.                     : owner (parent), pDescr (paramDescr), pError (paramError), outAU (outputAU), e (event)

  1868.                 {}

  1869. 

  1870.                 void messageCallback() override

  1871.                 {

  1872.                     outAU = owner.createAudioUnitOnMessageThread (pDescr, pError);

  1873.                     e.signal();

  1874.                 }

  1875.             };

  1876. 

  1877.             (new AUCreator (*this, descr, error, retval, creationEvent))->post();

  1878.             creationEvent.wait (-1);

  1879.         }

  1880.         else

  1881.         {

  1882.             retval = createAudioUnitOnMessageThread (descr, error);

  1883.         }

  1884. 

  1885.         return [retval autorelease];

  1886.     }

  1887. 

  1888. private:

  1889.     //==============================================================================

  1890.     AUViewController<AUAudioUnitFactory>* myself;

  1891.     AudioProcessorHolder::Ptr processorHolder = nullptr;

  1892.     Rectangle<int> preferredSize { 1, 1 };

  1893. 

  1894.     //==============================================================================

  1895.     AUAudioUnit* createAudioUnitOnMessageThread (const AudioComponentDescription& descr, NSError** error)

  1896.     {

  1897.         JUCE_ASSERT_MESSAGE_THREAD

  1898. 

  1899.         [myself view];  // this will call [view load] and ensure that the AudioProcessor has been instantiated

  1900. 

  1901.         if (processorHolder == nullptr)

  1902.             return nullptr;

  1903. 

  1904.         return (new JuceAudioUnitv3 (processorHolder, descr, 0, error))->getAudioUnit();

  1905.     }

  1906. 

  1907.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder; }

  1908. };

  1909. 

  1910. //==============================================================================

  1911. // necessary glue code

  1912. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  1913. @end

  1914. 

  1915. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  1916. {

  1917.     std::unique_ptr<JuceAUViewController> cpp;

  1918. }

  1919. 

  1920. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp.reset (new JuceAUViewController (self)); return self; }

  1921. - (void) loadView                { cpp->loadView(); }

  1922. - (AUAudioUnit *) createAudioUnitWithComponentDescription: (AudioComponentDescription) desc error: (NSError **) error { return cpp->createAudioUnit (desc, error); }

  1923. - (CGSize) preferredContentSize  { return cpp->getPreferredContentSize(); }

  1924. - (void) viewDidLayoutSubviews   { cpp->viewDidLayoutSubviews(); }

  1925. - (void) didReceiveMemoryWarning { cpp->didReceiveMemoryWarning(); }

  1926. #if JUCE_IOS

  1927. - (void) viewDidAppear: (BOOL) animated { cpp->viewDidAppear (animated); [super viewDidAppear:animated]; }

  1928. - (void) viewDidDisappear: (BOOL) animated { cpp->viewDidDisappear (animated); [super viewDidDisappear:animated]; }

  1929. #endif

  1930. @end

  1931. 

  1932. //==============================================================================

  1933. #if JUCE_IOS

  1934. bool JUCE_CALLTYPE juce_isInterAppAudioConnected() { return false; }

  1935. void JUCE_CALLTYPE juce_switchToHostApplication()  {}

  1936. Image JUCE_CALLTYPE juce_getIAAHostIcon (int)      { return {}; }

  1937. #endif

  1938. 

  1939. JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  1940. #endif