DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
9080 Commits
11 Branches
450MB
Tree: 955f6fbc2b
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '955f6fbc2b'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

1861 lines
80KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2017 - ROLI Ltd.

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 5 End-User License

  11.    Agreement and JUCE 5 Privacy Policy (both updated and effective as of the

  12.    27th April 2017).

  13. 

  14.    End User License Agreement: www.juce.com/juce-5-licence

  15.    Privacy Policy: www.juce.com/juce-5-privacy-policy

  16. 

  17.    Or: You may also use this code under the terms of the GPL v3 (see

  18.    www.gnu.org/licenses).

  19. 

  20.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  21.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  22.    DISCLAIMED.

  23. 

  24.   ==============================================================================

  25. */

  26. 

  27. #include "../../juce_core/system/juce_TargetPlatform.h"

  28. #include "../utility/juce_CheckSettingMacros.h"

  29. 

  30. #if JucePlugin_Build_AUv3

  31. 

  32. #import <CoreAudioKit/CoreAudioKit.h>

  33. #import <AudioToolbox/AudioToolbox.h>

  34. #import <AVFoundation/AVFoundation.h>

  35. 

  36. #if JUCE_MAC

  37.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  38.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  39.  #endif

  40.  #if (defined MAC_OS_X_VERSION_10_13) && (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_13)

  41.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  42.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  43.  #endif

  44. #endif

  45. 

  46. #if JUCE_IOS

  47.  #if (! defined __IPHONE_OS_VERSION_MIN_REQUIRED) || (! defined __IPHONE_9_0) || (__IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_9_0)

  48.   #error AUv3 needs Deployment Target iOS 9.0 or higher to compile

  49.  #endif

  50.  #if (defined __IPHONE_11_0) && (__IPHONE_OS_VERSION_MIN_REQUIRED >= __IPHONE_11_0)

  51.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  52.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  53.  #endif

  54. #endif

  55. 

  56. #ifndef __OBJC2__

  57.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  58. #endif

  59. 

  60. #define JUCE_CORE_INCLUDE_OBJC_HELPERS 1

  61. 

  62. #include "../utility/juce_IncludeSystemHeaders.h"

  63. #include "../utility/juce_IncludeModuleHeaders.h"

  64. #include "../../juce_graphics/native/juce_mac_CoreGraphicsHelpers.h"

  65. 

  66. #include "../../juce_audio_basics/native/juce_mac_CoreAudioLayouts.h"

  67. #include "../../juce_audio_processors/format_types/juce_LegacyAudioParameter.cpp"

  68. #include "../../juce_audio_processors/format_types/juce_AU_Shared.h"

  69. 

  70. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  71. 

  72. #if JUCE_IOS

  73.  #define JUCE_IOS_MAC_VIEW  UIView

  74. #else

  75.  #define JUCE_IOS_MAC_VIEW  NSView

  76. #endif

  77. 

  78. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  79. 

  80. #pragma clang diagnostic push

  81. #pragma clang diagnostic ignored "-Wnullability-completeness"

  82. 

  83. using namespace juce;

  84. 

  85. struct AudioProcessorHolder  : public ReferenceCountedObject

  86. {

  87.     AudioProcessorHolder() {}

  88.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  89.     AudioProcessor& operator*() noexcept        { return *processor; }

  90.     AudioProcessor* operator->() noexcept       { return processor.get(); }

  91.     AudioProcessor* get() noexcept              { return processor.get(); }

  92. 

  93.     struct ViewConfig

  94.     {

  95.         double width;

  96.         double height;

  97.         bool hostHasMIDIController;

  98.     };

  99. 

  100.     std::unique_ptr<ViewConfig> viewConfiguration;

  101. 

  102.     using Ptr = ReferenceCountedObjectPtr<AudioProcessorHolder>;

  103. 

  104. private:

  105.     std::unique_ptr<AudioProcessor> processor;

  106. 

  107.     AudioProcessorHolder& operator= (AudioProcessor*) = delete;

  108.     AudioProcessorHolder (AudioProcessorHolder&) = delete;

  109.     AudioProcessorHolder& operator= (AudioProcessorHolder&) = delete;

  110. };

  111. 

  112. //==============================================================================

  113. class JuceAudioUnitv3Base

  114. {

  115. public:

  116.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  117.                          AudioComponentInstantiationOptions options,

  118.                          NSError** error)

  119.        #pragma clang diagnostic push

  120.        #pragma clang diagnostic ignored "-Wobjc-method-access"

  121.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  122.                                                                         options: options

  123.                                                                           error: error

  124.                                                                       juceClass: this])

  125.        #pragma clang diagnostic pop

  126.     {}

  127. 

  128.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  129.     {

  130.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  131.         initialiseJuce_GUI();

  132.     }

  133. 

  134.     virtual ~JuceAudioUnitv3Base() {}

  135. 

  136.     //==============================================================================

  137.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  138. 

  139.     //==============================================================================

  140.     virtual void reset()                                                   = 0;

  141. 

  142.     //==============================================================================

  143.     virtual AUAudioUnitPreset* getCurrentPreset()                          = 0;

  144.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      = 0;

  145.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()               = 0;

  146. 

  147.     virtual NSDictionary<NSString*, id>* getFullState()

  148.     {

  149.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  150.         return ObjCMsgSendSuper<NSDictionary<NSString*, id>*> (&s, @selector (fullState));

  151.     }

  152. 

  153.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  154.     {

  155.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  156.         ObjCMsgSendSuper<void, NSDictionary<NSString*, id>*> (&s, @selector (setFullState:), state);

  157.     }

  158. 

  159.     virtual AUParameterTree* getParameterTree()                            = 0;

  160.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)       = 0;

  161. 

  162.     //==============================================================================

  163.     virtual NSTimeInterval getLatency()                                    = 0;

  164.     virtual NSTimeInterval getTailTime()                                   = 0;

  165. 

  166.     //==============================================================================

  167.     virtual AUAudioUnitBusArray* getInputBusses()                          = 0;

  168.     virtual AUAudioUnitBusArray* getOutputBusses()                         = 0;

  169.     virtual NSArray<NSNumber*>* getChannelCapabilities()                   = 0;

  170.     virtual bool shouldChangeToFormat (AVAudioFormat*, AUAudioUnitBus*)    = 0;

  171. 

  172.     //==============================================================================

  173.     virtual int getVirtualMIDICableCount()                                 = 0;

  174.     virtual bool getSupportsMPE()                                          = 0;

  175.     virtual NSArray<NSString*>* getMIDIOutputNames()                       = 0;

  176. 

  177.     //==============================================================================

  178.     virtual AUInternalRenderBlock getInternalRenderBlock()                 = 0;

  179.     virtual bool getCanProcessInPlace()                                    { return false; }

  180.     virtual bool getRenderingOffline()                                     = 0;

  181.     virtual void setRenderingOffline (bool offline)                        = 0;

  182. 

  183.     virtual bool getShouldBypassEffect()

  184.     {

  185.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  186.         return (ObjCMsgSendSuper<BOOL> (&s, @selector (shouldBypassEffect)) == YES);

  187.     }

  188. 

  189.     virtual void setShouldBypassEffect (bool shouldBypass)

  190.     {

  191.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  192.         ObjCMsgSendSuper<void, BOOL> (&s, @selector (setShouldBypassEffect:), shouldBypass ? YES : NO);

  193.     }

  194. 

  195.     //==============================================================================

  196.     virtual NSString* getContextName()      const                          = 0;

  197.     virtual void setContextName (NSString*)                                = 0;

  198. 

  199.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  200.     {

  201.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  202.         return (ObjCMsgSendSuper<BOOL, NSError**> (&s, @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  203.     }

  204. 

  205.     virtual void deallocateRenderResources()

  206.     {

  207.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  208.         ObjCMsgSendSuper<void> (&s, @selector (deallocateRenderResources));

  209.     }

  210. 

  211.     //==============================================================================

  212.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  213.     virtual NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>*) = 0;

  214.     virtual void selectViewConfiguration (AUAudioUnitViewConfiguration*)   = 0;

  215.    #endif

  216. 

  217. private:

  218.     struct Class  : public ObjCClass<AUAudioUnit>

  219.     {

  220.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  221.         {

  222.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  223. 

  224.            #pragma clang diagnostic push

  225.            #pragma clang diagnostic ignored "-Wundeclared-selector"

  226.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  227.                        initWithComponentDescriptionAndJuceClass, "@@:",

  228.                        @encode (AudioComponentDescription),

  229.                        @encode (AudioComponentInstantiationOptions), "^@@");

  230.            #pragma clang diagnostic pop

  231. 

  232.             addMethod (@selector (initWithComponentDescription:options:error:),

  233.                        initWithComponentDescription, "@@:",

  234.                        @encode (AudioComponentDescription),

  235.                        @encode (AudioComponentInstantiationOptions), "^@");

  236. 

  237.             addMethod (@selector (dealloc),                         dealloc,                        "v@:");

  238. 

  239.             //==============================================================================

  240.             addMethod (@selector (reset),                           reset,                          "v@:");

  241. 

  242.             //==============================================================================

  243.             addMethod (@selector (currentPreset),                   getCurrentPreset,               "@@:");

  244.             addMethod (@selector (setCurrentPreset:),               setCurrentPreset,               "v@:@");

  245.             addMethod (@selector (factoryPresets),                  getFactoryPresets,              "@@:");

  246.             addMethod (@selector (fullState),                       getFullState,                   "@@:");

  247.             addMethod (@selector (setFullState:),                   setFullState,                   "v@:@");

  248.             addMethod (@selector (parameterTree),                   getParameterTree,               "@@:");

  249.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  250. 

  251.             //==============================================================================

  252.             addMethod (@selector (latency),                         getLatency,                     @encode (NSTimeInterval), "@:");

  253.             addMethod (@selector (tailTime),                        getTailTime,                    @encode (NSTimeInterval),  "@:");

  254. 

  255.             //==============================================================================

  256.             addMethod (@selector (inputBusses),                     getInputBusses,                 "@@:");

  257.             addMethod (@selector (outputBusses),                    getOutputBusses,                "@@:");

  258.             addMethod (@selector (channelCapabilities),             getChannelCapabilities,         "@@:");

  259.             addMethod (@selector (shouldChangeToFormat:forBus:),    shouldChangeToFormat,           "B@:@@");

  260. 

  261.             //==============================================================================

  262.             addMethod (@selector (virtualMIDICableCount),           getVirtualMIDICableCount,       @encode (NSInteger), "@:");

  263.             addMethod (@selector (supportsMPE),                     getSupportsMPE,                 @encode (BOOL),      "@:");

  264. 

  265.            #if JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  266.             addMethod (@selector (MIDIOutputNames),                 getMIDIOutputNames,             "@@:");

  267.            #endif

  268. 

  269.             //==============================================================================

  270.             addMethod (@selector (internalRenderBlock),             getInternalRenderBlock,         @encode (AUInternalRenderBlock), "@:");

  271.             addMethod (@selector (canProcessInPlace),               getCanProcessInPlace,           @encode (BOOL), "@:");

  272.             addMethod (@selector (isRenderingOffline),              getRenderingOffline,            @encode (BOOL),  "@:");

  273.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  274.             addMethod (@selector (shouldBypassEffect),              getShouldBypassEffect,          @encode (BOOL),  "@:");

  275.             addMethod (@selector (setShouldBypassEffect:),          setShouldBypassEffect,          "v@:", @encode (BOOL));

  276.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "B@:^@");

  277.             addMethod (@selector (deallocateRenderResources),       deallocateRenderResources,      "v@:");

  278. 

  279.             //==============================================================================

  280.             addMethod (@selector (contextName),                     getContextName,                 "@@:");

  281.             addMethod (@selector (setContextName:),                  setContextName,                 "v@:@");

  282. 

  283.             //==============================================================================

  284.            #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  285.             addMethod (@selector (supportedViewConfigurations:),    getSupportedViewConfigurations, "@@:@");

  286.             addMethod (@selector (selectViewConfiguration:),        selectViewConfiguration,        "v@:@");

  287.            #endif

  288. 

  289.             registerClass();

  290.         }

  291. 

  292.         //==============================================================================

  293.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  294.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  295. 

  296.         //==============================================================================

  297.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  298.         {

  299.             AUAudioUnit* self = _self;

  300. 

  301.             objc_super s = { self, [AUAudioUnit class] };

  302.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  303.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  304. 

  305.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  306. 

  307.             setThis (self, juceAU);

  308.             return self;

  309.         }

  310. 

  311.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  312.         {

  313.             AUAudioUnit* self = _self;

  314. 

  315.             objc_super s = { self, [AUAudioUnit class] };

  316.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  317.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  318. 

  319. 

  320.             setThis (self, juceAU);

  321.             return self;

  322.         }

  323. 

  324.         static void dealloc (id self, SEL)

  325.         {

  326.             if (! MessageManager::getInstance()->isThisTheMessageThread())

  327.             {

  328.                 WaitableEvent deletionEvent;

  329. 

  330.                 struct AUDeleter  : public CallbackMessage

  331.                 {

  332.                     AUDeleter (id selfToDelete, WaitableEvent& event)

  333.                         : parentSelf (selfToDelete), parentDeletionEvent (event)

  334.                     {

  335.                     }

  336. 

  337.                     void messageCallback() override

  338.                     {

  339.                         delete _this (parentSelf);

  340.                         parentDeletionEvent.signal();

  341.                     }

  342. 

  343.                     id parentSelf;

  344.                     WaitableEvent& parentDeletionEvent;

  345.                 };

  346. 

  347.                 (new AUDeleter (self, deletionEvent))->post();

  348.                 deletionEvent.wait (-1);

  349.             }

  350.             else

  351.             {

  352.                 delete _this (self);

  353.             }

  354.         }

  355. 

  356.         //==============================================================================

  357.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  358. 

  359.         //==============================================================================

  360.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  361.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  362.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  363.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  364.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  365.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  366.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  367. 

  368.         //==============================================================================

  369.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  370.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  371. 

  372.         //==============================================================================

  373.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  374.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  375.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  376.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  377. 

  378.         //==============================================================================

  379.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  380.         static BOOL getSupportsMPE (id self, SEL)                                                   { return _this (self)->getSupportsMPE() ? YES : NO; }

  381.         static NSArray<NSString*>* getMIDIOutputNames (id self, SEL)                                { return _this (self)->getMIDIOutputNames(); }

  382. 

  383.         //==============================================================================

  384.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  385.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  386.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  387.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  388.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  389.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  390.         static BOOL getShouldBypassEffect (id self, SEL)                                            { return _this (self)->getShouldBypassEffect() ? YES : NO; }

  391.         static void setShouldBypassEffect (id self, SEL, BOOL shouldBypass)                         { _this (self)->setShouldBypassEffect (shouldBypass); }

  392. 

  393.         //==============================================================================

  394.         static NSString* getContextName (id self, SEL)                                              { return _this (self)->getContextName(); }

  395.         static void setContextName (id self, SEL, NSString* str)                                    { return _this (self)->setContextName (str); }

  396. 

  397.         //==============================================================================

  398.        #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  399.         static NSIndexSet* getSupportedViewConfigurations (id self, SEL, NSArray<AUAudioUnitViewConfiguration*>* configs) { return _this (self)->getSupportedViewConfigurations (configs); }

  400.         static void selectViewConfiguration (id self, SEL, AUAudioUnitViewConfiguration* config)    { _this (self)->selectViewConfiguration (config); }

  401.        #endif

  402.     };

  403. 

  404.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  405. 

  406.     //==============================================================================

  407.     static Class audioUnitObjCClass;

  408. 

  409. protected:

  410.     AUAudioUnit* au;

  411. };

  412. 

  413. //==============================================================================

  414. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  415. 

  416. //==============================================================================

  417. //=========================== The actual AudioUnit =============================

  418. //==============================================================================

  419. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  420.                          public AudioProcessorListener,

  421.                          public AudioPlayHead,

  422.                          private AudioProcessorParameter::Listener

  423. {

  424. public:

  425.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  426.                      const AudioComponentDescription& descr,

  427.                      AudioComponentInstantiationOptions options,

  428.                      NSError** error)

  429.         : JuceAudioUnitv3Base (descr, options, error),

  430.           processorHolder (processor),

  431.           mapper (*processorHolder->get())

  432.     {

  433.         init();

  434.     }

  435. 

  436.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  437.         : JuceAudioUnitv3Base (audioUnit),

  438.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  439.           mapper (*processorHolder->get())

  440.     {

  441.         init();

  442.     }

  443. 

  444.     ~JuceAudioUnitv3()

  445.     {

  446.         auto& processor = getAudioProcessor();

  447.         processor.removeListener (this);

  448. 

  449.         if (bypassParam != nullptr)

  450.             bypassParam->removeListener (this);

  451. 

  452.         removeEditor (processor);

  453. 

  454.         if (editorObserverToken != nullptr)

  455.         {

  456.             [paramTree.get() removeParameterObserver: editorObserverToken];

  457.             editorObserverToken = nullptr;

  458.         }

  459.     }

  460. 

  461.     //==============================================================================

  462.     void init()

  463.     {

  464.         inParameterChangedCallback = false;

  465. 

  466.         AudioProcessor& processor = getAudioProcessor();

  467.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  468. 

  469.        #ifdef JucePlugin_PreferredChannelConfigurations

  470.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  471.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  472. 

  473.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  474.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  475. 

  476.         Array<AUChannelInfo> channelInfos;

  477. 

  478.         for (int i = 0; i < numConfigs; ++i)

  479.         {

  480.             AUChannelInfo channelInfo;

  481. 

  482.             channelInfo.inChannels  = configs[i][0];

  483.             channelInfo.outChannels = configs[i][1];

  484. 

  485.             channelInfos.add (channelInfo);

  486.         }

  487.        #else

  488.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  489.        #endif

  490. 

  491.         processor.setPlayHead (this);

  492. 

  493.         totalInChannels  = processor.getTotalNumInputChannels();

  494.         totalOutChannels = processor.getTotalNumOutputChannels();

  495. 

  496.         {

  497.             channelCapabilities.reset ([[NSMutableArray<NSNumber*> alloc] init]);

  498. 

  499.             for (int i = 0; i < channelInfos.size(); ++i)

  500.             {

  501.                 AUChannelInfo& info = channelInfos.getReference (i);

  502. 

  503.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.inChannels]];

  504.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.outChannels]];

  505.             }

  506.         }

  507. 

  508.         editorObserverToken = nullptr;

  509.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  510. 

  511.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  512.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  513.         processor.addListener (this);

  514. 

  515.         addParameters();

  516.         addPresets();

  517. 

  518.         addAudioUnitBusses (true);

  519.         addAudioUnitBusses (false);

  520.     }

  521. 

  522.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  523. 

  524.     //==============================================================================

  525.     void reset() override

  526.     {

  527.         midiMessages.clear();

  528.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  529.     }

  530. 

  531.     //==============================================================================

  532.     AUAudioUnitPreset* getCurrentPreset() override

  533.     {

  534.         const int n = static_cast<int> ([factoryPresets.get() count]);

  535.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  536. 

  537.         if (idx < n)

  538.             return [factoryPresets.get() objectAtIndex:static_cast<unsigned int> (idx)];

  539. 

  540.         return nullptr;

  541.     }

  542. 

  543.     void setCurrentPreset(AUAudioUnitPreset* preset) override

  544.     {

  545.         const int n = static_cast<int> ([factoryPresets.get() count]);

  546.         const int idx = static_cast<int> ([preset number]);

  547. 

  548.         if (isPositiveAndBelow (idx, n))

  549.             getAudioProcessor().setCurrentProgram (idx);

  550.     }

  551. 

  552.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override

  553.     {

  554.         return factoryPresets.get();

  555.     }

  556. 

  557.     NSDictionary<NSString*, id>* getFullState() override

  558.     {

  559.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  560. 

  561.         {

  562.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  563. 

  564.             if (superRetval != nullptr)

  565.                 [retval addEntriesFromDictionary:superRetval];

  566.         }

  567. 

  568.         juce::MemoryBlock state;

  569.         getAudioProcessor().getCurrentProgramStateInformation (state);

  570. 

  571.         if (state.getSize() > 0)

  572.         {

  573.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  574.                                                       length: state.getSize()];

  575. 

  576.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  577. 

  578.             [retval setObject: ourState

  579.                        forKey: nsKey];

  580. 

  581.             [nsKey    release];

  582.             [ourState release];

  583.         }

  584. 

  585.         return [retval autorelease];

  586.     }

  587. 

  588.     void setFullState (NSDictionary<NSString*, id>* state) override

  589.     {

  590.         if (state == nullptr)

  591.             return;

  592. 

  593.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  594.         [modifiedState addEntriesFromDictionary: state];

  595. 

  596.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  597.         [modifiedState removeObjectForKey: nsPresetKey];

  598.         [nsPresetKey release];

  599. 

  600.         JuceAudioUnitv3Base::setFullState (modifiedState);

  601. 

  602.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  603.         NSObject* obj = [modifiedState objectForKey: nsKey];

  604.         [nsKey release];

  605. 

  606.         if (obj != nullptr)

  607.         {

  608.             if ([obj isKindOfClass:[NSData class]])

  609.             {

  610.                 NSData* data = reinterpret_cast<NSData*> (obj);

  611.                 const int numBytes = static_cast<int> ([data length]);

  612.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  613. 

  614.                 if (numBytes > 0)

  615.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  616.             }

  617.         }

  618. 

  619.         [modifiedState release];

  620.     }

  621. 

  622.     AUParameterTree* getParameterTree() override

  623.     {

  624.         return paramTree.get();

  625.     }

  626. 

  627.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  628.     {

  629.         const int n = static_cast<int> ([overviewParams.get() count]);

  630. 

  631.         if (count >= n)

  632.             return overviewParams.get();

  633. 

  634.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams.get()];

  635.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  636. 

  637.         return [retval autorelease];

  638.     }

  639. 

  640.     //==============================================================================

  641.     NSTimeInterval getLatency() override

  642.     {

  643.         auto& p = getAudioProcessor();

  644.         return p.getLatencySamples() / p.getSampleRate();

  645.     }

  646. 

  647.     NSTimeInterval getTailTime() override

  648.     {

  649.         return getAudioProcessor().getTailLengthSeconds();

  650.     }

  651. 

  652.     //==============================================================================

  653.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses.get();  }

  654.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses.get(); }

  655.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities.get(); }

  656. 

  657.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  658.     {

  659.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  660.         const int busIdx = static_cast<int> ([auBus index]);

  661.         const int newNumChannels = static_cast<int> ([format channelCount]);

  662. 

  663.         AudioProcessor& processor = getAudioProcessor();

  664. 

  665.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  666.         {

  667.           #ifdef JucePlugin_PreferredChannelConfigurations

  668.             ignoreUnused (bus);

  669. 

  670.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  671. 

  672.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  673.                 return false;

  674.           #else

  675.             const AVAudioChannelLayout* layout    = [format channelLayout];

  676.             const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  677. 

  678.             if (layoutTag != 0)

  679.             {

  680.                 AudioChannelSet newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  681. 

  682.                 if (newLayout.size() != newNumChannels)

  683.                     return false;

  684. 

  685.                 if (! bus->isLayoutSupported (newLayout))

  686.                     return false;

  687.             }

  688.             else

  689.             {

  690.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  691.                     return false;

  692.             }

  693.            #endif

  694. 

  695.             return true;

  696.         }

  697. 

  698.         return false;

  699.     }

  700. 

  701.     //==============================================================================

  702.     int getVirtualMIDICableCount() override

  703.     {

  704.        #if JucePlugin_WantsMidiInput

  705.         return 1;

  706.        #else

  707.         return 0;

  708.        #endif

  709.     }

  710. 

  711.     bool getSupportsMPE() override

  712.     {

  713.         return getAudioProcessor().supportsMPE();

  714.     }

  715. 

  716.     NSArray<NSString*>* getMIDIOutputNames() override

  717.     {

  718.        #if JucePlugin_ProducesMidiOutput

  719.         return @[@"MIDI Out"];

  720.        #else

  721.         return @[];

  722.        #endif

  723.     }

  724. 

  725.     //==============================================================================

  726.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  727.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  728.     void setRenderingOffline (bool offline) override

  729.     {

  730.         auto& processor = getAudioProcessor();

  731.         auto isCurrentlyNonRealtime = processor.isNonRealtime();

  732. 

  733.         if (isCurrentlyNonRealtime != offline)

  734.         {

  735.             ScopedLock callbackLock (processor.getCallbackLock());

  736. 

  737.             processor.setNonRealtime (offline);

  738.             processor.prepareToPlay (processor.getSampleRate(), processor.getBlockSize());

  739.         }

  740.     }

  741. 

  742.     bool getShouldBypassEffect() override

  743.     {

  744.         if (bypassParam != nullptr)

  745.             return (bypassParam->getValue() != 0.0f);

  746. 

  747.         return JuceAudioUnitv3Base::getShouldBypassEffect();

  748.     }

  749. 

  750.     void setShouldBypassEffect (bool shouldBypass) override

  751.     {

  752.         if (bypassParam != nullptr)

  753.             bypassParam->setValue (shouldBypass ? 1.0f : 0.0f);

  754. 

  755.         JuceAudioUnitv3Base::setShouldBypassEffect (shouldBypass);

  756.     }

  757. 

  758.     //==============================================================================

  759.     NSString* getContextName() const    override              { return juceStringToNS (contextName); }

  760.     void setContextName (NSString* str) override

  761.     {

  762.         if (str != nullptr)

  763.         {

  764.             AudioProcessor::TrackProperties props;

  765.             props.name = nsStringToJuce (str);

  766. 

  767.             getAudioProcessor().updateTrackProperties (props);

  768.         }

  769.     }

  770. 

  771.     //==============================================================================

  772.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  773.     {

  774.         AudioProcessor& processor = getAudioProcessor();

  775.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  776. 

  777.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  778.             return false;

  779. 

  780.         if (outError != nullptr)

  781.             *outError = nullptr;

  782. 

  783.         AudioProcessor::BusesLayout layouts;

  784.         for (int dir = 0; dir < 2; ++dir)

  785.         {

  786.             const bool isInput = (dir == 0);

  787.             const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  788.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  789. 

  790.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  791.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  792. 

  793.             for (int busIdx = 0; busIdx < n; ++busIdx)

  794.             {

  795.                 AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx);

  796.                 AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  797. 

  798.                 AudioChannelSet newLayout;

  799.                 const AVAudioChannelLayout* layout    = [format channelLayout];

  800.                 const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  801. 

  802.                 if (layoutTag != 0)

  803.                     newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  804.                 else

  805.                     newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  806. 

  807.                 if (newLayout.isDisabled())

  808.                     return false;

  809. 

  810.                 channelSets.add (newLayout);

  811.             }

  812.         }

  813. 

  814.        #ifdef JucePlugin_PreferredChannelConfigurations

  815.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  816. 

  817.         if (! AudioProcessor::containsLayout (layouts, configs))

  818.         {

  819.             if (outError != nullptr)

  820.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  821. 

  822.             return false;

  823.         }

  824.        #endif

  825. 

  826.         if (! AudioUnitHelpers::setBusesLayout (&getAudioProcessor(), layouts))

  827.         {

  828.             if (outError != nullptr)

  829.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  830. 

  831.             return false;

  832.         }

  833. 

  834.         totalInChannels  = processor.getTotalNumInputChannels();

  835.         totalOutChannels = processor.getTotalNumOutputChannels();

  836. 

  837.         allocateBusBuffer (true);

  838.         allocateBusBuffer (false);

  839. 

  840.         mapper.alloc();

  841. 

  842.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  843. 

  844.         double sampleRate = (jmax (AudioUnitHelpers::getBusCount (&processor, true), AudioUnitHelpers::getBusCount (&processor, false)) > 0 ?

  845.                              [[[([inputBusses.get() count] > 0 ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: 0] format] sampleRate] : 44100.0);

  846. 

  847.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  848.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  849. 

  850.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  851.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  852.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  853. 

  854.         reset();

  855. 

  856.         return true;

  857.     }

  858. 

  859.     void deallocateRenderResources() override

  860.     {

  861.         hostMusicalContextCallback = nullptr;

  862.         hostTransportStateCallback = nullptr;

  863. 

  864.         getAudioProcessor().releaseResources();

  865.         audioBuffer.release();

  866. 

  867.         inBusBuffers. clear();

  868.         outBusBuffers.clear();

  869. 

  870.         mapper.release();

  871. 

  872.         JuceAudioUnitv3Base::deallocateRenderResources();

  873.     }

  874. 

  875.     //==============================================================================

  876.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  877.     NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>* configs) override

  878.     {

  879.         auto supportedViewIndecies = [[NSMutableIndexSet alloc] init];

  880.         auto n = [configs count];

  881. 

  882.         if (auto* editor = getAudioProcessor().createEditorIfNeeded())

  883.         {

  884.             // If you hit this assertion then your plug-in's editor is reporting that it doesn't support

  885.             // any host MIDI controller configurations!

  886.             jassert (editor->supportsHostMIDIControllerPresence (true) || editor->supportsHostMIDIControllerPresence (false));

  887. 

  888.             for (auto i = 0u; i < n; ++i)

  889.             {

  890.                 if (auto* viewConfiguration = [configs objectAtIndex:i])

  891.                 {

  892.                     if (editor->supportsHostMIDIControllerPresence ([viewConfiguration hostHasController] == YES))

  893.                     {

  894.                         auto* constrainer = editor->getConstrainer();

  895.                         auto height = (int) [viewConfiguration height];

  896.                         auto width  = (int) [viewConfiguration width];

  897. 

  898.                         if (height <= constrainer->getMaximumHeight() && height >= constrainer->getMinimumHeight()

  899.                          && width  <= constrainer->getMaximumWidth()  && width  >= constrainer->getMinimumWidth())

  900.                             [supportedViewIndecies addIndex: i];

  901.                     }

  902.                 }

  903.             }

  904.         }

  905. 

  906.         return [supportedViewIndecies autorelease];

  907.     }

  908. 

  909.     void selectViewConfiguration (AUAudioUnitViewConfiguration* config) override

  910.     {

  911.         processorHolder->viewConfiguration.reset (new AudioProcessorHolder::ViewConfig { [config width], [config height], [config hostHasController] == YES });

  912.     }

  913.    #endif

  914. 

  915.     //==============================================================================

  916.     void audioProcessorChanged (AudioProcessor* processor) override

  917.     {

  918.         ignoreUnused (processor);

  919. 

  920.         [au willChangeValueForKey: @"allParameterValues"];

  921.         addPresets();

  922.         [au didChangeValueForKey: @"allParameterValues"];

  923.     }

  924. 

  925.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  926.     {

  927.         if (inParameterChangedCallback.get())

  928.         {

  929.             inParameterChangedCallback = false;

  930.             return;

  931.         }

  932. 

  933.         if (isPositiveAndBelow (idx, juceParameters.getNumParameters()))

  934.         {

  935.             if (AUParameter* param = [paramTree.get() parameterWithAddress: getAUParameterAddressForIndex (idx)])

  936.             {

  937.                 if (editorObserverToken != nullptr)

  938.                     [param setValue: newValue  originator: editorObserverToken];

  939.                 else

  940.                     [param setValue: newValue];

  941.             }

  942.         }

  943.     }

  944. 

  945.     //==============================================================================

  946.     bool getCurrentPosition (CurrentPositionInfo& info) override

  947.     {

  948.         bool musicContextCallSucceeded = false;

  949.         bool transportStateCallSucceeded = false;

  950. 

  951.         info = lastAudioHead;

  952.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  953.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  954. 

  955.         switch (lastTimeStamp.mSMPTETime.mType)

  956.         {

  957.             case kSMPTETimeType2398:        info.frameRate = AudioPlayHead::fps23976; break;

  958.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24; break;

  959.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25; break;

  960.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997; break;

  961.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  962.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop; break;

  963.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30; break;

  964.             case kSMPTETimeType60Drop:      info.frameRate = AudioPlayHead::fps60drop; break;

  965.             case kSMPTETimeType60:          info.frameRate = AudioPlayHead::fps60; break;

  966.             default:                        info.frameRate = AudioPlayHead::fpsUnknown; break;

  967.         }

  968. 

  969.         double num;

  970.         NSInteger den;

  971.         NSInteger outDeltaSampleOffsetToNextBeat;

  972.         double outCurrentMeasureDownBeat, bpm;

  973.         double ppqPosition;

  974. 

  975.         if (hostMusicalContextCallback != nullptr)

  976.         {

  977.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  978. 

  979.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  980.             {

  981.                 musicContextCallSucceeded = true;

  982. 

  983.                 info.timeSigNumerator   = (int) num;

  984.                 info.timeSigDenominator = (int) den;

  985.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  986.                 info.bpm = bpm;

  987.                 info.ppqPosition = ppqPosition;

  988.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  989.             }

  990.         }

  991. 

  992.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  993.         AUHostTransportStateFlags flags;

  994. 

  995.         if (hostTransportStateCallback != nullptr)

  996.         {

  997.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  998. 

  999.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  1000.             {

  1001.                 transportStateCallSucceeded = true;

  1002. 

  1003.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  1004.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  1005.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  1006.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  1007.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  1008.                 info.ppqLoopStart   = outCycleStartBeat;

  1009.                 info.ppqLoopEnd     = outCycleEndBeat;

  1010.             }

  1011.         }

  1012. 

  1013.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  1014.             lastAudioHead = info;

  1015. 

  1016.         return true;

  1017.     }

  1018. 

  1019.     //==============================================================================

  1020.     static void removeEditor (AudioProcessor& processor)

  1021.     {

  1022.         ScopedLock editorLock (processor.getCallbackLock());

  1023. 

  1024.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  1025.         {

  1026.             processor.editorBeingDeleted (editor);

  1027.             delete editor;

  1028.         }

  1029.     }

  1030. 

  1031. private:

  1032.     //==============================================================================

  1033.     struct BusBuffer

  1034.     {

  1035.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  1036.             : auBus (bus),

  1037.               maxFrames (maxFramesPerBuffer),

  1038.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  1039.               isInterleaved ([[auBus format] isInterleaved])

  1040.         {

  1041.             alloc();

  1042.         }

  1043. 

  1044.         //==============================================================================

  1045.         void alloc()

  1046.         {

  1047.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1048.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  1049.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  1050.             jassert (bytes > 0);

  1051. 

  1052.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  1053.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  1054. 

  1055.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  1056.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  1057.         }

  1058. 

  1059.         void dealloc()

  1060.         {

  1061.             bufferList = nullptr;

  1062.             bufferListStorage.free();

  1063.             scratchBuffer.setSize (0, 0);

  1064.         }

  1065. 

  1066.         //==============================================================================

  1067.         int numChannels() const noexcept                { return numberOfChannels; }

  1068.         bool interleaved() const noexcept               { return isInterleaved; }

  1069.         AudioBufferList* get() const noexcept           { return bufferList; }

  1070. 

  1071.         //==============================================================================

  1072.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  1073.         {

  1074.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1075.             const bool isCompatible = isCompatibleWith (other);

  1076. 

  1077.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  1078. 

  1079.             for (int i = 0; i < numBuffers; ++i)

  1080.             {

  1081.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  1082.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  1083.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  1084.                                                               : scratchBuffer.getWritePointer (i));

  1085.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  1086.             }

  1087.         }

  1088. 

  1089.         //==============================================================================

  1090.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  1091.         {

  1092.             if (other == nullptr)

  1093.                 return false;

  1094. 

  1095.             if (other->mNumberBuffers > 0)

  1096.             {

  1097.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  1098.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  1099.                                                                              : other->mNumberBuffers);

  1100. 

  1101.                 return otherInterleaved == isInterleaved

  1102.                     && numberOfChannels == otherChannels;

  1103.             }

  1104. 

  1105.             return numberOfChannels == 0;

  1106.         }

  1107. 

  1108.     private:

  1109.         AUAudioUnitBus* auBus;

  1110.         HeapBlock<char> bufferListStorage;

  1111.         AudioBufferList* bufferList = nullptr;

  1112.         int maxFrames, numberOfChannels;

  1113.         bool isInterleaved;

  1114.         AudioBuffer<float> scratchBuffer;

  1115.     };

  1116. 

  1117.     //==============================================================================

  1118.     void addAudioUnitBusses (bool isInput)

  1119.     {

  1120.         std::unique_ptr<NSMutableArray<AUAudioUnitBus*>, NSObjectDeleter> array ([[NSMutableArray<AUAudioUnitBus*> alloc] init]);

  1121.         AudioProcessor& processor = getAudioProcessor();

  1122.         const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  1123. 

  1124.         for (int i = 0; i < n; ++i)

  1125.         {

  1126.             std::unique_ptr<AUAudioUnitBus, NSObjectDeleter> audioUnitBus;

  1127. 

  1128.             {

  1129.                 std::unique_ptr<AVAudioFormat, NSObjectDeleter> defaultFormat ([[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  1130.                                                                                                                               channels: static_cast<AVAudioChannelCount> (processor.getChannelCountOfBus (isInput, i))]);

  1131. 

  1132.                 audioUnitBus.reset ([[AUAudioUnitBus alloc] initWithFormat: defaultFormat.get()

  1133.                                                                      error: nullptr]);

  1134.             }

  1135. 

  1136.             [array.get() addObject: audioUnitBus.get()];

  1137.         }

  1138. 

  1139.         (isInput ? inputBusses : outputBusses).reset ([[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  1140.                                                                                              busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  1141.                                                                                               busses: array.get()]);

  1142.     }

  1143. 

  1144.     // When parameters are discrete we need to use integer values.

  1145.     float getMaximumParameterValue (AudioProcessorParameter* juceParam)

  1146.     {

  1147.        #if JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1148.         ignoreUnused (juceParam);

  1149.         return 1.0f;

  1150.        #else

  1151.         return juceParam->isDiscrete() ? (float) (juceParam->getNumSteps() - 1) : 1.0f;

  1152.        #endif

  1153.     }

  1154. 

  1155.     void addParameters()

  1156.     {

  1157.         std::unique_ptr<NSMutableArray<AUParameterNode*>, NSObjectDeleter> params ([[NSMutableArray<AUParameterNode*> alloc] init]);

  1158. 

  1159.         overviewParams.reset ([[NSMutableArray<NSNumber*> alloc] init]);

  1160. 

  1161.         auto& processor = getAudioProcessor();

  1162.         juceParameters.update (processor, forceLegacyParamIDs);

  1163. 

  1164.         const int n = juceParameters.getNumParameters();

  1165. 

  1166.         for (int idx = 0; idx < n; ++idx)

  1167.         {

  1168.             auto* juceParam = juceParameters.getParamForIndex (idx);

  1169. 

  1170.             const String identifier (idx);

  1171.             const String name = juceParam->getName (512);

  1172. 

  1173.             AudioUnitParameterUnit unit = kAudioUnitParameterUnit_Generic;

  1174.             AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  1175.                                                       | kAudioUnitParameterFlag_IsReadable

  1176.                                                       | kAudioUnitParameterFlag_HasCFNameString

  1177.                                                       | kAudioUnitParameterFlag_ValuesHaveStrings);

  1178. 

  1179.             if (! forceLegacyParamIDs)

  1180.                 flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  1181. 

  1182.             // set whether the param is automatable (unnamed parameters aren't allowed to be automated)

  1183.             if (name.isEmpty() || ! juceParam->isAutomatable())

  1184.                 flags |= kAudioUnitParameterFlag_NonRealTime;

  1185. 

  1186.             const bool isParameterDiscrete = juceParam->isDiscrete();

  1187. 

  1188.             if (! isParameterDiscrete)

  1189.                 flags |= kAudioUnitParameterFlag_CanRamp;

  1190. 

  1191.             if (juceParam->isMetaParameter())

  1192.                 flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  1193. 

  1194.             std::unique_ptr<NSMutableArray, NSObjectDeleter> valueStrings;

  1195. 

  1196.             // is this a meter?

  1197.             if (((juceParam->getCategory() & 0xffff0000) >> 16) == 2)

  1198.             {

  1199.                 flags &= ~kAudioUnitParameterFlag_IsWritable;

  1200.                 flags |= kAudioUnitParameterFlag_MeterReadOnly | kAudioUnitParameterFlag_DisplayLogarithmic;

  1201.                 unit = kAudioUnitParameterUnit_LinearGain;

  1202.             }

  1203.             else

  1204.             {

  1205.                 if (! forceLegacyParamIDs)

  1206.                 {

  1207.                     if (juceParam->isDiscrete())

  1208.                     {

  1209.                         unit = juceParam->isBoolean() ? kAudioUnitParameterUnit_Boolean : kAudioUnitParameterUnit_Indexed;

  1210.                         auto maxValue = getMaximumParameterValue (juceParam);

  1211.                         auto numSteps = juceParam->getNumSteps();

  1212. 

  1213.                         // Some hosts can't handle the huge numbers of discrete parameter values created when

  1214.                         // using the default number of steps.

  1215.                         jassert (numSteps != AudioProcessor::getDefaultNumParameterSteps());

  1216. 

  1217.                         valueStrings.reset ([NSMutableArray new]);

  1218. 

  1219.                         for (int i = 0; i < numSteps; ++i)

  1220.                             [valueStrings.get() addObject: juceStringToNS (juceParam->getText ((float) i / maxValue, 0))];

  1221.                     }

  1222.                 }

  1223.             }

  1224. 

  1225.             AUParameterAddress address = generateAUParameterAddress (juceParam);

  1226. 

  1227.            #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1228.             // Consider yourself very unlucky if you hit this assertion. The hash codes of your

  1229.             // parameter ids are not unique.

  1230.             jassert (! paramMap.contains (static_cast<int64> (address)));

  1231. 

  1232.             paramAddresses.add (address);

  1233.             paramMap.set (static_cast<int64> (address), idx);

  1234.            #endif

  1235. 

  1236.             // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1237.             std::unique_ptr<AUParameter, NSObjectDeleter> param ([[AUParameterTree createParameterWithIdentifier: juceStringToNS (identifier)

  1238.                                                                                                             name: juceStringToNS (name)

  1239.                                                                                                          address: address

  1240.                                                                                                              min: 0.0f

  1241.                                                                                                              max: getMaximumParameterValue (juceParam)

  1242.                                                                                                             unit: unit

  1243.                                                                                                         unitName: nullptr

  1244.                                                                                                            flags: flags

  1245.                                                                                                     valueStrings: valueStrings.get()

  1246.                                                                                              dependentParameters: nullptr] retain]);

  1247. 

  1248.             [param.get() setValue: juceParam->getDefaultValue()];

  1249. 

  1250.             [params.get() addObject: param.get()];

  1251.             [overviewParams.get() addObject: [NSNumber numberWithUnsignedLongLong:address]];

  1252.         }

  1253. 

  1254.         // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1255.         paramTree.reset ([[AUParameterTree createTreeWithChildren: params.get()] retain]);

  1256. 

  1257.         paramObserver           = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  1258.         paramProvider           = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  1259.         stringFromValueProvider = CreateObjCBlock (this, &JuceAudioUnitv3::stringFromValue);

  1260.         valueFromStringProvider = CreateObjCBlock (this, &JuceAudioUnitv3::valueFromString);

  1261. 

  1262.         [paramTree.get() setImplementorValueObserver: paramObserver];

  1263.         [paramTree.get() setImplementorValueProvider: paramProvider];

  1264.         [paramTree.get() setImplementorStringFromValueCallback: stringFromValueProvider];

  1265.         [paramTree.get() setImplementorValueFromStringCallback: valueFromStringProvider];

  1266. 

  1267.         if (processor.hasEditor())

  1268.         {

  1269.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  1270.             editorObserverToken = [paramTree.get() tokenByAddingParameterObserver: editorParamObserver];

  1271.         }

  1272. 

  1273.         if ((bypassParam = processor.getBypassParameter()) != nullptr)

  1274.             bypassParam->addListener (this);

  1275.     }

  1276. 

  1277.     void setAudioProcessorParameter (AudioProcessorParameter* juceParam, float value)

  1278.     {

  1279.         if (value != juceParam->getValue())

  1280.         {

  1281.             juceParam->setValue (value);

  1282. 

  1283.             inParameterChangedCallback = true;

  1284.             juceParam->sendValueChangedMessageToListeners (value);

  1285.         }

  1286.     }

  1287. 

  1288.     void addPresets()

  1289.     {

  1290.         factoryPresets.reset ([[NSMutableArray<AUAudioUnitPreset*> alloc] init]);

  1291. 

  1292.         const int n = getAudioProcessor().getNumPrograms();

  1293. 

  1294.         for (int idx = 0; idx < n; ++idx)

  1295.         {

  1296.             String name = getAudioProcessor().getProgramName (idx);

  1297. 

  1298.             std::unique_ptr<AUAudioUnitPreset, NSObjectDeleter> preset ([[AUAudioUnitPreset alloc] init]);

  1299.             [preset.get() setName: juceStringToNS (name)];

  1300.             [preset.get() setNumber: static_cast<NSInteger> (idx)];

  1301. 

  1302.             [factoryPresets.get() addObject: preset.get()];

  1303.         }

  1304.     }

  1305. 

  1306.     //==============================================================================

  1307.     void allocateBusBuffer (bool isInput)

  1308.     {

  1309.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  1310.         busBuffers.clear();

  1311. 

  1312.         const int n = AudioUnitHelpers::getBusCount (&getAudioProcessor(), isInput);

  1313.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1314. 

  1315.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1316.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1317.                                            static_cast<int> (maxFrames)));

  1318.     }

  1319. 

  1320.     //==============================================================================

  1321.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1322.     {

  1323.         ignoreUnused (numParams);

  1324. 

  1325.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1326.         {

  1327.             switch (event->head.eventType)

  1328.             {

  1329.                 case AURenderEventMIDI:

  1330.                 {

  1331.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1332.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1333.                 }

  1334.                 break;

  1335. 

  1336.                 case AURenderEventParameter:

  1337.                 case AURenderEventParameterRamp:

  1338.                 {

  1339.                     const AUParameterEvent& paramEvent = event->parameter;

  1340. 

  1341.                     if (auto* p = getJuceParameterForAUAddress (paramEvent.parameterAddress))

  1342.                         setAudioProcessorParameter (p, paramEvent.value);

  1343.                 }

  1344.                 break;

  1345. 

  1346.                 default:

  1347.                     break;

  1348.             }

  1349.         }

  1350.     }

  1351. 

  1352.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1353.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1354.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1355.     {

  1356.         auto& processor = getAudioProcessor();

  1357.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1358. 

  1359.         // process params

  1360.         const int numParams = juceParameters.getNumParameters();

  1361.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1362. 

  1363.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1364.         {

  1365.             lastTimeStamp = *timestamp;

  1366. 

  1367.             const int numInputBuses  = inBusBuffers. size();

  1368.             const int numOutputBuses = outBusBuffers.size();

  1369. 

  1370.             // prepare buffers

  1371.             {

  1372.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1373.                 {

  1374.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1375.                      const bool canUseDirectOutput =

  1376.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1377. 

  1378.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1379.                 }

  1380. 

  1381.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1382.                 {

  1383.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1384.                     busBuffer.prepare (frameCount, busIdx < numOutputBuses ? outBusBuffers[busIdx]->get() : nullptr);

  1385.                 }

  1386. 

  1387.                 audioBuffer.reset();

  1388.             }

  1389. 

  1390.             // pull inputs

  1391.             {

  1392.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1393.                 {

  1394.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1395.                     AudioBufferList* buffer = busBuffer.get();

  1396. 

  1397.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1398.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1399. 

  1400.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1401.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1402.                 }

  1403.             }

  1404. 

  1405.             // set buffer pointer to minimize copying

  1406.             {

  1407.                 int chIdx = 0;

  1408. 

  1409.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1410.                 {

  1411.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1412.                     AudioBufferList* buffer = busBuffer.get();

  1413. 

  1414.                     const bool interleaved = busBuffer.interleaved();

  1415.                     const int numChannels = busBuffer.numChannels();

  1416. 

  1417.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1418. 

  1419.                     for (int ch = 0; ch < numChannels; ++ch)

  1420.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1421.                 }

  1422. 

  1423.                 // use input pointers on remaining channels

  1424. 

  1425.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1426.                 {

  1427.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1428. 

  1429.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1430.                     AudioBufferList* buffer = busBuffer.get();

  1431. 

  1432.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1433.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1434.                 }

  1435.             }

  1436. 

  1437.             // copy input

  1438.             {

  1439.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1440.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1441. 

  1442.                 // clear remaining channels

  1443.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1444.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1445.             }

  1446. 

  1447.             // process audio

  1448.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1449. 

  1450.             // send MIDI

  1451.            #if JucePlugin_ProducesMidiOutput && JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  1452.             auto midiOut = [au MIDIOutputEventBlock];

  1453.             MidiMessage msg;

  1454.             int samplePosition;

  1455. 

  1456.             for (MidiBuffer::Iterator it (midiMessages); it.getNextEvent (msg, samplePosition);)

  1457.                 midiOut (samplePosition, 0, msg.getRawDataSize(), msg.getRawData());

  1458.            #endif

  1459. 

  1460.             midiMessages.clear();

  1461.         }

  1462. 

  1463.         // copy back

  1464.         audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1465.                          mapper.get (false, (int) outputBusNumber));

  1466. 

  1467.         return noErr;

  1468.     }

  1469. 

  1470.     void processBlock (AudioBuffer<float>& buffer, MidiBuffer& midiBuffer) noexcept

  1471.     {

  1472.         auto& processor = getAudioProcessor();

  1473.         const ScopedLock sl (processor.getCallbackLock());

  1474. 

  1475.         if (processor.isSuspended())

  1476.             buffer.clear();

  1477.         else if (bypassParam != nullptr && [au shouldBypassEffect])

  1478.             processor.processBlockBypassed (buffer, midiBuffer);

  1479.         else

  1480.             processor.processBlock (buffer, midiBuffer);

  1481.     }

  1482. 

  1483.     //==============================================================================

  1484.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1485.     {

  1486.         if (param != nullptr)

  1487.         {

  1488.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1489.             {

  1490.                 auto normalisedValue = value / getMaximumParameterValue (p);

  1491.                 setAudioProcessorParameter (p, normalisedValue);

  1492.             }

  1493.         }

  1494.     }

  1495. 

  1496.     AUValue getValue (AUParameter* param)

  1497.     {

  1498.         if (param != nullptr)

  1499.         {

  1500.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1501.                 return p->getValue() * getMaximumParameterValue (p);

  1502.         }

  1503. 

  1504.         return 0;

  1505.     }

  1506. 

  1507.     void valueChangedForObserver (AUParameterAddress, AUValue)

  1508.     {

  1509.         // this will have already been handled by valueChangedFromHost

  1510.     }

  1511. 

  1512.     NSString* stringFromValue (AUParameter* param, const AUValue* value)

  1513.     {

  1514.         String text;

  1515. 

  1516.         if (param != nullptr && value != nullptr)

  1517.         {

  1518.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1519.             {

  1520.                 if (LegacyAudioParameter::isLegacy (p))

  1521.                     text = String (*value);

  1522.                 else

  1523.                     text = p->getText (*value / getMaximumParameterValue (p), 0);

  1524.             }

  1525.         }

  1526. 

  1527.         return juceStringToNS (text);

  1528.     }

  1529. 

  1530.     AUValue valueFromString (AUParameter* param, NSString* str)

  1531.     {

  1532.         if (param != nullptr && str != nullptr)

  1533.         {

  1534.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1535.             {

  1536.                 const String text (nsStringToJuce (str));

  1537. 

  1538.                 if (LegacyAudioParameter::isLegacy (p))

  1539.                     return text.getFloatValue();

  1540.                 else

  1541.                     return p->getValueForText (text) * getMaximumParameterValue (p);

  1542.             }

  1543.         }

  1544. 

  1545.         return 0;

  1546.     }

  1547. 

  1548.     //==============================================================================

  1549.     // this is only ever called for the bypass parameter

  1550.     void parameterValueChanged (int, float newValue) override

  1551.     {

  1552.         JuceAudioUnitv3Base::setShouldBypassEffect (newValue != 0.0f);

  1553.     }

  1554. 

  1555.     void parameterGestureChanged (int, bool) override {}

  1556. 

  1557.     //==============================================================================

  1558.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1559.     {

  1560.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1561.         return static_cast<AUParameterAddress> (paramIndex);

  1562.        #else

  1563.         return paramAddresses.getReference (paramIndex);

  1564.        #endif

  1565.     }

  1566. 

  1567.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1568.     {

  1569.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1570.         return static_cast<int> (address);

  1571.        #else

  1572.         return paramMap[static_cast<int64> (address)];

  1573.        #endif

  1574.     }

  1575. 

  1576.     AUParameterAddress generateAUParameterAddress (AudioProcessorParameter* param) const

  1577.     {

  1578.         const String& juceParamID = LegacyAudioParameter::getParamID (param, forceLegacyParamIDs);

  1579. 

  1580.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1581.         auto result = juceParamID.getIntValue();

  1582.        #else

  1583.         auto result = juceParamID.hashCode64();

  1584.        #endif

  1585. 

  1586.         return static_cast<AUParameterAddress> (result);

  1587.     }

  1588. 

  1589.     AudioProcessorParameter* getJuceParameterForAUAddress (AUParameterAddress address) const noexcept

  1590.     {

  1591.         return juceParameters.getParamForIndex (getJuceParameterIndexForAUAddress (address));

  1592.     }

  1593. 

  1594.     //==============================================================================

  1595.     static const double kDefaultSampleRate;

  1596. 

  1597.     AudioProcessorHolder::Ptr processorHolder;

  1598. 

  1599.     int totalInChannels, totalOutChannels;

  1600. 

  1601.     std::unique_ptr<AUAudioUnitBusArray, NSObjectDeleter> inputBusses, outputBusses;

  1602. 

  1603.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1604.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1605.     ObjCBlock<AUImplementorStringFromValueCallback> stringFromValueProvider;

  1606.     ObjCBlock<AUImplementorValueFromStringCallback> valueFromStringProvider;

  1607. 

  1608.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1609.     Array<AUParameterAddress> paramAddresses;

  1610.     HashMap<int64, int> paramMap;

  1611.    #endif

  1612.     LegacyAudioParametersWrapper juceParameters;

  1613. 

  1614.     // to avoid recursion on parameter changes, we need to add an

  1615.     // editor observer to do the parameter changes

  1616.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1617.     AUParameterObserverToken editorObserverToken;

  1618. 

  1619.     std::unique_ptr<AUParameterTree, NSObjectDeleter> paramTree;

  1620.     std::unique_ptr<NSMutableArray<NSNumber*>, NSObjectDeleter> overviewParams, channelCapabilities;

  1621. 

  1622.     std::unique_ptr<NSMutableArray<AUAudioUnitPreset*>, NSObjectDeleter> factoryPresets;

  1623. 

  1624.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1625. 

  1626.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1627.     AudioUnitHelpers::ChannelRemapper mapper;

  1628. 

  1629.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1630.     MidiBuffer midiMessages;

  1631. 

  1632.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1633.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1634. 

  1635.     AudioTimeStamp lastTimeStamp;

  1636.     CurrentPositionInfo lastAudioHead;

  1637. 

  1638.     String contextName;

  1639. 

  1640.     ThreadLocalValue<bool> inParameterChangedCallback;

  1641.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1642.     static constexpr bool forceLegacyParamIDs = true;

  1643.    #else

  1644.     static constexpr bool forceLegacyParamIDs = false;

  1645.    #endif

  1646.     AudioProcessorParameter* bypassParam = nullptr;

  1647. };

  1648. 

  1649. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1650. 

  1651. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1652. {

  1653.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1654.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1655. }

  1656. 

  1657. //==============================================================================

  1658. class JuceAUViewController

  1659. {

  1660. public:

  1661.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1662.         : myself (p)

  1663.     {

  1664.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1665. 

  1666.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1667.         initialiseJuce_GUI();

  1668.     }

  1669. 

  1670.     ~JuceAUViewController()

  1671.     {

  1672.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1673. 

  1674.         if (processorHolder != nullptr)

  1675.             JuceAudioUnitv3::removeEditor (getAudioProcessor());

  1676.     }

  1677. 

  1678.     //==============================================================================

  1679.     void loadView()

  1680.     {

  1681.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1682. 

  1683.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1684.         {

  1685.             processorHolder = new AudioProcessorHolder (p);

  1686.             auto& processor = getAudioProcessor();

  1687. 

  1688.             if (processor.hasEditor())

  1689.             {

  1690.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1691.                 {

  1692.                     preferredSize = editor->getBounds();

  1693. 

  1694.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1695.                     [myself setView: view];

  1696. 

  1697.                    #if JUCE_IOS

  1698.                     editor->setVisible (false);

  1699.                    #else

  1700.                     editor->setVisible (true);

  1701.                    #endif

  1702. 

  1703.                     editor->addToDesktop (0, view);

  1704. 

  1705.                    #if JUCE_IOS

  1706.                     if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1707.                         [peerView setContentMode: UIViewContentModeTop];

  1708.                    #endif

  1709.                 }

  1710.             }

  1711.         }

  1712.     }

  1713. 

  1714.     void viewDidLayoutSubviews()

  1715.     {

  1716.         if (processorHolder != nullptr && [myself view] != nullptr)

  1717.         {

  1718.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1719.             {

  1720.                 if (processorHolder->viewConfiguration != nullptr)

  1721.                     editor->hostMIDIControllerIsAvailable (processorHolder->viewConfiguration->hostHasMIDIController);

  1722. 

  1723.                 editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1724. 

  1725.                 if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1726.                 {

  1727.                    #if JUCE_IOS

  1728.                     [peerView setNeedsDisplay];

  1729.                    #else

  1730.                     [peerView setNeedsDisplay: YES];

  1731.                    #endif

  1732.                 }

  1733.             }

  1734.         }

  1735.     }

  1736. 

  1737.     void didReceiveMemoryWarning()

  1738.     {

  1739.         if (processorHolder != nullptr)

  1740.             if (auto* processor = processorHolder->get())

  1741.                 processor->memoryWarningReceived();

  1742.     }

  1743. 

  1744.     void viewDidAppear (bool)

  1745.     {

  1746.         if (processorHolder != nullptr)

  1747.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1748.                 editor->setVisible (true);

  1749.     }

  1750. 

  1751.     void viewDidDisappear (bool)

  1752.     {

  1753.         if (processorHolder != nullptr)

  1754.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1755.                 editor->setVisible (false);

  1756.     }

  1757. 

  1758.     CGSize getPreferredContentSize() const

  1759.     {

  1760.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1761.                            static_cast<float> (preferredSize.getHeight()));

  1762.     }

  1763. 

  1764.     //==============================================================================

  1765.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1766.     {

  1767.         AUAudioUnit* retval = nil;

  1768. 

  1769.         if (! MessageManager::getInstance()->isThisTheMessageThread())

  1770.         {

  1771.             WaitableEvent creationEvent;

  1772. 

  1773.             // AUv3 headers say that we may block this thread and that the message thread is guaranteed

  1774.             // to be unblocked

  1775.             struct AUCreator  : public CallbackMessage

  1776.             {

  1777.                 JuceAUViewController& owner;

  1778.                 AudioComponentDescription pDescr;

  1779.                 NSError** pError;

  1780.                 AUAudioUnit*& outAU;

  1781.                 WaitableEvent& e;

  1782. 

  1783.                 AUCreator (JuceAUViewController& parent, const AudioComponentDescription& paramDescr, NSError** paramError,

  1784.                            AUAudioUnit*& outputAU, WaitableEvent& event)

  1785.                     : owner (parent), pDescr (paramDescr), pError (paramError), outAU (outputAU), e (event)

  1786.                 {}

  1787. 

  1788.                 void messageCallback() override

  1789.                 {

  1790.                     outAU = owner.createAudioUnitOnMessageThread (pDescr, pError);

  1791.                     e.signal();

  1792.                 }

  1793.             };

  1794. 

  1795.             (new AUCreator (*this, descr, error, retval, creationEvent))->post();

  1796.             creationEvent.wait (-1);

  1797.         }

  1798.         else

  1799.         {

  1800.             retval = createAudioUnitOnMessageThread (descr, error);

  1801.         }

  1802. 

  1803.         return [retval autorelease];

  1804.     }

  1805. 

  1806. private:

  1807.     //==============================================================================

  1808.     AUViewController<AUAudioUnitFactory>* myself;

  1809.     AudioProcessorHolder::Ptr processorHolder = nullptr;

  1810.     Rectangle<int> preferredSize { 1, 1 };

  1811. 

  1812.     //==============================================================================

  1813.     AUAudioUnit* createAudioUnitOnMessageThread (const AudioComponentDescription& descr, NSError** error)

  1814.     {

  1815.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1816. 

  1817.         [myself view];  // this will call [view load] and ensure that the AudioProcessor has been instantiated

  1818. 

  1819.         if (processorHolder == nullptr)

  1820.             return nullptr;

  1821. 

  1822.         return (new JuceAudioUnitv3 (processorHolder, descr, 0, error))->getAudioUnit();

  1823.     }

  1824. 

  1825.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder; }

  1826. };

  1827. 

  1828. //==============================================================================

  1829. // necessary glue code

  1830. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  1831. @end

  1832. 

  1833. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  1834. {

  1835.     std::unique_ptr<JuceAUViewController> cpp;

  1836. }

  1837. 

  1838. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp.reset (new JuceAUViewController (self)); return self; }

  1839. - (void) loadView                { cpp->loadView(); }

  1840. - (AUAudioUnit *) createAudioUnitWithComponentDescription: (AudioComponentDescription) desc error: (NSError **) error { return cpp->createAudioUnit (desc, error); }

  1841. - (CGSize) preferredContentSize  { return cpp->getPreferredContentSize(); }

  1842. - (void) viewDidLayoutSubviews   { cpp->viewDidLayoutSubviews(); }

  1843. - (void) didReceiveMemoryWarning { cpp->didReceiveMemoryWarning(); }

  1844. #if JUCE_IOS

  1845. - (void) viewDidAppear: (BOOL) animated { cpp->viewDidAppear (animated); [super viewDidAppear:animated]; }

  1846. - (void) viewDidDisappear: (BOOL) animated { cpp->viewDidDisappear (animated); [super viewDidDisappear:animated]; }

  1847. #endif

  1848. @end

  1849. 

  1850. //==============================================================================

  1851. #if JUCE_IOS

  1852. bool JUCE_CALLTYPE juce_isInterAppAudioConnected() { return false; }

  1853. void JUCE_CALLTYPE juce_switchToHostApplication()  {}

  1854. #if JUCE_MODULE_AVAILABLE_juce_gui_basics

  1855. Image JUCE_CALLTYPE juce_getIAAHostIcon (int)      { return {}; }

  1856. #endif

  1857. #endif

  1858. 

  1859. #pragma clang diagnostic pop

  1860. #endif