DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
12316 Commits
9 Branches
2.8GB
Tree: 9199fa3c51
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '9199fa3c51'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

2033 lines
85KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2020 - Raw Material Software Limited

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 6 End-User License

  11.    Agreement and JUCE Privacy Policy (both effective as of the 16th June 2020).

  12. 

  13.    End User License Agreement: www.juce.com/juce-6-licence

  14.    Privacy Policy: www.juce.com/juce-privacy-policy

  15. 

  16.    Or: You may also use this code under the terms of the GPL v3 (see

  17.    www.gnu.org/licenses).

  18. 

  19.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  20.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  21.    DISCLAIMED.

  22. 

  23.   ==============================================================================

  24. */

  25. 

  26. #include <juce_core/system/juce_TargetPlatform.h>

  27. #include "../utility/juce_CheckSettingMacros.h"

  28. 

  29. #if JucePlugin_Build_AUv3

  30. 

  31. #if JUCE_MAC

  32.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  33.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  34.  #endif

  35.  #if (defined MAC_OS_X_VERSION_10_13) && (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_13)

  36.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  37.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  38.  #endif

  39.  #if defined (MAC_OS_VERSION_12_0)

  40.   #define JUCE_AUV3_MIDI_EVENT_LIST_SUPPORTED 1

  41.  #endif

  42. #endif

  43. 

  44. #if JUCE_IOS

  45.  #if (defined __IPHONE_11_0) && (__IPHONE_OS_VERSION_MIN_REQUIRED >= __IPHONE_11_0)

  46.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  47.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  48.  #endif

  49.  #if (defined __IPHONE_15_0)

  50.   #define JUCE_AUV3_MIDI_EVENT_LIST_SUPPORTED 1

  51.  #endif

  52. #endif

  53. 

  54. #ifndef __OBJC2__

  55.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  56. #endif

  57. 

  58. #define JUCE_CORE_INCLUDE_OBJC_HELPERS 1

  59. 

  60. #include "../utility/juce_IncludeSystemHeaders.h"

  61. #include "../utility/juce_IncludeModuleHeaders.h"

  62. 

  63. #import <CoreAudioKit/CoreAudioKit.h>

  64. #import <AudioToolbox/AudioToolbox.h>

  65. #import <AVFoundation/AVFoundation.h>

  66. 

  67. #include <juce_graphics/native/juce_mac_CoreGraphicsHelpers.h>

  68. #include <juce_audio_basics/native/juce_mac_CoreAudioLayouts.h>

  69. #include <juce_audio_processors/format_types/juce_LegacyAudioParameter.cpp>

  70. #include <juce_audio_processors/format_types/juce_AU_Shared.h>

  71. 

  72. #if JUCE_AUV3_MIDI_EVENT_LIST_SUPPORTED

  73.  #include <juce_audio_basics/midi/ump/juce_UMP.h>

  74. #endif

  75. 

  76. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  77. 

  78. #if JUCE_IOS

  79.  #define JUCE_IOS_MAC_VIEW  UIView

  80. #else

  81.  #define JUCE_IOS_MAC_VIEW  NSView

  82. #endif

  83. 

  84. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  85. 

  86. #include <future>

  87. 

  88. JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wnullability-completeness")

  89. 

  90. using namespace juce;

  91. 

  92. struct AudioProcessorHolder  : public ReferenceCountedObject

  93. {

  94.     AudioProcessorHolder() {}

  95.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  96.     AudioProcessor& operator*() noexcept        { return *processor; }

  97.     AudioProcessor* operator->() noexcept       { return processor.get(); }

  98.     AudioProcessor* get() noexcept              { return processor.get(); }

  99. 

  100.     struct ViewConfig

  101.     {

  102.         double width;

  103.         double height;

  104.         bool hostHasMIDIController;

  105.     };

  106. 

  107.     std::unique_ptr<ViewConfig> viewConfiguration;

  108. 

  109.     using Ptr = ReferenceCountedObjectPtr<AudioProcessorHolder>;

  110. 

  111. private:

  112.     std::unique_ptr<AudioProcessor> processor;

  113. 

  114.     AudioProcessorHolder& operator= (AudioProcessor*) = delete;

  115.     AudioProcessorHolder (AudioProcessorHolder&) = delete;

  116.     AudioProcessorHolder& operator= (AudioProcessorHolder&) = delete;

  117. };

  118. 

  119. //==============================================================================

  120. class JuceAudioUnitv3Base

  121. {

  122. public:

  123.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  124.                          AudioComponentInstantiationOptions options,

  125.                          NSError** error)

  126.         JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wobjc-method-access")

  127.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  128.                                                                         options: options

  129.                                                                           error: error

  130.                                                                       juceClass: this])

  131.         JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  132.     {}

  133. 

  134.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  135.     {

  136.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  137.         initialiseJuce_GUI();

  138.     }

  139. 

  140.     virtual ~JuceAudioUnitv3Base() = default;

  141. 

  142.     //==============================================================================

  143.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  144. 

  145.     //==============================================================================

  146.     virtual void reset()                                                   = 0;

  147. 

  148.     //==============================================================================

  149.     virtual AUAudioUnitPreset* getCurrentPreset()                          = 0;

  150.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      = 0;

  151.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()               = 0;

  152. 

  153.     virtual NSDictionary<NSString*, id>* getFullState()

  154.     {

  155.         return ObjCMsgSendSuper<AUAudioUnit, NSDictionary<NSString*, id>*> (getAudioUnit(), @selector (fullState));

  156.     }

  157. 

  158.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  159.     {

  160.         ObjCMsgSendSuper<AUAudioUnit, void> (getAudioUnit(), @selector (setFullState:), state);

  161.     }

  162. 

  163.     virtual AUParameterTree* getParameterTree()                            = 0;

  164.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)       = 0;

  165. 

  166.     //==============================================================================

  167.     virtual NSTimeInterval getLatency()                                    = 0;

  168.     virtual NSTimeInterval getTailTime()                                   = 0;

  169. 

  170.     //==============================================================================

  171.     virtual AUAudioUnitBusArray* getInputBusses()                          = 0;

  172.     virtual AUAudioUnitBusArray* getOutputBusses()                         = 0;

  173.     virtual NSArray<NSNumber*>* getChannelCapabilities()                   = 0;

  174.     virtual bool shouldChangeToFormat (AVAudioFormat*, AUAudioUnitBus*)    = 0;

  175. 

  176.     //==============================================================================

  177.     virtual int getVirtualMIDICableCount()                                 = 0;

  178.     virtual bool getSupportsMPE()                                          = 0;

  179.     virtual NSArray<NSString*>* getMIDIOutputNames()                       = 0;

  180. 

  181.     //==============================================================================

  182.     virtual AUInternalRenderBlock getInternalRenderBlock()                 = 0;

  183.     virtual bool getCanProcessInPlace()                                    { return false; }

  184.     virtual bool getRenderingOffline()                                     = 0;

  185.     virtual void setRenderingOffline (bool offline)                        = 0;

  186. 

  187.     virtual bool getShouldBypassEffect()

  188.     {

  189.         return (ObjCMsgSendSuper<AUAudioUnit, BOOL> (getAudioUnit(), @selector (shouldBypassEffect)) == YES);

  190.     }

  191. 

  192.     virtual void setShouldBypassEffect (bool shouldBypass)

  193.     {

  194.         ObjCMsgSendSuper<AUAudioUnit, void> (getAudioUnit(), @selector (setShouldBypassEffect:), shouldBypass ? YES : NO);

  195.     }

  196. 

  197.     //==============================================================================

  198.     virtual NSString* getContextName()      const                          = 0;

  199.     virtual void setContextName (NSString*)                                = 0;

  200. 

  201.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  202.     {

  203.         return (ObjCMsgSendSuper<AUAudioUnit, BOOL, NSError**> (getAudioUnit(), @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  204.     }

  205. 

  206.     virtual void deallocateRenderResources()

  207.     {

  208.         ObjCMsgSendSuper<AUAudioUnit, void> (getAudioUnit(), @selector (deallocateRenderResources));

  209.     }

  210. 

  211.     //==============================================================================

  212.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  213.     virtual NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>*) = 0;

  214.     virtual void selectViewConfiguration (AUAudioUnitViewConfiguration*)   = 0;

  215.    #endif

  216. 

  217. private:

  218.     struct Class  : public ObjCClass<AUAudioUnit>

  219.     {

  220.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  221.         {

  222.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  223. 

  224.             JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wundeclared-selector")

  225.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  226.                        initWithComponentDescriptionAndJuceClass, "@@:",

  227.                        @encode (AudioComponentDescription),

  228.                        @encode (AudioComponentInstantiationOptions), "^@@");

  229.             JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  230. 

  231.             addMethod (@selector (initWithComponentDescription:options:error:),

  232.                        initWithComponentDescription, "@@:",

  233.                        @encode (AudioComponentDescription),

  234.                        @encode (AudioComponentInstantiationOptions), "^@");

  235. 

  236.             addMethod (@selector (dealloc),                         dealloc,                        "v@:");

  237. 

  238.             //==============================================================================

  239.             addMethod (@selector (reset),                           reset,                          "v@:");

  240. 

  241.             //==============================================================================

  242.             addMethod (@selector (currentPreset),                   getCurrentPreset,               "@@:");

  243.             addMethod (@selector (setCurrentPreset:),               setCurrentPreset,               "v@:@");

  244.             addMethod (@selector (factoryPresets),                  getFactoryPresets,              "@@:");

  245.             addMethod (@selector (fullState),                       getFullState,                   "@@:");

  246.             addMethod (@selector (setFullState:),                   setFullState,                   "v@:@");

  247.             addMethod (@selector (parameterTree),                   getParameterTree,               "@@:");

  248.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  249. 

  250.             //==============================================================================

  251.             addMethod (@selector (latency),                         getLatency,                     @encode (NSTimeInterval), "@:");

  252.             addMethod (@selector (tailTime),                        getTailTime,                    @encode (NSTimeInterval),  "@:");

  253. 

  254.             //==============================================================================

  255.             addMethod (@selector (inputBusses),                     getInputBusses,                 "@@:");

  256.             addMethod (@selector (outputBusses),                    getOutputBusses,                "@@:");

  257.             addMethod (@selector (channelCapabilities),             getChannelCapabilities,         "@@:");

  258.             addMethod (@selector (shouldChangeToFormat:forBus:),    shouldChangeToFormat,           "c@:@@");

  259. 

  260.             //==============================================================================

  261.             addMethod (@selector (virtualMIDICableCount),           getVirtualMIDICableCount,       @encode (NSInteger), "@:");

  262. 

  263.             JUCE_BEGIN_IGNORE_WARNINGS_GCC_LIKE ("-Wundeclared-selector")

  264.             addMethod (@selector (supportsMPE),                     getSupportsMPE,                 @encode (BOOL),      "@:");

  265.             JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  266. 

  267.            #if JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  268.             addMethod (@selector (MIDIOutputNames),                 getMIDIOutputNames,             "@@:");

  269.            #endif

  270. 

  271.             //==============================================================================

  272.             addMethod (@selector (internalRenderBlock),             getInternalRenderBlock,         @encode (AUInternalRenderBlock), "@:");

  273.             addMethod (@selector (canProcessInPlace),               getCanProcessInPlace,           @encode (BOOL), "@:");

  274.             addMethod (@selector (isRenderingOffline),              getRenderingOffline,            @encode (BOOL),  "@:");

  275.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  276.             addMethod (@selector (shouldBypassEffect),              getShouldBypassEffect,          @encode (BOOL),  "@:");

  277.             addMethod (@selector (setShouldBypassEffect:),          setShouldBypassEffect,          "v@:", @encode (BOOL));

  278.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "c@:^@");

  279.             addMethod (@selector (deallocateRenderResources),       deallocateRenderResources,      "v@:");

  280. 

  281.             //==============================================================================

  282.             addMethod (@selector (contextName),                     getContextName,                 "@@:");

  283.             addMethod (@selector (setContextName:),                  setContextName,                 "v@:@");

  284. 

  285.             //==============================================================================

  286.            #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  287.             addMethod (@selector (supportedViewConfigurations:),    getSupportedViewConfigurations, "@@:@");

  288.             addMethod (@selector (selectViewConfiguration:),        selectViewConfiguration,        "v@:@");

  289.            #endif

  290. 

  291.             registerClass();

  292.         }

  293. 

  294.         //==============================================================================

  295.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  296.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  297. 

  298.         //==============================================================================

  299.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  300.         {

  301.             AUAudioUnit* self = _self;

  302. 

  303.             self = ObjCMsgSendSuper<AUAudioUnit, AUAudioUnit*, AudioComponentDescription,

  304.                                     AudioComponentInstantiationOptions, NSError**> (self, @selector (initWithComponentDescription:options:error:), descr, options, error);

  305. 

  306.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  307. 

  308.             setThis (self, juceAU);

  309.             return self;

  310.         }

  311. 

  312.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  313.         {

  314.             AUAudioUnit* self = _self;

  315. 

  316.             self = ObjCMsgSendSuper<AUAudioUnit, AUAudioUnit*, AudioComponentDescription,

  317.                                     AudioComponentInstantiationOptions, NSError**> (self, @selector(initWithComponentDescription:options:error:), descr, options, error);

  318. 

  319. 

  320.             setThis (self, juceAU);

  321.             return self;

  322.         }

  323. 

  324.         static void dealloc (id self, SEL)

  325.         {

  326.             if (! MessageManager::getInstance()->isThisTheMessageThread())

  327.             {

  328.                 WaitableEvent deletionEvent;

  329. 

  330.                 struct AUDeleter  : public CallbackMessage

  331.                 {

  332.                     AUDeleter (id selfToDelete, WaitableEvent& event)

  333.                         : parentSelf (selfToDelete), parentDeletionEvent (event)

  334.                     {

  335.                     }

  336. 

  337.                     void messageCallback() override

  338.                     {

  339.                         delete _this (parentSelf);

  340.                         parentDeletionEvent.signal();

  341.                     }

  342. 

  343.                     id parentSelf;

  344.                     WaitableEvent& parentDeletionEvent;

  345.                 };

  346. 

  347.                 (new AUDeleter (self, deletionEvent))->post();

  348.                 deletionEvent.wait (-1);

  349.             }

  350.             else

  351.             {

  352.                 delete _this (self);

  353.             }

  354.         }

  355. 

  356.         //==============================================================================

  357.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  358. 

  359.         //==============================================================================

  360.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  361.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  362.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  363.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  364.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  365.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  366.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  367. 

  368.         //==============================================================================

  369.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  370.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  371. 

  372.         //==============================================================================

  373.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  374.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  375.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  376.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  377. 

  378.         //==============================================================================

  379.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  380.         static BOOL getSupportsMPE (id self, SEL)                                                   { return _this (self)->getSupportsMPE() ? YES : NO; }

  381.         static NSArray<NSString*>* getMIDIOutputNames (id self, SEL)                                { return _this (self)->getMIDIOutputNames(); }

  382. 

  383.         //==============================================================================

  384.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  385.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  386.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  387.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  388.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  389.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  390.         static BOOL getShouldBypassEffect (id self, SEL)                                            { return _this (self)->getShouldBypassEffect() ? YES : NO; }

  391.         static void setShouldBypassEffect (id self, SEL, BOOL shouldBypass)                         { _this (self)->setShouldBypassEffect (shouldBypass); }

  392. 

  393.         //==============================================================================

  394.         static NSString* getContextName (id self, SEL)                                              { return _this (self)->getContextName(); }

  395.         static void setContextName (id self, SEL, NSString* str)                                    { return _this (self)->setContextName (str); }

  396. 

  397.         //==============================================================================

  398.        #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  399.         static NSIndexSet* getSupportedViewConfigurations (id self, SEL, NSArray<AUAudioUnitViewConfiguration*>* configs) { return _this (self)->getSupportedViewConfigurations (configs); }

  400.         static void selectViewConfiguration (id self, SEL, AUAudioUnitViewConfiguration* config)    { _this (self)->selectViewConfiguration (config); }

  401.        #endif

  402.     };

  403. 

  404.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  405. 

  406.     //==============================================================================

  407.     static Class audioUnitObjCClass;

  408. 

  409. protected:

  410.     AUAudioUnit* au;

  411. };

  412. 

  413. //==============================================================================

  414. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  415. 

  416. //==============================================================================

  417. //=========================== The actual AudioUnit =============================

  418. //==============================================================================

  419. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  420.                          public AudioProcessorListener,

  421.                          public AudioPlayHead,

  422.                          private AudioProcessorParameter::Listener

  423. {

  424. public:

  425.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  426.                      const AudioComponentDescription& descr,

  427.                      AudioComponentInstantiationOptions options,

  428.                      NSError** error)

  429.         : JuceAudioUnitv3Base (descr, options, error),

  430.           processorHolder (processor),

  431.           mapper (*processorHolder->get())

  432.     {

  433.         init();

  434.     }

  435. 

  436.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  437.         : JuceAudioUnitv3Base (audioUnit),

  438.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  439.           mapper (*processorHolder->get())

  440.     {

  441.         init();

  442.     }

  443. 

  444.     ~JuceAudioUnitv3() override

  445.     {

  446.         auto& processor = getAudioProcessor();

  447.         processor.removeListener (this);

  448. 

  449.         if (bypassParam != nullptr)

  450.             bypassParam->removeListener (this);

  451. 

  452.         removeEditor (processor);

  453. 

  454.         if (editorObserverToken != nullptr)

  455.         {

  456.             [paramTree.get() removeParameterObserver: editorObserverToken];

  457.             editorObserverToken = nullptr;

  458.         }

  459.     }

  460. 

  461.     //==============================================================================

  462.     void init()

  463.     {

  464.         inParameterChangedCallback = false;

  465. 

  466.         AudioProcessor& processor = getAudioProcessor();

  467.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  468. 

  469.        #ifdef JucePlugin_PreferredChannelConfigurations

  470.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  471.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  472. 

  473.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  474.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  475. 

  476.         Array<AUChannelInfo> channelInfos;

  477. 

  478.         for (int i = 0; i < numConfigs; ++i)

  479.         {

  480.             AUChannelInfo channelInfo;

  481. 

  482.             channelInfo.inChannels  = configs[i][0];

  483.             channelInfo.outChannels = configs[i][1];

  484. 

  485.             channelInfos.add (channelInfo);

  486.         }

  487.        #else

  488.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  489.        #endif

  490. 

  491.         processor.setPlayHead (this);

  492. 

  493.         totalInChannels  = processor.getTotalNumInputChannels();

  494.         totalOutChannels = processor.getTotalNumOutputChannels();

  495. 

  496.         {

  497.             channelCapabilities.reset ([[NSMutableArray<NSNumber*> alloc] init]);

  498. 

  499.             for (int i = 0; i < channelInfos.size(); ++i)

  500.             {

  501.                 AUChannelInfo& info = channelInfos.getReference (i);

  502. 

  503.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.inChannels]];

  504.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.outChannels]];

  505.             }

  506.         }

  507. 

  508.         editorObserverToken = nullptr;

  509.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  510. 

  511.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  512.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  513.         processor.addListener (this);

  514. 

  515.         addParameters();

  516.         addPresets();

  517. 

  518.         addAudioUnitBusses (true);

  519.         addAudioUnitBusses (false);

  520.     }

  521. 

  522.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  523. 

  524.     //==============================================================================

  525.     void reset() override

  526.     {

  527.         midiMessages.clear();

  528.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  529.     }

  530. 

  531.     //==============================================================================

  532.     AUAudioUnitPreset* getCurrentPreset() override

  533.     {

  534.         const int n = static_cast<int> ([factoryPresets.get() count]);

  535.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  536. 

  537.         if (idx < n)

  538.             return [factoryPresets.get() objectAtIndex:static_cast<unsigned int> (idx)];

  539. 

  540.         return nullptr;

  541.     }

  542. 

  543.     void setCurrentPreset (AUAudioUnitPreset* preset) override

  544.     {

  545.         const int n = static_cast<int> ([factoryPresets.get() count]);

  546.         const int idx = static_cast<int> ([preset number]);

  547. 

  548.         if (isPositiveAndBelow (idx, n))

  549.             getAudioProcessor().setCurrentProgram (idx);

  550.     }

  551. 

  552.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override

  553.     {

  554.         return factoryPresets.get();

  555.     }

  556. 

  557.     NSDictionary<NSString*, id>* getFullState() override

  558.     {

  559.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  560. 

  561.         {

  562.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  563. 

  564.             if (superRetval != nullptr)

  565.                 [retval addEntriesFromDictionary:superRetval];

  566.         }

  567. 

  568.         juce::MemoryBlock state;

  569. 

  570.        #if JUCE_AU_WRAPPERS_SAVE_PROGRAM_STATES

  571.         getAudioProcessor().getCurrentProgramStateInformation (state);

  572.        #else

  573.         getAudioProcessor().getStateInformation (state);

  574.        #endif

  575. 

  576.         if (state.getSize() > 0)

  577.         {

  578.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  579.                                                       length: state.getSize()];

  580. 

  581.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  582. 

  583.             [retval setObject: ourState

  584.                        forKey: nsKey];

  585. 

  586.             [nsKey    release];

  587.             [ourState release];

  588.         }

  589. 

  590.         return [retval autorelease];

  591.     }

  592. 

  593.     void setFullState (NSDictionary<NSString*, id>* state) override

  594.     {

  595.         if (state == nullptr)

  596.             return;

  597. 

  598.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  599.         [modifiedState addEntriesFromDictionary: state];

  600. 

  601.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  602.         [modifiedState removeObjectForKey: nsPresetKey];

  603.         [nsPresetKey release];

  604. 

  605.         JuceAudioUnitv3Base::setFullState (modifiedState);

  606. 

  607.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  608.         NSObject* obj = [modifiedState objectForKey: nsKey];

  609.         [nsKey release];

  610. 

  611.         if (obj != nullptr)

  612.         {

  613.             if ([obj isKindOfClass:[NSData class]])

  614.             {

  615.                 NSData* data = reinterpret_cast<NSData*> (obj);

  616.                 const int numBytes = static_cast<int> ([data length]);

  617.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  618. 

  619.                 if (numBytes > 0)

  620.                 {

  621.                    #if JUCE_AU_WRAPPERS_SAVE_PROGRAM_STATES

  622.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  623.                    #else

  624.                     getAudioProcessor().setStateInformation (rawBytes, numBytes);

  625.                    #endif

  626.                 }

  627.             }

  628.         }

  629. 

  630.         [modifiedState release];

  631.     }

  632. 

  633.     AUParameterTree* getParameterTree() override

  634.     {

  635.         return paramTree.get();

  636.     }

  637. 

  638.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  639.     {

  640.         const int n = static_cast<int> ([overviewParams.get() count]);

  641. 

  642.         if (count >= n)

  643.             return overviewParams.get();

  644. 

  645.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams.get()];

  646.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  647. 

  648.         return [retval autorelease];

  649.     }

  650. 

  651.     //==============================================================================

  652.     NSTimeInterval getLatency() override

  653.     {

  654.         auto& p = getAudioProcessor();

  655.         return p.getLatencySamples() / p.getSampleRate();

  656.     }

  657. 

  658.     NSTimeInterval getTailTime() override

  659.     {

  660.         return getAudioProcessor().getTailLengthSeconds();

  661.     }

  662. 

  663.     //==============================================================================

  664.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses.get();  }

  665.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses.get(); }

  666.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities.get(); }

  667. 

  668.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  669.     {

  670.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  671.         const int busIdx = static_cast<int> ([auBus index]);

  672.         const int newNumChannels = static_cast<int> ([format channelCount]);

  673. 

  674.         AudioProcessor& processor = getAudioProcessor();

  675. 

  676.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  677.         {

  678.           #ifdef JucePlugin_PreferredChannelConfigurations

  679.             ignoreUnused (bus);

  680. 

  681.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  682. 

  683.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  684.                 return false;

  685.           #else

  686.             const AVAudioChannelLayout* layout    = [format channelLayout];

  687.             const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  688. 

  689.             if (layoutTag != 0)

  690.             {

  691.                 AudioChannelSet newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  692. 

  693.                 if (newLayout.size() != newNumChannels)

  694.                     return false;

  695. 

  696.                 if (! bus->isLayoutSupported (newLayout))

  697.                     return false;

  698.             }

  699.             else

  700.             {

  701.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  702.                     return false;

  703.             }

  704.            #endif

  705. 

  706.             return true;

  707.         }

  708. 

  709.         return false;

  710.     }

  711. 

  712.     //==============================================================================

  713.     int getVirtualMIDICableCount() override

  714.     {

  715.        #if JucePlugin_WantsMidiInput

  716.         return 1;

  717.        #else

  718.         return 0;

  719.        #endif

  720.     }

  721. 

  722.     bool getSupportsMPE() override

  723.     {

  724.         return getAudioProcessor().supportsMPE();

  725.     }

  726. 

  727.     NSArray<NSString*>* getMIDIOutputNames() override

  728.     {

  729.        #if JucePlugin_ProducesMidiOutput

  730.         return @[@"MIDI Out"];

  731.        #else

  732.         return @[];

  733.        #endif

  734.     }

  735. 

  736.     //==============================================================================

  737.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  738.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  739.     void setRenderingOffline (bool offline) override

  740.     {

  741.         auto& processor = getAudioProcessor();

  742.         auto isCurrentlyNonRealtime = processor.isNonRealtime();

  743. 

  744.         if (isCurrentlyNonRealtime != offline)

  745.         {

  746.             ScopedLock callbackLock (processor.getCallbackLock());

  747. 

  748.             processor.setNonRealtime (offline);

  749.             processor.prepareToPlay (processor.getSampleRate(), processor.getBlockSize());

  750.         }

  751.     }

  752. 

  753.     bool getShouldBypassEffect() override

  754.     {

  755.         if (bypassParam != nullptr)

  756.             return (bypassParam->getValue() != 0.0f);

  757. 

  758.         return JuceAudioUnitv3Base::getShouldBypassEffect();

  759.     }

  760. 

  761.     void setShouldBypassEffect (bool shouldBypass) override

  762.     {

  763.         if (bypassParam != nullptr)

  764.             bypassParam->setValue (shouldBypass ? 1.0f : 0.0f);

  765. 

  766.         JuceAudioUnitv3Base::setShouldBypassEffect (shouldBypass);

  767.     }

  768. 

  769.     //==============================================================================

  770.     NSString* getContextName() const    override              { return juceStringToNS (contextName); }

  771.     void setContextName (NSString* str) override

  772.     {

  773.         if (str != nullptr)

  774.         {

  775.             AudioProcessor::TrackProperties props;

  776.             props.name = nsStringToJuce (str);

  777. 

  778.             getAudioProcessor().updateTrackProperties (props);

  779.         }

  780.     }

  781. 

  782.     //==============================================================================

  783.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  784.     {

  785.         AudioProcessor& processor = getAudioProcessor();

  786.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  787. 

  788.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  789.             return false;

  790. 

  791.         if (outError != nullptr)

  792.             *outError = nullptr;

  793. 

  794.         AudioProcessor::BusesLayout layouts;

  795.         for (int dir = 0; dir < 2; ++dir)

  796.         {

  797.             const bool isInput = (dir == 0);

  798.             const int n = AudioUnitHelpers::getBusCountForWrapper (processor, isInput);

  799.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  800. 

  801.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  802.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  803. 

  804.             for (int busIdx = 0; busIdx < n; ++busIdx)

  805.             {

  806.                 if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  807.                 {

  808.                     AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  809. 

  810.                     AudioChannelSet newLayout;

  811.                     const AVAudioChannelLayout* layout    = [format channelLayout];

  812.                     const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  813. 

  814.                     if (layoutTag != 0)

  815.                         newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  816.                     else

  817.                         newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  818. 

  819.                     if (newLayout.isDisabled())

  820.                         return false;

  821. 

  822.                     channelSets.add (newLayout);

  823.                 }

  824.             }

  825.         }

  826. 

  827.        #ifdef JucePlugin_PreferredChannelConfigurations

  828.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  829. 

  830.         if (! AudioProcessor::containsLayout (layouts, configs))

  831.         {

  832.             if (outError != nullptr)

  833.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  834. 

  835.             return false;

  836.         }

  837.        #endif

  838. 

  839.         if (! AudioUnitHelpers::setBusesLayout (&getAudioProcessor(), layouts))

  840.         {

  841.             if (outError != nullptr)

  842.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  843. 

  844.             return false;

  845.         }

  846. 

  847.         totalInChannels  = processor.getTotalNumInputChannels();

  848.         totalOutChannels = processor.getTotalNumOutputChannels();

  849. 

  850.         allocateBusBuffer (true);

  851.         allocateBusBuffer (false);

  852. 

  853.         mapper.alloc();

  854. 

  855.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  856. 

  857.         auto sampleRate = [&]

  858.         {

  859.             for (auto* buffer : { inputBusses.get(), outputBusses.get() })

  860.                 if ([buffer count] > 0)

  861.                     return [[[buffer objectAtIndexedSubscript: 0] format] sampleRate];

  862. 

  863.             return 44100.0;

  864.         }();

  865. 

  866.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  867.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  868. 

  869.         midiMessages.ensureSize (2048);

  870.         midiMessages.clear();

  871. 

  872.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  873.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  874.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  875. 

  876.         reset();

  877. 

  878.         return true;

  879.     }

  880. 

  881.     void deallocateRenderResources() override

  882.     {

  883.         hostMusicalContextCallback = nullptr;

  884.         hostTransportStateCallback = nullptr;

  885. 

  886.         getAudioProcessor().releaseResources();

  887.         audioBuffer.release();

  888. 

  889.         inBusBuffers. clear();

  890.         outBusBuffers.clear();

  891. 

  892.         mapper.release();

  893. 

  894.         JuceAudioUnitv3Base::deallocateRenderResources();

  895.     }

  896. 

  897.     //==============================================================================

  898.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  899.     NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>* configs) override

  900.     {

  901.         auto supportedViewIndecies = [[NSMutableIndexSet alloc] init];

  902.         auto n = [configs count];

  903. 

  904.         if (auto* editor = getAudioProcessor().createEditorIfNeeded())

  905.         {

  906.             // If you hit this assertion then your plug-in's editor is reporting that it doesn't support

  907.             // any host MIDI controller configurations!

  908.             jassert (editor->supportsHostMIDIControllerPresence (true) || editor->supportsHostMIDIControllerPresence (false));

  909. 

  910.             for (auto i = 0u; i < n; ++i)

  911.             {

  912.                 if (auto viewConfiguration = [configs objectAtIndex: i])

  913.                 {

  914.                     if (editor->supportsHostMIDIControllerPresence ([viewConfiguration hostHasController] == YES))

  915.                     {

  916.                         auto* constrainer = editor->getConstrainer();

  917.                         auto height = (int) [viewConfiguration height];

  918.                         auto width  = (int) [viewConfiguration width];

  919. 

  920.                         if (height <= constrainer->getMaximumHeight() && height >= constrainer->getMinimumHeight()

  921.                          && width  <= constrainer->getMaximumWidth()  && width  >= constrainer->getMinimumWidth())

  922.                             [supportedViewIndecies addIndex: i];

  923.                     }

  924.                 }

  925.             }

  926.         }

  927. 

  928.         return [supportedViewIndecies autorelease];

  929.     }

  930. 

  931.     void selectViewConfiguration (AUAudioUnitViewConfiguration* config) override

  932.     {

  933.         processorHolder->viewConfiguration.reset (new AudioProcessorHolder::ViewConfig { [config width], [config height], [config hostHasController] == YES });

  934.     }

  935.    #endif

  936. 

  937.     struct ScopedKeyChange

  938.     {

  939.         ScopedKeyChange (AUAudioUnit* a, NSString* k)

  940.             : au (a), key (k)

  941.         {

  942.             [au willChangeValueForKey: key];

  943.         }

  944. 

  945.         ~ScopedKeyChange()

  946.         {

  947.             [au didChangeValueForKey: key];

  948.         }

  949. 

  950.         AUAudioUnit* au;

  951.         NSString* key;

  952.     };

  953. 

  954.     //==============================================================================

  955.     void audioProcessorChanged (AudioProcessor* processor, const ChangeDetails& details) override

  956.     {

  957.         ignoreUnused (processor);

  958. 

  959.         if (! details.programChanged)

  960.             return;

  961. 

  962.         {

  963.             ScopedKeyChange scope (au, @"allParameterValues");

  964.             addPresets();

  965.         }

  966. 

  967.         {

  968.             ScopedKeyChange scope (au, @"currentPreset");

  969.         }

  970.     }

  971. 

  972.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  973.     {

  974.         if (inParameterChangedCallback.get())

  975.         {

  976.             inParameterChangedCallback = false;

  977.             return;

  978.         }

  979. 

  980.         if (auto* juceParam = juceParameters.getParamForIndex (idx))

  981.         {

  982.             if (AUParameter* param = [paramTree.get() parameterWithAddress: getAUParameterAddressForIndex (idx)])

  983.             {

  984.                 newValue *= getMaximumParameterValue (juceParam);

  985. 

  986.                 if (editorObserverToken != nullptr)

  987.                     [param setValue: newValue  originator: editorObserverToken];

  988.                 else

  989.                     [param setValue: newValue];

  990.             }

  991.         }

  992.     }

  993. 

  994.     //==============================================================================

  995.     bool getCurrentPosition (CurrentPositionInfo& info) override

  996.     {

  997.         bool musicContextCallSucceeded = false;

  998.         bool transportStateCallSucceeded = false;

  999. 

  1000.         info = lastAudioHead;

  1001.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  1002.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  1003. 

  1004.         switch (lastTimeStamp.mSMPTETime.mType)

  1005.         {

  1006.             case kSMPTETimeType2398:        info.frameRate = AudioPlayHead::fps23976;    break;

  1007.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24;       break;

  1008.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25;       break;

  1009.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997;     break;

  1010.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  1011.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop;   break;

  1012.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30;       break;

  1013.             case kSMPTETimeType60Drop:      info.frameRate = AudioPlayHead::fps60drop;   break;

  1014.             case kSMPTETimeType60:          info.frameRate = AudioPlayHead::fps60;       break;

  1015.             case kSMPTETimeType5994:

  1016.             case kSMPTETimeType5994Drop:

  1017.             case kSMPTETimeType50:

  1018.             default:                        info.frameRate = AudioPlayHead::fpsUnknown;  break;

  1019.         }

  1020. 

  1021.         double num;

  1022.         NSInteger den;

  1023.         NSInteger outDeltaSampleOffsetToNextBeat;

  1024.         double outCurrentMeasureDownBeat, bpm;

  1025.         double ppqPosition;

  1026. 

  1027.         if (hostMusicalContextCallback != nullptr)

  1028.         {

  1029.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  1030. 

  1031.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  1032.             {

  1033.                 musicContextCallSucceeded = true;

  1034. 

  1035.                 info.timeSigNumerator   = (int) num;

  1036.                 info.timeSigDenominator = (int) den;

  1037.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  1038.                 info.bpm = bpm;

  1039.                 info.ppqPosition = ppqPosition;

  1040.             }

  1041.         }

  1042. 

  1043.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  1044.         AUHostTransportStateFlags flags;

  1045. 

  1046.         if (hostTransportStateCallback != nullptr)

  1047.         {

  1048.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  1049. 

  1050.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  1051.             {

  1052.                 transportStateCallSucceeded = true;

  1053. 

  1054.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  1055.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  1056.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  1057.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  1058.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  1059.                 info.ppqLoopStart   = outCycleStartBeat;

  1060.                 info.ppqLoopEnd     = outCycleEndBeat;

  1061.             }

  1062.         }

  1063. 

  1064.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  1065.             lastAudioHead = info;

  1066. 

  1067.         return true;

  1068.     }

  1069. 

  1070.     //==============================================================================

  1071.     static void removeEditor (AudioProcessor& processor)

  1072.     {

  1073.         ScopedLock editorLock (processor.getCallbackLock());

  1074. 

  1075.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  1076.         {

  1077.             processor.editorBeingDeleted (editor);

  1078.             delete editor;

  1079.         }

  1080.     }

  1081. 

  1082. private:

  1083.     //==============================================================================

  1084.     struct BusBuffer

  1085.     {

  1086.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  1087.             : auBus (bus),

  1088.               maxFrames (maxFramesPerBuffer),

  1089.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  1090.               isInterleaved ([[auBus format] isInterleaved])

  1091.         {

  1092.             alloc();

  1093.         }

  1094. 

  1095.         //==============================================================================

  1096.         void alloc()

  1097.         {

  1098.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1099.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  1100.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  1101.             jassert (bytes > 0);

  1102. 

  1103.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  1104.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  1105. 

  1106.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  1107.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  1108.         }

  1109. 

  1110.         void dealloc()

  1111.         {

  1112.             bufferList = nullptr;

  1113.             bufferListStorage.free();

  1114.             scratchBuffer.setSize (0, 0);

  1115.         }

  1116. 

  1117.         //==============================================================================

  1118.         int numChannels() const noexcept                { return numberOfChannels; }

  1119.         bool interleaved() const noexcept               { return isInterleaved; }

  1120.         AudioBufferList* get() const noexcept           { return bufferList; }

  1121. 

  1122.         //==============================================================================

  1123.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  1124.         {

  1125.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1126.             const bool isCompatible = isCompatibleWith (other);

  1127. 

  1128.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  1129. 

  1130.             for (int i = 0; i < numBuffers; ++i)

  1131.             {

  1132.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  1133.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  1134.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  1135.                                                               : scratchBuffer.getWritePointer (i));

  1136.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  1137.             }

  1138.         }

  1139. 

  1140.         //==============================================================================

  1141.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  1142.         {

  1143.             if (other == nullptr)

  1144.                 return false;

  1145. 

  1146.             if (other->mNumberBuffers > 0)

  1147.             {

  1148.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  1149.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  1150.                                                                              : other->mNumberBuffers);

  1151. 

  1152.                 return otherInterleaved == isInterleaved

  1153.                     && numberOfChannels == otherChannels;

  1154.             }

  1155. 

  1156.             return numberOfChannels == 0;

  1157.         }

  1158. 

  1159.     private:

  1160.         AUAudioUnitBus* auBus;

  1161.         HeapBlock<char> bufferListStorage;

  1162.         AudioBufferList* bufferList = nullptr;

  1163.         int maxFrames, numberOfChannels;

  1164.         bool isInterleaved;

  1165.         juce::AudioBuffer<float> scratchBuffer;

  1166.     };

  1167. 

  1168.     //==============================================================================

  1169.     void addAudioUnitBusses (bool isInput)

  1170.     {

  1171.         std::unique_ptr<NSMutableArray<AUAudioUnitBus*>, NSObjectDeleter> array ([[NSMutableArray<AUAudioUnitBus*> alloc] init]);

  1172.         AudioProcessor& processor = getAudioProcessor();

  1173.         const auto numWrapperBuses = AudioUnitHelpers::getBusCountForWrapper (processor, isInput);

  1174.         const auto numProcessorBuses = AudioUnitHelpers::getBusCount (processor, isInput);

  1175. 

  1176.         for (int i = 0; i < numWrapperBuses; ++i)

  1177.         {

  1178.             std::unique_ptr<AUAudioUnitBus, NSObjectDeleter> audioUnitBus;

  1179. 

  1180.             {

  1181.                 const auto channels = numProcessorBuses <= i ? 2 : processor.getChannelCountOfBus (isInput, i);

  1182.                 std::unique_ptr<AVAudioFormat, NSObjectDeleter> defaultFormat ([[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  1183.                                                                                                                               channels: static_cast<AVAudioChannelCount> (channels)]);

  1184. 

  1185.                 audioUnitBus.reset ([[AUAudioUnitBus alloc] initWithFormat: defaultFormat.get()

  1186.                                                                      error: nullptr]);

  1187.             }

  1188. 

  1189.             [array.get() addObject: audioUnitBus.get()];

  1190.         }

  1191. 

  1192.         (isInput ? inputBusses : outputBusses).reset ([[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  1193.                                                                                              busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  1194.                                                                                               busses: array.get()]);

  1195.     }

  1196. 

  1197.     // When parameters are discrete we need to use integer values.

  1198.     float getMaximumParameterValue (AudioProcessorParameter* juceParam)

  1199.     {

  1200.        #if JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1201.         ignoreUnused (juceParam);

  1202.         return 1.0f;

  1203.        #else

  1204.         return juceParam->isDiscrete() ? (float) (juceParam->getNumSteps() - 1) : 1.0f;

  1205.        #endif

  1206.     }

  1207. 

  1208.     std::unique_ptr<AUParameter, NSObjectDeleter> createParameter (AudioProcessorParameter* parameter)

  1209.     {

  1210.         const String name (parameter->getName (512));

  1211. 

  1212.         AudioUnitParameterUnit unit = kAudioUnitParameterUnit_Generic;

  1213.         AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  1214.                                                   | kAudioUnitParameterFlag_IsReadable

  1215.                                                   | kAudioUnitParameterFlag_HasCFNameString

  1216.                                                   | kAudioUnitParameterFlag_ValuesHaveStrings);

  1217. 

  1218.        #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1219.         flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  1220.        #endif

  1221. 

  1222.         // Set whether the param is automatable (unnamed parameters aren't allowed to be automated).

  1223.         if (name.isEmpty() || ! parameter->isAutomatable())

  1224.             flags |= kAudioUnitParameterFlag_NonRealTime;

  1225. 

  1226.         const bool isParameterDiscrete = parameter->isDiscrete();

  1227. 

  1228.         if (! isParameterDiscrete)

  1229.             flags |= kAudioUnitParameterFlag_CanRamp;

  1230. 

  1231.         if (parameter->isMetaParameter())

  1232.             flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  1233. 

  1234.         std::unique_ptr<NSMutableArray, NSObjectDeleter> valueStrings;

  1235. 

  1236.         // Is this a meter?

  1237.         if (((parameter->getCategory() & 0xffff0000) >> 16) == 2)

  1238.         {

  1239.             flags &= ~kAudioUnitParameterFlag_IsWritable;

  1240.             flags |= kAudioUnitParameterFlag_MeterReadOnly | kAudioUnitParameterFlag_DisplayLogarithmic;

  1241.             unit = kAudioUnitParameterUnit_LinearGain;

  1242.         }

  1243.         else

  1244.         {

  1245.            #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1246.             if (parameter->isDiscrete())

  1247.             {

  1248.                 unit = parameter->isBoolean() ? kAudioUnitParameterUnit_Boolean : kAudioUnitParameterUnit_Indexed;

  1249.                 auto maxValue = getMaximumParameterValue (parameter);

  1250.                 auto numSteps = parameter->getNumSteps();

  1251. 

  1252.                 // Some hosts can't handle the huge numbers of discrete parameter values created when

  1253.                 // using the default number of steps.

  1254.                 jassert (numSteps != AudioProcessor::getDefaultNumParameterSteps());

  1255. 

  1256.                 valueStrings.reset ([NSMutableArray new]);

  1257. 

  1258.                 for (int i = 0; i < numSteps; ++i)

  1259.                     [valueStrings.get() addObject: juceStringToNS (parameter->getText ((float) i / maxValue, 0))];

  1260.             }

  1261.            #endif

  1262.         }

  1263. 

  1264.         AUParameterAddress address = generateAUParameterAddress (parameter);

  1265. 

  1266.        #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1267.         // If you hit this assertion then you have either put a parameter in two groups or you are

  1268.         // very unlucky and the hash codes of your parameter ids are not unique.

  1269.         jassert (! paramMap.contains (static_cast<int64> (address)));

  1270. 

  1271.         paramAddresses.add (address);

  1272.         paramMap.set (static_cast<int64> (address), parameter->getParameterIndex());

  1273.        #endif

  1274. 

  1275.         auto getParameterIdentifier = [parameter]

  1276.         {

  1277.             if (auto* paramWithID = dynamic_cast<AudioProcessorParameterWithID*> (parameter))

  1278.                 return paramWithID->paramID;

  1279. 

  1280.             // This could clash if any groups have been given integer IDs!

  1281.             return String (parameter->getParameterIndex());

  1282.         };

  1283. 

  1284.         std::unique_ptr<AUParameter, NSObjectDeleter> param;

  1285. 

  1286.         @try

  1287.         {

  1288.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1289.             param.reset([[AUParameterTree createParameterWithIdentifier: juceStringToNS (getParameterIdentifier())

  1290.                                                                    name: juceStringToNS (name)

  1291.                                                                 address: address

  1292.                                                                     min: 0.0f

  1293.                                                                     max: getMaximumParameterValue (parameter)

  1294.                                                                    unit: unit

  1295.                                                                unitName: nullptr

  1296.                                                                   flags: flags

  1297.                                                            valueStrings: valueStrings.get()

  1298.                                                     dependentParameters: nullptr]

  1299.                          retain]);

  1300.         }

  1301. 

  1302.         @catch (NSException* exception)

  1303.         {

  1304.             // Do you have duplicate identifiers in any of your groups or parameters,

  1305.             // or do your identifiers have unusual characters in them?

  1306.             jassertfalse;

  1307.         }

  1308. 

  1309.         [param.get() setValue: parameter->getDefaultValue()];

  1310. 

  1311.         [overviewParams.get() addObject: [NSNumber numberWithUnsignedLongLong: address]];

  1312. 

  1313.         return param;

  1314.     }

  1315. 

  1316.     std::unique_ptr<AUParameterGroup, NSObjectDeleter> createParameterGroup (AudioProcessorParameterGroup* group)

  1317.     {

  1318.         std::unique_ptr<NSMutableArray<AUParameterNode*>, NSObjectDeleter> children ([NSMutableArray<AUParameterNode*> new]);

  1319. 

  1320.         for (auto* node : *group)

  1321.         {

  1322.             if (auto* childGroup = node->getGroup())

  1323.                 [children.get() addObject: createParameterGroup (childGroup).get()];

  1324.             else

  1325.                 [children.get() addObject: createParameter (node->getParameter()).get()];

  1326.         }

  1327. 

  1328.         std::unique_ptr<AUParameterGroup, NSObjectDeleter> result;

  1329. 

  1330.         @try

  1331.         {

  1332.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1333.             result.reset ([[AUParameterTree createGroupWithIdentifier: juceStringToNS (group->getID())

  1334.                                                                  name: juceStringToNS (group->getName())

  1335.                                                              children: children.get()]

  1336.                            retain]);

  1337.         }

  1338. 

  1339.         @catch (NSException* exception)

  1340.         {

  1341.             // Do you have duplicate identifiers in any of your groups or parameters,

  1342.             // or do your identifiers have unusual characters in them?

  1343.             jassertfalse;

  1344.         }

  1345. 

  1346.         return result;

  1347.     }

  1348. 

  1349.     void addParameters()

  1350.     {

  1351.         auto& processor = getAudioProcessor();

  1352.         juceParameters.update (processor, forceLegacyParamIDs);

  1353. 

  1354.         // This is updated when we build the tree.

  1355.         overviewParams.reset ([NSMutableArray<NSNumber*> new]);

  1356. 

  1357.         std::unique_ptr<NSMutableArray<AUParameterNode*>, NSObjectDeleter> topLevelNodes ([NSMutableArray<AUParameterNode*> new]);

  1358. 

  1359.         for (auto* node : processor.getParameterTree())

  1360.             if (auto* childGroup = node->getGroup())

  1361.                 [topLevelNodes.get() addObject: createParameterGroup (childGroup).get()];

  1362.             else

  1363.                 [topLevelNodes.get() addObject: createParameter (node->getParameter()).get()];

  1364. 

  1365.         @try

  1366.         {

  1367.             // Create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1368.             paramTree.reset ([[AUParameterTree createTreeWithChildren: topLevelNodes.get()] retain]);

  1369.         }

  1370. 

  1371.         @catch (NSException* exception)

  1372.         {

  1373.             // Do you have duplicate identifiers in any of your groups or parameters,

  1374.             // or do your identifiers have unusual characters in them?

  1375.             jassertfalse;

  1376.         }

  1377. 

  1378.         paramObserver           = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  1379.         paramProvider           = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  1380.         stringFromValueProvider = CreateObjCBlock (this, &JuceAudioUnitv3::stringFromValue);

  1381.         valueFromStringProvider = CreateObjCBlock (this, &JuceAudioUnitv3::valueFromString);

  1382. 

  1383.         [paramTree.get() setImplementorValueObserver: paramObserver];

  1384.         [paramTree.get() setImplementorValueProvider: paramProvider];

  1385.         [paramTree.get() setImplementorStringFromValueCallback: stringFromValueProvider];

  1386.         [paramTree.get() setImplementorValueFromStringCallback: valueFromStringProvider];

  1387. 

  1388.         if (processor.hasEditor())

  1389.         {

  1390.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  1391.             editorObserverToken = [paramTree.get() tokenByAddingParameterObserver: editorParamObserver];

  1392.         }

  1393. 

  1394.         if ((bypassParam = processor.getBypassParameter()) != nullptr)

  1395.             bypassParam->addListener (this);

  1396.     }

  1397. 

  1398.     void setAudioProcessorParameter (AudioProcessorParameter* juceParam, float value)

  1399.     {

  1400.         if (value != juceParam->getValue())

  1401.         {

  1402.             juceParam->setValue (value);

  1403. 

  1404.             inParameterChangedCallback = true;

  1405.             juceParam->sendValueChangedMessageToListeners (value);

  1406.         }

  1407.     }

  1408. 

  1409.     void addPresets()

  1410.     {

  1411.         factoryPresets.reset ([[NSMutableArray<AUAudioUnitPreset*> alloc] init]);

  1412. 

  1413.         const int n = getAudioProcessor().getNumPrograms();

  1414. 

  1415.         for (int idx = 0; idx < n; ++idx)

  1416.         {

  1417.             String name = getAudioProcessor().getProgramName (idx);

  1418. 

  1419.             std::unique_ptr<AUAudioUnitPreset, NSObjectDeleter> preset ([[AUAudioUnitPreset alloc] init]);

  1420.             [preset.get() setName: juceStringToNS (name)];

  1421.             [preset.get() setNumber: static_cast<NSInteger> (idx)];

  1422. 

  1423.             [factoryPresets.get() addObject: preset.get()];

  1424.         }

  1425.     }

  1426. 

  1427.     //==============================================================================

  1428.     void allocateBusBuffer (bool isInput)

  1429.     {

  1430.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  1431.         busBuffers.clear();

  1432. 

  1433.         const int n = AudioUnitHelpers::getBusCountForWrapper (getAudioProcessor(), isInput);

  1434.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1435. 

  1436.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1437.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1438.                                            static_cast<int> (maxFrames)));

  1439.     }

  1440. 

  1441.     //==============================================================================

  1442.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1443.     {

  1444.         ignoreUnused (numParams);

  1445. 

  1446.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1447.         {

  1448.             switch (event->head.eventType)

  1449.             {

  1450.                 case AURenderEventMIDI:

  1451.                 {

  1452.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1453.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1454.                 }

  1455.                 break;

  1456. 

  1457.                #if JUCE_AUV3_MIDI_EVENT_LIST_SUPPORTED

  1458.                 case AURenderEventMIDIEventList:

  1459.                 {

  1460.                     const auto& list = event->MIDIEventsList.eventList;

  1461.                     auto* packet = &list.packet[0];

  1462. 

  1463.                     for (uint32_t i = 0; i < list.numPackets; ++i)

  1464.                     {

  1465.                         converter.dispatch (reinterpret_cast<const uint32_t*> (packet->words),

  1466.                                             reinterpret_cast<const uint32_t*> (packet->words + packet->wordCount),

  1467.                                             static_cast<int> (packet->timeStamp - (MIDITimeStamp) startTime),

  1468.                                             [this] (const MidiMessage& message) { midiMessages.addEvent (message, int (message.getTimeStamp())); });

  1469. 

  1470.                         packet = MIDIEventPacketNext (packet);

  1471.                     }

  1472.                 }

  1473.                 break;

  1474.                #endif

  1475. 

  1476.                 case AURenderEventParameter:

  1477.                 case AURenderEventParameterRamp:

  1478.                 {

  1479.                     const AUParameterEvent& paramEvent = event->parameter;

  1480. 

  1481.                     if (auto* p = getJuceParameterForAUAddress (paramEvent.parameterAddress))

  1482.                     {

  1483.                         auto normalisedValue = paramEvent.value / getMaximumParameterValue (p);

  1484.                         setAudioProcessorParameter (p, normalisedValue);

  1485.                     }

  1486.                 }

  1487.                 break;

  1488. 

  1489.                 case AURenderEventMIDISysEx:

  1490.                 default:

  1491.                     break;

  1492.             }

  1493.         }

  1494.     }

  1495. 

  1496.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1497.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1498.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1499.     {

  1500.         auto& processor = getAudioProcessor();

  1501.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1502. 

  1503.         // process params

  1504.         const int numParams = juceParameters.getNumParameters();

  1505.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1506. 

  1507.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1508.         {

  1509.             lastTimeStamp = *timestamp;

  1510. 

  1511.             const auto numWrapperBusesIn    = AudioUnitHelpers::getBusCountForWrapper (processor, true);

  1512.             const auto numWrapperBusesOut   = AudioUnitHelpers::getBusCountForWrapper (processor, false);

  1513.             const auto numProcessorBusesIn  = AudioUnitHelpers::getBusCount (processor, true);

  1514.             const auto numProcessorBusesOut = AudioUnitHelpers::getBusCount (processor, false);

  1515. 

  1516.             // prepare buffers

  1517.             {

  1518.                 for (int busIdx = 0; busIdx < numWrapperBusesOut; ++busIdx)

  1519.                 {

  1520.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1521.                      const bool canUseDirectOutput =

  1522.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1523. 

  1524.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1525. 

  1526.                     if (numProcessorBusesOut <= busIdx)

  1527.                         AudioUnitHelpers::clearAudioBuffer (*busBuffer.get());

  1528.                 }

  1529. 

  1530.                 for (int busIdx = 0; busIdx < numWrapperBusesIn; ++busIdx)

  1531.                 {

  1532.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1533.                     busBuffer.prepare (frameCount, busIdx < numWrapperBusesOut ? outBusBuffers[busIdx]->get() : nullptr);

  1534.                 }

  1535. 

  1536.                 audioBuffer.reset();

  1537.             }

  1538. 

  1539.             // pull inputs

  1540.             {

  1541.                 for (int busIdx = 0; busIdx < numProcessorBusesIn; ++busIdx)

  1542.                 {

  1543.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1544.                     AudioBufferList* buffer = busBuffer.get();

  1545. 

  1546.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1547.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1548. 

  1549.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1550.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1551.                 }

  1552.             }

  1553. 

  1554.             // set buffer pointer to minimize copying

  1555.             {

  1556.                 int chIdx = 0;

  1557. 

  1558.                 for (int busIdx = 0; busIdx < numProcessorBusesOut; ++busIdx)

  1559.                 {

  1560.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1561.                     AudioBufferList* buffer = busBuffer.get();

  1562. 

  1563.                     const bool interleaved = busBuffer.interleaved();

  1564.                     const int numChannels = busBuffer.numChannels();

  1565. 

  1566.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1567. 

  1568.                     for (int ch = 0; ch < numChannels; ++ch)

  1569.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1570.                 }

  1571. 

  1572.                 // use input pointers on remaining channels

  1573. 

  1574.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1575.                 {

  1576.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1577. 

  1578.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1579.                     AudioBufferList* buffer = busBuffer.get();

  1580. 

  1581.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1582.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1583.                 }

  1584.             }

  1585. 

  1586.             // copy input

  1587.             {

  1588.                 for (int busIdx = 0; busIdx < numProcessorBusesIn; ++busIdx)

  1589.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1590. 

  1591.                 // clear remaining channels

  1592.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1593.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1594.             }

  1595. 

  1596.             // process audio

  1597.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1598. 

  1599.             // send MIDI

  1600.            #if JucePlugin_ProducesMidiOutput && JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  1601.             if (auto midiOut = [au MIDIOutputEventBlock])

  1602.             {

  1603.                 for (const auto metadata : midiMessages)

  1604.                     midiOut (metadata.samplePosition, 0, metadata.numBytes, metadata.data);

  1605.             }

  1606.            #endif

  1607. 

  1608.             midiMessages.clear();

  1609. 

  1610.             // copy back

  1611.             if (outputBusNumber < numProcessorBusesOut)

  1612.                 audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1613.                                  mapper.get (false, (int) outputBusNumber));

  1614.         }

  1615. 

  1616.         return noErr;

  1617.     }

  1618. 

  1619.     void processBlock (juce::AudioBuffer<float>& buffer, MidiBuffer& midiBuffer) noexcept

  1620.     {

  1621.         auto& processor = getAudioProcessor();

  1622.         const ScopedLock sl (processor.getCallbackLock());

  1623. 

  1624.         if (processor.isSuspended())

  1625.             buffer.clear();

  1626.         else if (bypassParam != nullptr && [au shouldBypassEffect])

  1627.             processor.processBlockBypassed (buffer, midiBuffer);

  1628.         else

  1629.             processor.processBlock (buffer, midiBuffer);

  1630.     }

  1631. 

  1632.     //==============================================================================

  1633.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1634.     {

  1635.         if (param != nullptr)

  1636.         {

  1637.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1638.             {

  1639.                 auto normalisedValue = value / getMaximumParameterValue (p);

  1640.                 setAudioProcessorParameter (p, normalisedValue);

  1641.             }

  1642.         }

  1643.     }

  1644. 

  1645.     AUValue getValue (AUParameter* param)

  1646.     {

  1647.         if (param != nullptr)

  1648.         {

  1649.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1650.                 return p->getValue() * getMaximumParameterValue (p);

  1651.         }

  1652. 

  1653.         return 0;

  1654.     }

  1655. 

  1656.     void valueChangedForObserver (AUParameterAddress, AUValue)

  1657.     {

  1658.         // this will have already been handled by valueChangedFromHost

  1659.     }

  1660. 

  1661.     NSString* stringFromValue (AUParameter* param, const AUValue* value)

  1662.     {

  1663.         String text;

  1664. 

  1665.         if (param != nullptr && value != nullptr)

  1666.         {

  1667.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1668.             {

  1669.                 if (LegacyAudioParameter::isLegacy (p))

  1670.                     text = String (*value);

  1671.                 else

  1672.                     text = p->getText (*value / getMaximumParameterValue (p), 0);

  1673.             }

  1674.         }

  1675. 

  1676.         return juceStringToNS (text);

  1677.     }

  1678. 

  1679.     AUValue valueFromString (AUParameter* param, NSString* str)

  1680.     {

  1681.         if (param != nullptr && str != nullptr)

  1682.         {

  1683.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1684.             {

  1685.                 const String text (nsStringToJuce (str));

  1686. 

  1687.                 if (LegacyAudioParameter::isLegacy (p))

  1688.                     return text.getFloatValue();

  1689.                 else

  1690.                     return p->getValueForText (text) * getMaximumParameterValue (p);

  1691.             }

  1692.         }

  1693. 

  1694.         return 0;

  1695.     }

  1696. 

  1697.     //==============================================================================

  1698.     // this is only ever called for the bypass parameter

  1699.     void parameterValueChanged (int, float newValue) override

  1700.     {

  1701.         JuceAudioUnitv3Base::setShouldBypassEffect (newValue != 0.0f);

  1702.     }

  1703. 

  1704.     void parameterGestureChanged (int, bool) override {}

  1705. 

  1706.     //==============================================================================

  1707.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1708.     {

  1709.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1710.         return static_cast<AUParameterAddress> (paramIndex);

  1711.        #else

  1712.         return paramAddresses.getReference (paramIndex);

  1713.        #endif

  1714.     }

  1715. 

  1716.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1717.     {

  1718.        #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1719.         return static_cast<int> (address);

  1720.        #else

  1721.         return paramMap[static_cast<int64> (address)];

  1722.        #endif

  1723.     }

  1724. 

  1725.     AUParameterAddress generateAUParameterAddress (AudioProcessorParameter* param) const

  1726.     {

  1727.         const String& juceParamID = LegacyAudioParameter::getParamID (param, forceLegacyParamIDs);

  1728. 

  1729.         return static_cast<AUParameterAddress> (forceLegacyParamIDs ? juceParamID.getIntValue()

  1730.                                                                     : juceParamID.hashCode64());

  1731.     }

  1732. 

  1733.     AudioProcessorParameter* getJuceParameterForAUAddress (AUParameterAddress address) const noexcept

  1734.     {

  1735.         return juceParameters.getParamForIndex (getJuceParameterIndexForAUAddress (address));

  1736.     }

  1737. 

  1738.     //==============================================================================

  1739.     static const double kDefaultSampleRate;

  1740. 

  1741.     AudioProcessorHolder::Ptr processorHolder;

  1742. 

  1743.     int totalInChannels, totalOutChannels;

  1744. 

  1745.     std::unique_ptr<AUAudioUnitBusArray, NSObjectDeleter> inputBusses, outputBusses;

  1746. 

  1747.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1748.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1749.     ObjCBlock<AUImplementorStringFromValueCallback> stringFromValueProvider;

  1750.     ObjCBlock<AUImplementorValueFromStringCallback> valueFromStringProvider;

  1751. 

  1752.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1753.     Array<AUParameterAddress> paramAddresses;

  1754.     HashMap<int64, int> paramMap;

  1755.    #endif

  1756.     LegacyAudioParametersWrapper juceParameters;

  1757. 

  1758.     // to avoid recursion on parameter changes, we need to add an

  1759.     // editor observer to do the parameter changes

  1760.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1761.     AUParameterObserverToken editorObserverToken;

  1762. 

  1763.     std::unique_ptr<AUParameterTree, NSObjectDeleter> paramTree;

  1764.     std::unique_ptr<NSMutableArray<NSNumber*>, NSObjectDeleter> overviewParams, channelCapabilities;

  1765. 

  1766.     std::unique_ptr<NSMutableArray<AUAudioUnitPreset*>, NSObjectDeleter> factoryPresets;

  1767. 

  1768.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1769. 

  1770.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1771.     AudioUnitHelpers::ChannelRemapper mapper;

  1772. 

  1773.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1774.     MidiBuffer midiMessages;

  1775. 

  1776.    #if JUCE_AUV3_MIDI_EVENT_LIST_SUPPORTED

  1777.     ump::ToBytestreamDispatcher converter { 2048 };

  1778.    #endif

  1779. 

  1780.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1781.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1782. 

  1783.     AudioTimeStamp lastTimeStamp;

  1784.     CurrentPositionInfo lastAudioHead;

  1785. 

  1786.     String contextName;

  1787. 

  1788.     ThreadLocalValue<bool> inParameterChangedCallback;

  1789.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1790.     static constexpr bool forceLegacyParamIDs = true;

  1791.    #else

  1792.     static constexpr bool forceLegacyParamIDs = false;

  1793.    #endif

  1794.     AudioProcessorParameter* bypassParam = nullptr;

  1795. };

  1796. 

  1797. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1798. 

  1799. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1800. {

  1801.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1802.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1803. }

  1804. 

  1805. #if JUCE_IOS

  1806. namespace juce

  1807. {

  1808. struct UIViewPeerControllerReceiver

  1809. {

  1810.     virtual ~UIViewPeerControllerReceiver();

  1811.     virtual void setViewController (UIViewController*) = 0;

  1812. };

  1813. }

  1814. #endif

  1815. 

  1816. //==============================================================================

  1817. class JuceAUViewController

  1818. {

  1819. public:

  1820.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1821.         : myself (p)

  1822.     {

  1823.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1824.         initialiseJuce_GUI();

  1825.     }

  1826. 

  1827.     ~JuceAUViewController()

  1828.     {

  1829.         JUCE_ASSERT_MESSAGE_THREAD

  1830. 

  1831.         if (processorHolder.get() != nullptr)

  1832.             JuceAudioUnitv3::removeEditor (getAudioProcessor());

  1833.     }

  1834. 

  1835.     //==============================================================================

  1836.     void loadView()

  1837.     {

  1838.         JUCE_ASSERT_MESSAGE_THREAD

  1839. 

  1840.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1841.         {

  1842.             processorHolder = new AudioProcessorHolder (p);

  1843.             auto& processor = getAudioProcessor();

  1844. 

  1845.             if (processor.hasEditor())

  1846.             {

  1847.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1848.                 {

  1849.                     preferredSize = editor->getBounds();

  1850. 

  1851.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1852.                     [myself setView: view];

  1853. 

  1854.                    #if JUCE_IOS

  1855.                     editor->setVisible (false);

  1856.                    #else

  1857.                     editor->setVisible (true);

  1858.                    #endif

  1859. 

  1860.                     editor->addToDesktop (0, view);

  1861. 

  1862.                    #if JUCE_IOS

  1863.                     if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1864.                         [peerView setContentMode: UIViewContentModeTop];

  1865. 

  1866.                     if (auto* peer = dynamic_cast<UIViewPeerControllerReceiver*> (editor->getPeer()))

  1867.                         peer->setViewController (myself);

  1868.                    #endif

  1869.                 }

  1870.             }

  1871.         }

  1872.     }

  1873. 

  1874.     void viewDidLayoutSubviews()

  1875.     {

  1876.         if (auto holder = processorHolder.get())

  1877.         {

  1878.             if ([myself view] != nullptr)

  1879.             {

  1880.                 if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1881.                 {

  1882.                     if (holder->viewConfiguration != nullptr)

  1883.                         editor->hostMIDIControllerIsAvailable (holder->viewConfiguration->hostHasMIDIController);

  1884. 

  1885.                     editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1886. 

  1887.                     if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1888.                     {

  1889.                        #if JUCE_IOS

  1890.                         [peerView setNeedsDisplay];

  1891.                        #else

  1892.                         [peerView setNeedsDisplay: YES];

  1893.                        #endif

  1894.                     }

  1895.                 }

  1896.             }

  1897.         }

  1898.     }

  1899. 

  1900.     void didReceiveMemoryWarning()

  1901.     {

  1902.         if (auto ptr = processorHolder.get())

  1903.             if (auto* processor = ptr->get())

  1904.                 processor->memoryWarningReceived();

  1905.     }

  1906. 

  1907.     void viewDidAppear (bool)

  1908.     {

  1909.         if (processorHolder.get() != nullptr)

  1910.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1911.                 editor->setVisible (true);

  1912.     }

  1913. 

  1914.     void viewDidDisappear (bool)

  1915.     {

  1916.         if (processorHolder.get() != nullptr)

  1917.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1918.                 editor->setVisible (false);

  1919.     }

  1920. 

  1921.     CGSize getPreferredContentSize() const

  1922.     {

  1923.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1924.                            static_cast<float> (preferredSize.getHeight()));

  1925.     }

  1926. 

  1927.     //==============================================================================

  1928.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1929.     {

  1930.         const auto holder = [&]

  1931.         {

  1932.             if (auto initialisedHolder = processorHolder.get())

  1933.                 return initialisedHolder;

  1934. 

  1935.             waitForExecutionOnMainThread ([this] { [myself view]; });

  1936.             return processorHolder.get();

  1937.         }();

  1938. 

  1939.         if (holder == nullptr)

  1940.             return nullptr;

  1941. 

  1942.         return (new JuceAudioUnitv3 (holder, descr, 0, error))->getAudioUnit();

  1943.     }

  1944. 

  1945. private:

  1946.     template <typename Callback>

  1947.     static void waitForExecutionOnMainThread (Callback&& callback)

  1948.     {

  1949.         if (MessageManager::getInstance()->isThisTheMessageThread())

  1950.         {

  1951.             callback();

  1952.             return;

  1953.         }

  1954. 

  1955.         std::promise<void> promise;

  1956. 

  1957.         MessageManager::callAsync ([&]

  1958.         {

  1959.             callback();

  1960.             promise.set_value();

  1961.         });

  1962. 

  1963.         promise.get_future().get();

  1964.     }

  1965. 

  1966.     // There's a chance that createAudioUnit will be called from a background

  1967.     // thread while the processorHolder is being updated on the main thread.

  1968.     class LockedProcessorHolder

  1969.     {

  1970.     public:

  1971.         AudioProcessorHolder::Ptr get() const

  1972.         {

  1973.             const ScopedLock lock (mutex);

  1974.             return holder;

  1975.         }

  1976. 

  1977.         LockedProcessorHolder& operator= (const AudioProcessorHolder::Ptr& other)

  1978.         {

  1979.             const ScopedLock lock (mutex);

  1980.             holder = other;

  1981.             return *this;

  1982.         }

  1983. 

  1984.     private:

  1985.         mutable CriticalSection mutex;

  1986.         AudioProcessorHolder::Ptr holder;

  1987.     };

  1988. 

  1989.     //==============================================================================

  1990.     AUViewController<AUAudioUnitFactory>* myself;

  1991.     LockedProcessorHolder processorHolder;

  1992.     Rectangle<int> preferredSize { 1, 1 };

  1993. 

  1994.     //==============================================================================

  1995.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder.get(); }

  1996. };

  1997. 

  1998. //==============================================================================

  1999. // necessary glue code

  2000. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  2001. @end

  2002. 

  2003. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  2004. {

  2005.     std::unique_ptr<JuceAUViewController> cpp;

  2006. }

  2007. 

  2008. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp.reset (new JuceAUViewController (self)); return self; }

  2009. - (void) loadView                { cpp->loadView(); }

  2010. - (AUAudioUnit *) createAudioUnitWithComponentDescription: (AudioComponentDescription) desc error: (NSError **) error { return cpp->createAudioUnit (desc, error); }

  2011. - (CGSize) preferredContentSize  { return cpp->getPreferredContentSize(); }

  2012. 

  2013. // NSViewController and UIViewController have slightly different names for this function

  2014. - (void) viewDidLayoutSubviews   { cpp->viewDidLayoutSubviews(); }

  2015. - (void) viewDidLayout           { cpp->viewDidLayoutSubviews(); }

  2016. 

  2017. - (void) didReceiveMemoryWarning { cpp->didReceiveMemoryWarning(); }

  2018. #if JUCE_IOS

  2019. - (void) viewDidAppear: (BOOL) animated { cpp->viewDidAppear (animated); [super viewDidAppear:animated]; }

  2020. - (void) viewDidDisappear: (BOOL) animated { cpp->viewDidDisappear (animated); [super viewDidDisappear:animated]; }

  2021. #endif

  2022. @end

  2023. 

  2024. //==============================================================================

  2025. #if JUCE_IOS

  2026. bool JUCE_CALLTYPE juce_isInterAppAudioConnected() { return false; }

  2027. void JUCE_CALLTYPE juce_switchToHostApplication()  {}

  2028. Image JUCE_CALLTYPE juce_getIAAHostIcon (int)      { return {}; }

  2029. #endif

  2030. 

  2031. JUCE_END_IGNORE_WARNINGS_GCC_LIKE

  2032. #endif