DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
12316 Commits
9 Branches
1.8GB
Tree: 9199fa3c51
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '9199fa3c51'
${ noResults }
JUCE/modules/juce_gui_basics/native/accessibility/juce_mac_Accessibility.mm

954 lines
43KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2020 - Raw Material Software Limited

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 6 End-User License

  11.    Agreement and JUCE Privacy Policy (both effective as of the 16th June 2020).

  12. 

  13.    End User License Agreement: www.juce.com/juce-6-licence

  14.    Privacy Policy: www.juce.com/juce-privacy-policy

  15. 

  16.    Or: You may also use this code under the terms of the GPL v3 (see

  17.    www.gnu.org/licenses).

  18. 

  19.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  20.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  21.    DISCLAIMED.

  22. 

  23.   ==============================================================================

  24. */

  25. 

  26. namespace juce

  27. {

  28. 

  29. #if (! defined MAC_OS_X_VERSION_10_13) || MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_13

  30.  using NSAccessibilityRole = NSString*;

  31.  using NSAccessibilityNotificationName = NSString*;

  32. #endif

  33. 

  34. #if (! defined MAC_OS_X_VERSION_10_9) || MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_9

  35.  const NSAccessibilityNotificationName NSAccessibilityLayoutChangedNotificationJuce = @"AXLayoutChanged";

  36. #else

  37.  const NSAccessibilityNotificationName NSAccessibilityLayoutChangedNotificationJuce = NSAccessibilityLayoutChangedNotification;

  38. #endif

  39. 

  40. #if JUCE_OBJC_HAS_AVAILABLE_FEATURE || (defined (MAC_OS_X_VERSION_10_10) && MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_10)

  41. 

  42. #define JUCE_NATIVE_ACCESSIBILITY_INCLUDED 1

  43. 

  44. JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wunguarded-availability", "-Wunguarded-availability-new")

  45. 

  46. //==============================================================================

  47. class AccessibilityHandler::AccessibilityNativeImpl

  48. {

  49. public:

  50.     explicit AccessibilityNativeImpl (AccessibilityHandler& handler)

  51.         : accessibilityElement (AccessibilityElement::create (handler))

  52.     {}

  53. 

  54.     NSAccessibilityElement<NSAccessibility>* getAccessibilityElement() const noexcept

  55.     {

  56.         return accessibilityElement.get();

  57.     }

  58. 

  59. private:

  60.     //==============================================================================

  61.     class AccessibilityElement  : public AccessibleObjCClass<NSAccessibilityElement<NSAccessibility>>

  62.     {

  63.     public:

  64.         static Holder create (AccessibilityHandler& handler)

  65.         {

  66.            #if JUCE_OBJC_HAS_AVAILABLE_FEATURE

  67.             if (@available (macOS 10.10, *))

  68.            #endif

  69.             {

  70.                 static AccessibilityElement cls;

  71.                 Holder element ([cls.createInstance() init]);

  72.                 object_setInstanceVariable (element.get(), "handler", &handler);

  73.                 return element;

  74.             }

  75. 

  76.             return {};

  77.         }

  78. 

  79.     private:

  80.         AccessibilityElement()

  81.         {

  82.             addMethod (@selector (accessibilityNotifiesWhenDestroyed),     getAccessibilityNotifiesWhenDestroyed, "c@:");

  83.             addMethod (@selector (isAccessibilityElement),                 getIsAccessibilityElement,             "c@:");

  84.             addMethod (@selector (isAccessibilityEnabled),                 getIsAccessibilityEnabled,             "c@:");

  85.             addMethod (@selector (accessibilityWindow),                    getAccessibilityWindow,                "@@:");

  86.             addMethod (@selector (accessibilityTopLevelUIElement),         getAccessibilityWindow,                "@@:");

  87.             addMethod (@selector (accessibilityFocusedUIElement),          getAccessibilityFocusedUIElement,      "@@:");

  88.             addMethod (@selector (accessibilityHitTest:),                  accessibilityHitTest,                  "@@:", @encode (NSPoint));

  89.             addMethod (@selector (accessibilityParent),                    getAccessibilityParent,                "@@:");

  90.             addMethod (@selector (accessibilityChildren),                  getAccessibilityChildren,              "@@:");

  91.             addMethod (@selector (isAccessibilityFocused),                 getIsAccessibilityFocused,             "c@:");

  92.             addMethod (@selector (setAccessibilityFocused:),               setAccessibilityFocused,               "v@:c");

  93.             addMethod (@selector (isAccessibilityModal),                   getIsAccessibilityModal,               "c@:");

  94.             addMethod (@selector (accessibilityFrame),                     getAccessibilityFrame,                 @encode (NSRect), "@:");

  95.             addMethod (@selector (accessibilityRole),                      getAccessibilityRole,                  "@@:");

  96.             addMethod (@selector (accessibilitySubrole),                   getAccessibilitySubrole,               "@@:");

  97.             addMethod (@selector (accessibilityTitle),                     getAccessibilityTitle,                 "@@:");

  98.             addMethod (@selector (accessibilityLabel),                     getAccessibilityLabel,                 "@@:");

  99.             addMethod (@selector (accessibilityHelp),                      getAccessibilityHelp,                  "@@:");

  100.             addMethod (@selector (accessibilityValue),                     getAccessibilityValue,                 "@@:");

  101.             addMethod (@selector (setAccessibilityValue:),                 setAccessibilityValue,                 "v@:@");

  102.             addMethod (@selector (accessibilitySelectedChildren),          getAccessibilitySelectedChildren,      "@@:");

  103.             addMethod (@selector (setAccessibilitySelectedChildren:),      setAccessibilitySelectedChildren,      "v@:@");

  104.             addMethod (@selector (accessibilityOrientation),               getAccessibilityOrientation,           "i@:@");

  105. 

  106.             addMethod (@selector (accessibilityInsertionPointLineNumber),  getAccessibilityInsertionPointLineNumber, "i@:");

  107.             addMethod (@selector (accessibilityVisibleCharacterRange),     getAccessibilityVisibleCharacterRange,    @encode (NSRange), "@:");

  108.             addMethod (@selector (accessibilityNumberOfCharacters),        getAccessibilityNumberOfCharacters,       "i@:");

  109.             addMethod (@selector (accessibilitySelectedText),              getAccessibilitySelectedText,             "@@:");

  110.             addMethod (@selector (accessibilitySelectedTextRange),         getAccessibilitySelectedTextRange,        @encode (NSRange), "@:");

  111.             addMethod (@selector (accessibilityAttributedStringForRange:), getAccessibilityAttributedStringForRange, "@@:", @encode (NSRange));

  112.             addMethod (@selector (accessibilityRangeForLine:),             getAccessibilityRangeForLine,             @encode (NSRange), "@:i");

  113.             addMethod (@selector (accessibilityStringForRange:),           getAccessibilityStringForRange,           "@@:", @encode (NSRange));

  114.             addMethod (@selector (accessibilityRangeForPosition:),         getAccessibilityRangeForPosition,         @encode (NSRange), "@:", @encode (NSPoint));

  115.             addMethod (@selector (accessibilityRangeForIndex:),            getAccessibilityRangeForIndex,            @encode (NSRange), "@:i");

  116.             addMethod (@selector (accessibilityFrameForRange:),            getAccessibilityFrameForRange,            @encode (NSRect), "@:", @encode (NSRange));

  117.             addMethod (@selector (accessibilityLineForIndex:),             getAccessibilityLineForIndex,             "i@:i");

  118.             addMethod (@selector (setAccessibilitySelectedTextRange:),     setAccessibilitySelectedTextRange,        "v@:", @encode (NSRange));

  119. 

  120.             addMethod (@selector (accessibilityRowCount),            getAccessibilityRowCount,         "i@:");

  121.             addMethod (@selector (accessibilityRows),                getAccessibilityRows,             "@@:");

  122.             addMethod (@selector (accessibilitySelectedRows),        getAccessibilitySelectedRows,     "@@:");

  123.             addMethod (@selector (setAccessibilitySelectedRows:),    setAccessibilitySelectedRows,     "v@:@");

  124.             addMethod (@selector (accessibilityColumnCount),         getAccessibilityColumnCount,      "i@:");

  125.             addMethod (@selector (accessibilityColumns),             getAccessibilityColumns,          "@@:");

  126.             addMethod (@selector (accessibilitySelectedColumns),     getAccessibilitySelectedColumns,  "@@:");

  127.             addMethod (@selector (setAccessibilitySelectedColumns:), setAccessibilitySelectedColumns,  "v@:@");

  128. 

  129.             addMethod (@selector (accessibilityRowIndexRange),    getAccessibilityRowIndexRange,    @encode (NSRange), "@:");

  130.             addMethod (@selector (accessibilityColumnIndexRange), getAccessibilityColumnIndexRange, @encode (NSRange), "@:");

  131.             addMethod (@selector (accessibilityIndex),            getAccessibilityIndex,            "i@:");

  132.             addMethod (@selector (accessibilityDisclosureLevel),  getAccessibilityDisclosureLevel,  "i@:");

  133.             addMethod (@selector (isAccessibilityExpanded),       getIsAccessibilityExpanded,       "c@:");

  134. 

  135.             addMethod (@selector (accessibilityPerformIncrement), accessibilityPerformIncrement, "c@:");

  136.             addMethod (@selector (accessibilityPerformDecrement), accessibilityPerformDecrement, "c@:");

  137.             addMethod (@selector (accessibilityPerformDelete),    accessibilityPerformDelete,    "c@:");

  138.             addMethod (@selector (accessibilityPerformPress),     accessibilityPerformPress,     "c@:");

  139.             addMethod (@selector (accessibilityPerformShowMenu),  accessibilityPerformShowMenu,  "c@:");

  140.             addMethod (@selector (accessibilityPerformRaise),     accessibilityPerformRaise,     "c@:");

  141. 

  142.             addMethod (@selector (isAccessibilitySelectorAllowed:), getIsAccessibilitySelectorAllowed, "c@:@");

  143. 

  144.            #if defined (MAC_OS_X_VERSION_10_13) && MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_13

  145.             addMethod (@selector (accessibilityChildrenInNavigationOrder), getAccessibilityChildren, "@@:");

  146.            #endif

  147. 

  148.             registerClass();

  149.         }

  150. 

  151.         //==============================================================================

  152.         static bool isSelectable (AccessibleState state) noexcept

  153.         {

  154.             return state.isSelectable() || state.isMultiSelectable();

  155.         }

  156. 

  157.         static NSArray* getSelectedChildren (NSArray* children)

  158.         {

  159.             NSMutableArray* selected = [[NSMutableArray new] autorelease];

  160. 

  161.             for (id child in children)

  162.             {

  163.                 if (auto* handler = getHandler (child))

  164.                 {

  165.                     const auto currentState = handler->getCurrentState();

  166. 

  167.                     if (isSelectable (currentState) && currentState.isSelected())

  168.                         [selected addObject: child];

  169.                 }

  170.             }

  171. 

  172.             return selected;

  173.         }

  174. 

  175.         static void setSelectedChildren (NSArray* children, NSArray* selected)

  176.         {

  177.             for (id child in children)

  178.             {

  179.                 if (auto* handler = getHandler (child))

  180.                 {

  181.                     const auto currentState = handler->getCurrentState();

  182.                     const BOOL isSelected = [selected containsObject: child];

  183. 

  184.                     if (isSelectable (currentState))

  185.                     {

  186.                         if (currentState.isSelected() != isSelected)

  187.                             handler->getActions().invoke (AccessibilityActionType::toggle);

  188.                     }

  189.                     else if (currentState.isFocusable())

  190.                     {

  191.                         [child setAccessibilityFocused: isSelected];

  192.                     }

  193.                 }

  194.             }

  195.         }

  196. 

  197.         //==============================================================================

  198.         static BOOL getAccessibilityNotifiesWhenDestroyed (id, SEL)  { return YES; }

  199. 

  200.         static BOOL getIsAccessibilityEnabled (id self, SEL)

  201.         {

  202.             if (auto* handler = getHandler (self))

  203.                 return handler->getComponent().isEnabled();

  204. 

  205.             return NO;

  206.         }

  207. 

  208.         static id getAccessibilityWindow (id self, SEL)

  209.         {

  210.             return [[self accessibilityParent] accessibilityWindow];

  211.         }

  212. 

  213.         static id getAccessibilityFocusedUIElement (id self, SEL)

  214.         {

  215.             if (auto* handler = getHandler (self))

  216.             {

  217.                 if (auto* modal = Component::getCurrentlyModalComponent())

  218.                 {

  219.                     const auto& component = handler->getComponent();

  220. 

  221.                     if (! component.isParentOf (modal)

  222.                          && component.isCurrentlyBlockedByAnotherModalComponent())

  223.                     {

  224.                         if (auto* modalHandler = modal->getAccessibilityHandler())

  225.                         {

  226.                             if (auto* focusChild = modalHandler->getChildFocus())

  227.                                 return (id) focusChild->getNativeImplementation();

  228. 

  229.                             return (id) modalHandler->getNativeImplementation();

  230.                         }

  231.                     }

  232.                 }

  233. 

  234.                 if (auto* focusChild = handler->getChildFocus())

  235.                     return (id) focusChild->getNativeImplementation();

  236.             }

  237. 

  238.             return nil;

  239.         }

  240. 

  241.         static id accessibilityHitTest (id self, SEL, NSPoint point)

  242.         {

  243.             if (auto* handler = getHandler (self))

  244.             {

  245.                 if (auto* child = handler->getChildAt (roundToIntPoint (flippedScreenPoint (point))))

  246.                     return (id) child->getNativeImplementation();

  247. 

  248.                 return self;

  249.             }

  250. 

  251.             return nil;

  252.         }

  253. 

  254.         static id getAccessibilityParent (id self, SEL)

  255.         {

  256.             if (auto* handler = getHandler (self))

  257.             {

  258.                 if (auto* parentHandler = handler->getParent())

  259.                     return NSAccessibilityUnignoredAncestor ((id) parentHandler->getNativeImplementation());

  260. 

  261.                 return NSAccessibilityUnignoredAncestor ((id) handler->getComponent().getWindowHandle());

  262.             }

  263. 

  264.             return nil;

  265.         }

  266. 

  267.         static NSArray* getAccessibilityChildren (id self, SEL)

  268.         {

  269.             if (auto* handler = getHandler (self))

  270.             {

  271.                 auto children = handler->getChildren();

  272. 

  273.                 auto* accessibleChildren = [NSMutableArray arrayWithCapacity: (NSUInteger) children.size()];

  274. 

  275.                 for (auto* childHandler : children)

  276.                     [accessibleChildren addObject: (id) childHandler->getNativeImplementation()];

  277. 

  278.                 return accessibleChildren;

  279.             }

  280. 

  281.             return nil;

  282.         }

  283. 

  284.         static NSArray* getAccessibilitySelectedChildren (id self, SEL)

  285.         {

  286.             return getSelectedChildren ([self accessibilityChildren]);

  287.         }

  288. 

  289.         static void setAccessibilitySelectedChildren (id self, SEL, NSArray* selected)

  290.         {

  291.             setSelectedChildren ([self accessibilityChildren], selected);

  292.         }

  293. 

  294.         static NSAccessibilityOrientation getAccessibilityOrientation (id self, SEL)

  295.         {

  296.             if (auto* handler = getHandler (self))

  297.                 return handler->getComponent().getBounds().toFloat().getAspectRatio() > 1.0f

  298.                            ? NSAccessibilityOrientationHorizontal

  299.                            : NSAccessibilityOrientationVertical;

  300. 

  301.             return NSAccessibilityOrientationUnknown;

  302.         }

  303. 

  304.         static BOOL getIsAccessibilityFocused (id self, SEL)

  305.         {

  306.             return [[self accessibilityWindow] accessibilityFocusedUIElement] == self;

  307.         }

  308. 

  309.         static void setAccessibilityFocused (id self, SEL, BOOL focused)

  310.         {

  311.             if (auto* handler = getHandler (self))

  312.             {

  313.                 if (focused)

  314.                 {

  315.                     const WeakReference<Component> safeComponent (&handler->getComponent());

  316. 

  317.                     performActionIfSupported (self, AccessibilityActionType::focus);

  318. 

  319.                     if (safeComponent != nullptr)

  320.                         handler->grabFocus();

  321.                 }

  322.                 else

  323.                 {

  324.                     handler->giveAwayFocus();

  325.                 }

  326.             }

  327.         }

  328. 

  329.         static NSRect getAccessibilityFrame (id self, SEL)

  330.         {

  331.             if (auto* handler = getHandler (self))

  332.                 return flippedScreenRect (makeNSRect (handler->getComponent().getScreenBounds()));

  333. 

  334.             return NSZeroRect;

  335.         }

  336. 

  337.         static NSAccessibilityRole getAccessibilityRole (id self, SEL)

  338.         {

  339.             if (auto* handler = getHandler (self))

  340.             {

  341.                 switch (handler->getRole())

  342.                 {

  343.                     case AccessibilityRole::popupMenu:

  344.                     case AccessibilityRole::tooltip:

  345.                     case AccessibilityRole::splashScreen:

  346.                     case AccessibilityRole::dialogWindow:

  347.                     case AccessibilityRole::window:        return NSAccessibilityWindowRole;

  348. 

  349.                     case AccessibilityRole::tableHeader:

  350.                     case AccessibilityRole::unspecified:

  351.                     case AccessibilityRole::group:         return NSAccessibilityGroupRole;

  352. 

  353.                     case AccessibilityRole::label:

  354.                     case AccessibilityRole::staticText:    return NSAccessibilityStaticTextRole;

  355. 

  356.                     case AccessibilityRole::tree:

  357.                     case AccessibilityRole::list:          return NSAccessibilityOutlineRole;

  358. 

  359.                     case AccessibilityRole::listItem:

  360.                     case AccessibilityRole::treeItem:      return NSAccessibilityRowRole;

  361. 

  362.                     case AccessibilityRole::button:        return NSAccessibilityButtonRole;

  363.                     case AccessibilityRole::toggleButton:  return NSAccessibilityCheckBoxRole;

  364.                     case AccessibilityRole::radioButton:   return NSAccessibilityRadioButtonRole;

  365.                     case AccessibilityRole::comboBox:      return NSAccessibilityPopUpButtonRole;

  366.                     case AccessibilityRole::image:         return NSAccessibilityImageRole;

  367.                     case AccessibilityRole::slider:        return NSAccessibilitySliderRole;

  368.                     case AccessibilityRole::editableText:  return NSAccessibilityTextAreaRole;

  369.                     case AccessibilityRole::menuItem:      return NSAccessibilityMenuItemRole;

  370.                     case AccessibilityRole::menuBar:       return NSAccessibilityMenuRole;

  371.                     case AccessibilityRole::table:         return NSAccessibilityListRole;

  372.                     case AccessibilityRole::column:        return NSAccessibilityColumnRole;

  373.                     case AccessibilityRole::row:           return NSAccessibilityRowRole;

  374.                     case AccessibilityRole::cell:          return NSAccessibilityCellRole;

  375.                     case AccessibilityRole::hyperlink:     return NSAccessibilityLinkRole;

  376.                     case AccessibilityRole::progressBar:   return NSAccessibilityProgressIndicatorRole;

  377.                     case AccessibilityRole::scrollBar:     return NSAccessibilityScrollBarRole;

  378. 

  379.                     case AccessibilityRole::ignored:       break;

  380.                 }

  381. 

  382.                 return NSAccessibilityUnknownRole;

  383.             }

  384. 

  385.             return nil;

  386.         }

  387. 

  388.         static NSAccessibilityRole getAccessibilitySubrole (id self, SEL)

  389.         {

  390.             if (auto* handler = getHandler (self))

  391.             {

  392.                 if (auto* textInterface = getTextInterface (self))

  393.                     if (textInterface->isDisplayingProtectedText())

  394.                         return NSAccessibilitySecureTextFieldSubrole;

  395. 

  396.                 const auto role = handler->getRole();

  397. 

  398.                 if (role == AccessibilityRole::window)                                     return NSAccessibilityStandardWindowSubrole;

  399.                 if (role == AccessibilityRole::dialogWindow)                               return NSAccessibilityDialogSubrole;

  400.                 if (role == AccessibilityRole::tooltip

  401.                     || role == AccessibilityRole::splashScreen)                            return NSAccessibilityFloatingWindowSubrole;

  402.                 if (role == AccessibilityRole::toggleButton)                               return NSAccessibilityToggleSubrole;

  403.                 if (role == AccessibilityRole::treeItem

  404.                     || role == AccessibilityRole::listItem)                                return NSAccessibilityOutlineRowSubrole;

  405.                 if (role == AccessibilityRole::row && getCellInterface (self) != nullptr)  return NSAccessibilityTableRowSubrole;

  406. 

  407.                 const auto& component = handler->getComponent();

  408. 

  409.                 if (auto* documentWindow = component.findParentComponentOfClass<DocumentWindow>())

  410.                 {

  411.                     if (role == AccessibilityRole::button)

  412.                     {

  413.                         if (&component == documentWindow->getCloseButton())     return NSAccessibilityCloseButtonSubrole;

  414.                         if (&component == documentWindow->getMinimiseButton())  return NSAccessibilityMinimizeButtonSubrole;

  415.                         if (&component == documentWindow->getMaximiseButton())  return NSAccessibilityFullScreenButtonSubrole;

  416.                     }

  417.                 }

  418.             }

  419. 

  420.             return NSAccessibilityUnknownRole;

  421.         }

  422. 

  423.         static NSString* getAccessibilityLabel (id self, SEL)

  424.         {

  425.             if (auto* handler = getHandler (self))

  426.                 return juceStringToNS (handler->getDescription());

  427. 

  428.             return nil;

  429.         }

  430. 

  431.         //==============================================================================

  432.         static NSInteger getAccessibilityInsertionPointLineNumber (id self, SEL)

  433.         {

  434.             if (auto* textInterface = getTextInterface (self))

  435.                 return [self accessibilityLineForIndex: textInterface->getTextInsertionOffset()];

  436. 

  437.             return 0;

  438.         }

  439. 

  440.         static NSRange getAccessibilityVisibleCharacterRange (id self, SEL)

  441.         {

  442.             if (auto* textInterface = getTextInterface (self))

  443.                 return juceRangeToNS ({ 0, textInterface->getTotalNumCharacters() });

  444. 

  445.             return NSMakeRange (0, 0);

  446.         }

  447. 

  448.         static NSInteger getAccessibilityNumberOfCharacters (id self, SEL)

  449.         {

  450.             if (auto* textInterface = getTextInterface (self))

  451.                 return textInterface->getTotalNumCharacters();

  452. 

  453.             return 0;

  454.         }

  455. 

  456.         static NSString* getAccessibilitySelectedText (id self, SEL)

  457.         {

  458.             if (auto* textInterface = getTextInterface (self))

  459.                 return juceStringToNS (textInterface->getText (textInterface->getSelection()));

  460. 

  461.             return nil;

  462.         }

  463. 

  464.         static NSRange getAccessibilitySelectedTextRange (id self, SEL)

  465.         {

  466.             if (auto* textInterface = getTextInterface (self))

  467.             {

  468.                 const auto currentSelection = textInterface->getSelection();

  469. 

  470.                 if (currentSelection.isEmpty())

  471.                     return NSMakeRange ((NSUInteger) textInterface->getTextInsertionOffset(), 0);

  472. 

  473.                 return juceRangeToNS (currentSelection);

  474.             }

  475. 

  476.             return NSMakeRange (0, 0);

  477.         }

  478. 

  479.         static NSAttributedString* getAccessibilityAttributedStringForRange (id self, SEL, NSRange range)

  480.         {

  481.             NSString* string = [self accessibilityStringForRange: range];

  482. 

  483.             if (string != nil)

  484.                 return [[[NSAttributedString alloc] initWithString: string] autorelease];

  485. 

  486.             return nil;

  487.         }

  488. 

  489.         static NSRange getAccessibilityRangeForLine (id self, SEL, NSInteger line)

  490.         {

  491.             if (auto* textInterface = getTextInterface (self))

  492.             {

  493.                 auto text = textInterface->getText ({ 0, textInterface->getTotalNumCharacters() });

  494.                 auto lines = StringArray::fromLines (text);

  495. 

  496.                 if (line < lines.size())

  497.                 {

  498.                     auto lineText = lines[(int) line];

  499.                     auto start = text.indexOf (lineText);

  500. 

  501.                     if (start >= 0)

  502.                         return NSMakeRange ((NSUInteger) start, (NSUInteger) lineText.length());

  503.                 }

  504.             }

  505. 

  506.             return NSMakeRange (0, 0);

  507.         }

  508. 

  509.         static NSString* getAccessibilityStringForRange (id self, SEL, NSRange range)

  510.         {

  511.             if (auto* textInterface = getTextInterface (self))

  512.                 return juceStringToNS (textInterface->getText (nsRangeToJuce (range)));

  513. 

  514.             return nil;

  515.         }

  516. 

  517.         static NSRange getAccessibilityRangeForPosition (id self, SEL, NSPoint position)

  518.         {

  519.             if (auto* handler = getHandler (self))

  520.             {

  521.                 if (auto* textInterface = handler->getTextInterface())

  522.                 {

  523.                     auto screenPoint = roundToIntPoint (flippedScreenPoint (position));

  524. 

  525.                     if (handler->getComponent().getScreenBounds().contains (screenPoint))

  526.                     {

  527.                         auto offset = textInterface->getOffsetAtPoint (screenPoint);

  528. 

  529.                         if (offset >= 0)

  530.                             return NSMakeRange ((NSUInteger) offset, 1);

  531.                     }

  532.                 }

  533.             }

  534. 

  535.             return NSMakeRange (0, 0);

  536.         }

  537. 

  538.         static NSRange getAccessibilityRangeForIndex (id self, SEL, NSInteger index)

  539.         {

  540.             if (auto* textInterface = getTextInterface (self))

  541.                 if (isPositiveAndBelow (index, textInterface->getTotalNumCharacters()))

  542.                     return NSMakeRange ((NSUInteger) index, 1);

  543. 

  544.             return NSMakeRange (0, 0);

  545.         }

  546. 

  547.         static NSRect getAccessibilityFrameForRange (id self, SEL, NSRange range)

  548.         {

  549.             if (auto* textInterface = getTextInterface (self))

  550.                 return flippedScreenRect (makeNSRect (textInterface->getTextBounds (nsRangeToJuce (range)).getBounds()));

  551. 

  552.             return NSZeroRect;

  553.         }

  554. 

  555.         static NSInteger getAccessibilityLineForIndex (id self, SEL, NSInteger index)

  556.         {

  557.             if (auto* textInterface = getTextInterface (self))

  558.             {

  559.                 auto text = textInterface->getText ({ 0, (int) index });

  560. 

  561.                 if (! text.isEmpty())

  562.                     return StringArray::fromLines (text).size() - 1;

  563.             }

  564. 

  565.             return 0;

  566.         }

  567. 

  568.         static void setAccessibilitySelectedTextRange (id self, SEL, NSRange selectedRange)

  569.         {

  570.             if (auto* textInterface = getTextInterface (self))

  571.                 textInterface->setSelection (nsRangeToJuce (selectedRange));

  572.         }

  573. 

  574.         //==============================================================================

  575.         static NSArray* getAccessibilityRows (id self, SEL)

  576.         {

  577.             NSMutableArray* rows = [[NSMutableArray new] autorelease];

  578. 

  579.             if (auto* tableInterface = getTableInterface (self))

  580.             {

  581.                 for (int row = 0; row < tableInterface->getNumRows(); ++row)

  582.                 {

  583.                     if (auto* handler = tableInterface->getCellHandler (row, 0))

  584.                     {

  585.                         [rows addObject: (id) handler->getNativeImplementation()];

  586.                     }

  587.                     else

  588.                     {

  589.                         [rows addObject: [NSAccessibilityElement accessibilityElementWithRole: NSAccessibilityRowRole

  590.                                                                                          frame: NSZeroRect

  591.                                                                                          label: @"Offscreen Row"

  592.                                                                                         parent: self]];

  593.                     }

  594.                 }

  595.             }

  596. 

  597.             return rows;

  598.         }

  599. 

  600.         static NSArray* getAccessibilitySelectedRows (id self, SEL)

  601.         {

  602.             return getSelectedChildren ([self accessibilityRows]);

  603.         }

  604. 

  605.         static void setAccessibilitySelectedRows (id self, SEL, NSArray* selected)

  606.         {

  607.             setSelectedChildren ([self accessibilityRows], selected);

  608.         }

  609. 

  610.         static NSArray* getAccessibilityColumns (id self, SEL)

  611.         {

  612.             NSMutableArray* columns = [[NSMutableArray new] autorelease];

  613. 

  614.             if (auto* tableInterface = getTableInterface (self))

  615.             {

  616.                 for (int column = 0; column < tableInterface->getNumColumns(); ++column)

  617.                 {

  618.                     if (auto* handler = tableInterface->getCellHandler (0, column))

  619.                     {

  620.                         [columns addObject: (id) handler->getNativeImplementation()];

  621.                     }

  622.                     else

  623.                     {

  624.                         [columns addObject: [NSAccessibilityElement accessibilityElementWithRole: NSAccessibilityColumnRole

  625.                                                                                             frame: NSZeroRect

  626.                                                                                             label: @"Offscreen Column"

  627.                                                                                            parent: self]];

  628.                     }

  629.                 }

  630.             }

  631. 

  632.             return columns;

  633.         }

  634. 

  635.         static NSArray* getAccessibilitySelectedColumns (id self, SEL)

  636.         {

  637.             return getSelectedChildren ([self accessibilityColumns]);

  638.         }

  639. 

  640.         static void setAccessibilitySelectedColumns (id self, SEL, NSArray* selected)

  641.         {

  642.             setSelectedChildren ([self accessibilityColumns], selected);

  643.         }

  644. 

  645.         //==============================================================================

  646.         static NSInteger getAccessibilityIndex (id self, SEL)

  647.         {

  648.             if (auto* handler = getHandler (self))

  649.             {

  650.                 if (auto* cellInterface = handler->getCellInterface())

  651.                 {

  652.                     NSAccessibilityRole role = [self accessibilityRole];

  653. 

  654.                     if ([role isEqual: NSAccessibilityRowRole])

  655.                         return cellInterface->getRowIndex();

  656. 

  657.                     if ([role isEqual: NSAccessibilityColumnRole])

  658.                         return cellInterface->getColumnIndex();

  659.                 }

  660.             }

  661. 

  662.             return 0;

  663.         }

  664. 

  665.         static NSInteger getAccessibilityDisclosureLevel (id self, SEL)

  666.         {

  667.             if (auto* handler = getHandler (self))

  668.                 if (auto* cellInterface = handler->getCellInterface())

  669.                     return cellInterface->getDisclosureLevel();

  670. 

  671.             return 0;

  672.         }

  673. 

  674.         static BOOL getIsAccessibilityExpanded (id self, SEL)

  675.         {

  676.             if (auto* handler = getHandler (self))

  677.                 return handler->getCurrentState().isExpanded();

  678. 

  679.             return NO;

  680.         }

  681. 

  682.         //==============================================================================

  683.         static BOOL accessibilityPerformShowMenu (id self, SEL)  { return performActionIfSupported (self, AccessibilityActionType::showMenu); }

  684.         static BOOL accessibilityPerformRaise (id self, SEL)     { [self setAccessibilityFocused: YES]; return YES; }

  685. 

  686.         static BOOL accessibilityPerformDelete (id self, SEL)

  687.         {

  688.             if (auto* handler = getHandler (self))

  689.             {

  690.                 if (hasEditableText (*handler))

  691.                 {

  692.                     handler->getTextInterface()->setText ({});

  693.                     return YES;

  694.                 }

  695. 

  696.                 if (auto* valueInterface = handler->getValueInterface())

  697.                 {

  698.                     if (! valueInterface->isReadOnly())

  699.                     {

  700.                         valueInterface->setValue ({});

  701.                         return YES;

  702.                     }

  703.                 }

  704.             }

  705. 

  706.             return NO;

  707.         }

  708. 

  709.         //==============================================================================

  710.         static BOOL getIsAccessibilitySelectorAllowed (id self, SEL, SEL selector)

  711.         {

  712.             if (auto* handler = getHandler (self))

  713.             {

  714.                 const auto role = handler->getRole();

  715.                 const auto currentState = handler->getCurrentState();

  716. 

  717.                 for (auto textSelector : { @selector (accessibilityInsertionPointLineNumber),

  718.                                            @selector (accessibilityVisibleCharacterRange),

  719.                                            @selector (accessibilityNumberOfCharacters),

  720.                                            @selector (accessibilitySelectedText),

  721.                                            @selector (accessibilitySelectedTextRange),

  722.                                            @selector (accessibilityAttributedStringForRange:),

  723.                                            @selector (accessibilityRangeForLine:),

  724.                                            @selector (accessibilityStringForRange:),

  725.                                            @selector (accessibilityRangeForPosition:),

  726.                                            @selector (accessibilityRangeForIndex:),

  727.                                            @selector (accessibilityFrameForRange:),

  728.                                            @selector (accessibilityLineForIndex:),

  729.                                            @selector (setAccessibilitySelectedTextRange:) })

  730.                 {

  731.                     if (selector == textSelector)

  732.                         return handler->getTextInterface() != nullptr;

  733.                 }

  734. 

  735.                 for (auto tableSelector : { @selector (accessibilityRowCount),

  736.                                             @selector (accessibilityRows),

  737.                                             @selector (accessibilitySelectedRows),

  738.                                             @selector (accessibilityColumnCount),

  739.                                             @selector (accessibilityColumns),

  740.                                             @selector (accessibilitySelectedColumns) })

  741.                 {

  742.                     if (selector == tableSelector)

  743.                         return handler->getTableInterface() != nullptr;

  744.                 }

  745. 

  746.                 for (auto cellSelector : { @selector (accessibilityRowIndexRange),

  747.                                            @selector (accessibilityColumnIndexRange),

  748.                                            @selector (accessibilityIndex),

  749.                                            @selector (accessibilityDisclosureLevel) })

  750.                 {

  751.                     if (selector == cellSelector)

  752.                         return handler->getCellInterface() != nullptr;

  753.                 }

  754. 

  755.                 for (auto valueSelector : { @selector (accessibilityValue),

  756.                                             @selector (setAccessibilityValue:),

  757.                                             @selector (accessibilityPerformDelete),

  758.                                             @selector (accessibilityPerformIncrement),

  759.                                             @selector (accessibilityPerformDecrement) })

  760.                 {

  761.                     if (selector != valueSelector)

  762.                         continue;

  763. 

  764.                     auto* valueInterface = handler->getValueInterface();

  765. 

  766.                     if (selector == @selector (accessibilityValue))

  767.                         return valueInterface != nullptr

  768.                             || hasEditableText (*handler)

  769.                             || currentState.isCheckable();

  770. 

  771.                     auto hasEditableValue = [valueInterface] { return valueInterface != nullptr && ! valueInterface->isReadOnly(); };

  772. 

  773.                     if (selector == @selector (setAccessibilityValue:)

  774.                      || selector == @selector (accessibilityPerformDelete))

  775.                         return hasEditableValue() || hasEditableText (*handler);

  776. 

  777.                     auto isRanged = [valueInterface] { return valueInterface != nullptr && valueInterface->getRange().isValid(); };

  778. 

  779.                     if (selector == @selector (accessibilityPerformIncrement)

  780.                      || selector == @selector (accessibilityPerformDecrement))

  781.                         return hasEditableValue() && isRanged();

  782. 

  783.                     return NO;

  784.                 }

  785. 

  786.                 for (auto actionSelector : { @selector (accessibilityPerformPress),

  787.                                              @selector (accessibilityPerformShowMenu),

  788.                                              @selector (accessibilityPerformRaise),

  789.                                              @selector (setAccessibilityFocused:) })

  790.                 {

  791.                     if (selector != actionSelector)

  792.                         continue;

  793. 

  794.                     if (selector == @selector (accessibilityPerformPress))

  795.                         return handler->getActions().contains (AccessibilityActionType::press);

  796. 

  797.                     if (selector == @selector (accessibilityPerformShowMenu))

  798.                         return handler->getActions().contains (AccessibilityActionType::showMenu);

  799. 

  800.                     if (selector == @selector (accessibilityPerformRaise))

  801.                         return [[self accessibilityRole] isEqual: NSAccessibilityWindowRole];

  802. 

  803.                     if (selector == @selector (setAccessibilityFocused:))

  804.                         return currentState.isFocusable();

  805.                 }

  806. 

  807.                 if (selector == @selector (accessibilitySelectedChildren))

  808.                     return role == AccessibilityRole::popupMenu;

  809. 

  810.                 if (selector == @selector (accessibilityOrientation))

  811.                     return role == AccessibilityRole::scrollBar;

  812. 

  813.                 if (selector == @selector (isAccessibilityExpanded))

  814.                     return currentState.isExpandable();

  815. 

  816.                 return sendSuperclassMessage<BOOL> (self, @selector (isAccessibilitySelectorAllowed:), selector);

  817.             }

  818. 

  819.             return NO;

  820.         }

  821. 

  822.         //==============================================================================

  823.         JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityElement)

  824.     };

  825. 

  826.     //==============================================================================

  827.     AccessibilityElement::Holder accessibilityElement;

  828. 

  829.     //==============================================================================

  830.     JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityNativeImpl)

  831. };

  832. 

  833. //==============================================================================

  834. AccessibilityNativeHandle* AccessibilityHandler::getNativeImplementation() const

  835. {

  836.     return (AccessibilityNativeHandle*) nativeImpl->getAccessibilityElement();

  837. }

  838. 

  839. static bool areAnyAccessibilityClientsActive()

  840. {

  841.     const String voiceOverKeyString ("voiceOverOnOffKey");

  842.     const String applicationIDString ("com.apple.universalaccess");

  843. 

  844.     CFUniquePtr<CFStringRef> cfKey (voiceOverKeyString.toCFString());

  845.     CFUniquePtr<CFStringRef> cfID  (applicationIDString.toCFString());

  846. 

  847.     CFUniquePtr<CFPropertyListRef> value (CFPreferencesCopyAppValue (cfKey.get(), cfID.get()));

  848. 

  849.     if (value != nullptr)

  850.         return CFBooleanGetValue ((CFBooleanRef) value.get());

  851. 

  852.     return false;

  853. }

  854. 

  855. static void sendAccessibilityEvent (id accessibilityElement,

  856.                                     NSAccessibilityNotificationName notification,

  857.                                     NSDictionary* userInfo)

  858. {

  859.     jassert (notification != NSAccessibilityNotificationName{});

  860. 

  861.     NSAccessibilityPostNotificationWithUserInfo (accessibilityElement, notification, userInfo);

  862. }

  863. 

  864. static void sendHandlerNotification (const AccessibilityHandler& handler,

  865.                                      NSAccessibilityNotificationName notification)

  866. {

  867.     if (! areAnyAccessibilityClientsActive() || notification == NSAccessibilityNotificationName{})

  868.         return;

  869. 

  870.     if (id accessibilityElement = (id) handler.getNativeImplementation())

  871.     {

  872.         sendAccessibilityEvent (accessibilityElement, notification,

  873.                                 (notification == NSAccessibilityLayoutChangedNotification

  874.                                    ? @{ NSAccessibilityUIElementsKey: @[ accessibilityElement ] }

  875.                                    : nil));

  876.     }

  877. }

  878. 

  879. void notifyAccessibilityEventInternal (const AccessibilityHandler& handler, InternalAccessibilityEvent eventType)

  880. {

  881.     auto notification = [eventType]

  882.     {

  883.         switch (eventType)

  884.         {

  885.             case InternalAccessibilityEvent::elementCreated:         return NSAccessibilityCreatedNotification;

  886.             case InternalAccessibilityEvent::elementDestroyed:       return NSAccessibilityUIElementDestroyedNotification;

  887.             case InternalAccessibilityEvent::elementMovedOrResized:  return NSAccessibilityLayoutChangedNotificationJuce;

  888.             case InternalAccessibilityEvent::focusChanged:           return NSAccessibilityFocusedUIElementChangedNotification;

  889.             case InternalAccessibilityEvent::windowOpened:           return NSAccessibilityWindowCreatedNotification;

  890.             case InternalAccessibilityEvent::windowClosed:           break;

  891.         }

  892. 

  893.         return NSAccessibilityNotificationName{};

  894.     }();

  895. 

  896.     sendHandlerNotification (handler, notification);

  897. }

  898. 

  899. void AccessibilityHandler::notifyAccessibilityEvent (AccessibilityEvent eventType) const

  900. {

  901.     auto notification = [eventType]

  902.     {

  903.         switch (eventType)

  904.         {

  905.             case AccessibilityEvent::textSelectionChanged:  return NSAccessibilitySelectedTextChangedNotification;

  906.             case AccessibilityEvent::rowSelectionChanged:   return NSAccessibilitySelectedRowsChangedNotification;

  907. 

  908.             case AccessibilityEvent::textChanged:

  909.             case AccessibilityEvent::valueChanged:          return NSAccessibilityValueChangedNotification;

  910.             case AccessibilityEvent::titleChanged:          return NSAccessibilityTitleChangedNotification;

  911.             case AccessibilityEvent::structureChanged:      return NSAccessibilityLayoutChangedNotificationJuce;

  912.         }

  913. 

  914.         return NSAccessibilityNotificationName{};

  915.     }();

  916. 

  917.     sendHandlerNotification (*this, notification);

  918. }

  919. 

  920. void AccessibilityHandler::postAnnouncement (const String& announcementString, AnnouncementPriority priority)

  921. {

  922.     if (! areAnyAccessibilityClientsActive())

  923.         return;

  924. 

  925.     #if JUCE_OBJC_HAS_AVAILABLE_FEATURE

  926.      if (@available (macOS 10.10, *))

  927.     #endif

  928.      {

  929.         auto nsPriority = [priority]

  930.         {

  931.             switch (priority)

  932.             {

  933.                 case AnnouncementPriority::low:    return NSAccessibilityPriorityLow;

  934.                 case AnnouncementPriority::medium: return NSAccessibilityPriorityMedium;

  935.                 case AnnouncementPriority::high:   return NSAccessibilityPriorityHigh;

  936.             }

  937. 

  938.             jassertfalse;

  939.             return NSAccessibilityPriorityLow;

  940.         }();

  941. 

  942.         sendAccessibilityEvent ((id) [NSApp mainWindow],

  943.                                 NSAccessibilityAnnouncementRequestedNotification,

  944.                                 @{ NSAccessibilityAnnouncementKey: juceStringToNS (announcementString),

  945.                                    NSAccessibilityPriorityKey:     @(nsPriority) });

  946.      }

  947. }

  948. 

  949. JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  950. 

  951. #endif

  952. 

  953. } // namespace juce