DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
11577 Commits
9 Branches
479MB
Tree: a6bfcc6427
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'a6bfcc6427'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

1953 lines
82KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2020 - Raw Material Software Limited

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 6 End-User License

  11.    Agreement and JUCE Privacy Policy (both effective as of the 16th June 2020).

  12. 

  13.    End User License Agreement: www.juce.com/juce-6-licence

  14.    Privacy Policy: www.juce.com/juce-privacy-policy

  15. 

  16.    Or: You may also use this code under the terms of the GPL v3 (see

  17.    www.gnu.org/licenses).

  18. 

  19.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  20.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  21.    DISCLAIMED.

  22. 

  23.   ==============================================================================

  24. */

  25. 

  26. #include <juce_core/system/juce_TargetPlatform.h>

  27. #include "../utility/juce_CheckSettingMacros.h"

  28. 

  29. #if JucePlugin_Build_AUv3

  30. 

  31. #if JUCE_MAC

  32.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  33.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  34.  #endif

  35.  #if (defined MAC_OS_X_VERSION_10_13) && (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_13)

  36.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  37.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  38.  #endif

  39. #endif

  40. 

  41. #if JUCE_IOS

  42.  #if (defined __IPHONE_11_0) && (__IPHONE_OS_VERSION_MIN_REQUIRED >= __IPHONE_11_0)

  43.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  44.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  45.  #endif

  46. #endif

  47. 

  48. #ifndef __OBJC2__

  49.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  50. #endif

  51. 

  52. #define JUCE_CORE_INCLUDE_OBJC_HELPERS 1

  53. 

  54. #include "../utility/juce_IncludeSystemHeaders.h"

  55. #include "../utility/juce_IncludeModuleHeaders.h"

  56. 

  57. #import <CoreAudioKit/CoreAudioKit.h>

  58. #import <AudioToolbox/AudioToolbox.h>

  59. #import <AVFoundation/AVFoundation.h>

  60. 

  61. #include <juce_graphics/native/juce_mac_CoreGraphicsHelpers.h>

  62. #include <juce_audio_basics/native/juce_mac_CoreAudioLayouts.h>

  63. #include <juce_audio_processors/format_types/juce_LegacyAudioParameter.cpp>

  64. #include <juce_audio_processors/format_types/juce_AU_Shared.h>

  65. 

  66. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  67. 

  68. #if JUCE_IOS

  69.  #define JUCE_IOS_MAC_VIEW  UIView

  70. #else

  71.  #define JUCE_IOS_MAC_VIEW  NSView

  72. #endif

  73. 

  74. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  75. 

  76. #include <future>

  77. 

  78. JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wnullability-completeness")

  79. 

  80. using namespace juce;

  81. 

  82. struct AudioProcessorHolder  : public ReferenceCountedObject

  83. {

  84.     AudioProcessorHolder() {}

  85.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  86.     AudioProcessor& operator*() noexcept        { return *processor; }

  87.     AudioProcessor* operator->() noexcept       { return processor.get(); }

  88.     AudioProcessor* get() noexcept              { return processor.get(); }

  89. 

  90.     struct ViewConfig

  91.     {

  92.         double width;

  93.         double height;

  94.         bool hostHasMIDIController;

  95.     };

  96. 

  97.     std::unique_ptr<ViewConfig> viewConfiguration;

  98. 

  99.     using Ptr = ReferenceCountedObjectPtr<AudioProcessorHolder>;

  100. 

  101. private:

  102.     std::unique_ptr<AudioProcessor> processor;

  103. 

  104.     AudioProcessorHolder& operator= (AudioProcessor*) = delete;

  105.     AudioProcessorHolder (AudioProcessorHolder&) = delete;

  106.     AudioProcessorHolder& operator= (AudioProcessorHolder&) = delete;

  107. };

  108. 

  109. //==============================================================================

  110. class JuceAudioUnitv3Base

  111. {

  112. public:

  113.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  114.                          AudioComponentInstantiationOptions options,

  115.                          NSError** error)

  116.         JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wobjc-method-access")

  117.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  118.                                                                         options: options

  119.                                                                           error: error

  120.                                                                       juceClass: this])

  121.         JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  122.     {}

  123. 

  124.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  125.     {

  126.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  127.         initialiseJuce_GUI();

  128.     }

  129. 

  130.     virtual ~JuceAudioUnitv3Base() = default;

  131. 

  132.     //==============================================================================

  133.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  134. 

  135.     //==============================================================================

  136.     virtual void reset()                                                   = 0;

  137. 

  138.     //==============================================================================

  139.     virtual AUAudioUnitPreset* getCurrentPreset()                          = 0;

  140.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      = 0;

  141.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()               = 0;

  142. 

  143.     virtual NSDictionary<NSString*, id>* getFullState()

  144.     {

  145.         return ObjCMsgSendSuper<AUAudioUnit, NSDictionary<NSString*, id>*> (getAudioUnit(), @selector (fullState));

  146.     }

  147. 

  148.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  149.     {

  150.         ObjCMsgSendSuper<AUAudioUnit, void> (getAudioUnit(), @selector (setFullState:), state);

  151.     }

  152. 

  153.     virtual AUParameterTree* getParameterTree()                            = 0;

  154.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)       = 0;

  155. 

  156.     //==============================================================================

  157.     virtual NSTimeInterval getLatency()                                    = 0;

  158.     virtual NSTimeInterval getTailTime()                                   = 0;

  159. 

  160.     //==============================================================================

  161.     virtual AUAudioUnitBusArray* getInputBusses()                          = 0;

  162.     virtual AUAudioUnitBusArray* getOutputBusses()                         = 0;

  163.     virtual NSArray<NSNumber*>* getChannelCapabilities()                   = 0;

  164.     virtual bool shouldChangeToFormat (AVAudioFormat*, AUAudioUnitBus*)    = 0;

  165. 

  166.     //==============================================================================

  167.     virtual int getVirtualMIDICableCount()                                 = 0;

  168.     virtual bool getSupportsMPE()                                          = 0;

  169.     virtual NSArray<NSString*>* getMIDIOutputNames()                       = 0;

  170. 

  171.     //==============================================================================

  172.     virtual AUInternalRenderBlock getInternalRenderBlock()                 = 0;

  173.     virtual bool getCanProcessInPlace()                                    { return false; }

  174.     virtual bool getRenderingOffline()                                     = 0;

  175.     virtual void setRenderingOffline (bool offline)                        = 0;

  176. 

  177.     virtual bool getShouldBypassEffect()

  178.     {

  179.         return (ObjCMsgSendSuper<AUAudioUnit, BOOL> (getAudioUnit(), @selector (shouldBypassEffect)) == YES);

  180.     }

  181. 

  182.     virtual void setShouldBypassEffect (bool shouldBypass)

  183.     {

  184.         ObjCMsgSendSuper<AUAudioUnit, void> (getAudioUnit(), @selector (setShouldBypassEffect:), shouldBypass ? YES : NO);

  185.     }

  186. 

  187.     //==============================================================================

  188.     virtual NSString* getContextName()      const                          = 0;

  189.     virtual void setContextName (NSString*)                                = 0;

  190. 

  191.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  192.     {

  193.         return (ObjCMsgSendSuper<AUAudioUnit, BOOL, NSError**> (getAudioUnit(), @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  194.     }

  195. 

  196.     virtual void deallocateRenderResources()

  197.     {

  198.         ObjCMsgSendSuper<AUAudioUnit, void> (getAudioUnit(), @selector (deallocateRenderResources));

  199.     }

  200. 

  201.     //==============================================================================

  202.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  203.     virtual NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>*) = 0;

  204.     virtual void selectViewConfiguration (AUAudioUnitViewConfiguration*)   = 0;

  205.    #endif

  206. 

  207. private:

  208.     struct Class  : public ObjCClass<AUAudioUnit>

  209.     {

  210.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  211.         {

  212.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  213. 

  214.             JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wundeclared-selector")

  215.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  216.                        initWithComponentDescriptionAndJuceClass, "@@:",

  217.                        @encode (AudioComponentDescription),

  218.                        @encode (AudioComponentInstantiationOptions), "^@@");

  219.             JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  220. 

  221.             addMethod (@selector (initWithComponentDescription:options:error:),

  222.                        initWithComponentDescription, "@@:",

  223.                        @encode (AudioComponentDescription),

  224.                        @encode (AudioComponentInstantiationOptions), "^@");

  225. 

  226.             addMethod (@selector (dealloc),                         dealloc,                        "v@:");

  227. 

  228.             //==============================================================================

  229.             addMethod (@selector (reset),                           reset,                          "v@:");

  230. 

  231.             //==============================================================================

  232.             addMethod (@selector (currentPreset),                   getCurrentPreset,               "@@:");

  233.             addMethod (@selector (setCurrentPreset:),               setCurrentPreset,               "v@:@");

  234.             addMethod (@selector (factoryPresets),                  getFactoryPresets,              "@@:");

  235.             addMethod (@selector (fullState),                       getFullState,                   "@@:");

  236.             addMethod (@selector (setFullState:),                   setFullState,                   "v@:@");

  237.             addMethod (@selector (parameterTree),                   getParameterTree,               "@@:");

  238.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  239. 

  240.             //==============================================================================

  241.             addMethod (@selector (latency),                         getLatency,                     @encode (NSTimeInterval), "@:");

  242.             addMethod (@selector (tailTime),                        getTailTime,                    @encode (NSTimeInterval),  "@:");

  243. 

  244.             //==============================================================================

  245.             addMethod (@selector (inputBusses),                     getInputBusses,                 "@@:");

  246.             addMethod (@selector (outputBusses),                    getOutputBusses,                "@@:");

  247.             addMethod (@selector (channelCapabilities),             getChannelCapabilities,         "@@:");

  248.             addMethod (@selector (shouldChangeToFormat:forBus:),    shouldChangeToFormat,           "B@:@@");

  249. 

  250.             //==============================================================================

  251.             addMethod (@selector (virtualMIDICableCount),           getVirtualMIDICableCount,       @encode (NSInteger), "@:");

  252.             addMethod (@selector (supportsMPE),                     getSupportsMPE,                 @encode (BOOL),      "@:");

  253. 

  254.            #if JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  255.             addMethod (@selector (MIDIOutputNames),                 getMIDIOutputNames,             "@@:");

  256.            #endif

  257. 

  258.             //==============================================================================

  259.             addMethod (@selector (internalRenderBlock),             getInternalRenderBlock,         @encode (AUInternalRenderBlock), "@:");

  260.             addMethod (@selector (canProcessInPlace),               getCanProcessInPlace,           @encode (BOOL), "@:");

  261.             addMethod (@selector (isRenderingOffline),              getRenderingOffline,            @encode (BOOL),  "@:");

  262.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  263.             addMethod (@selector (shouldBypassEffect),              getShouldBypassEffect,          @encode (BOOL),  "@:");

  264.             addMethod (@selector (setShouldBypassEffect:),          setShouldBypassEffect,          "v@:", @encode (BOOL));

  265.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "B@:^@");

  266.             addMethod (@selector (deallocateRenderResources),       deallocateRenderResources,      "v@:");

  267. 

  268.             //==============================================================================

  269.             addMethod (@selector (contextName),                     getContextName,                 "@@:");

  270.             addMethod (@selector (setContextName:),                  setContextName,                 "v@:@");

  271. 

  272.             //==============================================================================

  273.            #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  274.             addMethod (@selector (supportedViewConfigurations:),    getSupportedViewConfigurations, "@@:@");

  275.             addMethod (@selector (selectViewConfiguration:),        selectViewConfiguration,        "v@:@");

  276.            #endif

  277. 

  278.             registerClass();

  279.         }

  280. 

  281.         //==============================================================================

  282.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  283.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  284. 

  285.         //==============================================================================

  286.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  287.         {

  288.             AUAudioUnit* self = _self;

  289. 

  290.             self = ObjCMsgSendSuper<AUAudioUnit, AUAudioUnit*, AudioComponentDescription,

  291.                                     AudioComponentInstantiationOptions, NSError**> (self, @selector (initWithComponentDescription:options:error:), descr, options, error);

  292. 

  293.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  294. 

  295.             setThis (self, juceAU);

  296.             return self;

  297.         }

  298. 

  299.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  300.         {

  301.             AUAudioUnit* self = _self;

  302. 

  303.             self = ObjCMsgSendSuper<AUAudioUnit, AUAudioUnit*, AudioComponentDescription,

  304.                                     AudioComponentInstantiationOptions, NSError**> (self, @selector(initWithComponentDescription:options:error:), descr, options, error);

  305. 

  306. 

  307.             setThis (self, juceAU);

  308.             return self;

  309.         }

  310. 

  311.         static void dealloc (id self, SEL)

  312.         {

  313.             if (! MessageManager::getInstance()->isThisTheMessageThread())

  314.             {

  315.                 WaitableEvent deletionEvent;

  316. 

  317.                 struct AUDeleter  : public CallbackMessage

  318.                 {

  319.                     AUDeleter (id selfToDelete, WaitableEvent& event)

  320.                         : parentSelf (selfToDelete), parentDeletionEvent (event)

  321.                     {

  322.                     }

  323. 

  324.                     void messageCallback() override

  325.                     {

  326.                         delete _this (parentSelf);

  327.                         parentDeletionEvent.signal();

  328.                     }

  329. 

  330.                     id parentSelf;

  331.                     WaitableEvent& parentDeletionEvent;

  332.                 };

  333. 

  334.                 (new AUDeleter (self, deletionEvent))->post();

  335.                 deletionEvent.wait (-1);

  336.             }

  337.             else

  338.             {

  339.                 delete _this (self);

  340.             }

  341.         }

  342. 

  343.         //==============================================================================

  344.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  345. 

  346.         //==============================================================================

  347.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  348.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  349.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  350.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  351.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  352.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  353.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  354. 

  355.         //==============================================================================

  356.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  357.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  358. 

  359.         //==============================================================================

  360.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  361.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  362.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  363.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  364. 

  365.         //==============================================================================

  366.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  367.         static BOOL getSupportsMPE (id self, SEL)                                                   { return _this (self)->getSupportsMPE() ? YES : NO; }

  368.         static NSArray<NSString*>* getMIDIOutputNames (id self, SEL)                                { return _this (self)->getMIDIOutputNames(); }

  369. 

  370.         //==============================================================================

  371.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  372.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  373.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  374.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  375.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  376.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  377.         static BOOL getShouldBypassEffect (id self, SEL)                                            { return _this (self)->getShouldBypassEffect() ? YES : NO; }

  378.         static void setShouldBypassEffect (id self, SEL, BOOL shouldBypass)                         { _this (self)->setShouldBypassEffect (shouldBypass); }

  379. 

  380.         //==============================================================================

  381.         static NSString* getContextName (id self, SEL)                                              { return _this (self)->getContextName(); }

  382.         static void setContextName (id self, SEL, NSString* str)                                    { return _this (self)->setContextName (str); }

  383. 

  384.         //==============================================================================

  385.        #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  386.         static NSIndexSet* getSupportedViewConfigurations (id self, SEL, NSArray<AUAudioUnitViewConfiguration*>* configs) { return _this (self)->getSupportedViewConfigurations (configs); }

  387.         static void selectViewConfiguration (id self, SEL, AUAudioUnitViewConfiguration* config)    { _this (self)->selectViewConfiguration (config); }

  388.        #endif

  389.     };

  390. 

  391.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  392. 

  393.     //==============================================================================

  394.     static Class audioUnitObjCClass;

  395. 

  396. protected:

  397.     AUAudioUnit* au;

  398. };

  399. 

  400. //==============================================================================

  401. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  402. 

  403. //==============================================================================

  404. //=========================== The actual AudioUnit =============================

  405. //==============================================================================

  406. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  407.                          public AudioProcessorListener,

  408.                          public AudioPlayHead,

  409.                          private AudioProcessorParameter::Listener

  410. {

  411. public:

  412.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  413.                      const AudioComponentDescription& descr,

  414.                      AudioComponentInstantiationOptions options,

  415.                      NSError** error)

  416.         : JuceAudioUnitv3Base (descr, options, error),

  417.           processorHolder (processor),

  418.           mapper (*processorHolder->get())

  419.     {

  420.         init();

  421.     }

  422. 

  423.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  424.         : JuceAudioUnitv3Base (audioUnit),

  425.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  426.           mapper (*processorHolder->get())

  427.     {

  428.         init();

  429.     }

  430. 

  431.     ~JuceAudioUnitv3() override

  432.     {

  433.         auto& processor = getAudioProcessor();

  434.         processor.removeListener (this);

  435. 

  436.         if (bypassParam != nullptr)

  437.             bypassParam->removeListener (this);

  438. 

  439.         removeEditor (processor);

  440. 

  441.         if (editorObserverToken != nullptr)

  442.         {

  443.             [paramTree.get() removeParameterObserver: editorObserverToken];

  444.             editorObserverToken = nullptr;

  445.         }

  446.     }

  447. 

  448.     //==============================================================================

  449.     void init()

  450.     {

  451.         inParameterChangedCallback = false;

  452. 

  453.         AudioProcessor& processor = getAudioProcessor();

  454.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  455. 

  456.        #ifdef JucePlugin_PreferredChannelConfigurations

  457.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  458.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  459. 

  460.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  461.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  462. 

  463.         Array<AUChannelInfo> channelInfos;

  464. 

  465.         for (int i = 0; i < numConfigs; ++i)

  466.         {

  467.             AUChannelInfo channelInfo;

  468. 

  469.             channelInfo.inChannels  = configs[i][0];

  470.             channelInfo.outChannels = configs[i][1];

  471. 

  472.             channelInfos.add (channelInfo);

  473.         }

  474.        #else

  475.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  476.        #endif

  477. 

  478.         processor.setPlayHead (this);

  479. 

  480.         totalInChannels  = processor.getTotalNumInputChannels();

  481.         totalOutChannels = processor.getTotalNumOutputChannels();

  482. 

  483.         {

  484.             channelCapabilities.reset ([[NSMutableArray<NSNumber*> alloc] init]);

  485. 

  486.             for (int i = 0; i < channelInfos.size(); ++i)

  487.             {

  488.                 AUChannelInfo& info = channelInfos.getReference (i);

  489. 

  490.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.inChannels]];

  491.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.outChannels]];

  492.             }

  493.         }

  494. 

  495.         editorObserverToken = nullptr;

  496.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  497. 

  498.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  499.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  500.         processor.addListener (this);

  501. 

  502.         addParameters();

  503.         addPresets();

  504. 

  505.         addAudioUnitBusses (true);

  506.         addAudioUnitBusses (false);

  507.     }

  508. 

  509.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  510. 

  511.     //==============================================================================

  512.     void reset() override

  513.     {

  514.         midiMessages.clear();

  515.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  516.     }

  517. 

  518.     //==============================================================================

  519.     AUAudioUnitPreset* getCurrentPreset() override

  520.     {

  521.         const int n = static_cast<int> ([factoryPresets.get() count]);

  522.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  523. 

  524.         if (idx < n)

  525.             return [factoryPresets.get() objectAtIndex:static_cast<unsigned int> (idx)];

  526. 

  527.         return nullptr;

  528.     }

  529. 

  530.     void setCurrentPreset(AUAudioUnitPreset* preset) override

  531.     {

  532.         const int n = static_cast<int> ([factoryPresets.get() count]);

  533.         const int idx = static_cast<int> ([preset number]);

  534. 

  535.         if (isPositiveAndBelow (idx, n))

  536.             getAudioProcessor().setCurrentProgram (idx);

  537.     }

  538. 

  539.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override

  540.     {

  541.         return factoryPresets.get();

  542.     }

  543. 

  544.     NSDictionary<NSString*, id>* getFullState() override

  545.     {

  546.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  547. 

  548.         {

  549.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  550. 

  551.             if (superRetval != nullptr)

  552.                 [retval addEntriesFromDictionary:superRetval];

  553.         }

  554. 

  555.         juce::MemoryBlock state;

  556. 

  557.        #if JUCE_AU_WRAPPERS_SAVE_PROGRAM_STATES

  558.         getAudioProcessor().getCurrentProgramStateInformation (state);

  559.        #else

  560.         getAudioProcessor().getStateInformation (state);

  561.        #endif

  562. 

  563.         if (state.getSize() > 0)

  564.         {

  565.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  566.                                                       length: state.getSize()];

  567. 

  568.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  569. 

  570.             [retval setObject: ourState

  571.                        forKey: nsKey];

  572. 

  573.             [nsKey    release];

  574.             [ourState release];

  575.         }

  576. 

  577.         return [retval autorelease];

  578.     }

  579. 

  580.     void setFullState (NSDictionary<NSString*, id>* state) override

  581.     {

  582.         if (state == nullptr)

  583.             return;

  584. 

  585.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  586.         [modifiedState addEntriesFromDictionary: state];

  587. 

  588.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  589.         [modifiedState removeObjectForKey: nsPresetKey];

  590.         [nsPresetKey release];

  591. 

  592.         JuceAudioUnitv3Base::setFullState (modifiedState);

  593. 

  594.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  595.         NSObject* obj = [modifiedState objectForKey: nsKey];

  596.         [nsKey release];

  597. 

  598.         if (obj != nullptr)

  599.         {

  600.             if ([obj isKindOfClass:[NSData class]])

  601.             {

  602.                 NSData* data = reinterpret_cast<NSData*> (obj);

  603.                 const int numBytes = static_cast<int> ([data length]);

  604.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  605. 

  606.                 if (numBytes > 0)

  607.                 {

  608.                    #if JUCE_AU_WRAPPERS_SAVE_PROGRAM_STATES

  609.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  610.                    #else

  611.                     getAudioProcessor().setStateInformation (rawBytes, numBytes);

  612.                    #endif

  613.                 }

  614.             }

  615.         }

  616. 

  617.         [modifiedState release];

  618.     }

  619. 

  620.     AUParameterTree* getParameterTree() override

  621.     {

  622.         return paramTree.get();

  623.     }

  624. 

  625.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  626.     {

  627.         const int n = static_cast<int> ([overviewParams.get() count]);

  628. 

  629.         if (count >= n)

  630.             return overviewParams.get();

  631. 

  632.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams.get()];

  633.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  634. 

  635.         return [retval autorelease];

  636.     }

  637. 

  638.     //==============================================================================

  639.     NSTimeInterval getLatency() override

  640.     {

  641.         auto& p = getAudioProcessor();

  642.         return p.getLatencySamples() / p.getSampleRate();

  643.     }

  644. 

  645.     NSTimeInterval getTailTime() override

  646.     {

  647.         return getAudioProcessor().getTailLengthSeconds();

  648.     }

  649. 

  650.     //==============================================================================

  651.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses.get();  }

  652.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses.get(); }

  653.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities.get(); }

  654. 

  655.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  656.     {

  657.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  658.         const int busIdx = static_cast<int> ([auBus index]);

  659.         const int newNumChannels = static_cast<int> ([format channelCount]);

  660. 

  661.         AudioProcessor& processor = getAudioProcessor();

  662. 

  663.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  664.         {

  665.           #ifdef JucePlugin_PreferredChannelConfigurations

  666.             ignoreUnused (bus);

  667. 

  668.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  669. 

  670.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  671.                 return false;

  672.           #else

  673.             const AVAudioChannelLayout* layout    = [format channelLayout];

  674.             const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  675. 

  676.             if (layoutTag != 0)

  677.             {

  678.                 AudioChannelSet newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  679. 

  680.                 if (newLayout.size() != newNumChannels)

  681.                     return false;

  682. 

  683.                 if (! bus->isLayoutSupported (newLayout))

  684.                     return false;

  685.             }

  686.             else

  687.             {

  688.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  689.                     return false;

  690.             }

  691.            #endif

  692. 

  693.             return true;

  694.         }

  695. 

  696.         return false;

  697.     }

  698. 

  699.     //==============================================================================

  700.     int getVirtualMIDICableCount() override

  701.     {

  702.        #if JucePlugin_WantsMidiInput

  703.         return 1;

  704.        #else

  705.         return 0;

  706.        #endif

  707.     }

  708. 

  709.     bool getSupportsMPE() override

  710.     {

  711.         return getAudioProcessor().supportsMPE();

  712.     }

  713. 

  714.     NSArray<NSString*>* getMIDIOutputNames() override

  715.     {

  716.        #if JucePlugin_ProducesMidiOutput

  717.         return @[@"MIDI Out"];

  718.        #else

  719.         return @[];

  720.        #endif

  721.     }

  722. 

  723.     //==============================================================================

  724.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  725.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  726.     void setRenderingOffline (bool offline) override

  727.     {

  728.         auto& processor = getAudioProcessor();

  729.         auto isCurrentlyNonRealtime = processor.isNonRealtime();

  730. 

  731.         if (isCurrentlyNonRealtime != offline)

  732.         {

  733.             ScopedLock callbackLock (processor.getCallbackLock());

  734. 

  735.             processor.setNonRealtime (offline);

  736.             processor.prepareToPlay (processor.getSampleRate(), processor.getBlockSize());

  737.         }

  738.     }

  739. 

  740.     bool getShouldBypassEffect() override

  741.     {

  742.         if (bypassParam != nullptr)

  743.             return (bypassParam->getValue() != 0.0f);

  744. 

  745.         return JuceAudioUnitv3Base::getShouldBypassEffect();

  746.     }

  747. 

  748.     void setShouldBypassEffect (bool shouldBypass) override

  749.     {

  750.         if (bypassParam != nullptr)

  751.             bypassParam->setValue (shouldBypass ? 1.0f : 0.0f);

  752. 

  753.         JuceAudioUnitv3Base::setShouldBypassEffect (shouldBypass);

  754.     }

  755. 

  756.     //==============================================================================

  757.     NSString* getContextName() const    override              { return juceStringToNS (contextName); }

  758.     void setContextName (NSString* str) override

  759.     {

  760.         if (str != nullptr)

  761.         {

  762.             AudioProcessor::TrackProperties props;

  763.             props.name = nsStringToJuce (str);

  764. 

  765.             getAudioProcessor().updateTrackProperties (props);

  766.         }

  767.     }

  768. 

  769.     //==============================================================================

  770.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  771.     {

  772.         AudioProcessor& processor = getAudioProcessor();

  773.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  774. 

  775.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  776.             return false;

  777. 

  778.         if (outError != nullptr)

  779.             *outError = nullptr;

  780. 

  781.         AudioProcessor::BusesLayout layouts;

  782.         for (int dir = 0; dir < 2; ++dir)

  783.         {

  784.             const bool isInput = (dir == 0);

  785.             const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  786.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  787. 

  788.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  789.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  790. 

  791.             for (int busIdx = 0; busIdx < n; ++busIdx)

  792.             {

  793.                 AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx);

  794.                 AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  795. 

  796.                 AudioChannelSet newLayout;

  797.                 const AVAudioChannelLayout* layout    = [format channelLayout];

  798.                 const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  799. 

  800.                 if (layoutTag != 0)

  801.                     newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  802.                 else

  803.                     newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  804. 

  805.                 if (newLayout.isDisabled())

  806.                     return false;

  807. 

  808.                 channelSets.add (newLayout);

  809.             }

  810.         }

  811. 

  812.        #ifdef JucePlugin_PreferredChannelConfigurations

  813.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  814. 

  815.         if (! AudioProcessor::containsLayout (layouts, configs))

  816.         {

  817.             if (outError != nullptr)

  818.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  819. 

  820.             return false;

  821.         }

  822.        #endif

  823. 

  824.         if (! AudioUnitHelpers::setBusesLayout (&getAudioProcessor(), layouts))

  825.         {

  826.             if (outError != nullptr)

  827.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  828. 

  829.             return false;

  830.         }

  831. 

  832.         totalInChannels  = processor.getTotalNumInputChannels();

  833.         totalOutChannels = processor.getTotalNumOutputChannels();

  834. 

  835.         allocateBusBuffer (true);

  836.         allocateBusBuffer (false);

  837. 

  838.         mapper.alloc();

  839. 

  840.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  841. 

  842.         double sampleRate = (jmax (AudioUnitHelpers::getBusCount (&processor, true), AudioUnitHelpers::getBusCount (&processor, false)) > 0 ?

  843.                              [[[([inputBusses.get() count] > 0 ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: 0] format] sampleRate] : 44100.0);

  844. 

  845.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  846.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  847. 

  848.         midiMessages.ensureSize (2048);

  849.         midiMessages.clear();

  850. 

  851.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  852.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  853.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  854. 

  855.         reset();

  856. 

  857.         return true;

  858.     }

  859. 

  860.     void deallocateRenderResources() override

  861.     {

  862.         hostMusicalContextCallback = nullptr;

  863.         hostTransportStateCallback = nullptr;

  864. 

  865.         getAudioProcessor().releaseResources();

  866.         audioBuffer.release();

  867. 

  868.         inBusBuffers. clear();

  869.         outBusBuffers.clear();

  870. 

  871.         mapper.release();

  872. 

  873.         JuceAudioUnitv3Base::deallocateRenderResources();

  874.     }

  875. 

  876.     //==============================================================================

  877.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  878.     NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>* configs) override

  879.     {

  880.         auto supportedViewIndecies = [[NSMutableIndexSet alloc] init];

  881.         auto n = [configs count];

  882. 

  883.         if (auto* editor = getAudioProcessor().createEditorIfNeeded())

  884.         {

  885.             // If you hit this assertion then your plug-in's editor is reporting that it doesn't support

  886.             // any host MIDI controller configurations!

  887.             jassert (editor->supportsHostMIDIControllerPresence (true) || editor->supportsHostMIDIControllerPresence (false));

  888. 

  889.             for (auto i = 0u; i < n; ++i)

  890.             {

  891.                 if (auto viewConfiguration = [configs objectAtIndex: i])

  892.                 {

  893.                     if (editor->supportsHostMIDIControllerPresence ([viewConfiguration hostHasController] == YES))

  894.                     {

  895.                         auto* constrainer = editor->getConstrainer();

  896.                         auto height = (int) [viewConfiguration height];

  897.                         auto width  = (int) [viewConfiguration width];

  898. 

  899.                         if (height <= constrainer->getMaximumHeight() && height >= constrainer->getMinimumHeight()

  900.                          && width  <= constrainer->getMaximumWidth()  && width  >= constrainer->getMinimumWidth())

  901.                             [supportedViewIndecies addIndex: i];

  902.                     }

  903.                 }

  904.             }

  905.         }

  906. 

  907.         return [supportedViewIndecies autorelease];

  908.     }

  909. 

  910.     void selectViewConfiguration (AUAudioUnitViewConfiguration* config) override

  911.     {

  912.         processorHolder->viewConfiguration.reset (new AudioProcessorHolder::ViewConfig { [config width], [config height], [config hostHasController] == YES });

  913.     }

  914.    #endif

  915. 

  916.     //==============================================================================

  917.     void audioProcessorChanged (AudioProcessor* processor) override

  918.     {

  919.         ignoreUnused (processor);

  920. 

  921.         [au willChangeValueForKey: @"allParameterValues"];

  922.         addPresets();

  923.         [au didChangeValueForKey: @"allParameterValues"];

  924.     }

  925. 

  926.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  927.     {

  928.         if (inParameterChangedCallback.get())

  929.         {

  930.             inParameterChangedCallback = false;

  931.             return;

  932.         }

  933. 

  934.         if (auto* juceParam = juceParameters.getParamForIndex (idx))

  935.         {

  936.             if (AUParameter* param = [paramTree.get() parameterWithAddress: getAUParameterAddressForIndex (idx)])

  937.             {

  938.                 newValue *= getMaximumParameterValue (juceParam);

  939. 

  940.                 if (editorObserverToken != nullptr)

  941.                     [param setValue: newValue  originator: editorObserverToken];

  942.                 else

  943.                     [param setValue: newValue];

  944.             }

  945.         }

  946.     }

  947. 

  948.     //==============================================================================

  949.     bool getCurrentPosition (CurrentPositionInfo& info) override

  950.     {

  951.         bool musicContextCallSucceeded = false;

  952.         bool transportStateCallSucceeded = false;

  953. 

  954.         info = lastAudioHead;

  955.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  956.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  957. 

  958.         switch (lastTimeStamp.mSMPTETime.mType)

  959.         {

  960.             case kSMPTETimeType2398:        info.frameRate = AudioPlayHead::fps23976;    break;

  961.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24;       break;

  962.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25;       break;

  963.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997;     break;

  964.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  965.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop;   break;

  966.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30;       break;

  967.             case kSMPTETimeType60Drop:      info.frameRate = AudioPlayHead::fps60drop;   break;

  968.             case kSMPTETimeType60:          info.frameRate = AudioPlayHead::fps60;       break;

  969.             case kSMPTETimeType5994:

  970.             case kSMPTETimeType5994Drop:

  971.             case kSMPTETimeType50:

  972.             default:                        info.frameRate = AudioPlayHead::fpsUnknown;  break;

  973.         }

  974. 

  975.         double num;

  976.         NSInteger den;

  977.         NSInteger outDeltaSampleOffsetToNextBeat;

  978.         double outCurrentMeasureDownBeat, bpm;

  979.         double ppqPosition;

  980. 

  981.         if (hostMusicalContextCallback != nullptr)

  982.         {

  983.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  984. 

  985.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  986.             {

  987.                 musicContextCallSucceeded = true;

  988. 

  989.                 info.timeSigNumerator   = (int) num;

  990.                 info.timeSigDenominator = (int) den;

  991.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  992.                 info.bpm = bpm;

  993.                 info.ppqPosition = ppqPosition;

  994.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  995.             }

  996.         }

  997. 

  998.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  999.         AUHostTransportStateFlags flags;

  1000. 

  1001.         if (hostTransportStateCallback != nullptr)

  1002.         {

  1003.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  1004. 

  1005.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  1006.             {

  1007.                 transportStateCallSucceeded = true;

  1008. 

  1009.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  1010.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  1011.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  1012.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  1013.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  1014.                 info.ppqLoopStart   = outCycleStartBeat;

  1015.                 info.ppqLoopEnd     = outCycleEndBeat;

  1016.             }

  1017.         }

  1018. 

  1019.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  1020.             lastAudioHead = info;

  1021. 

  1022.         return true;

  1023.     }

  1024. 

  1025.     //==============================================================================

  1026.     static void removeEditor (AudioProcessor& processor)

  1027.     {

  1028.         ScopedLock editorLock (processor.getCallbackLock());

  1029. 

  1030.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  1031.         {

  1032.             processor.editorBeingDeleted (editor);

  1033.             delete editor;

  1034.         }

  1035.     }

  1036. 

  1037. private:

  1038.     //==============================================================================

  1039.     struct BusBuffer

  1040.     {

  1041.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  1042.             : auBus (bus),

  1043.               maxFrames (maxFramesPerBuffer),

  1044.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  1045.               isInterleaved ([[auBus format] isInterleaved])

  1046.         {

  1047.             alloc();

  1048.         }

  1049. 

  1050.         //==============================================================================

  1051.         void alloc()

  1052.         {

  1053.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1054.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  1055.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  1056.             jassert (bytes > 0);

  1057. 

  1058.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  1059.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  1060. 

  1061.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  1062.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  1063.         }

  1064. 

  1065.         void dealloc()

  1066.         {

  1067.             bufferList = nullptr;

  1068.             bufferListStorage.free();

  1069.             scratchBuffer.setSize (0, 0);

  1070.         }

  1071. 

  1072.         //==============================================================================

  1073.         int numChannels() const noexcept                { return numberOfChannels; }

  1074.         bool interleaved() const noexcept               { return isInterleaved; }

  1075.         AudioBufferList* get() const noexcept           { return bufferList; }

  1076. 

  1077.         //==============================================================================

  1078.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  1079.         {

  1080.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1081.             const bool isCompatible = isCompatibleWith (other);

  1082. 

  1083.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  1084. 

  1085.             for (int i = 0; i < numBuffers; ++i)

  1086.             {

  1087.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  1088.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  1089.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  1090.                                                               : scratchBuffer.getWritePointer (i));

  1091.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  1092.             }

  1093.         }

  1094. 

  1095.         //==============================================================================

  1096.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  1097.         {

  1098.             if (other == nullptr)

  1099.                 return false;

  1100. 

  1101.             if (other->mNumberBuffers > 0)

  1102.             {

  1103.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  1104.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  1105.                                                                              : other->mNumberBuffers);

  1106. 

  1107.                 return otherInterleaved == isInterleaved

  1108.                     && numberOfChannels == otherChannels;

  1109.             }

  1110. 

  1111.             return numberOfChannels == 0;

  1112.         }

  1113. 

  1114.     private:

  1115.         AUAudioUnitBus* auBus;

  1116.         HeapBlock<char> bufferListStorage;

  1117.         AudioBufferList* bufferList = nullptr;

  1118.         int maxFrames, numberOfChannels;

  1119.         bool isInterleaved;

  1120.         juce::AudioBuffer<float> scratchBuffer;

  1121.     };

  1122. 

  1123.     //==============================================================================

  1124.     void addAudioUnitBusses (bool isInput)

  1125.     {

  1126.         std::unique_ptr<NSMutableArray<AUAudioUnitBus*>, NSObjectDeleter> array ([[NSMutableArray<AUAudioUnitBus*> alloc] init]);

  1127.         AudioProcessor& processor = getAudioProcessor();

  1128.         const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  1129. 

  1130.         for (int i = 0; i < n; ++i)

  1131.         {

  1132.             std::unique_ptr<AUAudioUnitBus, NSObjectDeleter> audioUnitBus;

  1133. 

  1134.             {

  1135.                 std::unique_ptr<AVAudioFormat, NSObjectDeleter> defaultFormat ([[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  1136.                                                                                                                               channels: static_cast<AVAudioChannelCount> (processor.getChannelCountOfBus (isInput, i))]);

  1137. 

  1138.                 audioUnitBus.reset ([[AUAudioUnitBus alloc] initWithFormat: defaultFormat.get()

  1139.                                                                      error: nullptr]);

  1140.             }

  1141. 

  1142.             [array.get() addObject: audioUnitBus.get()];

  1143.         }

  1144. 

  1145.         (isInput ? inputBusses : outputBusses).reset ([[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  1146.                                                                                              busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  1147.                                                                                               busses: array.get()]);

  1148.     }

  1149. 

  1150.     // When parameters are discrete we need to use integer values.

  1151.     float getMaximumParameterValue (AudioProcessorParameter* juceParam)

  1152.     {

  1153.        #if JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1154.         ignoreUnused (juceParam);

  1155.         return 1.0f;

  1156.        #else

  1157.         return juceParam->isDiscrete() ? (float) (juceParam->getNumSteps() - 1) : 1.0f;

  1158.        #endif

  1159.     }

  1160. 

  1161.     std::unique_ptr<AUParameter, NSObjectDeleter> createParameter (AudioProcessorParameter* parameter)

  1162.     {

  1163.         const String name (parameter->getName (512));

  1164. 

  1165.         AudioUnitParameterUnit unit = kAudioUnitParameterUnit_Generic;

  1166.         AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  1167.                                                   | kAudioUnitParameterFlag_IsReadable

  1168.                                                   | kAudioUnitParameterFlag_HasCFNameString

  1169.                                                   | kAudioUnitParameterFlag_ValuesHaveStrings);

  1170. 

  1171.        #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1172.         flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  1173.        #endif

  1174. 

  1175.         // Set whether the param is automatable (unnamed parameters aren't allowed to be automated).

  1176.         if (name.isEmpty() || ! parameter->isAutomatable())

  1177.             flags |= kAudioUnitParameterFlag_NonRealTime;

  1178. 

  1179.         const bool isParameterDiscrete = parameter->isDiscrete();

  1180. 

  1181.         if (! isParameterDiscrete)

  1182.             flags |= kAudioUnitParameterFlag_CanRamp;

  1183. 

  1184.         if (parameter->isMetaParameter())

  1185.             flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  1186. 

  1187.         std::unique_ptr<NSMutableArray, NSObjectDeleter> valueStrings;

  1188. 

  1189.         // Is this a meter?

  1190.         if (((parameter->getCategory() & 0xffff0000) >> 16) == 2)

  1191.         {

  1192.             flags &= ~kAudioUnitParameterFlag_IsWritable;

  1193.             flags |= kAudioUnitParameterFlag_MeterReadOnly | kAudioUnitParameterFlag_DisplayLogarithmic;

  1194.             unit = kAudioUnitParameterUnit_LinearGain;

  1195.         }

  1196.         else

  1197.         {

  1198.            #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1199.             if (parameter->isDiscrete())

  1200.             {

  1201.                 unit = parameter->isBoolean() ? kAudioUnitParameterUnit_Boolean : kAudioUnitParameterUnit_Indexed;

  1202.                 auto maxValue = getMaximumParameterValue (parameter);

  1203.                 auto numSteps = parameter->getNumSteps();

  1204. 

  1205.                 // Some hosts can't handle the huge numbers of discrete parameter values created when

  1206.                 // using the default number of steps.

  1207.                 jassert (numSteps != AudioProcessor::getDefaultNumParameterSteps());

  1208. 

  1209.                 valueStrings.reset ([NSMutableArray new]);

  1210. 

  1211.                 for (int i = 0; i < numSteps; ++i)

  1212.                     [valueStrings.get() addObject: juceStringToNS (parameter->getText ((float) i / maxValue, 0))];

  1213.             }

  1214.            #endif

  1215.         }

  1216. 

  1217.         AUParameterAddress address = generateAUParameterAddress (parameter);

  1218. 

  1219.        #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1220.         // If you hit this assertion then you have either put a parameter in two groups or you are

  1221.         // very unlucky and the hash codes of your parameter ids are not unique.

  1222.         jassert (! paramMap.contains (static_cast<int64> (address)));

  1223. 

  1224.         paramAddresses.add (address);

  1225.         paramMap.set (static_cast<int64> (address), parameter->getParameterIndex());

  1226.        #endif

  1227. 

  1228.         auto getParameterIdentifier = [parameter]

  1229.         {

  1230.             if (auto* paramWithID = dynamic_cast<AudioProcessorParameterWithID*> (parameter))

  1231.                 return paramWithID->paramID;

  1232. 

  1233.             // This could clash if any groups have been given integer IDs!

  1234.             return String (parameter->getParameterIndex());

  1235.         };

  1236. 

  1237.         std::unique_ptr<AUParameter, NSObjectDeleter> param;

  1238. 

  1239.         @try

  1240.         {

  1241.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1242.             param.reset([[AUParameterTree createParameterWithIdentifier: juceStringToNS (getParameterIdentifier())

  1243.                                                                    name: juceStringToNS (name)

  1244.                                                                 address: address

  1245.                                                                     min: 0.0f

  1246.                                                                     max: getMaximumParameterValue (parameter)

  1247.                                                                    unit: unit

  1248.                                                                unitName: nullptr

  1249.                                                                   flags: flags

  1250.                                                            valueStrings: valueStrings.get()

  1251.                                                     dependentParameters: nullptr]

  1252.                          retain]);

  1253.         }

  1254. 

  1255.         @catch (NSException* exception)

  1256.         {

  1257.             // Do you have duplicate identifiers in any of your groups or parameters,

  1258.             // or do your identifiers have unusual characters in them?

  1259.             jassertfalse;

  1260.         }

  1261. 

  1262.         [param.get() setValue: parameter->getDefaultValue()];

  1263. 

  1264.         [overviewParams.get() addObject: [NSNumber numberWithUnsignedLongLong: address]];

  1265. 

  1266.         return param;

  1267.     }

  1268. 

  1269.     std::unique_ptr<AUParameterGroup, NSObjectDeleter> createParameterGroup (AudioProcessorParameterGroup* group)

  1270.     {

  1271.         std::unique_ptr<NSMutableArray<AUParameterNode*>, NSObjectDeleter> children ([NSMutableArray<AUParameterNode*> new]);

  1272. 

  1273.         for (auto* node : *group)

  1274.         {

  1275.             if (auto* childGroup = node->getGroup())

  1276.                 [children.get() addObject: createParameterGroup (childGroup).get()];

  1277.             else

  1278.                 [children.get() addObject: createParameter (node->getParameter()).get()];

  1279.         }

  1280. 

  1281.         std::unique_ptr<AUParameterGroup, NSObjectDeleter> result;

  1282. 

  1283.         @try

  1284.         {

  1285.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1286.             result.reset ([[AUParameterTree createGroupWithIdentifier: juceStringToNS (group->getID())

  1287.                                                                  name: juceStringToNS (group->getName())

  1288.                                                              children: children.get()]

  1289.                            retain]);

  1290.         }

  1291. 

  1292.         @catch (NSException* exception)

  1293.         {

  1294.             // Do you have duplicate identifiers in any of your groups or parameters,

  1295.             // or do your identifiers have unusual characters in them?

  1296.             jassertfalse;

  1297.         }

  1298. 

  1299.         return result;

  1300.     }

  1301. 

  1302.     void addParameters()

  1303.     {

  1304.         auto& processor = getAudioProcessor();

  1305.         juceParameters.update (processor, forceLegacyParamIDs);

  1306. 

  1307.         // This is updated when we build the tree.

  1308.         overviewParams.reset ([NSMutableArray<NSNumber*> new]);

  1309. 

  1310.         std::unique_ptr<NSMutableArray<AUParameterNode*>, NSObjectDeleter> topLevelNodes ([NSMutableArray<AUParameterNode*> new]);

  1311. 

  1312.         for (auto* node : processor.getParameterTree())

  1313.             if (auto* childGroup = node->getGroup())

  1314.                 [topLevelNodes.get() addObject: createParameterGroup (childGroup).get()];

  1315.             else

  1316.                 [topLevelNodes.get() addObject: createParameter (node->getParameter()).get()];

  1317. 

  1318.         @try

  1319.         {

  1320.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1321.             paramTree.reset ([[AUParameterTree createTreeWithChildren: topLevelNodes.get()] retain]);

  1322.         }

  1323. 

  1324.         @catch (NSException* exception)

  1325.         {

  1326.             // Do you have duplicate identifiers in any of your groups or parameters,

  1327.             // or do your identifiers have unusual characters in them?

  1328.             jassertfalse;

  1329.         }

  1330. 

  1331.         paramObserver           = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  1332.         paramProvider           = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  1333.         stringFromValueProvider = CreateObjCBlock (this, &JuceAudioUnitv3::stringFromValue);

  1334.         valueFromStringProvider = CreateObjCBlock (this, &JuceAudioUnitv3::valueFromString);

  1335. 

  1336.         [paramTree.get() setImplementorValueObserver: paramObserver];

  1337.         [paramTree.get() setImplementorValueProvider: paramProvider];

  1338.         [paramTree.get() setImplementorStringFromValueCallback: stringFromValueProvider];

  1339.         [paramTree.get() setImplementorValueFromStringCallback: valueFromStringProvider];

  1340. 

  1341.         if (processor.hasEditor())

  1342.         {

  1343.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  1344.             editorObserverToken = [paramTree.get() tokenByAddingParameterObserver: editorParamObserver];

  1345.         }

  1346. 

  1347.         if ((bypassParam = processor.getBypassParameter()) != nullptr)

  1348.             bypassParam->addListener (this);

  1349.     }

  1350. 

  1351.     void setAudioProcessorParameter (AudioProcessorParameter* juceParam, float value)

  1352.     {

  1353.         if (value != juceParam->getValue())

  1354.         {

  1355.             juceParam->setValue (value);

  1356. 

  1357.             inParameterChangedCallback = true;

  1358.             juceParam->sendValueChangedMessageToListeners (value);

  1359.         }

  1360.     }

  1361. 

  1362.     void addPresets()

  1363.     {

  1364.         factoryPresets.reset ([[NSMutableArray<AUAudioUnitPreset*> alloc] init]);

  1365. 

  1366.         const int n = getAudioProcessor().getNumPrograms();

  1367. 

  1368.         for (int idx = 0; idx < n; ++idx)

  1369.         {

  1370.             String name = getAudioProcessor().getProgramName (idx);

  1371. 

  1372.             std::unique_ptr<AUAudioUnitPreset, NSObjectDeleter> preset ([[AUAudioUnitPreset alloc] init]);

  1373.             [preset.get() setName: juceStringToNS (name)];

  1374.             [preset.get() setNumber: static_cast<NSInteger> (idx)];

  1375. 

  1376.             [factoryPresets.get() addObject: preset.get()];

  1377.         }

  1378.     }

  1379. 

  1380.     //==============================================================================

  1381.     void allocateBusBuffer (bool isInput)

  1382.     {

  1383.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  1384.         busBuffers.clear();

  1385. 

  1386.         const int n = AudioUnitHelpers::getBusCount (&getAudioProcessor(), isInput);

  1387.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1388. 

  1389.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1390.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1391.                                            static_cast<int> (maxFrames)));

  1392.     }

  1393. 

  1394.     //==============================================================================

  1395.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1396.     {

  1397.         ignoreUnused (numParams);

  1398. 

  1399.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1400.         {

  1401.             switch (event->head.eventType)

  1402.             {

  1403.                 case AURenderEventMIDI:

  1404.                 {

  1405.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1406.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1407.                 }

  1408.                 break;

  1409. 

  1410.                 case AURenderEventParameter:

  1411.                 case AURenderEventParameterRamp:

  1412.                 {

  1413.                     const AUParameterEvent& paramEvent = event->parameter;

  1414. 

  1415.                     if (auto* p = getJuceParameterForAUAddress (paramEvent.parameterAddress))

  1416.                     {

  1417.                         auto normalisedValue = paramEvent.value / getMaximumParameterValue (p);

  1418.                         setAudioProcessorParameter (p, normalisedValue);

  1419.                     }

  1420.                 }

  1421.                 break;

  1422. 

  1423.                 case AURenderEventMIDISysEx:

  1424.                 default:

  1425.                     break;

  1426.             }

  1427.         }

  1428.     }

  1429. 

  1430.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1431.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1432.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1433.     {

  1434.         auto& processor = getAudioProcessor();

  1435.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1436. 

  1437.         // process params

  1438.         const int numParams = juceParameters.getNumParameters();

  1439.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1440. 

  1441.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1442.         {

  1443.             lastTimeStamp = *timestamp;

  1444. 

  1445.             const int numInputBuses  = inBusBuffers. size();

  1446.             const int numOutputBuses = outBusBuffers.size();

  1447. 

  1448.             // prepare buffers

  1449.             {

  1450.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1451.                 {

  1452.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1453.                      const bool canUseDirectOutput =

  1454.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1455. 

  1456.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1457.                 }

  1458. 

  1459.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1460.                 {

  1461.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1462.                     busBuffer.prepare (frameCount, busIdx < numOutputBuses ? outBusBuffers[busIdx]->get() : nullptr);

  1463.                 }

  1464. 

  1465.                 audioBuffer.reset();

  1466.             }

  1467. 

  1468.             // pull inputs

  1469.             {

  1470.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1471.                 {

  1472.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1473.                     AudioBufferList* buffer = busBuffer.get();

  1474. 

  1475.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1476.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1477. 

  1478.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1479.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1480.                 }

  1481.             }

  1482. 

  1483.             // set buffer pointer to minimize copying

  1484.             {

  1485.                 int chIdx = 0;

  1486. 

  1487.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1488.                 {

  1489.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1490.                     AudioBufferList* buffer = busBuffer.get();

  1491. 

  1492.                     const bool interleaved = busBuffer.interleaved();

  1493.                     const int numChannels = busBuffer.numChannels();

  1494. 

  1495.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1496. 

  1497.                     for (int ch = 0; ch < numChannels; ++ch)

  1498.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1499.                 }

  1500. 

  1501.                 // use input pointers on remaining channels

  1502. 

  1503.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1504.                 {

  1505.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1506. 

  1507.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1508.                     AudioBufferList* buffer = busBuffer.get();

  1509. 

  1510.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1511.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1512.                 }

  1513.             }

  1514. 

  1515.             // copy input

  1516.             {

  1517.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1518.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1519. 

  1520.                 // clear remaining channels

  1521.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1522.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1523.             }

  1524. 

  1525.             // process audio

  1526.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1527. 

  1528.             // send MIDI

  1529.            #if JucePlugin_ProducesMidiOutput && JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  1530.             if (auto midiOut = [au MIDIOutputEventBlock])

  1531.             {

  1532.                 for (const auto metadata : midiMessages)

  1533.                     midiOut (metadata.samplePosition, 0, metadata.numBytes, metadata.data);

  1534.             }

  1535.            #endif

  1536. 

  1537.             midiMessages.clear();

  1538. 

  1539.             // copy back

  1540.             audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1541.                              mapper.get (false, (int) outputBusNumber));

  1542.         }

  1543. 

  1544.         return noErr;

  1545.     }

  1546. 

  1547.     void processBlock (juce::AudioBuffer<float>& buffer, MidiBuffer& midiBuffer) noexcept

  1548.     {

  1549.         auto& processor = getAudioProcessor();

  1550.         const ScopedLock sl (processor.getCallbackLock());

  1551. 

  1552.         if (processor.isSuspended())

  1553.             buffer.clear();

  1554.         else if (bypassParam != nullptr && [au shouldBypassEffect])

  1555.             processor.processBlockBypassed (buffer, midiBuffer);

  1556.         else

  1557.             processor.processBlock (buffer, midiBuffer);

  1558.     }

  1559. 

  1560.     //==============================================================================

  1561.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1562.     {

  1563.         if (param != nullptr)

  1564.         {

  1565.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1566.             {

  1567.                 auto normalisedValue = value / getMaximumParameterValue (p);

  1568.                 setAudioProcessorParameter (p, normalisedValue);

  1569.             }

  1570.         }

  1571.     }

  1572. 

  1573.     AUValue getValue (AUParameter* param)

  1574.     {

  1575.         if (param != nullptr)

  1576.         {

  1577.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1578.                 return p->getValue() * getMaximumParameterValue (p);

  1579.         }

  1580. 

  1581.         return 0;

  1582.     }

  1583. 

  1584.     void valueChangedForObserver (AUParameterAddress, AUValue)

  1585.     {

  1586.         // this will have already been handled by valueChangedFromHost

  1587.     }

  1588. 

  1589.     NSString* stringFromValue (AUParameter* param, const AUValue* value)

  1590.     {

  1591.         String text;

  1592. 

  1593.         if (param != nullptr && value != nullptr)

  1594.         {

  1595.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1596.             {

  1597.                 if (LegacyAudioParameter::isLegacy (p))

  1598.                     text = String (*value);

  1599.                 else

  1600.                     text = p->getText (*value / getMaximumParameterValue (p), 0);

  1601.             }

  1602.         }

  1603. 

  1604.         return juceStringToNS (text);

  1605.     }

  1606. 

  1607.     AUValue valueFromString (AUParameter* param, NSString* str)

  1608.     {

  1609.         if (param != nullptr && str != nullptr)

  1610.         {

  1611.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1612.             {

  1613.                 const String text (nsStringToJuce (str));

  1614. 

  1615.                 if (LegacyAudioParameter::isLegacy (p))

  1616.                     return text.getFloatValue();

  1617.                 else

  1618.                     return p->getValueForText (text) * getMaximumParameterValue (p);

  1619.             }

  1620.         }

  1621. 

  1622.         return 0;

  1623.     }

  1624. 

  1625.     //==============================================================================

  1626.     // this is only ever called for the bypass parameter

  1627.     void parameterValueChanged (int, float newValue) override

  1628.     {

  1629.         JuceAudioUnitv3Base::setShouldBypassEffect (newValue != 0.0f);

  1630.     }

  1631. 

  1632.     void parameterGestureChanged (int, bool) override {}

  1633. 

  1634.     //==============================================================================

  1635.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1636.     {

  1637.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1638.         return static_cast<AUParameterAddress> (paramIndex);

  1639.        #else

  1640.         return paramAddresses.getReference (paramIndex);

  1641.        #endif

  1642.     }

  1643. 

  1644.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1645.     {

  1646.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1647.         return static_cast<int> (address);

  1648.        #else

  1649.         return paramMap[static_cast<int64> (address)];

  1650.        #endif

  1651.     }

  1652. 

  1653.     AUParameterAddress generateAUParameterAddress (AudioProcessorParameter* param) const

  1654.     {

  1655.         const String& juceParamID = LegacyAudioParameter::getParamID (param, forceLegacyParamIDs);

  1656. 

  1657.         return static_cast<AUParameterAddress> (forceLegacyParamIDs ? juceParamID.getIntValue()

  1658.                                                                     : juceParamID.hashCode64());

  1659.     }

  1660. 

  1661.     AudioProcessorParameter* getJuceParameterForAUAddress (AUParameterAddress address) const noexcept

  1662.     {

  1663.         return juceParameters.getParamForIndex (getJuceParameterIndexForAUAddress (address));

  1664.     }

  1665. 

  1666.     //==============================================================================

  1667.     static const double kDefaultSampleRate;

  1668. 

  1669.     AudioProcessorHolder::Ptr processorHolder;

  1670. 

  1671.     int totalInChannels, totalOutChannels;

  1672. 

  1673.     std::unique_ptr<AUAudioUnitBusArray, NSObjectDeleter> inputBusses, outputBusses;

  1674. 

  1675.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1676.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1677.     ObjCBlock<AUImplementorStringFromValueCallback> stringFromValueProvider;

  1678.     ObjCBlock<AUImplementorValueFromStringCallback> valueFromStringProvider;

  1679. 

  1680.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1681.     Array<AUParameterAddress> paramAddresses;

  1682.     HashMap<int64, int> paramMap;

  1683.    #endif

  1684.     LegacyAudioParametersWrapper juceParameters;

  1685. 

  1686.     // to avoid recursion on parameter changes, we need to add an

  1687.     // editor observer to do the parameter changes

  1688.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1689.     AUParameterObserverToken editorObserverToken;

  1690. 

  1691.     std::unique_ptr<AUParameterTree, NSObjectDeleter> paramTree;

  1692.     std::unique_ptr<NSMutableArray<NSNumber*>, NSObjectDeleter> overviewParams, channelCapabilities;

  1693. 

  1694.     std::unique_ptr<NSMutableArray<AUAudioUnitPreset*>, NSObjectDeleter> factoryPresets;

  1695. 

  1696.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1697. 

  1698.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1699.     AudioUnitHelpers::ChannelRemapper mapper;

  1700. 

  1701.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1702.     MidiBuffer midiMessages;

  1703. 

  1704.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1705.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1706. 

  1707.     AudioTimeStamp lastTimeStamp;

  1708.     CurrentPositionInfo lastAudioHead;

  1709. 

  1710.     String contextName;

  1711. 

  1712.     ThreadLocalValue<bool> inParameterChangedCallback;

  1713.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1714.     static constexpr bool forceLegacyParamIDs = true;

  1715.    #else

  1716.     static constexpr bool forceLegacyParamIDs = false;

  1717.    #endif

  1718.     AudioProcessorParameter* bypassParam = nullptr;

  1719. };

  1720. 

  1721. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1722. 

  1723. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1724. {

  1725.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1726.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1727. }

  1728. 

  1729. #if JUCE_IOS

  1730. namespace juce

  1731. {

  1732. struct UIViewPeerControllerReceiver

  1733. {

  1734.     virtual ~UIViewPeerControllerReceiver();

  1735.     virtual void setViewController (UIViewController*) = 0;

  1736. };

  1737. }

  1738. #endif

  1739. 

  1740. //==============================================================================

  1741. class JuceAUViewController

  1742. {

  1743. public:

  1744.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1745.         : myself (p)

  1746.     {

  1747.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1748.         initialiseJuce_GUI();

  1749.     }

  1750. 

  1751.     ~JuceAUViewController()

  1752.     {

  1753.         JUCE_ASSERT_MESSAGE_THREAD

  1754. 

  1755.         if (processorHolder.get() != nullptr)

  1756.             JuceAudioUnitv3::removeEditor (getAudioProcessor());

  1757.     }

  1758. 

  1759.     //==============================================================================

  1760.     void loadView()

  1761.     {

  1762.         JUCE_ASSERT_MESSAGE_THREAD

  1763. 

  1764.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1765.         {

  1766.             processorHolder = new AudioProcessorHolder (p);

  1767.             auto& processor = getAudioProcessor();

  1768. 

  1769.             if (processor.hasEditor())

  1770.             {

  1771.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1772.                 {

  1773.                     preferredSize = editor->getBounds();

  1774. 

  1775.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1776.                     [myself setView: view];

  1777. 

  1778.                    #if JUCE_IOS

  1779.                     editor->setVisible (false);

  1780.                    #else

  1781.                     editor->setVisible (true);

  1782.                    #endif

  1783. 

  1784.                     editor->addToDesktop (0, view);

  1785. 

  1786.                    #if JUCE_IOS

  1787.                     if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1788.                         [peerView setContentMode: UIViewContentModeTop];

  1789. 

  1790.                     if (auto* peer = dynamic_cast<UIViewPeerControllerReceiver*> (editor->getPeer()))

  1791.                         peer->setViewController (myself);

  1792.                    #endif

  1793.                 }

  1794.             }

  1795.         }

  1796.     }

  1797. 

  1798.     void viewDidLayoutSubviews()

  1799.     {

  1800.         if (auto holder = processorHolder.get())

  1801.         {

  1802.             if ([myself view] != nullptr)

  1803.             {

  1804.                 if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1805.                 {

  1806.                     if (holder->viewConfiguration != nullptr)

  1807.                         editor->hostMIDIControllerIsAvailable (holder->viewConfiguration->hostHasMIDIController);

  1808. 

  1809.                     editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1810. 

  1811.                     if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1812.                     {

  1813.                        #if JUCE_IOS

  1814.                         [peerView setNeedsDisplay];

  1815.                        #else

  1816.                         [peerView setNeedsDisplay: YES];

  1817.                        #endif

  1818.                     }

  1819.                 }

  1820.             }

  1821.         }

  1822.     }

  1823. 

  1824.     void didReceiveMemoryWarning()

  1825.     {

  1826.         if (auto ptr = processorHolder.get())

  1827.             if (auto* processor = ptr->get())

  1828.                 processor->memoryWarningReceived();

  1829.     }

  1830. 

  1831.     void viewDidAppear (bool)

  1832.     {

  1833.         if (processorHolder.get() != nullptr)

  1834.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1835.                 editor->setVisible (true);

  1836.     }

  1837. 

  1838.     void viewDidDisappear (bool)

  1839.     {

  1840.         if (processorHolder.get() != nullptr)

  1841.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1842.                 editor->setVisible (false);

  1843.     }

  1844. 

  1845.     CGSize getPreferredContentSize() const

  1846.     {

  1847.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1848.                            static_cast<float> (preferredSize.getHeight()));

  1849.     }

  1850. 

  1851.     //==============================================================================

  1852.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1853.     {

  1854.         const auto holder = [&]

  1855.         {

  1856.             if (auto initialisedHolder = processorHolder.get())

  1857.                 return initialisedHolder;

  1858. 

  1859.             waitForExecutionOnMainThread ([this] { [myself view]; });

  1860.             return processorHolder.get();

  1861.         }();

  1862. 

  1863.         if (holder == nullptr)

  1864.             return nullptr;

  1865. 

  1866.         return (new JuceAudioUnitv3 (holder, descr, 0, error))->getAudioUnit();

  1867.     }

  1868. 

  1869. private:

  1870.     template <typename Callback>

  1871.     static void waitForExecutionOnMainThread (Callback&& callback)

  1872.     {

  1873.         if (MessageManager::getInstance()->isThisTheMessageThread())

  1874.         {

  1875.             callback();

  1876.             return;

  1877.         }

  1878. 

  1879.         std::promise<void> promise;

  1880. 

  1881.         MessageManager::callAsync ([&]

  1882.         {

  1883.             callback();

  1884.             promise.set_value();

  1885.         });

  1886. 

  1887.         promise.get_future().get();

  1888.     }

  1889. 

  1890.     // There's a chance that createAudioUnit will be called from a background

  1891.     // thread while the processorHolder is being updated on the main thread.

  1892.     class LockedProcessorHolder

  1893.     {

  1894.     public:

  1895.         AudioProcessorHolder::Ptr get() const

  1896.         {

  1897.             const ScopedLock lock (mutex);

  1898.             return holder;

  1899.         }

  1900. 

  1901.         LockedProcessorHolder& operator= (const AudioProcessorHolder::Ptr& other)

  1902.         {

  1903.             const ScopedLock lock (mutex);

  1904.             holder = other;

  1905.             return *this;

  1906.         }

  1907. 

  1908.     private:

  1909.         mutable CriticalSection mutex;

  1910.         AudioProcessorHolder::Ptr holder;

  1911.     };

  1912. 

  1913.     //==============================================================================

  1914.     AUViewController<AUAudioUnitFactory>* myself;

  1915.     LockedProcessorHolder processorHolder;

  1916.     Rectangle<int> preferredSize { 1, 1 };

  1917. 

  1918.     //==============================================================================

  1919.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder.get(); }

  1920. };

  1921. 

  1922. //==============================================================================

  1923. // necessary glue code

  1924. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  1925. @end

  1926. 

  1927. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  1928. {

  1929.     std::unique_ptr<JuceAUViewController> cpp;

  1930. }

  1931. 

  1932. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp.reset (new JuceAUViewController (self)); return self; }

  1933. - (void) loadView                { cpp->loadView(); }

  1934. - (AUAudioUnit *) createAudioUnitWithComponentDescription: (AudioComponentDescription) desc error: (NSError **) error { return cpp->createAudioUnit (desc, error); }

  1935. - (CGSize) preferredContentSize  { return cpp->getPreferredContentSize(); }

  1936. - (void) viewDidLayoutSubviews   { cpp->viewDidLayoutSubviews(); }

  1937. - (void) didReceiveMemoryWarning { cpp->didReceiveMemoryWarning(); }

  1938. #if JUCE_IOS

  1939. - (void) viewDidAppear: (BOOL) animated { cpp->viewDidAppear (animated); [super viewDidAppear:animated]; }

  1940. - (void) viewDidDisappear: (BOOL) animated { cpp->viewDidDisappear (animated); [super viewDidDisappear:animated]; }

  1941. #endif

  1942. @end

  1943. 

  1944. //==============================================================================

  1945. #if JUCE_IOS

  1946. bool JUCE_CALLTYPE juce_isInterAppAudioConnected() { return false; }

  1947. void JUCE_CALLTYPE juce_switchToHostApplication()  {}

  1948. Image JUCE_CALLTYPE juce_getIAAHostIcon (int)      { return {}; }

  1949. #endif

  1950. 

  1951. JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  1952. #endif