DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
8213 Commits
11 Branches
450MB
Tree: aecb819985
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'aecb819985'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

1659 lines
73KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2017 - ROLI Ltd.

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 5 End-User License

  11.    Agreement and JUCE 5 Privacy Policy (both updated and effective as of the

  12.    27th April 2017).

  13. 

  14.    End User License Agreement: www.juce.com/juce-5-licence

  15.    Privacy Policy: www.juce.com/juce-5-privacy-policy

  16. 

  17.    Or: You may also use this code under the terms of the GPL v3 (see

  18.    www.gnu.org/licenses).

  19. 

  20.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  21.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  22.    DISCLAIMED.

  23. 

  24.   ==============================================================================

  25. */

  26. 

  27. #include "../../juce_core/system/juce_TargetPlatform.h"

  28. #include "../utility/juce_CheckSettingMacros.h"

  29. 

  30. #if JucePlugin_Build_AUv3

  31. 

  32. #import <CoreAudioKit/CoreAudioKit.h>

  33. #import <AudioToolbox/AudioToolbox.h>

  34. #import <AVFoundation/AVFoundation.h>

  35. 

  36. #if JUCE_MAC

  37.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  38.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  39.  #endif

  40.  #if (defined MAC_OS_X_VERSION_10_13) && (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_13)

  41.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  42.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  43.  #endif

  44. #endif

  45. 

  46. #if JUCE_IOS

  47.  #if (! defined __IPHONE_OS_VERSION_MIN_REQUIRED) || (! defined __IPHONE_9_0) || (__IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_9_0)

  48.   #error AUv3 needs Deployment Target iOS 9.0 or higher to compile

  49.  #endif

  50.  #if (defined __IPHONE_11_0) && (__IPHONE_OS_VERSION_MIN_REQUIRED >= __IPHONE_11_0)

  51.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  52.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  53.  #endif

  54. #endif

  55. 

  56. #ifndef __OBJC2__

  57.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  58. #endif

  59. 

  60. #define JUCE_CORE_INCLUDE_OBJC_HELPERS 1

  61. 

  62. #include "../utility/juce_IncludeSystemHeaders.h"

  63. #include "../utility/juce_IncludeModuleHeaders.h"

  64. #include "../../juce_graphics/native/juce_mac_CoreGraphicsHelpers.h"

  65. 

  66. #include "../../juce_audio_basics/native/juce_mac_CoreAudioLayouts.h"

  67. #include "../../juce_audio_processors/format_types/juce_AU_Shared.h"

  68. 

  69. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  70. 

  71. #if ! JUCE_COMPILER_SUPPORTS_VARIADIC_TEMPLATES

  72.  #error AUv3 wrapper requires variadic template support

  73. #endif

  74. 

  75. #if JUCE_IOS

  76.  #define JUCE_IOS_MAC_VIEW  UIView

  77. #else

  78.  #define JUCE_IOS_MAC_VIEW  NSView

  79. #endif

  80. 

  81. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  82. 

  83. #pragma clang diagnostic push

  84. #pragma clang diagnostic ignored "-Wnullability-completeness"

  85. 

  86. using namespace juce;

  87. 

  88. // TODO: use SFINAE to automatically generate this for all NSObjects

  89. template <> struct ContainerDeletePolicy<AUAudioUnitBusArray>                   { static void destroy (NSObject* o) { [o release]; } };

  90. template <> struct ContainerDeletePolicy<AUParameterTree>                       { static void destroy (NSObject* o) { [o release]; } };

  91. template <> struct ContainerDeletePolicy<NSMutableArray<AUParameterNode*>>      { static void destroy (NSObject* o) { [o release]; } };

  92. template <> struct ContainerDeletePolicy<AUParameter>                           { static void destroy (NSObject* o) { [o release]; } };

  93. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitBus*>>       { static void destroy (NSObject* o) { [o release]; } };

  94. template <> struct ContainerDeletePolicy<AUAudioUnitBus>                        { static void destroy (NSObject* o) { [o release]; } };

  95. template <> struct ContainerDeletePolicy<AVAudioFormat>                         { static void destroy (NSObject* o) { [o release]; } };

  96. template <> struct ContainerDeletePolicy<AVAudioPCMBuffer>                      { static void destroy (NSObject* o) { [o release]; } };

  97. template <> struct ContainerDeletePolicy<NSMutableArray<NSNumber*>>             { static void destroy (NSObject* o) { [o release]; } };

  98. template <> struct ContainerDeletePolicy<NSNumber>                              { static void destroy (NSObject* o) { [o release]; } };

  99. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitPreset*>>    { static void destroy (NSObject* o) { [o release]; } };

  100. template <> struct ContainerDeletePolicy<AUAudioUnitPreset>                     { static void destroy (NSObject* o) { [o release]; } };

  101. 

  102. //==============================================================================

  103. struct AudioProcessorHolder  : public ReferenceCountedObject

  104. {

  105.     AudioProcessorHolder() {}

  106.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  107.     AudioProcessor& operator*() noexcept        { return *processor; }

  108.     AudioProcessor* operator->() noexcept       { return processor; }

  109.     AudioProcessor* get() noexcept              { return processor; }

  110. 

  111.     struct ViewConfig

  112.     {

  113.         double width;

  114.         double height;

  115.         bool hostHasMIDIController;

  116.     };

  117. 

  118.     ScopedPointer<ViewConfig> viewConfiguration;

  119. 

  120.     typedef ReferenceCountedObjectPtr<AudioProcessorHolder> Ptr;

  121. 

  122. private:

  123.     ScopedPointer<AudioProcessor> processor;

  124. 

  125.     AudioProcessorHolder& operator= (AudioProcessor*) JUCE_DELETED_FUNCTION;

  126.     AudioProcessorHolder (AudioProcessorHolder&) JUCE_DELETED_FUNCTION;

  127.     AudioProcessorHolder& operator= (AudioProcessorHolder&) JUCE_DELETED_FUNCTION;

  128. };

  129. 

  130. //==============================================================================

  131. class JuceAudioUnitv3Base

  132. {

  133. public:

  134.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  135.                          AudioComponentInstantiationOptions options,

  136.                          NSError** error)

  137.        #pragma clang diagnostic push

  138.        #pragma clang diagnostic ignored "-Wobjc-method-access"

  139.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  140.                                                                         options: options

  141.                                                                           error: error

  142.                                                                       juceClass: this])

  143.        #pragma clang diagnostic pop

  144.     {}

  145. 

  146.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  147.     {

  148.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  149.         initialiseJuce_GUI();

  150.     }

  151. 

  152.     virtual ~JuceAudioUnitv3Base() {}

  153. 

  154.     //==============================================================================

  155.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  156. 

  157.     //==============================================================================

  158.     virtual void reset()                                                   = 0;

  159. 

  160.     //==============================================================================

  161.     virtual AUAudioUnitPreset* getCurrentPreset()                          = 0;

  162.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      = 0;

  163.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()               = 0;

  164. 

  165.     virtual NSDictionary<NSString*, id>* getFullState()

  166.     {

  167.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  168.         return ObjCMsgSendSuper<NSDictionary<NSString*, id>*> (&s, @selector (fullState));

  169.     }

  170. 

  171.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  172.     {

  173.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  174.         ObjCMsgSendSuper<void, NSDictionary<NSString*, id>*> (&s, @selector (setFullState:), state);

  175.     }

  176. 

  177.     virtual AUParameterTree* getParameterTree()                            = 0;

  178.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)       = 0;

  179. 

  180.     //==============================================================================

  181.     virtual NSTimeInterval getLatency()                                    = 0;

  182.     virtual NSTimeInterval getTailTime()                                   = 0;

  183. 

  184.     //==============================================================================

  185.     virtual AUAudioUnitBusArray* getInputBusses()                          = 0;

  186.     virtual AUAudioUnitBusArray* getOutputBusses()                         = 0;

  187.     virtual NSArray<NSNumber*>* getChannelCapabilities()                   = 0;

  188.     virtual bool shouldChangeToFormat (AVAudioFormat*, AUAudioUnitBus*)    = 0;

  189. 

  190.     //==============================================================================

  191.     virtual int getVirtualMIDICableCount()                                 = 0;

  192.     virtual bool getSupportsMPE()                                          = 0;

  193.     virtual NSArray<NSString*>* getMIDIOutputNames()                       = 0;

  194. 

  195.     //==============================================================================

  196.     virtual AUInternalRenderBlock getInternalRenderBlock()                 = 0;

  197.     virtual bool getCanProcessInPlace()                                    { return false; }

  198.     virtual bool getRenderingOffline()                                     = 0;

  199.     virtual void setRenderingOffline (bool offline)                        = 0;

  200. 

  201.     //==============================================================================

  202.     virtual NSString* getContextName()      const                          = 0;

  203.     virtual void setContextName (NSString*)                                = 0;

  204. 

  205.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  206.     {

  207.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  208.         return (ObjCMsgSendSuper<BOOL, NSError**> (&s, @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  209.     }

  210. 

  211.     virtual void deallocateRenderResources()

  212.     {

  213.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  214.         ObjCMsgSendSuper<void> (&s, @selector (deallocateRenderResources));

  215.     }

  216. 

  217.     //==============================================================================

  218.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  219.     virtual NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>*) = 0;

  220.     virtual void selectViewConfiguration (AUAudioUnitViewConfiguration*)   = 0;

  221.    #endif

  222. 

  223. private:

  224.     struct Class  : public ObjCClass<AUAudioUnit>

  225.     {

  226.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  227.         {

  228.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  229. 

  230.            #pragma clang diagnostic push

  231.            #pragma clang diagnostic ignored "-Wundeclared-selector"

  232.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  233.                        initWithComponentDescriptionAndJuceClass, "@@:",

  234.                        @encode (AudioComponentDescription),

  235.                        @encode (AudioComponentInstantiationOptions), "^@@");

  236.            #pragma clang diagnostic pop

  237. 

  238.             addMethod (@selector (initWithComponentDescription:options:error:),

  239.                        initWithComponentDescription, "@@:",

  240.                        @encode (AudioComponentDescription),

  241.                        @encode (AudioComponentInstantiationOptions), "^@");

  242. 

  243.             addMethod (@selector (dealloc),                         dealloc,                        "v@:");

  244. 

  245.             //==============================================================================

  246.             addMethod (@selector (reset),                           reset,                          "v@:");

  247. 

  248.             //==============================================================================

  249.             addMethod (@selector (currentPreset),                   getCurrentPreset,               "@@:");

  250.             addMethod (@selector (setCurrentPreset:),               setCurrentPreset,               "v@:@");

  251.             addMethod (@selector (factoryPresets),                  getFactoryPresets,              "@@:");

  252.             addMethod (@selector (fullState),                       getFullState,                   "@@:");

  253.             addMethod (@selector (setFullState:),                   setFullState,                   "v@:@");

  254.             addMethod (@selector (parameterTree),                   getParameterTree,               "@@:");

  255.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  256. 

  257.             //==============================================================================

  258.             addMethod (@selector (latency),                         getLatency,                     @encode (NSTimeInterval), "@:");

  259.             addMethod (@selector (tailTime),                        getTailTime,                    @encode (NSTimeInterval),  "@:");

  260. 

  261.             //==============================================================================

  262.             addMethod (@selector (inputBusses),                     getInputBusses,                 "@@:");

  263.             addMethod (@selector (outputBusses),                    getOutputBusses,                "@@:");

  264.             addMethod (@selector (channelCapabilities),             getChannelCapabilities,         "@@:");

  265.             addMethod (@selector (shouldChangeToFormat:forBus:),    shouldChangeToFormat,           "B@:@@");

  266. 

  267.             //==============================================================================

  268.             addMethod (@selector (virtualMIDICableCount),           getVirtualMIDICableCount,       @encode (NSInteger), "@:");

  269.             addMethod (@selector (supportsMPE),                     getSupportsMPE,                 @encode (BOOL),      "@:");

  270. 

  271.            #if JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  272.             addMethod (@selector (MIDIOutputNames),                 getMIDIOutputNames,             "@@:");

  273.            #endif

  274. 

  275.             //==============================================================================

  276.             addMethod (@selector (internalRenderBlock),             getInternalRenderBlock,         @encode (AUInternalRenderBlock), "@:");

  277.             addMethod (@selector (canProcessInPlace),               getCanProcessInPlace,           @encode (BOOL), "@:");

  278.             addMethod (@selector (isRenderingOffline),              getRenderingOffline,            @encode (BOOL),  "@:");

  279.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  280.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "B@:^@");

  281.             addMethod (@selector (deallocateRenderResources),       deallocateRenderResources,      "v@:");

  282. 

  283.             //==============================================================================

  284.             addMethod (@selector (contextName),                     getContextName,                 "@@:");

  285.             addMethod (@selector (setContextName:),                  setContextName,                 "v@:@");

  286. 

  287.             //==============================================================================

  288.            #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  289.             addMethod (@selector (supportedViewConfigurations:),    getSupportedViewConfigurations, "@@:@");

  290.             addMethod (@selector (selectViewConfiguration:),        selectViewConfiguration,        "v@:@");

  291.            #endif

  292. 

  293.             registerClass();

  294.         }

  295. 

  296.         //==============================================================================

  297.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  298.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  299. 

  300.         //==============================================================================

  301.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  302.         {

  303.             AUAudioUnit* self = _self;

  304. 

  305.             objc_super s = { self, [AUAudioUnit class] };

  306.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  307.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  308. 

  309.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  310. 

  311.             setThis (self, juceAU);

  312.             return self;

  313.         }

  314. 

  315.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  316.         {

  317.             AUAudioUnit* self = _self;

  318. 

  319.             objc_super s = { self, [AUAudioUnit class] };

  320.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  321.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  322. 

  323. 

  324.             setThis (self, juceAU);

  325.             return self;

  326.         }

  327. 

  328.         static void dealloc (id self, SEL)                                                          { delete _this (self); }

  329. 

  330.         //==============================================================================

  331.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  332. 

  333.         //==============================================================================

  334.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  335.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  336.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  337.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  338.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  339.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  340.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  341. 

  342.         //==============================================================================

  343.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  344.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  345. 

  346.         //==============================================================================

  347.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  348.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  349.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  350.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  351. 

  352.         //==============================================================================

  353.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  354.         static BOOL getSupportsMPE (id self, SEL)                                                   { return _this (self)->getSupportsMPE() ? YES : NO; }

  355.         static NSArray<NSString*>* getMIDIOutputNames (id self, SEL)                                { return _this (self)->getMIDIOutputNames(); }

  356. 

  357.         //==============================================================================

  358.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  359.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  360.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  361.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  362.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  363.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  364. 

  365.         //==============================================================================

  366.         static NSString* getContextName (id self, SEL)                                              { return _this (self)->getContextName(); }

  367.         static void setContextName (id self, SEL, NSString* str)                                    { return _this (self)->setContextName (str); }

  368. 

  369.         //==============================================================================

  370.        #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  371.         static NSIndexSet* getSupportedViewConfigurations (id self, SEL, NSArray<AUAudioUnitViewConfiguration*>* configs) { return _this (self)->getSupportedViewConfigurations (configs); }

  372.         static void selectViewConfiguration (id self, SEL, AUAudioUnitViewConfiguration* config)    { _this (self)->selectViewConfiguration (config); }

  373.        #endif

  374.     };

  375. 

  376.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  377. 

  378.     //==============================================================================

  379.     static Class audioUnitObjCClass;

  380. 

  381. protected:

  382.     AUAudioUnit* au;

  383. };

  384. 

  385. //==============================================================================

  386. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  387. 

  388. //==============================================================================

  389. //=========================== The actual AudioUnit =============================

  390. //==============================================================================

  391. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  392.                          public AudioProcessorListener,

  393.                          public AudioPlayHead

  394. {

  395. public:

  396.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  397.                      const AudioComponentDescription& descr,

  398.                      AudioComponentInstantiationOptions options,

  399.                      NSError** error)

  400.         : JuceAudioUnitv3Base (descr, options, error),

  401.           processorHolder (processor),

  402.           mapper (*processorHolder->get())

  403.     {

  404.         init();

  405.     }

  406. 

  407.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  408.         : JuceAudioUnitv3Base (audioUnit),

  409.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  410.           mapper (*processorHolder->get())

  411.     {

  412.         init();

  413.     }

  414. 

  415.     ~JuceAudioUnitv3()

  416.     {

  417.         auto& processor = getAudioProcessor();

  418.         processor.removeListener (this);

  419. 

  420.         removeEditor (processor);

  421. 

  422.         if (editorObserverToken != nullptr)

  423.         {

  424.             [paramTree removeParameterObserver: editorObserverToken];

  425.             editorObserverToken = nullptr;

  426.         }

  427.     }

  428. 

  429.     //==============================================================================

  430.     void init()

  431.     {

  432.         AudioProcessor& processor = getAudioProcessor();

  433.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  434. 

  435.        #ifdef JucePlugin_PreferredChannelConfigurations

  436.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  437.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  438. 

  439.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  440.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  441. 

  442.         Array<AUChannelInfo> channelInfos;

  443. 

  444.         for (int i = 0; i < numConfigs; ++i)

  445.         {

  446.             AUChannelInfo channelInfo;

  447. 

  448.             channelInfo.inChannels  = configs[i][0];

  449.             channelInfo.outChannels = configs[i][1];

  450. 

  451.             channelInfos.add (channelInfo);

  452.         }

  453.        #else

  454.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  455.        #endif

  456. 

  457.         processor.setPlayHead (this);

  458. 

  459.         totalInChannels  = processor.getTotalNumInputChannels();

  460.         totalOutChannels = processor.getTotalNumOutputChannels();

  461. 

  462.         {

  463.             channelCapabilities = [[NSMutableArray<NSNumber*> alloc] init];

  464. 

  465. 

  466.             for (int i = 0; i < channelInfos.size(); ++i)

  467.             {

  468.                 AUChannelInfo& info = channelInfos.getReference (i);

  469. 

  470.                 [channelCapabilities addObject: [NSNumber numberWithInteger: info.inChannels]];

  471.                 [channelCapabilities addObject: [NSNumber numberWithInteger: info.outChannels]];

  472.             }

  473.         }

  474. 

  475.         editorObserverToken = nullptr;

  476.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  477. 

  478.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  479.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  480.         processor.addListener (this);

  481. 

  482.         addParameters();

  483.         addPresets();

  484. 

  485.         addAudioUnitBusses (true);

  486.         addAudioUnitBusses (false);

  487.     }

  488. 

  489.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  490. 

  491.     //==============================================================================

  492.     void reset() override

  493.     {

  494.         midiMessages.clear();

  495.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  496.     }

  497. 

  498.     //==============================================================================

  499.     AUAudioUnitPreset* getCurrentPreset() override

  500.     {

  501.         const int n = static_cast<int> ([factoryPresets count]);

  502.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  503. 

  504.         if (idx < n)

  505.             return [factoryPresets objectAtIndex:static_cast<unsigned int> (idx)];

  506. 

  507.         return nullptr;

  508.     }

  509. 

  510.     void setCurrentPreset(AUAudioUnitPreset* preset) override

  511.     {

  512.         const int n = static_cast<int> ([factoryPresets count]);

  513.         const int idx = static_cast<int> ([preset number]);

  514. 

  515.         if (isPositiveAndBelow (idx, n))

  516.             getAudioProcessor().setCurrentProgram (idx);

  517.     }

  518. 

  519.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override

  520.     {

  521.         return factoryPresets;

  522.     }

  523. 

  524.     NSDictionary<NSString*, id>* getFullState() override

  525.     {

  526.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  527. 

  528.         {

  529.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  530. 

  531.             if (superRetval != nullptr)

  532.                 [retval addEntriesFromDictionary:superRetval];

  533.         }

  534. 

  535.         juce::MemoryBlock state;

  536.         getAudioProcessor().getCurrentProgramStateInformation (state);

  537. 

  538.         if (state.getSize() > 0)

  539.         {

  540.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  541.                                                       length: state.getSize()];

  542. 

  543.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  544. 

  545.             [retval setObject: ourState

  546.                        forKey: nsKey];

  547. 

  548.             [nsKey    release];

  549.             [ourState release];

  550.         }

  551. 

  552.         return [retval autorelease];

  553.     }

  554. 

  555.     void setFullState (NSDictionary<NSString*, id>* state) override

  556.     {

  557.         if (state == nullptr)

  558.             return;

  559. 

  560.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  561.         [modifiedState addEntriesFromDictionary: state];

  562. 

  563.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  564.         [modifiedState removeObjectForKey: nsPresetKey];

  565.         [nsPresetKey release];

  566. 

  567.         JuceAudioUnitv3Base::setFullState (modifiedState);

  568. 

  569.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  570.         NSObject* obj = [modifiedState objectForKey: nsKey];

  571.         [nsKey release];

  572. 

  573.         if (obj != nullptr)

  574.         {

  575.             if ([obj isKindOfClass:[NSData class]])

  576.             {

  577.                 NSData* data = reinterpret_cast<NSData*> (obj);

  578.                 const int numBytes = static_cast<int> ([data length]);

  579.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  580. 

  581.                 if (numBytes > 0)

  582.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  583.             }

  584.         }

  585. 

  586.         [modifiedState release];

  587.     }

  588. 

  589.     AUParameterTree* getParameterTree() override

  590.     {

  591.         return paramTree;

  592.     }

  593. 

  594.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  595.     {

  596.         const int n = static_cast<int> ([overviewParams count]);

  597. 

  598.         if (count >= n)

  599.             return overviewParams;

  600. 

  601.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams];

  602.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  603. 

  604.         return [retval autorelease];

  605.     }

  606. 

  607.     //==============================================================================

  608.     NSTimeInterval getLatency() override

  609.     {

  610.         auto& p = getAudioProcessor();

  611.         return p.getLatencySamples() / p.getSampleRate();

  612.     }

  613. 

  614.     NSTimeInterval getTailTime() override

  615.     {

  616.         return getAudioProcessor().getTailLengthSeconds();

  617.     }

  618. 

  619.     //==============================================================================

  620.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses;  }

  621.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses; }

  622.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities; }

  623. 

  624.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  625.     {

  626.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  627.         const int busIdx = static_cast<int> ([auBus index]);

  628.         const int newNumChannels = static_cast<int> ([format channelCount]);

  629. 

  630.         AudioProcessor& processor = getAudioProcessor();

  631. 

  632.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  633.         {

  634.           #ifdef JucePlugin_PreferredChannelConfigurations

  635.             ignoreUnused (bus);

  636. 

  637.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  638. 

  639.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  640.                 return false;

  641.           #else

  642.             const AVAudioChannelLayout* layout    = [format channelLayout];

  643.             const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  644. 

  645.             if (layoutTag != 0)

  646.             {

  647.                 AudioChannelSet newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  648. 

  649.                 if (newLayout.size() != newNumChannels)

  650.                     return false;

  651. 

  652.                 if (! bus->isLayoutSupported (newLayout))

  653.                     return false;

  654.             }

  655.             else

  656.             {

  657.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  658.                     return false;

  659.             }

  660.            #endif

  661. 

  662.             return true;

  663.         }

  664. 

  665.         return false;

  666.     }

  667. 

  668.     //==============================================================================

  669.     int getVirtualMIDICableCount() override

  670.     {

  671.        #if JucePlugin_WantsMidiInput

  672.         return 1;

  673.        #else

  674.         return 0;

  675.        #endif

  676.     }

  677. 

  678.     bool getSupportsMPE() override

  679.     {

  680.         return getAudioProcessor().supportsMPE();

  681.     }

  682. 

  683.     NSArray<NSString*>* getMIDIOutputNames() override

  684.     {

  685.        #if JucePlugin_ProducesMidiOutput

  686.         return @[@"MIDI Out"];

  687.        #else

  688.         return @[];

  689.        #endif

  690.     }

  691. 

  692.     //==============================================================================

  693.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  694.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  695.     void setRenderingOffline (bool offline) override

  696.     {

  697.         auto& processor = getAudioProcessor();

  698.         auto isCurrentlyNonRealtime = processor.isNonRealtime();

  699. 

  700.         if (isCurrentlyNonRealtime != offline)

  701.         {

  702.             ScopedLock callbackLock (processor.getCallbackLock());

  703. 

  704.             processor.setNonRealtime (offline);

  705.             processor.prepareToPlay (processor.getSampleRate(), processor.getBlockSize());

  706.         }

  707.     }

  708. 

  709.     //==============================================================================

  710.     NSString* getContextName() const    override              { return juceStringToNS (contextName); }

  711.     void setContextName (NSString* str) override

  712.     {

  713.         if (str != nullptr)

  714.         {

  715.             AudioProcessor::TrackProperties props;

  716.             props.name = nsStringToJuce (str);

  717. 

  718.             getAudioProcessor().updateTrackProperties (props);

  719.         }

  720.     }

  721. 

  722.     //==============================================================================

  723.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  724.     {

  725.         AudioProcessor& processor = getAudioProcessor();

  726.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  727. 

  728.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  729.             return false;

  730. 

  731.         if (outError != nullptr)

  732.             *outError = nullptr;

  733. 

  734.         AudioProcessor::BusesLayout layouts;

  735.         for (int dir = 0; dir < 2; ++dir)

  736.         {

  737.             const bool isInput = (dir == 0);

  738.             const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  739.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  740. 

  741.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  742.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  743. 

  744.             for (int busIdx = 0; busIdx < n; ++busIdx)

  745.             {

  746.                 AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx);

  747.                 AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  748. 

  749.                 AudioChannelSet newLayout;

  750.                 const AVAudioChannelLayout* layout    = [format channelLayout];

  751.                 const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  752. 

  753.                 if (layoutTag != 0)

  754.                     newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  755.                 else

  756.                     newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  757. 

  758.                 if (newLayout.isDisabled())

  759.                     return false;

  760. 

  761.                 channelSets.add (newLayout);

  762.             }

  763.         }

  764. 

  765.        #ifdef JucePlugin_PreferredChannelConfigurations

  766.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  767. 

  768.         if (! AudioProcessor::containsLayout (layouts, configs))

  769.         {

  770.             if (outError != nullptr)

  771.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  772. 

  773.             return false;

  774.         }

  775.        #endif

  776. 

  777.         if (! AudioUnitHelpers::setBusesLayout (&getAudioProcessor(), layouts))

  778.         {

  779.             if (outError != nullptr)

  780.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  781. 

  782.             return false;

  783.         }

  784. 

  785.         totalInChannels  = processor.getTotalNumInputChannels();

  786.         totalOutChannels = processor.getTotalNumOutputChannels();

  787. 

  788.         allocateBusBuffer (true);

  789.         allocateBusBuffer (false);

  790. 

  791.         mapper.alloc();

  792. 

  793.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  794. 

  795.         double sampleRate = (jmax (AudioUnitHelpers::getBusCount (&processor, true), AudioUnitHelpers::getBusCount (&processor, false)) > 0 ?

  796.                              [[[([inputBusses count] > 0 ? inputBusses : outputBusses) objectAtIndexedSubscript: 0] format] sampleRate] : 44100.0);

  797. 

  798.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  799.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  800. 

  801.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  802.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  803.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  804. 

  805.         reset();

  806. 

  807.         return true;

  808.     }

  809. 

  810.     void deallocateRenderResources() override

  811.     {

  812.         hostMusicalContextCallback = nullptr;

  813.         hostTransportStateCallback = nullptr;

  814. 

  815.         getAudioProcessor().releaseResources();

  816.         audioBuffer.release();

  817. 

  818.         inBusBuffers. clear();

  819.         outBusBuffers.clear();

  820. 

  821.         mapper.release();

  822. 

  823.         JuceAudioUnitv3Base::deallocateRenderResources();

  824.     }

  825. 

  826.     //==============================================================================

  827.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  828.     NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>* configs) override

  829.     {

  830.         auto supportedViewIndecies = [[NSMutableIndexSet alloc] init];

  831.         auto n = [configs count];

  832. 

  833.         if (auto* editor = getAudioProcessor().createEditorIfNeeded())

  834.         {

  835.             // If you hit this assertion then your plug-in's editor is reporting that it doesn't support

  836.             // any host MIDI controller configurations!

  837.             jassert (editor->supportsHostMIDIControllerPresence (true) || editor->supportsHostMIDIControllerPresence (false));

  838. 

  839.             for (auto i = 0u; i < n; ++i)

  840.             {

  841.                 if (auto* viewConfiguration = [configs objectAtIndex:i])

  842.                 {

  843.                     if (editor->supportsHostMIDIControllerPresence ([viewConfiguration hostHasController] == YES))

  844.                     {

  845.                         auto* constrainer = editor->getConstrainer();

  846.                         auto height = (int) [viewConfiguration height];

  847.                         auto width  = (int) [viewConfiguration width];

  848. 

  849.                         if (height <= constrainer->getMaximumHeight() && height >= constrainer->getMinimumHeight()

  850.                          && width  <= constrainer->getMaximumWidth()  && width  >= constrainer->getMinimumWidth())

  851.                             [supportedViewIndecies addIndex: i];

  852.                     }

  853.                 }

  854.             }

  855.         }

  856. 

  857.         return [supportedViewIndecies autorelease];

  858.     }

  859. 

  860.     void selectViewConfiguration (AUAudioUnitViewConfiguration* config) override

  861.     {

  862.         processorHolder->viewConfiguration = new AudioProcessorHolder::ViewConfig { [config width], [config height], [config hostHasController] == YES };

  863.     }

  864.    #endif

  865. 

  866.     //==============================================================================

  867.     void audioProcessorChanged (AudioProcessor* processor) override

  868.     {

  869.         ignoreUnused (processor);

  870. 

  871.         [au willChangeValueForKey: @"allParameterValues"];

  872.         addPresets();

  873.         [au didChangeValueForKey: @"allParameterValues"];

  874.     }

  875. 

  876.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  877.     {

  878.         if (isPositiveAndBelow (idx, getAudioProcessor().getNumParameters()))

  879.         {

  880.             if (AUParameter* param = [paramTree parameterWithAddress: getAUParameterAddressForIndex (idx)])

  881.             {

  882.                 if (editorObserverToken != nullptr)

  883.                     [param setValue: newValue  originator: editorObserverToken];

  884.                 else

  885.                     [param setValue: newValue];

  886.             }

  887.         }

  888.     }

  889. 

  890.     //==============================================================================

  891.     bool getCurrentPosition (CurrentPositionInfo& info) override

  892.     {

  893.         bool musicContextCallSucceeded = false;

  894.         bool transportStateCallSucceeded = false;

  895. 

  896.         info = lastAudioHead;

  897.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  898.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  899. 

  900.         switch (lastTimeStamp.mSMPTETime.mType)

  901.         {

  902.             case kSMPTETimeType2398:        info.frameRate = AudioPlayHead::fps23976; break;

  903.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24; break;

  904.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25; break;

  905.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997; break;

  906.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  907.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop; break;

  908.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30; break;

  909.             case kSMPTETimeType60Drop:      info.frameRate = AudioPlayHead::fps60drop; break;

  910.             case kSMPTETimeType60:          info.frameRate = AudioPlayHead::fps60; break;

  911.             default:                        info.frameRate = AudioPlayHead::fpsUnknown; break;

  912.         }

  913. 

  914.         double num;

  915.         NSInteger den;

  916.         NSInteger outDeltaSampleOffsetToNextBeat;

  917.         double outCurrentMeasureDownBeat, bpm;

  918.         double ppqPosition;

  919. 

  920.         if (hostMusicalContextCallback != nullptr)

  921.         {

  922.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  923. 

  924.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  925.             {

  926.                 musicContextCallSucceeded = true;

  927. 

  928.                 info.timeSigNumerator   = (int) num;

  929.                 info.timeSigDenominator = (int) den;

  930.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  931.                 info.bpm = bpm;

  932.                 info.ppqPosition = ppqPosition;

  933.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  934.             }

  935.         }

  936. 

  937.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  938.         AUHostTransportStateFlags flags;

  939. 

  940.         if (hostTransportStateCallback != nullptr)

  941.         {

  942.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  943. 

  944.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  945.             {

  946.                 transportStateCallSucceeded = true;

  947. 

  948.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  949.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  950.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  951.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  952.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  953.                 info.ppqLoopStart   = outCycleStartBeat;

  954.                 info.ppqLoopEnd     = outCycleEndBeat;

  955.             }

  956.         }

  957. 

  958.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  959.             lastAudioHead = info;

  960. 

  961.         return true;

  962.     }

  963. 

  964.     //==============================================================================

  965.     static void removeEditor (AudioProcessor& processor)

  966.     {

  967.         ScopedLock editorLock (processor.getCallbackLock());

  968. 

  969.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  970.         {

  971.             processor.editorBeingDeleted (editor);

  972.             delete editor;

  973.         }

  974.     }

  975. 

  976. private:

  977.     //==============================================================================

  978.     struct BusBuffer

  979.     {

  980.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  981.             : auBus (bus),

  982.               maxFrames (maxFramesPerBuffer),

  983.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  984.               isInterleaved ([[auBus format] isInterleaved])

  985.         {

  986.             alloc();

  987.         }

  988. 

  989.         //==============================================================================

  990.         void alloc()

  991.         {

  992.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  993.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  994.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  995.             jassert (bytes > 0);

  996. 

  997.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  998.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  999. 

  1000.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  1001.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  1002.         }

  1003. 

  1004.         void dealloc()

  1005.         {

  1006.             bufferList = nullptr;

  1007.             bufferListStorage.free();

  1008.             scratchBuffer.setSize (0, 0);

  1009.         }

  1010. 

  1011.         //==============================================================================

  1012.         int numChannels() const noexcept                { return numberOfChannels; }

  1013.         bool interleaved() const noexcept               { return isInterleaved; }

  1014.         AudioBufferList* get() const noexcept           { return bufferList; }

  1015. 

  1016.         //==============================================================================

  1017.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  1018.         {

  1019.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1020.             const bool isCompatible = isCompatibleWith (other);

  1021. 

  1022.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  1023. 

  1024.             for (int i = 0; i < numBuffers; ++i)

  1025.             {

  1026.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  1027.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  1028.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  1029.                                                               : scratchBuffer.getWritePointer (i));

  1030.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  1031.             }

  1032.         }

  1033. 

  1034.         //==============================================================================

  1035.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  1036.         {

  1037.             if (other == nullptr)

  1038.                 return false;

  1039. 

  1040.             if (other->mNumberBuffers > 0)

  1041.             {

  1042.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  1043.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  1044.                                                                              : other->mNumberBuffers);

  1045. 

  1046.                 return otherInterleaved == isInterleaved

  1047.                     && numberOfChannels == otherChannels;

  1048.             }

  1049. 

  1050.             return numberOfChannels == 0;

  1051.         }

  1052. 

  1053.     private:

  1054.         AUAudioUnitBus* auBus;

  1055.         HeapBlock<char> bufferListStorage;

  1056.         AudioBufferList* bufferList = nullptr;

  1057.         int maxFrames, numberOfChannels;

  1058.         bool isInterleaved;

  1059.         AudioBuffer<float> scratchBuffer;

  1060.     };

  1061. 

  1062.     //==============================================================================

  1063.     void addAudioUnitBusses (bool isInput)

  1064.     {

  1065.         ScopedPointer<NSMutableArray<AUAudioUnitBus*>> array = [[NSMutableArray<AUAudioUnitBus*> alloc] init];

  1066.         AudioProcessor& processor = getAudioProcessor();

  1067.         const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  1068. 

  1069.         for (int i = 0; i < n; ++i)

  1070.         {

  1071.             ScopedPointer<AUAudioUnitBus> audioUnitBus;

  1072. 

  1073.             {

  1074.                 ScopedPointer<AVAudioFormat> defaultFormat = [[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  1075.                                                                                                             channels: static_cast<AVAudioChannelCount> (processor.getChannelCountOfBus (isInput, i))];

  1076. 

  1077.                 audioUnitBus = [[AUAudioUnitBus alloc] initWithFormat: defaultFormat

  1078.                                                                 error: nullptr];

  1079.             }

  1080. 

  1081.             [array addObject: audioUnitBus];

  1082.         }

  1083. 

  1084.         (isInput ? inputBusses : outputBusses) = [[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  1085.                                                                                         busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  1086.                                                                                          busses: array];

  1087.     }

  1088. 

  1089.     void addParameters()

  1090.     {

  1091.         ScopedPointer<NSMutableArray<AUParameterNode*>> params = [[NSMutableArray<AUParameterNode*> alloc] init];

  1092. 

  1093.         paramObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  1094.         paramProvider = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  1095. 

  1096.         overviewParams = [[NSMutableArray<NSNumber*> alloc] init];

  1097. 

  1098.         auto& processor = getAudioProcessor();

  1099.         const int n = processor.getNumParameters();

  1100. 

  1101.        #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1102.         // check if all parameters are managed?

  1103.         usingManagedParameter = (processor.getParameters().size() == processor.getNumParameters());

  1104.        #endif

  1105. 

  1106.         for (int idx = 0; idx < n; ++idx)

  1107.         {

  1108.             const String identifier (idx);

  1109.             const String name = processor.getParameterName (idx);

  1110. 

  1111.             AudioUnitParameterUnit unit = kAudioUnitParameterUnit_Generic;

  1112.             AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  1113.                                                       | kAudioUnitParameterFlag_IsReadable

  1114.                                                       | kAudioUnitParameterFlag_HasCFNameString

  1115.                                                       | kAudioUnitParameterFlag_ValuesHaveStrings);

  1116. 

  1117.            #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1118.             flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  1119.            #endif

  1120. 

  1121.             // set whether the param is automatable (unnamed parameters aren't allowed to be automated)

  1122.             if (name.isEmpty() || ! processor.isParameterAutomatable (idx))

  1123.                 flags |= kAudioUnitParameterFlag_NonRealTime;

  1124. 

  1125.             if (processor.isMetaParameter (idx))

  1126.                 flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  1127. 

  1128.             // is this a meter?

  1129.             if (((processor.getParameterCategory (idx) & 0xffff0000) >> 16) == 2)

  1130.             {

  1131.                 flags &= ~kAudioUnitParameterFlag_IsWritable;

  1132.                 flags |= kAudioUnitParameterFlag_MeterReadOnly | kAudioUnitParameterFlag_DisplayLogarithmic;

  1133.                 unit = kAudioUnitParameterUnit_LinearGain;

  1134.             }

  1135. 

  1136.            #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1137.             AUParameterAddress address = static_cast<AUParameterAddress> (idx);

  1138.            #else

  1139.             AUParameterAddress address = generateAUParameterAddressForIndex (idx);

  1140. 

  1141.             // Consider yourself very unlucky if you hit this assertion. The hash code of your

  1142.             // parameter ids are not unique.

  1143.             jassert (! paramMap.contains (static_cast<int64> (address)));

  1144. 

  1145.             paramAddresses.add (address);

  1146.             paramMap.set (static_cast<int64> (address), idx);

  1147.           #endif

  1148. 

  1149.             // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1150. 

  1151.             ScopedPointer<AUParameter> param = [[AUParameterTree createParameterWithIdentifier: juceStringToNS (identifier)

  1152.                                                                                           name: juceStringToNS (name)

  1153.                                                                                        address: address

  1154.                                                                                            min: 0.0f

  1155.                                                                                            max: 1.0f

  1156.                                                                                           unit: unit

  1157.                                                                                       unitName: nullptr

  1158.                                                                                          flags: flags

  1159.                                                                                   valueStrings: nullptr

  1160.                                                                            dependentParameters: nullptr] retain];

  1161. 

  1162.             [params addObject: param];

  1163.             [overviewParams addObject: [NSNumber numberWithUnsignedLongLong:address]];

  1164.         }

  1165. 

  1166.         // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1167.         paramTree = [[AUParameterTree createTreeWithChildren: params] retain];

  1168. 

  1169.         [paramTree setImplementorValueObserver: paramObserver];

  1170.         [paramTree setImplementorValueProvider: paramProvider];

  1171. 

  1172.         if (processor.hasEditor())

  1173.         {

  1174.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  1175.             editorObserverToken = [paramTree tokenByAddingParameterObserver: editorParamObserver];

  1176.         }

  1177.     }

  1178. 

  1179.     void addPresets()

  1180.     {

  1181.         factoryPresets = [[NSMutableArray<AUAudioUnitPreset*> alloc] init];

  1182. 

  1183.         const int n = getAudioProcessor().getNumPrograms();

  1184. 

  1185.         for (int idx = 0; idx < n; ++idx)

  1186.         {

  1187.             String name = getAudioProcessor().getProgramName (idx);

  1188. 

  1189.             ScopedPointer<AUAudioUnitPreset> preset = [[AUAudioUnitPreset alloc] init];

  1190.             [preset setName: juceStringToNS (name)];

  1191.             [preset setNumber: static_cast<NSInteger> (idx)];

  1192. 

  1193.             [factoryPresets addObject: preset];

  1194.         }

  1195.     }

  1196. 

  1197.     //==============================================================================

  1198.     void allocateBusBuffer (bool isInput)

  1199.     {

  1200.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  1201.         busBuffers.clear();

  1202. 

  1203.         const int n = AudioUnitHelpers::getBusCount (&getAudioProcessor(), isInput);

  1204.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1205. 

  1206.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1207.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses : outputBusses) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1208.                                            static_cast<int> (maxFrames)));

  1209.     }

  1210. 

  1211.     //==============================================================================

  1212.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1213.     {

  1214.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1215.         {

  1216.             switch (event->head.eventType)

  1217.             {

  1218.                 case AURenderEventMIDI:

  1219.                 {

  1220.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1221.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1222.                 }

  1223.                 break;

  1224. 

  1225.                 case AURenderEventParameter:

  1226.                 case AURenderEventParameterRamp:

  1227.                 {

  1228.                     const AUParameterEvent& paramEvent = event->parameter;

  1229.                     const int idx = getJuceParameterIndexForAUAddress (paramEvent.parameterAddress);

  1230. 

  1231.                     if (isPositiveAndBelow (idx, numParams))

  1232.                         getAudioProcessor().setParameter (idx, paramEvent.value);

  1233.                 }

  1234.                 break;

  1235. 

  1236.                 default:

  1237.                     break;

  1238.             }

  1239.         }

  1240.     }

  1241. 

  1242.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1243.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1244.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1245.     {

  1246.         auto& processor = getAudioProcessor();

  1247.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1248. 

  1249.         // process params

  1250.         const int numParams = processor.getNumParameters();

  1251.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1252. 

  1253.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1254.         {

  1255.             lastTimeStamp = *timestamp;

  1256. 

  1257.             const int numInputBuses  = inBusBuffers. size();

  1258.             const int numOutputBuses = outBusBuffers.size();

  1259. 

  1260.             // prepare buffers

  1261.             {

  1262.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1263.                 {

  1264.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1265.                      const bool canUseDirectOutput =

  1266.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1267. 

  1268.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1269.                 }

  1270. 

  1271.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1272.                 {

  1273.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1274.                     busBuffer.prepare (frameCount, busIdx < numOutputBuses ? outBusBuffers[busIdx]->get() : nullptr);

  1275.                 }

  1276. 

  1277.                 audioBuffer.reset();

  1278.             }

  1279. 

  1280.             // pull inputs

  1281.             {

  1282.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1283.                 {

  1284.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1285.                     AudioBufferList* buffer = busBuffer.get();

  1286. 

  1287.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1288.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1289. 

  1290.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1291.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1292.                 }

  1293.             }

  1294. 

  1295.             // set buffer pointer to minimize copying

  1296.             {

  1297.                 int chIdx = 0;

  1298. 

  1299.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1300.                 {

  1301.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1302.                     AudioBufferList* buffer = busBuffer.get();

  1303. 

  1304.                     const bool interleaved = busBuffer.interleaved();

  1305.                     const int numChannels = busBuffer.numChannels();

  1306. 

  1307.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1308. 

  1309.                     for (int ch = 0; ch < numChannels; ++ch)

  1310.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1311.                 }

  1312. 

  1313.                 // use input pointers on remaining channels

  1314. 

  1315.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1316.                 {

  1317.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1318. 

  1319.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1320.                     AudioBufferList* buffer = busBuffer.get();

  1321. 

  1322.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1323.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1324.                 }

  1325.             }

  1326. 

  1327.             // copy input

  1328.             {

  1329.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1330.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1331. 

  1332.                 // clear remaining channels

  1333.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1334.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1335.             }

  1336. 

  1337.             // process audio

  1338.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1339. 

  1340.             // send MIDI

  1341.            #if JucePlugin_ProducesMidiOutput && JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  1342.             auto midiOut = [au MIDIOutputEventBlock];

  1343.             MidiMessage msg;

  1344.             int samplePosition;

  1345. 

  1346.             for (MidiBuffer::Iterator it (midiMessages); it.getNextEvent (msg, samplePosition);)

  1347.                 midiOut (samplePosition, 0, msg.getRawDataSize(), msg.getRawData());

  1348.            #endif

  1349. 

  1350.             midiMessages.clear();

  1351.         }

  1352. 

  1353.         // copy back

  1354.         audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1355.                          mapper.get (false, (int) outputBusNumber));

  1356. 

  1357.         return noErr;

  1358.     }

  1359. 

  1360.     void processBlock (AudioBuffer<float>& buffer, MidiBuffer& midiBuffer) noexcept

  1361.     {

  1362.         auto& processor = getAudioProcessor();

  1363.         const ScopedLock sl (processor.getCallbackLock());

  1364. 

  1365.         if (processor.isSuspended())

  1366.             buffer.clear();

  1367.         else if ([au shouldBypassEffect])

  1368.             processor.processBlockBypassed (buffer, midiBuffer);

  1369.         else

  1370.             processor.processBlock (buffer, midiBuffer);

  1371.     }

  1372. 

  1373.     //==============================================================================

  1374.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1375.     {

  1376.         if (param != nullptr)

  1377.         {

  1378.             const int idx = getJuceParameterIndexForAUAddress ([param address]);

  1379.             auto& processor = getAudioProcessor();

  1380. 

  1381.             if (isPositiveAndBelow (idx, processor.getNumParameters()))

  1382.                 processor.setParameter (idx, value);

  1383.         }

  1384.     }

  1385. 

  1386.     AUValue getValue (AUParameter* param)

  1387.     {

  1388.         if (param != nullptr)

  1389.         {

  1390.             const int idx = getJuceParameterIndexForAUAddress ([param address]);

  1391.             auto& processor = getAudioProcessor();

  1392. 

  1393.             if (isPositiveAndBelow (idx, processor.getNumParameters()))

  1394.                 return processor.getParameter (idx);

  1395.         }

  1396. 

  1397.         return 0;

  1398.     }

  1399. 

  1400.     void valueChangedForObserver(AUParameterAddress, AUValue)

  1401.     {

  1402.         // this will have already been handled by valueChangedFromHost

  1403.     }

  1404. 

  1405.     //==============================================================================

  1406.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1407.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept     { return static_cast<AUParameterAddress> (paramIndex); }

  1408.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept    { return static_cast<int> (address); }

  1409.    #else

  1410.     AUParameterAddress generateAUParameterAddressForIndex (int paramIndex) const

  1411.     {

  1412.         auto& processor = getAudioProcessor();

  1413.         const int n = processor.getNumParameters();

  1414. 

  1415.         if (isPositiveAndBelow (paramIndex, n))

  1416.         {

  1417.             const String& juceParamID = processor.getParameterID (paramIndex);

  1418.             return usingManagedParameter ? static_cast<AUParameterAddress> (juceParamID.hashCode64())

  1419.                                          : static_cast<AUParameterAddress> (juceParamID.getIntValue());

  1420.         }

  1421. 

  1422.         return static_cast<AUParameterAddress> (-1);

  1423.     }

  1424. 

  1425.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1426.     {

  1427.         return usingManagedParameter ? paramAddresses.getReference (paramIndex)

  1428.                                      : static_cast<AUParameterAddress> (paramIndex);

  1429.     }

  1430. 

  1431.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1432.     {

  1433.         return usingManagedParameter ? paramMap[static_cast<int64> (address)]

  1434.                                      : static_cast<int> (address);

  1435.     }

  1436.    #endif

  1437. 

  1438.     //==============================================================================

  1439.     static const double kDefaultSampleRate;

  1440. 

  1441.     AudioProcessorHolder::Ptr processorHolder;

  1442. 

  1443.     int totalInChannels, totalOutChannels;

  1444. 

  1445.     ScopedPointer<AUAudioUnitBusArray> inputBusses;

  1446.     ScopedPointer<AUAudioUnitBusArray> outputBusses;

  1447. 

  1448.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1449.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1450. 

  1451.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1452.     bool usingManagedParameter;

  1453.     Array<AUParameterAddress> paramAddresses;

  1454.     HashMap<int64, int> paramMap;

  1455.    #endif

  1456. 

  1457.     // to avoid recursion on parameter changes, we need to add an

  1458.     // editor observer to do the parameter changes

  1459.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1460.     AUParameterObserverToken editorObserverToken;

  1461. 

  1462.     ScopedPointer<AUParameterTree> paramTree;

  1463.     ScopedPointer<NSMutableArray<NSNumber*>> overviewParams;

  1464.     ScopedPointer<NSMutableArray<NSNumber*>> channelCapabilities;

  1465. 

  1466.     ScopedPointer<NSMutableArray<AUAudioUnitPreset*>> factoryPresets;

  1467. 

  1468.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1469. 

  1470.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1471.     AudioUnitHelpers::ChannelRemapper mapper;

  1472. 

  1473.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1474.     MidiBuffer midiMessages;

  1475. 

  1476.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1477.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1478. 

  1479.     AudioTimeStamp lastTimeStamp;

  1480.     CurrentPositionInfo lastAudioHead;

  1481. 

  1482.     String contextName;

  1483. };

  1484. 

  1485. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1486. 

  1487. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1488. {

  1489.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1490.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1491. }

  1492. 

  1493. //==============================================================================

  1494. class JuceAUViewController

  1495. {

  1496. public:

  1497.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1498.         : myself (p)

  1499.     {

  1500.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1501. 

  1502.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1503.         initialiseJuce_GUI();

  1504.     }

  1505. 

  1506.     ~JuceAUViewController()

  1507.     {

  1508.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1509. 

  1510.         if (processorHolder != nullptr)

  1511.             JuceAudioUnitv3::removeEditor (getAudioProcessor());

  1512.     }

  1513. 

  1514.     //==============================================================================

  1515.     void loadView()

  1516.     {

  1517.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1518. 

  1519.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1520.         {

  1521.             processorHolder = new AudioProcessorHolder (p);

  1522.             auto& processor = getAudioProcessor();

  1523. 

  1524.             if (processor.hasEditor())

  1525.             {

  1526.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1527.                 {

  1528.                     preferredSize = editor->getBounds();

  1529. 

  1530.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1531.                     [myself setView: view];

  1532. 

  1533.                     editor->setVisible (true);

  1534.                     editor->addToDesktop (0, view);

  1535.                 }

  1536.             }

  1537.         }

  1538.     }

  1539. 

  1540.     void viewDidLayoutSubviews()

  1541.     {

  1542.         if (processorHolder != nullptr && [myself view] != nullptr)

  1543.         {

  1544.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1545.             {

  1546.                 if (processorHolder->viewConfiguration != nullptr)

  1547.                     editor->hostMIDIControllerIsAvailable (processorHolder->viewConfiguration->hostHasMIDIController);

  1548. 

  1549.                 editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1550. 

  1551.                 if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1552.                 {

  1553.                    #if JUCE_IOS

  1554.                     [peerView setNeedsDisplay];

  1555.                    #else

  1556.                     [peerView setNeedsDisplay: YES];

  1557.                    #endif

  1558.                 }

  1559.             }

  1560.         }

  1561.     }

  1562. 

  1563.     CGSize getPreferredContentSize() const

  1564.     {

  1565.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1566.                            static_cast<float> (preferredSize.getHeight()));

  1567.     }

  1568. 

  1569.     //==============================================================================

  1570.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1571.     {

  1572.         AUAudioUnit* retval = nil;

  1573. 

  1574.         if (! MessageManager::getInstance()->isThisTheMessageThread())

  1575.         {

  1576.             WaitableEvent creationEvent;

  1577. 

  1578.             // AUv3 headers say that we may block this thread and that the message thread is guaranteed

  1579.             // to be unblocked

  1580.             struct AUCreator  : public CallbackMessage

  1581.             {

  1582.                 JuceAUViewController& owner;

  1583.                 AudioComponentDescription pDescr;

  1584.                 NSError** pError;

  1585.                 AUAudioUnit*& outAU;

  1586.                 WaitableEvent& e;

  1587. 

  1588.                 AUCreator (JuceAUViewController& parent, const AudioComponentDescription& paramDescr, NSError** paramError,

  1589.                            AUAudioUnit*& outputAU, WaitableEvent& event)

  1590.                     : owner (parent), pDescr (paramDescr), pError (paramError), outAU (outputAU), e (event)

  1591.                 {}

  1592. 

  1593.                 void messageCallback() override

  1594.                 {

  1595.                     outAU = owner.createAudioUnitOnMessageThread (pDescr, pError);

  1596.                     e.signal();

  1597.                 }

  1598.             };

  1599. 

  1600.             (new AUCreator (*this, descr, error, retval, creationEvent))->post();

  1601.             creationEvent.wait (-1);

  1602.         }

  1603.         else

  1604.             retval = createAudioUnitOnMessageThread (descr, error);

  1605. 

  1606.         return [retval autorelease];

  1607.     }

  1608. 

  1609. private:

  1610.     //==============================================================================

  1611.     AUViewController<AUAudioUnitFactory>* myself;

  1612.     AudioProcessorHolder::Ptr processorHolder = nullptr;

  1613.     Rectangle<int> preferredSize { 1, 1 };

  1614. 

  1615.     //==============================================================================

  1616.     AUAudioUnit* createAudioUnitOnMessageThread (const AudioComponentDescription& descr, NSError** error)

  1617.     {

  1618.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1619. 

  1620.         [myself view];  // this will call [view load] and ensure that the AudioProcessor has been instantiated

  1621. 

  1622.         if (processorHolder == nullptr)

  1623.             return nullptr;

  1624. 

  1625.         return (new JuceAudioUnitv3 (processorHolder, descr, 0, error))->getAudioUnit();

  1626.     }

  1627. 

  1628.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder; }

  1629. };

  1630. 

  1631. //==============================================================================

  1632. // necessary glue code

  1633. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  1634. @end

  1635. 

  1636. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  1637. {

  1638.     ScopedPointer<JuceAUViewController> cpp;

  1639. }

  1640. 

  1641. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp = new JuceAUViewController (self); return self;}

  1642. - (void) loadView               { cpp->loadView(); }

  1643. - (AUAudioUnit *)createAudioUnitWithComponentDescription:(AudioComponentDescription)desc error:(NSError **)error { return cpp->createAudioUnit (desc, error); }

  1644. - (CGSize) preferredContentSize { return cpp->getPreferredContentSize(); }

  1645. - (void)viewDidLayoutSubviews   { return cpp->viewDidLayoutSubviews(); }

  1646. @end

  1647. 

  1648. //==============================================================================

  1649. #if JUCE_IOS

  1650. bool JUCE_CALLTYPE juce_isInterAppAudioConnected() { return false; }

  1651. void JUCE_CALLTYPE juce_switchToHostApplication()  {}

  1652. #if JUCE_MODULE_AVAILABLE_juce_gui_basics

  1653. Image JUCE_CALLTYPE juce_getIAAHostIcon (int)      { return Image(); }

  1654. #endif

  1655. #endif

  1656. 

  1657. #pragma clang diagnostic pop

  1658. #endif