DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1675 Commits
11 Branches
3.3GB
Tree: 674aa73dd7
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '674aa73dd7'
${ noResults }
JUCE/modules/juce_gui_basics/native/juce_mac_NSViewComponentPee...

1978 lines
64KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library - "Jules' Utility Class Extensions"

  5.    Copyright 2004-11 by Raw Material Software Ltd.

  6. 

  7.   ------------------------------------------------------------------------------

  8. 

  9.    JUCE can be redistributed and/or modified under the terms of the GNU General

  10.    Public License (Version 2), as published by the Free Software Foundation.

  11.    A copy of the license is included in the JUCE distribution, or can be found

  12.    online at www.gnu.org/licenses.

  13. 

  14.    JUCE is distributed in the hope that it will be useful, but WITHOUT ANY

  15.    WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR

  16.    A PARTICULAR PURPOSE.  See the GNU General Public License for more details.

  17. 

  18.   ------------------------------------------------------------------------------

  19. 

  20.    To release a closed-source product which uses JUCE, commercial licenses are

  21.    available: visit www.rawmaterialsoftware.com/juce for more information.

  22. 

  23.   ==============================================================================

  24. */

  25. 

  26. class NSViewComponentPeer;

  27. 

  28. typedef void (*AppFocusChangeCallback)();

  29. extern AppFocusChangeCallback appFocusChangeCallback;

  30. typedef bool (*CheckEventBlockedByModalComps) (NSEvent*);

  31. extern CheckEventBlockedByModalComps isEventBlockedByModalComps;

  32. 

  33. #if JUCE_MODULE_AVAILABLE_juce_opengl && ! defined (JUCE_OSX_OPENGL_RENDERER)

  34.  //#define JUCE_OSX_OPENGL_RENDERER 1

  35. #endif

  36. 

  37. //==============================================================================

  38. END_JUCE_NAMESPACE

  39. 

  40. @interface NSEvent (JuceDeviceDelta)

  41.  - (float) deviceDeltaX;

  42.  - (float) deviceDeltaY;

  43. @end

  44. 

  45. #define JuceNSView MakeObjCClassName(JuceNSView)

  46. 

  47. @interface JuceNSView : NSView<NSTextInput>

  48. {

  49. @public

  50.     NSViewComponentPeer* owner;

  51.     NSNotificationCenter* notificationCenter;

  52.     String* stringBeingComposed;

  53.     bool textWasInserted;

  54. }

  55. 

  56. - (JuceNSView*) initWithOwner: (NSViewComponentPeer*) owner withFrame: (NSRect) frame;

  57. - (void) dealloc;

  58. 

  59. - (BOOL) isOpaque;

  60. - (void) drawRect: (NSRect) r;

  61. 

  62. - (void) mouseDown: (NSEvent*) ev;

  63. - (void) asyncMouseDown: (NSEvent*) ev;

  64. - (void) mouseUp: (NSEvent*) ev;

  65. - (void) asyncMouseUp: (NSEvent*) ev;

  66. - (void) mouseDragged: (NSEvent*) ev;

  67. - (void) mouseMoved: (NSEvent*) ev;

  68. - (void) mouseEntered: (NSEvent*) ev;

  69. - (void) mouseExited: (NSEvent*) ev;

  70. - (void) rightMouseDown: (NSEvent*) ev;

  71. - (void) rightMouseDragged: (NSEvent*) ev;

  72. - (void) rightMouseUp: (NSEvent*) ev;

  73. - (void) otherMouseDown: (NSEvent*) ev;

  74. - (void) otherMouseDragged: (NSEvent*) ev;

  75. - (void) otherMouseUp: (NSEvent*) ev;

  76. - (void) scrollWheel: (NSEvent*) ev;

  77. - (BOOL) acceptsFirstMouse: (NSEvent*) ev;

  78. - (void) frameChanged: (NSNotification*) n;

  79. - (void) viewDidMoveToWindow;

  80. 

  81. - (void) keyDown: (NSEvent*) ev;

  82. - (void) keyUp: (NSEvent*) ev;

  83. 

  84. // NSTextInput Methods

  85. - (void) insertText: (id) aString;

  86. - (void) doCommandBySelector: (SEL) aSelector;

  87. - (void) setMarkedText: (id) aString selectedRange: (NSRange) selRange;

  88. - (void) unmarkText;

  89. - (BOOL) hasMarkedText;

  90. - (long) conversationIdentifier;

  91. - (NSAttributedString*) attributedSubstringFromRange: (NSRange) theRange;

  92. - (NSRange) markedRange;

  93. - (NSRange) selectedRange;

  94. - (NSRect) firstRectForCharacterRange: (NSRange) theRange;

  95. - (NSUInteger) characterIndexForPoint: (NSPoint) thePoint;

  96. - (NSArray*) validAttributesForMarkedText;

  97. 

  98. - (void) flagsChanged: (NSEvent*) ev;

  99. #if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_5

  100. - (BOOL) performKeyEquivalent: (NSEvent*) ev;

  101. #endif

  102. 

  103. - (BOOL) becomeFirstResponder;

  104. - (BOOL) resignFirstResponder;

  105. - (BOOL) acceptsFirstResponder;

  106. 

  107. - (NSArray*) getSupportedDragTypes;

  108. - (BOOL) sendDragCallback: (int) type sender: (id <NSDraggingInfo>) sender;

  109. - (NSDragOperation) draggingEntered: (id <NSDraggingInfo>) sender;

  110. - (NSDragOperation) draggingUpdated: (id <NSDraggingInfo>) sender;

  111. - (void) draggingEnded: (id <NSDraggingInfo>) sender;

  112. - (void) draggingExited: (id <NSDraggingInfo>) sender;

  113. - (BOOL) prepareForDragOperation: (id <NSDraggingInfo>) sender;

  114. - (BOOL) performDragOperation: (id <NSDraggingInfo>) sender;

  115. - (void) concludeDragOperation: (id <NSDraggingInfo>) sender;

  116. 

  117. @end

  118. 

  119. //==============================================================================

  120. #define JuceNSWindow MakeObjCClassName(JuceNSWindow)

  121. 

  122. #if defined (MAC_OS_X_VERSION_10_6) && MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_6

  123. @interface JuceNSWindow : NSWindow <NSWindowDelegate>

  124. #else

  125. @interface JuceNSWindow : NSWindow

  126. #endif

  127. {

  128. @private

  129.     NSViewComponentPeer* owner;

  130.     bool isZooming;

  131. }

  132. 

  133. - (void) setOwner: (NSViewComponentPeer*) owner;

  134. - (BOOL) canBecomeKeyWindow;

  135. - (void) becomeKeyWindow;

  136. - (BOOL) windowShouldClose: (id) window;

  137. - (NSRect) constrainFrameRect: (NSRect) frameRect toScreen: (NSScreen*) screen;

  138. - (NSSize) windowWillResize: (NSWindow*) window toSize: (NSSize) proposedFrameSize;

  139. - (void) zoom: (id) sender;

  140. @end

  141. 

  142. BEGIN_JUCE_NAMESPACE

  143. 

  144. //==============================================================================

  145. class NSViewComponentPeer  : public ComponentPeer

  146. {

  147. public:

  148.     NSViewComponentPeer (Component* const component,

  149.                          const int windowStyleFlags,

  150.                          NSView* viewToAttachTo);

  151. 

  152.     ~NSViewComponentPeer();

  153. 

  154.     //==============================================================================

  155.     void* getNativeHandle() const;

  156.     void setVisible (bool shouldBeVisible);

  157.     void setTitle (const String& title);

  158.     void setPosition (int x, int y);

  159.     void setSize (int w, int h);

  160.     void setBounds (int x, int y, int w, int h, const bool isNowFullScreen);

  161.     const Rectangle<int> getBounds (const bool global) const;

  162.     const Rectangle<int> getBounds() const;

  163.     const Point<int> getScreenPosition() const;

  164.     const Point<int> localToGlobal (const Point<int>& relativePosition);

  165.     const Point<int> globalToLocal (const Point<int>& screenPosition);

  166.     void setAlpha (float newAlpha);

  167.     void setMinimised (bool shouldBeMinimised);

  168.     bool isMinimised() const;

  169.     void setFullScreen (bool shouldBeFullScreen);

  170.     bool isFullScreen() const;

  171.     void updateFullscreenStatus();

  172.     bool contains (const Point<int>& position, bool trueIfInAChildWindow) const;

  173.     bool hasNativeTitleBar() const        { return (getStyleFlags() & windowHasTitleBar) != 0; }

  174.     const BorderSize<int> getFrameSize() const;

  175.     bool setAlwaysOnTop (bool alwaysOnTop);

  176.     void toFront (bool makeActiveWindow);

  177.     void toBehind (ComponentPeer* other);

  178.     void setIcon (const Image& newIcon);

  179.     StringArray getAvailableRenderingEngines();

  180.     int getCurrentRenderingEngine() const;

  181.     void setCurrentRenderingEngine (int index);

  182. 

  183.     /* When you use multiple DLLs which share similarly-named obj-c classes - like

  184.        for example having more than one juce plugin loaded into a host, then when a

  185.        method is called, the actual code that runs might actually be in a different module

  186.        than the one you expect... So any calls to library functions or statics that are

  187.        made inside obj-c methods will probably end up getting executed in a different DLL's

  188.        memory space. Not a great thing to happen - this obviously leads to bizarre crashes.

  189. 

  190.        To work around this insanity, I'm only allowing obj-c methods to make calls to

  191.        virtual methods of an object that's known to live inside the right module's space.

  192.     */

  193.     virtual void redirectMouseDown (NSEvent* ev);

  194.     virtual void redirectMouseUp (NSEvent* ev);

  195.     virtual void redirectMouseDrag (NSEvent* ev);

  196.     virtual void redirectMouseMove (NSEvent* ev);

  197.     virtual void redirectMouseEnter (NSEvent* ev);

  198.     virtual void redirectMouseExit (NSEvent* ev);

  199.     virtual void redirectMouseWheel (NSEvent* ev);

  200.     void sendMouseEvent (NSEvent* ev);

  201. 

  202.     bool handleKeyEvent (NSEvent* ev, bool isKeyDown);

  203.     virtual bool redirectKeyDown (NSEvent* ev);

  204.     virtual bool redirectKeyUp (NSEvent* ev);

  205.     virtual void redirectModKeyChange (NSEvent* ev);

  206.    #if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_5

  207.     virtual bool redirectPerformKeyEquivalent (NSEvent* ev);

  208.    #endif

  209. 

  210.     virtual BOOL sendDragCallback (int type, id <NSDraggingInfo> sender);

  211. 

  212.     virtual bool isOpaque();

  213.     virtual void drawRect (NSRect r);

  214. 

  215.    #if JUCE_OSX_OPENGL_RENDERER

  216.     virtual void drawOpenGL();

  217.    #endif

  218. 

  219.     virtual bool canBecomeKeyWindow();

  220.     virtual void becomeKeyWindow();

  221.     virtual bool windowShouldClose();

  222. 

  223.     virtual void redirectMovedOrResized();

  224.     virtual void viewMovedToWindow();

  225. 

  226.     virtual NSRect constrainRect (NSRect r);

  227. 

  228.     static void showArrowCursorIfNeeded();

  229.     static void updateModifiers (NSEvent* e);

  230.     static void updateKeysDown (NSEvent* ev, bool isKeyDown);

  231. 

  232.     static int getKeyCodeFromEvent (NSEvent* ev)

  233.     {

  234.         const String unmodified (nsStringToJuce ([ev charactersIgnoringModifiers]));

  235.         int keyCode = unmodified[0];

  236. 

  237.         if (keyCode == 0x19) // (backwards-tab)

  238.             keyCode = '\t';

  239.         else if (keyCode == 0x03) // (enter)

  240.             keyCode = '\r';

  241.         else

  242.             keyCode = (int) CharacterFunctions::toUpperCase ((juce_wchar) keyCode);

  243. 

  244.         if (([ev modifierFlags] & NSNumericPadKeyMask) != 0)

  245.         {

  246.             const int numPadConversions[] = { '0', KeyPress::numberPad0, '1', KeyPress::numberPad1,

  247.                                               '2', KeyPress::numberPad2, '3', KeyPress::numberPad3,

  248.                                               '4', KeyPress::numberPad4, '5', KeyPress::numberPad5,

  249.                                               '6', KeyPress::numberPad6, '7', KeyPress::numberPad7,

  250.                                               '8', KeyPress::numberPad8, '9', KeyPress::numberPad9,

  251.                                               '+', KeyPress::numberPadAdd,  '-', KeyPress::numberPadSubtract,

  252.                                               '*', KeyPress::numberPadMultiply, '/', KeyPress::numberPadDivide,

  253.                                               '.', KeyPress::numberPadDecimalPoint, '=', KeyPress::numberPadEquals };

  254. 

  255.             for (int i = 0; i < numElementsInArray (numPadConversions); i += 2)

  256.                 if (keyCode == numPadConversions [i])

  257.                     keyCode = numPadConversions [i + 1];

  258.         }

  259. 

  260.         return keyCode;

  261.     }

  262. 

  263.     static int64 getMouseTime (NSEvent* e)

  264.     {

  265.         return (Time::currentTimeMillis() - Time::getMillisecondCounter())

  266.                 + (int64) ([e timestamp] * 1000.0);

  267.     }

  268. 

  269.     static const Point<int> getMousePos (NSEvent* e, NSView* view)

  270.     {

  271.         NSPoint p = [view convertPoint: [e locationInWindow] fromView: nil];

  272.         return Point<int> (roundToInt (p.x), roundToInt ([view frame].size.height - p.y));

  273.     }

  274. 

  275.     static int getModifierForButtonNumber (const NSInteger num)

  276.     {

  277.         return num == 0 ? ModifierKeys::leftButtonModifier

  278.                     : (num == 1 ? ModifierKeys::rightButtonModifier

  279.                                 : (num == 2 ? ModifierKeys::middleButtonModifier : 0));

  280.     }

  281. 

  282.     static unsigned int getNSWindowStyleMask (const int flags) noexcept

  283.     {

  284.         unsigned int style = (flags & windowHasTitleBar) != 0 ? NSTitledWindowMask

  285.                                                               : NSBorderlessWindowMask;

  286. 

  287.         if ((flags & windowHasMinimiseButton) != 0)  style |= NSMiniaturizableWindowMask;

  288.         if ((flags & windowHasCloseButton) != 0)     style |= NSClosableWindowMask;

  289.         if ((flags & windowIsResizable) != 0)        style |= NSResizableWindowMask;

  290.         return style;

  291.     }

  292. 

  293.     //==============================================================================

  294.     virtual void viewFocusGain();

  295.     virtual void viewFocusLoss();

  296.     bool isFocused() const;

  297.     void grabFocus();

  298.     void textInputRequired (const Point<int>& position);

  299. 

  300.     //==============================================================================

  301.     void repaint (const Rectangle<int>& area);

  302.     void performAnyPendingRepaintsNow();

  303. 

  304.     //==============================================================================

  305.     NSWindow* window;

  306.     JuceNSView* view;

  307.     bool isSharedWindow, fullScreen, insideDrawRect, usingCoreGraphics, usingOpenGL, recursiveToFrontCall;

  308. 

  309.     static ModifierKeys currentModifiers;

  310.     static ComponentPeer* currentlyFocusedPeer;

  311.     static Array<int> keysCurrentlyDown;

  312. 

  313. private:

  314.     static void appFocusChanged()

  315.     {

  316.         keysCurrentlyDown.clear();

  317. 

  318.         if (isValidPeer (currentlyFocusedPeer))

  319.         {

  320.             if (Process::isForegroundProcess())

  321.             {

  322.                 currentlyFocusedPeer->handleFocusGain();

  323. 

  324.                 ModalComponentManager::getInstance()->bringModalComponentsToFront();

  325.             }

  326.             else

  327.             {

  328.                 currentlyFocusedPeer->handleFocusLoss();

  329. 

  330.                 // turn kiosk mode off if we lose focus..

  331.                 Desktop::getInstance().setKioskModeComponent (nullptr);

  332.             }

  333.         }

  334.     }

  335. 

  336.     static bool checkEventBlockedByModalComps (NSEvent* e)

  337.     {

  338.         if (Component::getNumCurrentlyModalComponents() == 0)

  339.             return false;

  340. 

  341.         NSWindow* const w = [e window];

  342.         if (w == nil || [w worksWhenModal])

  343.             return false;

  344. 

  345.         bool isKey = false, isInputAttempt = false;

  346. 

  347.         switch ([e type])

  348.         {

  349.             case NSKeyDown:

  350.             case NSKeyUp:

  351.                 isKey = isInputAttempt = true;

  352.                 break;

  353. 

  354.             case NSLeftMouseDown:

  355.             case NSRightMouseDown:

  356.             case NSOtherMouseDown:

  357.                 isInputAttempt = true;

  358.                 break;

  359. 

  360.             case NSLeftMouseDragged:

  361.             case NSRightMouseDragged:

  362.             case NSLeftMouseUp:

  363.             case NSRightMouseUp:

  364.             case NSOtherMouseUp:

  365.             case NSOtherMouseDragged:

  366.                 if (Desktop::getInstance().getDraggingMouseSource(0) != nullptr)

  367.                     return false;

  368.                 break;

  369. 

  370.             case NSMouseMoved:

  371.             case NSMouseEntered:

  372.             case NSMouseExited:

  373.             case NSCursorUpdate:

  374.             case NSScrollWheel:

  375.             case NSTabletPoint:

  376.             case NSTabletProximity:

  377.                 break;

  378. 

  379.             default:

  380.                 return false;

  381.         }

  382. 

  383.         for (int i = ComponentPeer::getNumPeers(); --i >= 0;)

  384.         {

  385.             ComponentPeer* const peer = ComponentPeer::getPeer (i);

  386.             NSView* const compView = (NSView*) peer->getNativeHandle();

  387. 

  388.             if ([compView window] == w)

  389.             {

  390.                 if (isKey)

  391.                 {

  392.                     if (compView == [w firstResponder])

  393.                         return false;

  394.                 }

  395.                 else

  396.                 {

  397.                     NSViewComponentPeer* nsViewPeer = dynamic_cast<NSViewComponentPeer*> (peer);

  398. 

  399.                     if ((nsViewPeer == nullptr || ! nsViewPeer->isSharedWindow)

  400.                             ? NSPointInRect ([e locationInWindow], NSMakeRect (0, 0, [w frame].size.width, [w frame].size.height))

  401.                             : NSPointInRect ([compView convertPoint: [e locationInWindow] fromView: nil], [compView bounds]))

  402.                         return false;

  403.                 }

  404.             }

  405.         }

  406. 

  407.         if (isInputAttempt)

  408.         {

  409.             if (! [NSApp isActive])

  410.                 [NSApp activateIgnoringOtherApps: YES];

  411. 

  412.             Component* const modal = Component::getCurrentlyModalComponent (0);

  413.             if (modal != nullptr)

  414.                 modal->inputAttemptWhenModal();

  415.         }

  416. 

  417.         return true;

  418.     }

  419. 

  420.     JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (NSViewComponentPeer);

  421. };

  422. 

  423. //==============================================================================

  424. END_JUCE_NAMESPACE

  425. 

  426. @implementation JuceNSView

  427. 

  428. - (JuceNSView*) initWithOwner: (NSViewComponentPeer*) owner_

  429.                     withFrame: (NSRect) frame

  430. {

  431.     [super initWithFrame: frame];

  432.     owner = owner_;

  433.     stringBeingComposed = nullptr;

  434.     textWasInserted = false;

  435. 

  436.     notificationCenter = [NSNotificationCenter defaultCenter];

  437. 

  438.     [notificationCenter  addObserver: self

  439.                             selector: @selector (frameChanged:)

  440.                                 name: NSViewFrameDidChangeNotification

  441.                               object: self];

  442. 

  443.     if (! owner_->isSharedWindow)

  444.     {

  445.         [notificationCenter  addObserver: self

  446.                                 selector: @selector (frameChanged:)

  447.                                     name: NSWindowDidMoveNotification

  448.                                   object: owner_->window];

  449.     }

  450. 

  451.     [self registerForDraggedTypes: [self getSupportedDragTypes]];

  452. 

  453.     return self;

  454. }

  455. 

  456. - (void) dealloc

  457. {

  458.     [notificationCenter removeObserver: self];

  459.     delete stringBeingComposed;

  460.     [super dealloc];

  461. }

  462. 

  463. //==============================================================================

  464. - (void) drawRect: (NSRect) r

  465. {

  466.     if (owner != nullptr)

  467.         owner->drawRect (r);

  468. }

  469. 

  470. - (BOOL) isOpaque

  471. {

  472.     return owner == nullptr || owner->isOpaque();

  473. }

  474. 

  475. //==============================================================================

  476. - (void) mouseDown: (NSEvent*) ev

  477. {

  478.     if (JUCEApplication::isStandaloneApp())

  479.         [self asyncMouseDown: ev];

  480.     else

  481.         // In some host situations, the host will stop modal loops from working

  482.         // correctly if they're called from a mouse event, so we'll trigger

  483.         // the event asynchronously..

  484.         [self performSelectorOnMainThread: @selector (asyncMouseDown:)

  485.                                withObject: ev

  486.                             waitUntilDone: NO];

  487. }

  488. 

  489. - (void) asyncMouseDown: (NSEvent*) ev

  490. {

  491.     if (owner != nullptr)

  492.         owner->redirectMouseDown (ev);

  493. }

  494. 

  495. - (void) mouseUp: (NSEvent*) ev

  496. {

  497.     if (! JUCEApplication::isStandaloneApp())

  498.         [self asyncMouseUp: ev];

  499.     else

  500.         // In some host situations, the host will stop modal loops from working

  501.         // correctly if they're called from a mouse event, so we'll trigger

  502.         // the event asynchronously..

  503.         [self performSelectorOnMainThread: @selector (asyncMouseUp:)

  504.                                withObject: ev

  505.                             waitUntilDone: NO];

  506. }

  507. 

  508. - (void) asyncMouseUp: (NSEvent*) ev    { if (owner != nullptr) owner->redirectMouseUp    (ev); }

  509. - (void) mouseDragged: (NSEvent*) ev    { if (owner != nullptr) owner->redirectMouseDrag  (ev); }

  510. - (void) mouseMoved:   (NSEvent*) ev    { if (owner != nullptr) owner->redirectMouseMove  (ev); }

  511. - (void) mouseEntered: (NSEvent*) ev    { if (owner != nullptr) owner->redirectMouseEnter (ev); }

  512. - (void) mouseExited:  (NSEvent*) ev    { if (owner != nullptr) owner->redirectMouseExit  (ev); }

  513. - (void) scrollWheel:  (NSEvent*) ev    { if (owner != nullptr) owner->redirectMouseWheel (ev); }

  514. 

  515. - (void) rightMouseDown:    (NSEvent*) ev   { [self mouseDown:    ev]; }

  516. - (void) rightMouseDragged: (NSEvent*) ev   { [self mouseDragged: ev]; }

  517. - (void) rightMouseUp:      (NSEvent*) ev   { [self mouseUp:      ev]; }

  518. - (void) otherMouseDown:    (NSEvent*) ev   { [self mouseDown:    ev]; }

  519. - (void) otherMouseDragged: (NSEvent*) ev   { [self mouseDragged: ev]; }

  520. - (void) otherMouseUp:      (NSEvent*) ev   { [self mouseUp:      ev]; }

  521. 

  522. - (BOOL) acceptsFirstMouse: (NSEvent*) ev

  523. {

  524.     (void) ev;

  525.     return YES;

  526. }

  527. 

  528. - (void) frameChanged: (NSNotification*) n

  529. {

  530.     (void) n;

  531.     if (owner != nullptr)

  532.         owner->redirectMovedOrResized();

  533. }

  534. 

  535. - (void) viewDidMoveToWindow

  536. {

  537.    if (owner != nullptr)

  538.        owner->viewMovedToWindow();

  539. }

  540. 

  541. //==============================================================================

  542. - (void) keyDown: (NSEvent*) ev

  543. {

  544.     TextInputTarget* const target = owner->findCurrentTextInputTarget();

  545.     textWasInserted = false;

  546. 

  547.     if (target != nullptr)

  548.         [self interpretKeyEvents: [NSArray arrayWithObject: ev]];

  549.     else

  550.         deleteAndZero (stringBeingComposed);

  551. 

  552.     if ((! textWasInserted) && (owner == nullptr || ! owner->redirectKeyDown (ev)))

  553.         [super keyDown: ev];

  554. }

  555. 

  556. - (void) keyUp: (NSEvent*) ev

  557. {

  558.     if (owner == nullptr || ! owner->redirectKeyUp (ev))

  559.         [super keyUp: ev];

  560. }

  561. 

  562. //==============================================================================

  563. - (void) insertText: (id) aString

  564. {

  565.     // This commits multi-byte text when return is pressed, or after every keypress for western keyboards

  566.     NSString* newText = [aString isKindOfClass: [NSAttributedString class]] ? [aString string] : aString;

  567. 

  568.     if ([newText length] > 0)

  569.     {

  570.         TextInputTarget* const target = owner->findCurrentTextInputTarget();

  571. 

  572.         if (target != nullptr)

  573.         {

  574.             target->insertTextAtCaret (nsStringToJuce (newText));

  575.             textWasInserted = true;

  576.         }

  577.     }

  578. 

  579.     deleteAndZero (stringBeingComposed);

  580. }

  581. 

  582. - (void) doCommandBySelector: (SEL) aSelector

  583. {

  584.     (void) aSelector;

  585. }

  586. 

  587. - (void) setMarkedText: (id) aString selectedRange: (NSRange) selectionRange

  588. {

  589.     (void) selectionRange;

  590. 

  591.     if (stringBeingComposed == 0)

  592.         stringBeingComposed = new String();

  593. 

  594.     *stringBeingComposed = nsStringToJuce ([aString isKindOfClass:[NSAttributedString class]] ? [aString string] : aString);

  595. 

  596.     TextInputTarget* const target = owner->findCurrentTextInputTarget();

  597. 

  598.     if (target != nullptr)

  599.     {

  600.         const Range<int> currentHighlight (target->getHighlightedRegion());

  601.         target->insertTextAtCaret (*stringBeingComposed);

  602.         target->setHighlightedRegion (currentHighlight.withLength (stringBeingComposed->length()));

  603.         textWasInserted = true;

  604.     }

  605. }

  606. 

  607. - (void) unmarkText

  608. {

  609.     if (stringBeingComposed != nullptr)

  610.     {

  611.         TextInputTarget* const target = owner->findCurrentTextInputTarget();

  612. 

  613.         if (target != nullptr)

  614.         {

  615.             target->insertTextAtCaret (*stringBeingComposed);

  616.             textWasInserted = true;

  617.         }

  618.     }

  619. 

  620.     deleteAndZero (stringBeingComposed);

  621. }

  622. 

  623. - (BOOL) hasMarkedText

  624. {

  625.     return stringBeingComposed != nullptr;

  626. }

  627. 

  628. - (long) conversationIdentifier

  629. {

  630.     return (long) (pointer_sized_int) self;

  631. }

  632. 

  633. - (NSAttributedString*) attributedSubstringFromRange: (NSRange) theRange

  634. {

  635.     TextInputTarget* const target = owner->findCurrentTextInputTarget();

  636. 

  637.     if (target != nullptr)

  638.     {

  639.         const Range<int> r ((int) theRange.location,

  640.                             (int) (theRange.location + theRange.length));

  641. 

  642.         return [[[NSAttributedString alloc] initWithString: juceStringToNS (target->getTextInRange (r))] autorelease];

  643.     }

  644. 

  645.     return nil;

  646. }

  647. 

  648. - (NSRange) markedRange

  649. {

  650.     return stringBeingComposed != nullptr ? NSMakeRange (0, stringBeingComposed->length())

  651.                                           : NSMakeRange (NSNotFound, 0);

  652. }

  653. 

  654. - (NSRange) selectedRange

  655. {

  656.     TextInputTarget* const target = owner->findCurrentTextInputTarget();

  657. 

  658.     if (target != nullptr)

  659.     {

  660.         const Range<int> highlight (target->getHighlightedRegion());

  661. 

  662.         if (! highlight.isEmpty())

  663.             return NSMakeRange (highlight.getStart(), highlight.getLength());

  664.     }

  665. 

  666.     return NSMakeRange (NSNotFound, 0);

  667. }

  668. 

  669. - (NSRect) firstRectForCharacterRange: (NSRange) theRange

  670. {

  671.     (void) theRange;

  672.     juce::Component* const comp = dynamic_cast <juce::Component*> (owner->findCurrentTextInputTarget());

  673. 

  674.     if (comp == 0)

  675.         return NSMakeRect (0, 0, 0, 0);

  676. 

  677.     const Rectangle<int> bounds (comp->getScreenBounds());

  678. 

  679.     return NSMakeRect (bounds.getX(),

  680.                        [[[NSScreen screens] objectAtIndex: 0] frame].size.height - bounds.getY(),

  681.                        bounds.getWidth(),

  682.                        bounds.getHeight());

  683. }

  684. 

  685. - (NSUInteger) characterIndexForPoint: (NSPoint) thePoint

  686. {

  687.     (void) thePoint;

  688.     return NSNotFound;

  689. }

  690. 

  691. - (NSArray*) validAttributesForMarkedText

  692. {

  693.     return [NSArray array];

  694. }

  695. 

  696. //==============================================================================

  697. - (void) flagsChanged: (NSEvent*) ev

  698. {

  699.     if (owner != nullptr)

  700.         owner->redirectModKeyChange (ev);

  701. }

  702. 

  703. #if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_5

  704. - (BOOL) performKeyEquivalent: (NSEvent*) ev

  705. {

  706.     if (owner != nullptr && owner->redirectPerformKeyEquivalent (ev))

  707.         return true;

  708. 

  709.     return [super performKeyEquivalent: ev];

  710. }

  711. #endif

  712. 

  713. - (BOOL) becomeFirstResponder   { if (owner != nullptr) owner->viewFocusGain(); return YES; }

  714. - (BOOL) resignFirstResponder   { if (owner != nullptr) owner->viewFocusLoss(); return YES; }

  715. 

  716. - (BOOL) acceptsFirstResponder  { return owner != nullptr && owner->canBecomeKeyWindow(); }

  717. 

  718. //==============================================================================

  719. - (NSArray*) getSupportedDragTypes

  720. {

  721.     return [NSArray arrayWithObjects: NSFilenamesPboardType, NSFilesPromisePboardType, /* NSStringPboardType,*/ nil];

  722. }

  723. 

  724. - (BOOL) sendDragCallback: (int) type sender: (id <NSDraggingInfo>) sender

  725. {

  726.     return owner != nullptr && owner->sendDragCallback (type, sender);

  727. }

  728. 

  729. - (NSDragOperation) draggingEntered: (id <NSDraggingInfo>) sender

  730. {

  731.     if ([self sendDragCallback: 0 sender: sender])

  732.         return NSDragOperationCopy | NSDragOperationMove | NSDragOperationGeneric;

  733.     else

  734.         return NSDragOperationNone;

  735. }

  736. 

  737. - (NSDragOperation) draggingUpdated: (id <NSDraggingInfo>) sender

  738. {

  739.     if ([self sendDragCallback: 0 sender: sender])

  740.         return NSDragOperationCopy | NSDragOperationMove | NSDragOperationGeneric;

  741.     else

  742.         return NSDragOperationNone;

  743. }

  744. 

  745. - (void) draggingEnded: (id <NSDraggingInfo>) sender

  746. {

  747.     [self sendDragCallback: 1 sender: sender];

  748. }

  749. 

  750. - (void) draggingExited: (id <NSDraggingInfo>) sender

  751. {

  752.     [self sendDragCallback: 1 sender: sender];

  753. }

  754. 

  755. - (BOOL) prepareForDragOperation: (id <NSDraggingInfo>) sender

  756. {

  757.     (void) sender;

  758.     return YES;

  759. }

  760. 

  761. - (BOOL) performDragOperation: (id <NSDraggingInfo>) sender

  762. {

  763.     return [self sendDragCallback: 2 sender: sender];

  764. }

  765. 

  766. - (void) concludeDragOperation: (id <NSDraggingInfo>) sender

  767. {

  768.     (void) sender;

  769. }

  770. 

  771. @end

  772. 

  773. //==============================================================================

  774. @implementation JuceNSWindow

  775. 

  776. - (void) setOwner: (NSViewComponentPeer*) owner_

  777. {

  778.     owner = owner_;

  779.     isZooming = false;

  780. }

  781. 

  782. - (BOOL) canBecomeKeyWindow

  783. {

  784.     return owner != nullptr && owner->canBecomeKeyWindow();

  785. }

  786. 

  787. - (void) becomeKeyWindow

  788. {

  789.     [super becomeKeyWindow];

  790. 

  791.     if (owner != nullptr)

  792.         owner->becomeKeyWindow();

  793. }

  794. 

  795. - (BOOL) windowShouldClose: (id) window

  796. {

  797.     (void) window;

  798.     return owner == nullptr || owner->windowShouldClose();

  799. }

  800. 

  801. - (NSRect) constrainFrameRect: (NSRect) frameRect toScreen: (NSScreen*) screen

  802. {

  803.     (void) screen;

  804.     if (owner != nullptr)

  805.         frameRect = owner->constrainRect (frameRect);

  806. 

  807.     return frameRect;

  808. }

  809. 

  810. - (NSSize) windowWillResize: (NSWindow*) window toSize: (NSSize) proposedFrameSize

  811. {

  812.     (void) window;

  813.     if (isZooming)

  814.         return proposedFrameSize;

  815. 

  816.     NSRect frameRect = [self frame];

  817.     frameRect.origin.y -= proposedFrameSize.height - frameRect.size.height;

  818.     frameRect.size = proposedFrameSize;

  819. 

  820.     if (owner != nullptr)

  821.         frameRect = owner->constrainRect (frameRect);

  822. 

  823.     if (juce::Component::getCurrentlyModalComponent() != nullptr

  824.           && owner->getComponent()->isCurrentlyBlockedByAnotherModalComponent()

  825.           && owner->hasNativeTitleBar())

  826.         juce::Component::getCurrentlyModalComponent()->inputAttemptWhenModal();

  827. 

  828.     return frameRect.size;

  829. }

  830. 

  831. - (void) zoom: (id) sender

  832. {

  833.     isZooming = true;

  834.     [super zoom: sender];

  835.     isZooming = false;

  836. 

  837.     owner->redirectMovedOrResized();

  838. }

  839. 

  840. - (void) windowWillMove: (NSNotification*) notification

  841. {

  842.     (void) notification;

  843. 

  844.     if (juce::Component::getCurrentlyModalComponent() != nullptr

  845.           && owner->getComponent()->isCurrentlyBlockedByAnotherModalComponent()

  846.           && owner->hasNativeTitleBar())

  847.         juce::Component::getCurrentlyModalComponent()->inputAttemptWhenModal();

  848. }

  849. 

  850. @end

  851. 

  852. 

  853. //==============================================================================

  854. #if JUCE_OSX_OPENGL_RENDERER

  855. 

  856. @interface JuceOpenGLLayer : CAOpenGLLayer

  857. {

  858.     NSViewComponentPeer* owner;

  859. }

  860. 

  861. - (JuceOpenGLLayer*) initWithPeer: (NSViewComponentPeer*) owner;

  862. - (void) dealloc;

  863. 

  864. - (void) drawInCGLContext: (CGLContextObj) glContext

  865.               pixelFormat: (CGLPixelFormatObj) pixelFormat

  866.              forLayerTime: (CFTimeInterval) timeInterval

  867.               displayTime: (const CVTimeStamp*) timeStamp;

  868. @end

  869. 

  870. @implementation JuceOpenGLLayer

  871. 

  872. - (JuceOpenGLLayer*) initWithPeer: (NSViewComponentPeer*) owner_

  873. {

  874.     [super init];

  875.     owner = owner_;

  876.     return self;

  877. }

  878. 

  879. - (void) dealloc

  880. {

  881.     [super dealloc];

  882. }

  883. 

  884. - (void) drawInCGLContext: (CGLContextObj) glContext

  885.               pixelFormat: (CGLPixelFormatObj) pixelFormat

  886.              forLayerTime: (CFTimeInterval) timeInterval

  887.               displayTime: (const CVTimeStamp*) timeStamp

  888. {

  889.     owner->drawOpenGL();

  890. }

  891. 

  892. @end

  893. #endif

  894. 

  895. //==============================================================================

  896. //==============================================================================

  897. BEGIN_JUCE_NAMESPACE

  898. 

  899. //==============================================================================

  900. ModifierKeys NSViewComponentPeer::currentModifiers;

  901. ComponentPeer* NSViewComponentPeer::currentlyFocusedPeer = nullptr;

  902. Array<int> NSViewComponentPeer::keysCurrentlyDown;

  903. 

  904. //==============================================================================

  905. bool KeyPress::isKeyCurrentlyDown (const int keyCode)

  906. {

  907.     if (NSViewComponentPeer::keysCurrentlyDown.contains (keyCode))

  908.         return true;

  909. 

  910.     if (keyCode >= 'A' && keyCode <= 'Z'

  911.          && NSViewComponentPeer::keysCurrentlyDown.contains ((int) CharacterFunctions::toLowerCase ((juce_wchar) keyCode)))

  912.         return true;

  913. 

  914.     if (keyCode >= 'a' && keyCode <= 'z'

  915.          && NSViewComponentPeer::keysCurrentlyDown.contains ((int) CharacterFunctions::toUpperCase ((juce_wchar) keyCode)))

  916.         return true;

  917. 

  918.     return false;

  919. }

  920. 

  921. void NSViewComponentPeer::updateModifiers (NSEvent* e)

  922. {

  923.     int m = 0;

  924. 

  925.     if (([e modifierFlags] & NSShiftKeyMask) != 0)          m |= ModifierKeys::shiftModifier;

  926.     if (([e modifierFlags] & NSControlKeyMask) != 0)        m |= ModifierKeys::ctrlModifier;

  927.     if (([e modifierFlags] & NSAlternateKeyMask) != 0)      m |= ModifierKeys::altModifier;

  928.     if (([e modifierFlags] & NSCommandKeyMask) != 0)        m |= ModifierKeys::commandModifier;

  929. 

  930.     currentModifiers = currentModifiers.withOnlyMouseButtons().withFlags (m);

  931. }

  932. 

  933. void NSViewComponentPeer::updateKeysDown (NSEvent* ev, bool isKeyDown)

  934. {

  935.     updateModifiers (ev);

  936.     int keyCode = getKeyCodeFromEvent (ev);

  937. 

  938.     if (keyCode != 0)

  939.     {

  940.         if (isKeyDown)

  941.             keysCurrentlyDown.addIfNotAlreadyThere (keyCode);

  942.         else

  943.             keysCurrentlyDown.removeValue (keyCode);

  944.     }

  945. }

  946. 

  947. ModifierKeys ModifierKeys::getCurrentModifiersRealtime() noexcept

  948. {

  949.     return NSViewComponentPeer::currentModifiers;

  950. }

  951. 

  952. void ModifierKeys::updateCurrentModifiers() noexcept

  953. {

  954.     currentModifiers = NSViewComponentPeer::currentModifiers;

  955. }

  956. 

  957. //==============================================================================

  958. NSViewComponentPeer::NSViewComponentPeer (Component* const component_,

  959.                                           const int windowStyleFlags,

  960.                                           NSView* viewToAttachTo)

  961.     : ComponentPeer (component_, windowStyleFlags),

  962.       window (nil),

  963.       view (nil),

  964.       isSharedWindow (viewToAttachTo != nil),

  965.       fullScreen (false),

  966.       insideDrawRect (false),

  967.      #if USE_COREGRAPHICS_RENDERING

  968.       usingCoreGraphics (true),

  969.      #else

  970.       usingCoreGraphics (false),

  971.      #endif

  972.       usingOpenGL (false),

  973.       recursiveToFrontCall (false)

  974. {

  975.     appFocusChangeCallback = appFocusChanged;

  976.     isEventBlockedByModalComps = checkEventBlockedByModalComps;

  977. 

  978.     NSRect r = NSMakeRect (0, 0, (CGFloat) component->getWidth(), (CGFloat) component->getHeight());

  979. 

  980.     view = [[JuceNSView alloc] initWithOwner: this withFrame: r];

  981.     [view setPostsFrameChangedNotifications: YES];

  982. 

  983.     if (isSharedWindow)

  984.     {

  985.         window = [viewToAttachTo window];

  986.         [viewToAttachTo addSubview: view];

  987.     }

  988.     else

  989.     {

  990.         r.origin.x = (CGFloat) component->getX();

  991.         r.origin.y = (CGFloat) component->getY();

  992.         r.origin.y = [[[NSScreen screens] objectAtIndex: 0] frame].size.height - (r.origin.y + r.size.height);

  993. 

  994.         window = [[JuceNSWindow alloc] initWithContentRect: r

  995.                                                  styleMask: getNSWindowStyleMask (windowStyleFlags)

  996.                                                    backing: NSBackingStoreBuffered

  997.                                                      defer: YES];

  998. 

  999.         [((JuceNSWindow*) window) setOwner: this];

  1000.         [window orderOut: nil];

  1001.         [window setDelegate: (JuceNSWindow*) window];

  1002.         [window setOpaque: component->isOpaque()];

  1003.         [window setHasShadow: ((windowStyleFlags & windowHasDropShadow) != 0)];

  1004. 

  1005.         if (component->isAlwaysOnTop())

  1006.             [window setLevel: NSFloatingWindowLevel];

  1007. 

  1008.         [window setContentView: view];

  1009.         [window setAutodisplay: YES];

  1010.         [window setAcceptsMouseMovedEvents: YES];

  1011. 

  1012.         // We'll both retain and also release this on closing because plugin hosts can unexpectedly

  1013.         // close the window for us, and also tend to get cause trouble if setReleasedWhenClosed is NO.

  1014.         [window setReleasedWhenClosed: YES];

  1015.         [window retain];

  1016. 

  1017.         [window setExcludedFromWindowsMenu: (windowStyleFlags & windowIsTemporary) != 0];

  1018.         [window setIgnoresMouseEvents: (windowStyleFlags & windowIgnoresMouseClicks) != 0];

  1019.     }

  1020. 

  1021.     const float alpha = component->getAlpha();

  1022.     if (alpha < 1.0f)

  1023.         setAlpha (alpha);

  1024. 

  1025.     setTitle (component->getName());

  1026. }

  1027. 

  1028. NSViewComponentPeer::~NSViewComponentPeer()

  1029. {

  1030.     view->owner = nullptr;

  1031.     [view removeFromSuperview];

  1032.     [view release];

  1033. 

  1034.     if (! isSharedWindow)

  1035.     {

  1036.         [((JuceNSWindow*) window) setOwner: 0];

  1037.         [window close];

  1038.         [window release];

  1039.     }

  1040. }

  1041. 

  1042. //==============================================================================

  1043. void* NSViewComponentPeer::getNativeHandle() const

  1044. {

  1045.     return view;

  1046. }

  1047. 

  1048. void NSViewComponentPeer::setVisible (bool shouldBeVisible)

  1049. {

  1050.     if (isSharedWindow)

  1051.     {

  1052.         [view setHidden: ! shouldBeVisible];

  1053.     }

  1054.     else

  1055.     {

  1056.         if (shouldBeVisible)

  1057.         {

  1058.             [window orderFront: nil];

  1059.             handleBroughtToFront();

  1060.         }

  1061.         else

  1062.         {

  1063.             [window orderOut: nil];

  1064.         }

  1065.     }

  1066. }

  1067. 

  1068. void NSViewComponentPeer::setTitle (const String& title)

  1069. {

  1070.     JUCE_AUTORELEASEPOOL

  1071. 

  1072.     if (! isSharedWindow)

  1073.         [window setTitle: juceStringToNS (title)];

  1074. }

  1075. 

  1076. void NSViewComponentPeer::setPosition (int x, int y)

  1077. {

  1078.     setBounds (x, y, component->getWidth(), component->getHeight(), false);

  1079. }

  1080. 

  1081. void NSViewComponentPeer::setSize (int w, int h)

  1082. {

  1083.     setBounds (component->getX(), component->getY(), w, h, false);

  1084. }

  1085. 

  1086. void NSViewComponentPeer::setBounds (int x, int y, int w, int h, bool isNowFullScreen)

  1087. {

  1088.     fullScreen = isNowFullScreen;

  1089. 

  1090.     NSRect r = NSMakeRect ((CGFloat) x, (CGFloat) y, (CGFloat) jmax (0, w), (CGFloat) jmax (0, h));

  1091. 

  1092.     if (isSharedWindow)

  1093.     {

  1094.         r.origin.y = [[view superview] frame].size.height - (r.origin.y + r.size.height);

  1095. 

  1096.         if ([view frame].size.width != r.size.width

  1097.              || [view frame].size.height != r.size.height)

  1098.         {

  1099.            #if JUCE_OSX_OPENGL_RENDERER

  1100.             if (usingOpenGL)

  1101.                 [[view layer] setNeedsDisplay: true];

  1102.            #endif

  1103.                 [view setNeedsDisplay: true];

  1104.         }

  1105. 

  1106.         [view setFrame: r];

  1107.     }

  1108.     else

  1109.     {

  1110.         r.origin.y = [[[NSScreen screens] objectAtIndex: 0] frame].size.height - (r.origin.y + r.size.height);

  1111. 

  1112.         [window setFrame: [window frameRectForContentRect: r]

  1113.                  display: true];

  1114. 

  1115.        #if JUCE_OSX_OPENGL_RENDERER

  1116.         if (usingOpenGL)

  1117.             [[view layer] setFrame: CGRectMake (0, 0, [view frame].size.width, [view frame].size.height)];

  1118.        #endif

  1119.     }

  1120. }

  1121. 

  1122. const Rectangle<int> NSViewComponentPeer::getBounds (const bool global) const

  1123. {

  1124.     NSRect r = [view frame];

  1125. 

  1126.     if (global && [view window] != nil)

  1127.     {

  1128.         r = [view convertRect: r toView: nil];

  1129.         NSRect wr = [[view window] frame];

  1130.         r.origin.x += wr.origin.x;

  1131.         r.origin.y += wr.origin.y;

  1132.         r.origin.y = [[[NSScreen screens] objectAtIndex: 0] frame].size.height - r.origin.y - r.size.height;

  1133.     }

  1134.     else

  1135.     {

  1136.         r.origin.y = [[view superview] frame].size.height - r.origin.y - r.size.height;

  1137.     }

  1138. 

  1139.     return Rectangle<int> (convertToRectInt (r));

  1140. }

  1141. 

  1142. const Rectangle<int> NSViewComponentPeer::getBounds() const

  1143. {

  1144.     return getBounds (! isSharedWindow);

  1145. }

  1146. 

  1147. const Point<int> NSViewComponentPeer::getScreenPosition() const

  1148. {

  1149.     return getBounds (true).getPosition();

  1150. }

  1151. 

  1152. const Point<int> NSViewComponentPeer::localToGlobal (const Point<int>& relativePosition)

  1153. {

  1154.     return relativePosition + getScreenPosition();

  1155. }

  1156. 

  1157. const Point<int> NSViewComponentPeer::globalToLocal (const Point<int>& screenPosition)

  1158. {

  1159.     return screenPosition - getScreenPosition();

  1160. }

  1161. 

  1162. NSRect NSViewComponentPeer::constrainRect (NSRect r)

  1163. {

  1164.     if (constrainer != nullptr)

  1165.     {

  1166.         NSRect current = [window frame];

  1167.         current.origin.y = [[[NSScreen screens] objectAtIndex: 0] frame].size.height - current.origin.y - current.size.height;

  1168. 

  1169.         r.origin.y = [[[NSScreen screens] objectAtIndex: 0] frame].size.height - r.origin.y - r.size.height;

  1170. 

  1171.         Rectangle<int> pos (convertToRectInt (r));

  1172.         Rectangle<int> original (convertToRectInt (current));

  1173. 

  1174.        #if defined (MAC_OS_X_VERSION_10_6) && MAC_OS_X_VERSION_MIN_ALLOWED >= MAC_OS_X_VERSION_10_6

  1175.         if ([window inLiveResize])

  1176.        #else

  1177.         if ([window respondsToSelector: @selector (inLiveResize)]

  1178.              && [window performSelector: @selector (inLiveResize)])

  1179.        #endif

  1180.         {

  1181.             constrainer->checkBounds (pos, original,

  1182.                                       Desktop::getInstance().getAllMonitorDisplayAreas().getBounds(),

  1183.                                       false, false, true, true);

  1184.         }

  1185.         else

  1186.         {

  1187.             constrainer->checkBounds (pos, original,

  1188.                                       Desktop::getInstance().getAllMonitorDisplayAreas().getBounds(),

  1189.                                       pos.getY() != original.getY() && pos.getBottom() == original.getBottom(),

  1190.                                       pos.getX() != original.getX() && pos.getRight() == original.getRight(),

  1191.                                       pos.getY() == original.getY() && pos.getBottom() != original.getBottom(),

  1192.                                       pos.getX() == original.getX() && pos.getRight() != original.getRight());

  1193.         }

  1194. 

  1195.         r.origin.x = pos.getX();

  1196.         r.origin.y = [[[NSScreen screens] objectAtIndex: 0] frame].size.height - r.size.height - pos.getY();

  1197.         r.size.width = pos.getWidth();

  1198.         r.size.height = pos.getHeight();

  1199.     }

  1200. 

  1201.     return r;

  1202. }

  1203. 

  1204. void NSViewComponentPeer::setAlpha (float newAlpha)

  1205. {

  1206.     if (! isSharedWindow)

  1207.     {

  1208.         [window setAlphaValue: (CGFloat) newAlpha];

  1209.     }

  1210.     else

  1211.     {

  1212.        #if defined (MAC_OS_X_VERSION_10_5) && MAC_OS_X_VERSION_MIN_ALLOWED >= MAC_OS_X_VERSION_10_5

  1213.         [view setAlphaValue: (CGFloat) newAlpha];

  1214.        #else

  1215.         if ([view respondsToSelector: @selector (setAlphaValue:)])

  1216.         {

  1217.             // PITA dynamic invocation for 10.4 builds..

  1218.             NSInvocation* inv = [NSInvocation invocationWithMethodSignature: [view methodSignatureForSelector: @selector (setAlphaValue:)]];

  1219.             [inv setSelector: @selector (setAlphaValue:)];

  1220.             [inv setTarget: view];

  1221.             CGFloat cgNewAlpha = (CGFloat) newAlpha;

  1222.             [inv setArgument: &cgNewAlpha atIndex: 2];

  1223.             [inv invoke];

  1224.         }

  1225.        #endif

  1226.     }

  1227. }

  1228. 

  1229. void NSViewComponentPeer::setMinimised (bool shouldBeMinimised)

  1230. {

  1231.     if (! isSharedWindow)

  1232.     {

  1233.         if (shouldBeMinimised)

  1234.             [window miniaturize: nil];

  1235.         else

  1236.             [window deminiaturize: nil];

  1237.     }

  1238. }

  1239. 

  1240. bool NSViewComponentPeer::isMinimised() const

  1241. {

  1242.     return [window isMiniaturized];

  1243. }

  1244. 

  1245. void NSViewComponentPeer::setFullScreen (bool shouldBeFullScreen)

  1246. {

  1247.     if (! isSharedWindow)

  1248.     {

  1249.         Rectangle<int> r (lastNonFullscreenBounds);

  1250. 

  1251.         if (isMinimised())

  1252.             setMinimised (false);

  1253. 

  1254.         if (fullScreen != shouldBeFullScreen)

  1255.         {

  1256.             if (shouldBeFullScreen && hasNativeTitleBar())

  1257.             {

  1258.                 fullScreen = true;

  1259.                 [window performZoom: nil];

  1260.             }

  1261.             else

  1262.             {

  1263.                 if (shouldBeFullScreen)

  1264.                     r = component->getParentMonitorArea();

  1265. 

  1266.                 // (can't call the component's setBounds method because that'll reset our fullscreen flag)

  1267.                 if (r != getComponent()->getBounds() && ! r.isEmpty())

  1268.                     setBounds (r.getX(), r.getY(), r.getWidth(), r.getHeight(), shouldBeFullScreen);

  1269.             }

  1270.         }

  1271.     }

  1272. }

  1273. 

  1274. bool NSViewComponentPeer::isFullScreen() const

  1275. {

  1276.     return fullScreen;

  1277. }

  1278. 

  1279. bool NSViewComponentPeer::contains (const Point<int>& position, bool trueIfInAChildWindow) const

  1280. {

  1281.     if (! (isPositiveAndBelow (position.getX(), component->getWidth())

  1282.             && isPositiveAndBelow (position.getY(), component->getHeight())))

  1283.         return false;

  1284. 

  1285.     NSRect frameRect = [view frame];

  1286. 

  1287.     NSView* v = [view hitTest: NSMakePoint (frameRect.origin.x + position.getX(),

  1288.                                             frameRect.origin.y + frameRect.size.height - position.getY())];

  1289. 

  1290.     if (trueIfInAChildWindow)

  1291.         return v != nil;

  1292. 

  1293.     return v == view;

  1294. }

  1295. 

  1296. const BorderSize<int> NSViewComponentPeer::getFrameSize() const

  1297. {

  1298.     BorderSize<int> b;

  1299. 

  1300.     if (! isSharedWindow)

  1301.     {

  1302.         NSRect v = [view convertRect: [view frame] toView: nil];

  1303.         NSRect w = [window frame];

  1304. 

  1305.         b.setTop ((int) (w.size.height - (v.origin.y + v.size.height)));

  1306.         b.setBottom ((int) v.origin.y);

  1307.         b.setLeft ((int) v.origin.x);

  1308.         b.setRight ((int) (w.size.width - (v.origin.x + v.size.width)));

  1309.     }

  1310. 

  1311.     return b;

  1312. }

  1313. 

  1314. bool NSViewComponentPeer::setAlwaysOnTop (bool alwaysOnTop)

  1315. {

  1316.     if (! isSharedWindow)

  1317.         [window setLevel: alwaysOnTop ? NSFloatingWindowLevel

  1318.                                       : NSNormalWindowLevel];

  1319.     return true;

  1320. }

  1321. 

  1322. void NSViewComponentPeer::toFront (bool makeActiveWindow)

  1323. {

  1324.     if (isSharedWindow)

  1325.         [[view superview] addSubview: view

  1326.                           positioned: NSWindowAbove

  1327.                           relativeTo: nil];

  1328. 

  1329.     if (window != nil && component->isVisible())

  1330.     {

  1331.         if (makeActiveWindow)

  1332.             [window makeKeyAndOrderFront: nil];

  1333.         else

  1334.             [window orderFront: nil];

  1335. 

  1336.         if (! recursiveToFrontCall)

  1337.         {

  1338.             recursiveToFrontCall = true;

  1339.             Desktop::getInstance().getMainMouseSource().forceMouseCursorUpdate();

  1340.             handleBroughtToFront();

  1341.             recursiveToFrontCall = false;

  1342.         }

  1343.     }

  1344. }

  1345. 

  1346. void NSViewComponentPeer::toBehind (ComponentPeer* other)

  1347. {

  1348.     NSViewComponentPeer* const otherPeer = dynamic_cast <NSViewComponentPeer*> (other);

  1349.     jassert (otherPeer != nullptr); // wrong type of window?

  1350. 

  1351.     if (otherPeer != nullptr)

  1352.     {

  1353.         if (isSharedWindow)

  1354.         {

  1355.             [[view superview] addSubview: view

  1356.                               positioned: NSWindowBelow

  1357.                               relativeTo: otherPeer->view];

  1358.         }

  1359.         else

  1360.         {

  1361.             [window orderWindow: NSWindowBelow

  1362.                      relativeTo: [otherPeer->window windowNumber]];

  1363.         }

  1364.     }

  1365. }

  1366. 

  1367. void NSViewComponentPeer::setIcon (const Image& /*newIcon*/)

  1368. {

  1369.     // to do..

  1370. }

  1371. 

  1372. //==============================================================================

  1373. void NSViewComponentPeer::viewFocusGain()

  1374. {

  1375.     if (currentlyFocusedPeer != this)

  1376.     {

  1377.         if (ComponentPeer::isValidPeer (currentlyFocusedPeer))

  1378.             currentlyFocusedPeer->handleFocusLoss();

  1379. 

  1380.         currentlyFocusedPeer = this;

  1381.         handleFocusGain();

  1382.     }

  1383. }

  1384. 

  1385. void NSViewComponentPeer::viewFocusLoss()

  1386. {

  1387.     if (currentlyFocusedPeer == this)

  1388.     {

  1389.         currentlyFocusedPeer = nullptr;

  1390.         handleFocusLoss();

  1391.     }

  1392. }

  1393. 

  1394. bool NSViewComponentPeer::isFocused() const

  1395. {

  1396.     return isSharedWindow ? this == currentlyFocusedPeer

  1397.                           : [window isKeyWindow];

  1398. }

  1399. 

  1400. void NSViewComponentPeer::grabFocus()

  1401. {

  1402.     if (window != nil)

  1403.     {

  1404.         [window makeKeyWindow];

  1405.         [window makeFirstResponder: view];

  1406. 

  1407.         viewFocusGain();

  1408.     }

  1409. }

  1410. 

  1411. void NSViewComponentPeer::textInputRequired (const Point<int>&)

  1412. {

  1413. }

  1414. 

  1415. bool NSViewComponentPeer::handleKeyEvent (NSEvent* ev, bool isKeyDown)

  1416. {

  1417.     String unicode (nsStringToJuce ([ev characters]));

  1418.     String unmodified (nsStringToJuce ([ev charactersIgnoringModifiers]));

  1419.     int keyCode = getKeyCodeFromEvent (ev);

  1420. 

  1421.     //DBG ("unicode: " + unicode + " " + String::toHexString ((int) unicode[0]));

  1422.     //DBG ("unmodified: " + unmodified + " " + String::toHexString ((int) unmodified[0]));

  1423. 

  1424.     if (unicode.isNotEmpty() || keyCode != 0)

  1425.     {

  1426.         if (isKeyDown)

  1427.         {

  1428.             bool used = false;

  1429. 

  1430.             while (unicode.length() > 0)

  1431.             {

  1432.                 juce_wchar textCharacter = unicode[0];

  1433.                 unicode = unicode.substring (1);

  1434. 

  1435.                 if (([ev modifierFlags] & NSCommandKeyMask) != 0)

  1436.                     textCharacter = 0;

  1437. 

  1438.                 used = handleKeyUpOrDown (true) || used;

  1439.                 used = handleKeyPress (keyCode, textCharacter) || used;

  1440.             }

  1441. 

  1442.             return used;

  1443.         }

  1444.         else

  1445.         {

  1446.             if (handleKeyUpOrDown (false))

  1447.                 return true;

  1448.         }

  1449.     }

  1450. 

  1451.     return false;

  1452. }

  1453. 

  1454. bool NSViewComponentPeer::redirectKeyDown (NSEvent* ev)

  1455. {

  1456.     updateKeysDown (ev, true);

  1457.     bool used = handleKeyEvent (ev, true);

  1458. 

  1459.     if (([ev modifierFlags] & NSCommandKeyMask) != 0)

  1460.     {

  1461.         // for command keys, the key-up event is thrown away, so simulate one..

  1462.         updateKeysDown (ev, false);

  1463.         used = (isValidPeer (this) && handleKeyEvent (ev, false)) || used;

  1464.     }

  1465. 

  1466.     // (If we're running modally, don't allow unused keystrokes to be passed

  1467.     // along to other blocked views..)

  1468.     if (Component::getCurrentlyModalComponent() != nullptr)

  1469.         used = true;

  1470. 

  1471.     return used;

  1472. }

  1473. 

  1474. bool NSViewComponentPeer::redirectKeyUp (NSEvent* ev)

  1475. {

  1476.     updateKeysDown (ev, false);

  1477.     return handleKeyEvent (ev, false)

  1478.             || Component::getCurrentlyModalComponent() != nullptr;

  1479. }

  1480. 

  1481. void NSViewComponentPeer::redirectModKeyChange (NSEvent* ev)

  1482. {

  1483.     keysCurrentlyDown.clear();

  1484.     handleKeyUpOrDown (true);

  1485. 

  1486.     updateModifiers (ev);

  1487.     handleModifierKeysChange();

  1488. }

  1489. 

  1490. #if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_5

  1491. bool NSViewComponentPeer::redirectPerformKeyEquivalent (NSEvent* ev)

  1492. {

  1493.     if ([ev type] == NSKeyDown)

  1494.         return redirectKeyDown (ev);

  1495.     else if ([ev type] == NSKeyUp)

  1496.         return redirectKeyUp (ev);

  1497. 

  1498.     return false;

  1499. }

  1500. #endif

  1501. 

  1502. //==============================================================================

  1503. void NSViewComponentPeer::sendMouseEvent (NSEvent* ev)

  1504. {

  1505.     updateModifiers (ev);

  1506.     handleMouseEvent (0, getMousePos (ev, view), currentModifiers, getMouseTime (ev));

  1507. }

  1508. 

  1509. void NSViewComponentPeer::redirectMouseDown (NSEvent* ev)

  1510. {

  1511.     currentModifiers = currentModifiers.withFlags (getModifierForButtonNumber ([ev buttonNumber]));

  1512.     sendMouseEvent (ev);

  1513. }

  1514. 

  1515. void NSViewComponentPeer::redirectMouseUp (NSEvent* ev)

  1516. {

  1517.     currentModifiers = currentModifiers.withoutFlags (getModifierForButtonNumber ([ev buttonNumber]));

  1518.     sendMouseEvent (ev);

  1519.     showArrowCursorIfNeeded();

  1520. }

  1521. 

  1522. void NSViewComponentPeer::redirectMouseDrag (NSEvent* ev)

  1523. {

  1524.     currentModifiers = currentModifiers.withFlags (getModifierForButtonNumber ([ev buttonNumber]));

  1525.     sendMouseEvent (ev);

  1526. }

  1527. 

  1528. void NSViewComponentPeer::redirectMouseMove (NSEvent* ev)

  1529. {

  1530.     currentModifiers = currentModifiers.withoutMouseButtons();

  1531.     sendMouseEvent (ev);

  1532.     showArrowCursorIfNeeded();

  1533. }

  1534. 

  1535. void NSViewComponentPeer::redirectMouseEnter (NSEvent* ev)

  1536. {

  1537.     Desktop::getInstance().getMainMouseSource().forceMouseCursorUpdate();

  1538.     currentModifiers = currentModifiers.withoutMouseButtons();

  1539.     sendMouseEvent (ev);

  1540. }

  1541. 

  1542. void NSViewComponentPeer::redirectMouseExit (NSEvent* ev)

  1543. {

  1544.     currentModifiers = currentModifiers.withoutMouseButtons();

  1545.     sendMouseEvent (ev);

  1546. }

  1547. 

  1548. void NSViewComponentPeer::redirectMouseWheel (NSEvent* ev)

  1549. {

  1550.     updateModifiers (ev);

  1551. 

  1552.     float x = 0, y = 0;

  1553. 

  1554.     @try

  1555.     {

  1556.         x = [ev deviceDeltaX] * 0.5f;

  1557.         y = [ev deviceDeltaY] * 0.5f;

  1558.     }

  1559.     @catch (...)

  1560.     {}

  1561. 

  1562.     if (x == 0 && y == 0)

  1563.     {

  1564.         x = [ev deltaX] * 10.0f;

  1565.         y = [ev deltaY] * 10.0f;

  1566.     }

  1567. 

  1568.     handleMouseWheel (0, getMousePos (ev, view), getMouseTime (ev), x, y);

  1569. }

  1570. 

  1571. void NSViewComponentPeer::showArrowCursorIfNeeded()

  1572. {

  1573.     MouseInputSource& mouse = Desktop::getInstance().getMainMouseSource();

  1574. 

  1575.     if (mouse.getComponentUnderMouse() == nullptr

  1576.          && Desktop::getInstance().findComponentAt (mouse.getScreenPosition()) == nullptr)

  1577.     {

  1578.         [[NSCursor arrowCursor] set];

  1579.     }

  1580. }

  1581. 

  1582. //==============================================================================

  1583. BOOL NSViewComponentPeer::sendDragCallback (const int type, id <NSDraggingInfo> sender)

  1584. {

  1585.     NSString* bestType

  1586.         = [[sender draggingPasteboard] availableTypeFromArray: [view getSupportedDragTypes]];

  1587. 

  1588.     if (bestType == nil)

  1589.         return false;

  1590. 

  1591.     NSPoint p = [view convertPoint: [sender draggingLocation] fromView: nil];

  1592.     const Point<int> pos ((int) p.x, (int) ([view frame].size.height - p.y));

  1593. 

  1594.     NSPasteboard* pasteBoard = [sender draggingPasteboard];

  1595.     StringArray files;

  1596. 

  1597.     NSString* iTunesPasteboardType = nsStringLiteral ("CorePasteboardFlavorType 0x6974756E"); // 'itun'

  1598. 

  1599.     if (bestType == NSFilesPromisePboardType

  1600.          && [[pasteBoard types] containsObject: iTunesPasteboardType])

  1601.     {

  1602.         id list = [pasteBoard propertyListForType: iTunesPasteboardType];

  1603. 

  1604.         if ([list isKindOfClass: [NSDictionary class]])

  1605.         {

  1606.             NSDictionary* iTunesDictionary = (NSDictionary*) list;

  1607.             NSArray* tracks = [iTunesDictionary valueForKey: nsStringLiteral ("Tracks")];

  1608.             NSEnumerator* enumerator = [tracks objectEnumerator];

  1609.             NSDictionary* track;

  1610. 

  1611.             while ((track = [enumerator nextObject]) != nil)

  1612.             {

  1613.                 NSURL* url = [NSURL URLWithString: [track valueForKey: nsStringLiteral ("Location")]];

  1614. 

  1615.                 if ([url isFileURL])

  1616.                     files.add (nsStringToJuce ([url path]));

  1617.             }

  1618.         }

  1619.     }

  1620.     else

  1621.     {

  1622.         id list = [pasteBoard propertyListForType: NSFilenamesPboardType];

  1623. 

  1624.         if ([list isKindOfClass: [NSArray class]])

  1625.         {

  1626.             NSArray* items = (NSArray*) [pasteBoard propertyListForType: NSFilenamesPboardType];

  1627. 

  1628.             for (unsigned int i = 0; i < [items count]; ++i)

  1629.                 files.add (nsStringToJuce ((NSString*) [items objectAtIndex: i]));

  1630.         }

  1631.     }

  1632. 

  1633.     if (files.size() > 0)

  1634.     {

  1635.         switch (type)

  1636.         {

  1637.             case 0:   return handleFileDragMove (files, pos);

  1638.             case 1:   return handleFileDragExit (files);

  1639.             case 2:   return handleFileDragDrop (files, pos);

  1640.             default:  jassertfalse; break;

  1641.         }

  1642.     }

  1643. 

  1644.     return false;

  1645. }

  1646. 

  1647. bool NSViewComponentPeer::isOpaque()

  1648. {

  1649.     return component == nullptr || component->isOpaque();

  1650. }

  1651. 

  1652. static void getClipRects (RectangleList& clip, NSView* view,

  1653.                           const int xOffset, const int yOffset, const int clipW, const int clipH)

  1654. {

  1655.     const NSRect* rects = nullptr;

  1656.     NSInteger numRects = 0;

  1657.     [view getRectsBeingDrawn: &rects count: &numRects];

  1658. 

  1659.     const Rectangle<int> clipBounds (clipW, clipH);

  1660.     const CGFloat viewH = [view frame].size.height;

  1661. 

  1662.     for (int i = 0; i < numRects; ++i)

  1663.         clip.addWithoutMerging (clipBounds.getIntersection (Rectangle<int> (roundToInt (rects[i].origin.x) + xOffset,

  1664.                                                                             roundToInt (viewH - (rects[i].origin.y + rects[i].size.height)) + yOffset,

  1665.                                                                             roundToInt (rects[i].size.width),

  1666.                                                                             roundToInt (rects[i].size.height))));

  1667. }

  1668. 

  1669. #if JUCE_OSX_OPENGL_RENDERER

  1670. void NSViewComponentPeer::drawOpenGL()

  1671. {

  1672.     if (! component->isOpaque())

  1673.         OpenGLHelpers::clear (Colours::transparentBlack);

  1674. 

  1675.     OpenGLRenderer context (OpenGLFrameBuffer::getCurrentFrameBufferTarget(),

  1676.                             component->getWidth(), component->getHeight());

  1677. 

  1678.     insideDrawRect = true;

  1679.     handlePaint (context);

  1680.     insideDrawRect = false;

  1681. }

  1682. #endif

  1683. 

  1684. void NSViewComponentPeer::drawRect (NSRect r)

  1685. {

  1686.     if (r.size.width < 1.0f || r.size.height < 1.0f)

  1687.         return;

  1688. 

  1689.     CGContextRef cg = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];

  1690. 

  1691.     if (! component->isOpaque())

  1692.         CGContextClearRect (cg, CGContextGetClipBoundingBox (cg));

  1693. 

  1694.    #if USE_COREGRAPHICS_RENDERING

  1695.     if (usingCoreGraphics)

  1696.     {

  1697.         CoreGraphicsContext context (cg, (float) [view frame].size.height);

  1698. 

  1699.         insideDrawRect = true;

  1700.         handlePaint (context);

  1701.         insideDrawRect = false;

  1702.     }

  1703.     else

  1704.    #endif

  1705.     {

  1706.         const int xOffset = -roundToInt (r.origin.x);

  1707.         const int yOffset = -roundToInt ([view frame].size.height - (r.origin.y + r.size.height));

  1708.         const int clipW = (int) (r.size.width  + 0.5f);

  1709.         const int clipH = (int) (r.size.height + 0.5f);

  1710. 

  1711.         RectangleList clip;

  1712.         getClipRects (clip, view, xOffset, yOffset, clipW, clipH);

  1713. 

  1714.         if (! clip.isEmpty())

  1715.         {

  1716.             Image temp (getComponent()->isOpaque() ? Image::RGB : Image::ARGB,

  1717.                         clipW, clipH, ! getComponent()->isOpaque());

  1718. 

  1719.             {

  1720.                 ScopedPointer<LowLevelGraphicsContext> context (component->getLookAndFeel()

  1721.                                                                     .createGraphicsContext (temp, Point<int> (xOffset, yOffset), clip));

  1722. 

  1723.                 insideDrawRect = true;

  1724.                 handlePaint (*context);

  1725.                 insideDrawRect = false;

  1726.             }

  1727. 

  1728.             CGColorSpaceRef colourSpace = CGColorSpaceCreateDeviceRGB();

  1729.             CGImageRef image = juce_createCoreGraphicsImage (temp, false, colourSpace, false);

  1730.             CGColorSpaceRelease (colourSpace);

  1731.             CGContextDrawImage (cg, CGRectMake (r.origin.x, r.origin.y, clipW, clipH), image);

  1732.             CGImageRelease (image);

  1733.         }

  1734.     }

  1735. }

  1736. 

  1737. StringArray NSViewComponentPeer::getAvailableRenderingEngines()

  1738. {

  1739.     StringArray s (ComponentPeer::getAvailableRenderingEngines());

  1740. 

  1741.    #if USE_COREGRAPHICS_RENDERING

  1742.     s.add ("CoreGraphics Renderer");

  1743.    #endif

  1744. 

  1745.    #if JUCE_OSX_OPENGL_RENDERER

  1746.     s.add ("OpenGL Renderer");

  1747.    #endif

  1748. 

  1749.     return s;

  1750. }

  1751. 

  1752. int NSViewComponentPeer::getCurrentRenderingEngine() const

  1753. {

  1754.    #if JUCE_OSX_OPENGL_RENDERER

  1755.     if (usingOpenGL) return 2;

  1756.    #endif

  1757. 

  1758.     return usingCoreGraphics ? 1 : 0;

  1759. }

  1760. 

  1761. void NSViewComponentPeer::setCurrentRenderingEngine (int index)

  1762. {

  1763.    #if JUCE_OSX_OPENGL_RENDERER

  1764.     if (index == 2)

  1765.     {

  1766.         usingCoreGraphics = false;

  1767.         usingOpenGL = true;

  1768. 

  1769.         JuceOpenGLLayer* glLayer = [[JuceOpenGLLayer alloc] initWithPeer: this];

  1770.         [view setLayer: glLayer];

  1771.         [view setWantsLayer: YES];

  1772.         [glLayer release];

  1773.     }

  1774.     else

  1775.     {

  1776.         usingOpenGL = false;

  1777. 

  1778.         [view setLayer: nil];

  1779.         [view setWantsLayer: NO];

  1780.     }

  1781.    #endif

  1782. 

  1783.    #if USE_COREGRAPHICS_RENDERING

  1784.     if (usingCoreGraphics != (index > 0))

  1785.     {

  1786.         usingCoreGraphics = index > 0;

  1787.         [view setNeedsDisplay: true];

  1788.     }

  1789.    #endif

  1790. }

  1791. 

  1792. bool NSViewComponentPeer::canBecomeKeyWindow()

  1793. {

  1794.     return (getStyleFlags() & juce::ComponentPeer::windowIgnoresKeyPresses) == 0;

  1795. }

  1796. 

  1797. void NSViewComponentPeer::becomeKeyWindow()

  1798. {

  1799.     handleBroughtToFront();

  1800.     grabFocus();

  1801. }

  1802. 

  1803. bool NSViewComponentPeer::windowShouldClose()

  1804. {

  1805.     if (! isValidPeer (this))

  1806.         return YES;

  1807. 

  1808.     handleUserClosingWindow();

  1809.     return NO;

  1810. }

  1811. 

  1812. void NSViewComponentPeer::updateFullscreenStatus()

  1813. {

  1814.     if (hasNativeTitleBar())

  1815.     {

  1816.         const Rectangle<int> screen (getFrameSize().subtractedFrom (component->getParentMonitorArea()));

  1817.         const Rectangle<int> window (component->getScreenBounds());

  1818. 

  1819.         fullScreen = std::abs (screen.getX() - window.getX()) <= 2

  1820.                   && std::abs (screen.getY() - window.getY()) <= 2

  1821.                   && std::abs (screen.getRight() - window.getRight()) <= 2

  1822.                   && std::abs (screen.getBottom() - window.getBottom()) <= 2;

  1823.     }

  1824. }

  1825. 

  1826. void NSViewComponentPeer::redirectMovedOrResized()

  1827. {

  1828.     updateFullscreenStatus();

  1829.     handleMovedOrResized();

  1830. }

  1831. 

  1832. void NSViewComponentPeer::viewMovedToWindow()

  1833. {

  1834.     if (isSharedWindow)

  1835.         window = [view window];

  1836. }

  1837. 

  1838. //==============================================================================

  1839. void Desktop::createMouseInputSources()

  1840. {

  1841.     mouseSources.add (new MouseInputSource (0, true));

  1842. }

  1843. 

  1844. //==============================================================================

  1845. void Desktop::setKioskComponent (Component* kioskModeComponent, bool enableOrDisable, bool allowMenusAndBars)

  1846. {

  1847.    #if defined (MAC_OS_X_VERSION_10_6) && MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_6

  1848.     if (enableOrDisable)

  1849.     {

  1850.         [NSApp setPresentationOptions: (allowMenusAndBars ? (NSApplicationPresentationAutoHideDock | NSApplicationPresentationAutoHideMenuBar)

  1851.                                                           : (NSApplicationPresentationHideDock | NSApplicationPresentationHideMenuBar))];

  1852.         kioskModeComponent->setBounds (Desktop::getInstance().getMainMonitorArea (false));

  1853.     }

  1854.     else

  1855.     {

  1856.         [NSApp setPresentationOptions: NSApplicationPresentationDefault];

  1857.     }

  1858.    #elif JUCE_SUPPORT_CARBON

  1859.     if (enableOrDisable)

  1860.     {

  1861.         SetSystemUIMode (kUIModeAllSuppressed, allowMenusAndBars ? kUIOptionAutoShowMenuBar : 0);

  1862.         kioskModeComponent->setBounds (Desktop::getInstance().getMainMonitorArea (false));

  1863.     }

  1864.     else

  1865.     {

  1866.         SetSystemUIMode (kUIModeNormal, 0);

  1867.     }

  1868.    #else

  1869.     // If you're targeting OSes earlier than 10.6 and want to use this feature,

  1870.     // you'll need to enable JUCE_SUPPORT_CARBON.

  1871.     jassertfalse;

  1872.    #endif

  1873. }

  1874. 

  1875. //==============================================================================

  1876. void NSViewComponentPeer::repaint (const Rectangle<int>& area)

  1877. {

  1878.     if (insideDrawRect)

  1879.     {

  1880.         class AsyncRepaintMessage  : public CallbackMessage

  1881.         {

  1882.         public:

  1883.             AsyncRepaintMessage (NSViewComponentPeer* const peer_, const Rectangle<int>& rect_)

  1884.                 : peer (peer_), rect (rect_)

  1885.             {

  1886.             }

  1887. 

  1888.             void messageCallback()

  1889.             {

  1890.                 if (ComponentPeer::isValidPeer (peer))

  1891.                     peer->repaint (rect);

  1892.             }

  1893. 

  1894.         private:

  1895.             NSViewComponentPeer* const peer;

  1896.             const Rectangle<int> rect;

  1897.         };

  1898. 

  1899.         (new AsyncRepaintMessage (this, area))->post();

  1900.     }

  1901.     else

  1902.     {

  1903.        #if JUCE_OSX_OPENGL_RENDERER

  1904.         if (usingOpenGL)

  1905.             [[view layer] setNeedsDisplayInRect: CGRectMake ((CGFloat) area.getX(), [view frame].size.height - (CGFloat) area.getBottom(),

  1906.                                                              (CGFloat) area.getWidth(), (CGFloat) area.getHeight())];

  1907.         else

  1908.        #endif

  1909.             [view setNeedsDisplayInRect: NSMakeRect ((CGFloat) area.getX(), [view frame].size.height - (CGFloat) area.getBottom(),

  1910.                                                      (CGFloat) area.getWidth(), (CGFloat) area.getHeight())];

  1911.     }

  1912. }

  1913. 

  1914. void NSViewComponentPeer::performAnyPendingRepaintsNow()

  1915. {

  1916.     [view displayIfNeeded];

  1917. }

  1918. 

  1919. ComponentPeer* Component::createNewPeer (int styleFlags, void* windowToAttachTo)

  1920. {

  1921.     return new NSViewComponentPeer (this, styleFlags, (NSView*) windowToAttachTo);

  1922. }

  1923. 

  1924. //==============================================================================

  1925. const int KeyPress::spaceKey        = ' ';

  1926. const int KeyPress::returnKey       = 0x0d;

  1927. const int KeyPress::escapeKey       = 0x1b;

  1928. const int KeyPress::backspaceKey    = 0x7f;

  1929. const int KeyPress::leftKey         = NSLeftArrowFunctionKey;

  1930. const int KeyPress::rightKey        = NSRightArrowFunctionKey;

  1931. const int KeyPress::upKey           = NSUpArrowFunctionKey;

  1932. const int KeyPress::downKey         = NSDownArrowFunctionKey;

  1933. const int KeyPress::pageUpKey       = NSPageUpFunctionKey;

  1934. const int KeyPress::pageDownKey     = NSPageDownFunctionKey;

  1935. const int KeyPress::endKey          = NSEndFunctionKey;

  1936. const int KeyPress::homeKey         = NSHomeFunctionKey;

  1937. const int KeyPress::deleteKey       = NSDeleteFunctionKey;

  1938. const int KeyPress::insertKey       = -1;

  1939. const int KeyPress::tabKey          = 9;

  1940. const int KeyPress::F1Key           = NSF1FunctionKey;

  1941. const int KeyPress::F2Key           = NSF2FunctionKey;

  1942. const int KeyPress::F3Key           = NSF3FunctionKey;

  1943. const int KeyPress::F4Key           = NSF4FunctionKey;

  1944. const int KeyPress::F5Key           = NSF5FunctionKey;

  1945. const int KeyPress::F6Key           = NSF6FunctionKey;

  1946. const int KeyPress::F7Key           = NSF7FunctionKey;

  1947. const int KeyPress::F8Key           = NSF8FunctionKey;

  1948. const int KeyPress::F9Key           = NSF9FunctionKey;

  1949. const int KeyPress::F10Key          = NSF10FunctionKey;

  1950. const int KeyPress::F11Key          = NSF1FunctionKey;

  1951. const int KeyPress::F12Key          = NSF12FunctionKey;

  1952. const int KeyPress::F13Key          = NSF13FunctionKey;

  1953. const int KeyPress::F14Key          = NSF14FunctionKey;

  1954. const int KeyPress::F15Key          = NSF15FunctionKey;

  1955. const int KeyPress::F16Key          = NSF16FunctionKey;

  1956. const int KeyPress::numberPad0      = 0x30020;

  1957. const int KeyPress::numberPad1      = 0x30021;

  1958. const int KeyPress::numberPad2      = 0x30022;

  1959. const int KeyPress::numberPad3      = 0x30023;

  1960. const int KeyPress::numberPad4      = 0x30024;

  1961. const int KeyPress::numberPad5      = 0x30025;

  1962. const int KeyPress::numberPad6      = 0x30026;

  1963. const int KeyPress::numberPad7      = 0x30027;

  1964. const int KeyPress::numberPad8      = 0x30028;

  1965. const int KeyPress::numberPad9      = 0x30029;

  1966. const int KeyPress::numberPadAdd            = 0x3002a;

  1967. const int KeyPress::numberPadSubtract       = 0x3002b;

  1968. const int KeyPress::numberPadMultiply       = 0x3002c;

  1969. const int KeyPress::numberPadDivide         = 0x3002d;

  1970. const int KeyPress::numberPadSeparator      = 0x3002e;

  1971. const int KeyPress::numberPadDecimalPoint   = 0x3002f;

  1972. const int KeyPress::numberPadEquals         = 0x30030;

  1973. const int KeyPress::numberPadDelete         = 0x30031;

  1974. const int KeyPress::playKey         = 0x30000;

  1975. const int KeyPress::stopKey         = 0x30001;

  1976. const int KeyPress::fastForwardKey  = 0x30002;

  1977. const int KeyPress::rewindKey       = 0x30003;