DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
6555 Commits
9 Branches
519MB
Tree: 4b96ffbf6f
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '4b96ffbf6f'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

1427 lines
63KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2015 - ROLI Ltd.

  6. 

  7.    Permission is granted to use this software under the terms of either:

  8.    a) the GPL v2 (or any later version)

  9.    b) the Affero GPL v3

  10. 

  11.    Details of these licenses can be found at: www.gnu.org/licenses

  12. 

  13.    JUCE is distributed in the hope that it will be useful, but WITHOUT ANY

  14.    WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR

  15.    A PARTICULAR PURPOSE.  See the GNU General Public License for more details.

  16. 

  17.    ------------------------------------------------------------------------------

  18. 

  19.    To release a closed-source product which uses JUCE, commercial licenses are

  20.    available: visit www.juce.com for more information.

  21. 

  22.   ==============================================================================

  23. */

  24. 

  25. #include "../../juce_core/system/juce_TargetPlatform.h"

  26. #include "../utility/juce_CheckSettingMacros.h"

  27. 

  28. #if JucePlugin_Build_AUv3

  29. 

  30. #import <CoreAudioKit/CoreAudioKit.h>

  31. #import <AudioToolbox/AudioToolbox.h>

  32. #import <AVFoundation/AVFoundation.h>

  33. 

  34. #if JUCE_MAC

  35.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  36.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  37.  #endif

  38. #endif

  39. 

  40. #if JUCE_IOS

  41.  #if (! defined __IPHONE_OS_VERSION_MIN_REQUIRED) || (! defined __IPHONE_9_0) || (__IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_9_0)

  42.   #error AUv3 needs Deployment Target iOS 9.0 or higher to compile

  43.  #endif

  44. #endif

  45. 

  46. #ifndef __OBJC2__

  47.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  48. #endif

  49. 

  50. #include "../utility/juce_IncludeSystemHeaders.h"

  51. #include "../utility/juce_IncludeModuleHeaders.h"

  52. #include "../../juce_core/native/juce_osx_ObjCHelpers.h"

  53. #include "../../juce_graphics/native/juce_mac_CoreGraphicsHelpers.h"

  54. 

  55. #include "juce_AU_Shared.h"

  56. 

  57. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  58. 

  59. #if ! JUCE_COMPILER_SUPPORTS_VARIADIC_TEMPLATES

  60.  #error AUv3 wrapper requires variadic template support

  61. #endif

  62. 

  63. #if JUCE_IOS

  64.  #define JUCE_IOS_MAC_VIEW  UIView

  65. #else

  66.  #define JUCE_IOS_MAC_VIEW  NSView

  67. #endif

  68. 

  69. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  70. 

  71. #pragma clang diagnostic push

  72. #pragma clang diagnostic ignored "-Wnullability-completeness"

  73. 

  74. // TODO: ask Timur: use SFINAE to automatically generate this for all NSObjects

  75. template <> struct ContainerDeletePolicy<AUAudioUnitBusArray>                   { static void destroy (NSObject* o) { [o release]; } };

  76. template <> struct ContainerDeletePolicy<AUParameterTree>                       { static void destroy (NSObject* o) { [o release]; } };

  77. template <> struct ContainerDeletePolicy<NSMutableArray<AUParameterNode *> >    { static void destroy (NSObject* o) { [o release]; } };

  78. template <> struct ContainerDeletePolicy<AUParameter>                           { static void destroy (NSObject* o) { [o release]; } };

  79. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitBus*> >      { static void destroy (NSObject* o) { [o release]; } };

  80. template <> struct ContainerDeletePolicy<AUAudioUnitBus>                        { static void destroy (NSObject* o) { [o release]; } };

  81. template <> struct ContainerDeletePolicy<AVAudioFormat>                         { static void destroy (NSObject* o) { [o release]; } };

  82. template <> struct ContainerDeletePolicy<AVAudioPCMBuffer>                      { static void destroy (NSObject* o) { [o release]; } };

  83. template <> struct ContainerDeletePolicy<NSMutableArray<NSNumber*> >            { static void destroy (NSObject* o) { [o release]; } };

  84. template <> struct ContainerDeletePolicy<NSNumber>                              { static void destroy (NSObject* o) { [o release]; } };

  85. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitPreset*> >   { static void destroy (NSObject* o) { [o release]; } };

  86. template <> struct ContainerDeletePolicy<AUAudioUnitPreset>                     { static void destroy (NSObject* o) { [o release]; } };

  87. 

  88. //==============================================================================

  89. struct AudioProcessorHolder  : public ReferenceCountedObject

  90. {

  91.     AudioProcessorHolder() {}

  92.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  93.     AudioProcessor& operator*() noexcept        { return *processor; }

  94.     AudioProcessor* operator->() noexcept       { return processor; }

  95.     AudioProcessor* get() noexcept              { return processor; }

  96. 

  97.     typedef ReferenceCountedObjectPtr<AudioProcessorHolder> Ptr;

  98. 

  99. private:

  100.     ScopedPointer<AudioProcessor> processor;

  101. 

  102.     AudioProcessorHolder& operator= (AudioProcessor*) JUCE_DELETED_FUNCTION;

  103.     AudioProcessorHolder (AudioProcessorHolder&) JUCE_DELETED_FUNCTION;

  104.     AudioProcessorHolder& operator= (AudioProcessorHolder&) JUCE_DELETED_FUNCTION;

  105. };

  106. 

  107. //==============================================================================

  108. class JuceAudioUnitv3Base

  109. {

  110. public:

  111.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  112.                          AudioComponentInstantiationOptions options,

  113.                          NSError** error)

  114.        #pragma clang diagnostic push

  115.        #pragma clang diagnostic ignored "-Wobjc-method-access"

  116.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  117.                                                                         options: options

  118.                                                                           error: error

  119.                                                                       juceClass: this])

  120.        #pragma clang diagnostic pop

  121.     {

  122.     }

  123. 

  124.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  125.     {

  126.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  127.         initialiseJuce_GUI();

  128.     }

  129. 

  130.     virtual ~JuceAudioUnitv3Base() {}

  131. 

  132.     //==============================================================================

  133.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  134.     virtual int getVirtualMIDICableCount()                                 { return 0; }

  135.     virtual void reset()                                                   {}

  136.     virtual bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* bus)

  137.     {

  138.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  139.         return (ObjCMsgSendSuper<BOOL, AVAudioFormat*,AUAudioUnitBus* > (&s, @selector (shouldChangeToFormat:forBus:), format, bus) == YES);

  140.     }

  141. 

  142.     virtual AUAudioUnitPreset* getCurrentPreset()                          { return nullptr; }

  143.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      {}

  144.     virtual NSTimeInterval getLatency()                                    { return 0.0; }

  145.     virtual NSTimeInterval getTailTime()                                   { return 0.0; }

  146.     virtual bool getCanProcessInPlace()                                    { return false; }

  147.     virtual bool getRenderingOffline()                                     { return false; }

  148. 

  149.     //==============================================================================

  150.     virtual AUAudioUnitBusArray* getInputBusses()          = 0;

  151.     virtual AUAudioUnitBusArray* getOutputBusses()         = 0;

  152.     virtual AUParameterTree* getParameterTree()            = 0;

  153.     virtual AUInternalRenderBlock getInternalRenderBlock() = 0;

  154.     virtual void setRenderingOffline (bool offline)        = 0;

  155.     virtual NSArray<NSNumber*> *getChannelCapabilities()   = 0;

  156. 

  157.     //==============================================================================

  158.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)

  159.     {

  160.         return [NSArray<NSNumber*> array];

  161.     }

  162. 

  163.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()

  164.     {

  165.         return [NSArray<AUAudioUnitPreset*> array];

  166.     }

  167. 

  168.     virtual NSDictionary<NSString*, id>* getFullState()

  169.     {

  170.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  171.         return ObjCMsgSendSuper<NSDictionary<NSString*, id>*> (&s, @selector (fullState));

  172.     }

  173. 

  174.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  175.     {

  176.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  177.         ObjCMsgSendSuper<void, NSDictionary<NSString*, id>*> (&s, @selector (setFullState:), state);

  178.     }

  179. 

  180.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  181.     {

  182.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  183.         return (ObjCMsgSendSuper<BOOL, NSError**> (&s, @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  184.     }

  185. 

  186.     virtual void deallocateRenderResources()

  187.     {

  188.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  189.         ObjCMsgSendSuper<void> (&s, @selector (deallocateRenderResources));

  190.     }

  191. 

  192. private:

  193.     struct Class  : public ObjCClass<AUAudioUnit>

  194.     {

  195.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  196.         {

  197.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  198. 

  199.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  200.                        initWithComponentDescriptionAndJuceClass, "@@:",

  201.                        @encode (AudioComponentDescription),

  202.                        @encode (AudioComponentInstantiationOptions), "^@@");

  203. 

  204.             addMethod (@selector (initWithComponentDescription:options:error:),

  205.                        initWithComponentDescription, "@@:",

  206.                        @encode (AudioComponentDescription),

  207.                        @encode (AudioComponentInstantiationOptions), "^@");

  208. 

  209.             addMethod (@selector (dealloc),                                 dealloc,                               "v@:");

  210.             addMethod (@selector (inputBusses),                             getInputBusses,                        "@@:");

  211.             addMethod (@selector (outputBusses),                            getOutputBusses,                       "@@:");

  212.             addMethod (@selector (parameterTree),                           getParameterTree,                      "@@:");

  213.             addMethod (@selector (deallocateRenderResources),               deallocateRenderResources,             "v@:");

  214.             addMethod (@selector (reset),                                   reset,                                 "v@:");

  215.             addMethod (@selector (shouldChangeToFormat:forBus:),            shouldChangeToFormat,                  "B@:@@");

  216.             addMethod (@selector (factoryPresets),                          getFactoryPresets,                     "@@:");

  217.             addMethod (@selector (currentPreset),                           getCurrentPreset,                      "@@:");

  218.             addMethod (@selector (setCurrentPreset:),                       setCurrentPreset,                      "v@:@");

  219.             addMethod (@selector (fullState),                               getFullState,                          "@@:");

  220.             addMethod (@selector (setFullState:),                           setFullState,                          "v@:@");

  221.             addMethod (@selector (channelCapabilities),                     getChannelCapabilities,                "@@:");

  222.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "B@:^@");

  223. 

  224.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  225.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  226. 

  227. 

  228.             addMethod (@selector (internalRenderBlock),   getInternalRenderBlock,   @encode (AUInternalRenderBlock), "@:");

  229.             addMethod (@selector (virtualMIDICableCount), getVirtualMIDICableCount, @encode (NSInteger),             "@:");

  230.             addMethod (@selector (latency),               getLatency,               @encode (NSTimeInterval),        "@:");

  231.             addMethod (@selector (tailTime),              getTailTime,              @encode (NSTimeInterval),        "@:");

  232.             addMethod (@selector (canProcessInPlace),     getCanProcessInPlace,     @encode (BOOL),                  "@:");

  233.             addMethod (@selector (isRenderingOffline),    getRenderingOffline,      @encode (BOOL),                  "@:");

  234. 

  235.             registerClass();

  236.         }

  237. 

  238.         //==============================================================================

  239.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  240.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  241. 

  242.         //==============================================================================

  243.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  244.         {

  245.             AUAudioUnit* self = _self;

  246. 

  247.             objc_super s = { self, [AUAudioUnit class] };

  248.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  249.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  250. 

  251.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  252. 

  253.             setThis (self, juceAU);

  254.             return self;

  255.         }

  256. 

  257.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  258.         {

  259.             AUAudioUnit* self = _self;

  260. 

  261.             objc_super s = { self, [AUAudioUnit class] };

  262.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  263.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  264. 

  265. 

  266.             setThis (self, juceAU);

  267.             return self;

  268.         }

  269. 

  270.         static void dealloc (id self, SEL)                                                          { delete _this (self); }

  271.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  272.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  273.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  274.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  275.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  276.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  277.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  278.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  279.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  280.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  281.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  282.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  283.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  284.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  285.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  286.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  287.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  288.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  289.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  290.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  291.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  292.     };

  293. 

  294.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  295. 

  296.     //==============================================================================

  297.     static Class audioUnitObjCClass;

  298. 

  299. protected:

  300.     AUAudioUnit* au;

  301. };

  302. 

  303. //==============================================================================

  304. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  305. 

  306. //==============================================================================

  307. //=========================== The actual AudioUnit =============================

  308. //==============================================================================

  309. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  310.                          public AudioProcessorListener,

  311.                          public AudioPlayHead

  312. {

  313. public:

  314.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  315.                      const AudioComponentDescription& descr,

  316.                      AudioComponentInstantiationOptions options,

  317.                      NSError** error)

  318.         : JuceAudioUnitv3Base (descr, options, error),

  319.           processorHolder (processor),

  320.           mapper (*processorHolder->get())

  321.     {

  322.         init();

  323.     }

  324. 

  325.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  326.         : JuceAudioUnitv3Base (audioUnit),

  327.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  328.           mapper (*processorHolder->get())

  329.     {

  330.         init();

  331.     }

  332. 

  333.     ~JuceAudioUnitv3()

  334.     {

  335.         auto& processor = getAudioProcessor();

  336.         processor.removeListener (this);

  337. 

  338.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  339.             processor.editorBeingDeleted (editor);

  340. 

  341.         if (editorObserverToken != nullptr)

  342.         {

  343.             [paramTree removeParameterObserver: editorObserverToken];

  344.             editorObserverToken = nullptr;

  345.         }

  346.     }

  347. 

  348.     //==============================================================================

  349.     void init()

  350.     {

  351.         AudioProcessor& processor = getAudioProcessor();

  352.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  353. 

  354.        #ifdef JucePlugin_PreferredChannelConfigurations

  355.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  356.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  357. 

  358.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  359.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  360. 

  361.         Array<AUChannelInfo> channelInfos;

  362. 

  363.         for (int i = 0; i < numConfigs; ++i)

  364.         {

  365.             AUChannelInfo channelInfo;

  366. 

  367.             channelInfo.inChannels  = configs[i][0];

  368.             channelInfo.outChannels = configs[i][1];

  369. 

  370.             channelInfos.add (channelInfo);

  371.         }

  372.        #else

  373.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  374.        #endif

  375. 

  376.         processor.setPlayHead (this);

  377. 

  378.         totalInChannels  = processor.getTotalNumInputChannels();

  379.         totalOutChannels = processor.getTotalNumOutputChannels();

  380. 

  381.         {

  382.             channelCapabilities = [[NSMutableArray<NSNumber*> alloc] init];

  383. 

  384. 

  385.             for (int i = 0; i < channelInfos.size(); ++i)

  386.             {

  387.                 AUChannelInfo& info = channelInfos.getReference (i);

  388. 

  389.                 [channelCapabilities addObject: [NSNumber numberWithInteger: info.inChannels]];

  390.                 [channelCapabilities addObject: [NSNumber numberWithInteger: info.outChannels]];

  391.             }

  392.         }

  393. 

  394.         editorObserverToken = nullptr;

  395.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  396. 

  397.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  398.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  399.         processor.addListener (this);

  400. 

  401.         addParameters();

  402.         addPresets();

  403. 

  404.         addAudioUnitBusses (true);

  405.         addAudioUnitBusses (false);

  406.     }

  407. 

  408.     //==============================================================================

  409.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  410.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses;  }

  411.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses; }

  412.     AUParameterTree*     getParameterTree() override          { return paramTree; }

  413.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  414.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override { return factoryPresets; }

  415.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  416.     void setRenderingOffline (bool offline) override          { getAudioProcessor().setNonRealtime (offline); }

  417.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities; }

  418. 

  419.     //==============================================================================

  420.     AUAudioUnitPreset* getCurrentPreset() override

  421.     {

  422.         const int n = static_cast<int> ([factoryPresets count]);

  423.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  424. 

  425.         if (idx < n)

  426.             return [factoryPresets objectAtIndex:static_cast<unsigned int> (idx)];

  427. 

  428.         return nullptr;

  429.     }

  430. 

  431.     void setCurrentPreset(AUAudioUnitPreset* preset) override

  432.     {

  433.         const int n = static_cast<int> ([factoryPresets count]);

  434.         const int idx = static_cast<int> ([preset number]);

  435. 

  436.         if (isPositiveAndBelow (idx, n))

  437.             getAudioProcessor().setCurrentProgram (idx);

  438.     }

  439. 

  440.     //==============================================================================

  441.     NSDictionary<NSString*, id>* getFullState() override

  442.     {

  443.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  444. 

  445.         {

  446.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  447. 

  448.             if (superRetval != nullptr)

  449.                 [retval addEntriesFromDictionary:superRetval];

  450.         }

  451. 

  452.         juce::MemoryBlock state;

  453.         getAudioProcessor().getCurrentProgramStateInformation (state);

  454. 

  455.         if (state.getSize() > 0)

  456.         {

  457.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  458.                                                       length: state.getSize()];

  459. 

  460.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  461. 

  462.             [retval setObject: ourState

  463.                        forKey: nsKey];

  464. 

  465.             [nsKey    release];

  466.             [ourState release];

  467.         }

  468. 

  469.         return [retval autorelease];

  470.     }

  471. 

  472.     void setFullState (NSDictionary<NSString*, id>* state) override

  473.     {

  474.         if (state == nullptr)

  475.             return;

  476. 

  477.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  478.         [modifiedState addEntriesFromDictionary: state];

  479. 

  480.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  481.         [modifiedState removeObjectForKey: nsPresetKey];

  482.         [nsPresetKey release];

  483. 

  484.         JuceAudioUnitv3Base::setFullState (modifiedState);

  485. 

  486.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  487.         NSObject* obj = [modifiedState objectForKey: nsKey];

  488.         [nsKey release];

  489. 

  490.         if (obj != nullptr)

  491.         {

  492.             if ([obj isKindOfClass:[NSData class]])

  493.             {

  494.                 NSData* data = reinterpret_cast<NSData*> (obj);

  495.                 const int numBytes = static_cast<int> ([data length]);

  496.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  497. 

  498.                 if (numBytes > 0)

  499.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  500.             }

  501.         }

  502. 

  503.         [modifiedState release];

  504.     }

  505. 

  506.     //==============================================================================

  507.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  508.     {

  509.         const int n = static_cast<int> ([overviewParams count]);

  510. 

  511.         if (count >= n)

  512.             return overviewParams;

  513. 

  514.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams];

  515.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  516. 

  517.         return [retval autorelease];

  518.     }

  519. 

  520.     int getVirtualMIDICableCount() override

  521.     {

  522.        #if JucePlugin_WantsMidiInput

  523.         return 1;

  524.        #else

  525.         return 0;

  526.        #endif

  527.     }

  528. 

  529.     //==============================================================================

  530.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  531.     {

  532.         AudioProcessor& processor = getAudioProcessor();

  533.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  534. 

  535.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  536.             return false;

  537. 

  538.         if (outError != nullptr)

  539.             *outError = nullptr;

  540. 

  541.         AudioProcessor::BusesLayout layouts;

  542.         for (int dir = 0; dir < 2; ++dir)

  543.         {

  544.             const bool isInput = (dir == 0);

  545.             const int n = processor.getBusCount (isInput);

  546.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  547. 

  548.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  549.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  550. 

  551.             for (int busIdx = 0; busIdx < n; ++busIdx)

  552.             {

  553.                 AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx);

  554.                 AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  555. 

  556.                 AudioChannelSet newLayout;

  557.                 if (const AVAudioChannelLayout* layout = [format channelLayout])

  558.                     newLayout = AudioUnitHelpers::CALayoutTagToChannelSet ([layout layoutTag]);

  559.                 else

  560.                     newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  561. 

  562.                 if (newLayout.isDisabled())

  563.                     return false;

  564. 

  565.                 channelSets.add (newLayout);

  566.             }

  567.         }

  568. 

  569.        #ifdef JucePlugin_PreferredChannelConfigurations

  570.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  571. 

  572.         if (! AudioProcessor::containsLayout (layouts, configs))

  573.         {

  574.             if (outError != nullptr)

  575.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  576. 

  577.             return false;

  578.         }

  579.        #endif

  580. 

  581.         if (! processor.setBusesLayout (layouts))

  582.         {

  583.             if (outError != nullptr)

  584.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  585. 

  586.             return false;

  587.         }

  588. 

  589.         totalInChannels  = processor.getTotalNumInputChannels();

  590.         totalOutChannels = processor.getTotalNumOutputChannels();

  591. 

  592.         allocateBusBuffer (true);

  593.         allocateBusBuffer (false);

  594. 

  595.         mapper.alloc();

  596. 

  597.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  598. 

  599.         double sampleRate = (jmax (processor.getBusCount (true), processor.getBusCount (false)) > 0 ?

  600.                              [[[([inputBusses count] > 0 ? inputBusses : outputBusses) objectAtIndexedSubscript: 0] format] sampleRate] : 44100.0);

  601. 

  602.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  603.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  604. 

  605.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  606.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  607.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  608. 

  609.         reset();

  610. 

  611.         return true;

  612.     }

  613. 

  614.     void deallocateRenderResources() override

  615.     {

  616.         hostMusicalContextCallback = nullptr;

  617.         hostTransportStateCallback = nullptr;

  618. 

  619.         getAudioProcessor().releaseResources();

  620.         audioBuffer.release();

  621. 

  622.         inBusBuffers. clear();

  623.         outBusBuffers.clear();

  624. 

  625.         mapper.release();

  626. 

  627.         JuceAudioUnitv3Base::deallocateRenderResources();

  628.     }

  629. 

  630.     void reset() override

  631.     {

  632.         midiMessages.clear();

  633.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  634.     }

  635. 

  636.     //==============================================================================

  637.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  638.     {

  639.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  640.         const int busIdx = static_cast<int> ([auBus index]);

  641.         const int newNumChannels = static_cast<int> ([format channelCount]);

  642. 

  643.         AudioProcessor& processor = getAudioProcessor();

  644. 

  645.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  646.         {

  647.           #ifdef JucePlugin_PreferredChannelConfigurations

  648.             ignoreUnused (bus);

  649. 

  650.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  651. 

  652.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  653.                 return false;

  654.           #else

  655.             if (const AVAudioChannelLayout* layout = [format channelLayout])

  656.             {

  657.                 AudioChannelSet newLayout = AudioUnitHelpers::CALayoutTagToChannelSet ([layout layoutTag]);

  658. 

  659.                 if (newLayout.size() != newNumChannels)

  660.                     return false;

  661. 

  662.                 if (! bus->isLayoutSupported (newLayout))

  663.                     return false;

  664.             }

  665.             else

  666.             {

  667.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  668.                     return false;

  669.             }

  670.            #endif

  671. 

  672.             return true;

  673.         }

  674. 

  675.         return false;

  676.     }

  677. 

  678.     //==============================================================================

  679.     void audioProcessorChanged (AudioProcessor* processor) override

  680.     {

  681.         ignoreUnused (processor);

  682. 

  683.         [au willChangeValueForKey: @"allParameterValues"];

  684.         [au didChangeValueForKey: @"allParameterValues"];

  685.     }

  686. 

  687.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  688.     {

  689.         if (isPositiveAndBelow (idx, getAudioProcessor().getNumParameters()))

  690.         {

  691.             if (AUParameter* param = [paramTree parameterWithAddress: getAUParameterAddressForIndex (idx)])

  692.             {

  693.                 if (editorObserverToken != nullptr)

  694.                     [param setValue: newValue  originator: editorObserverToken];

  695.                 else

  696.                     [param setValue: newValue];

  697.             }

  698.         }

  699.     }

  700. 

  701.     //==============================================================================

  702.     NSTimeInterval getLatency() override

  703.     {

  704.         auto& p = getAudioProcessor();

  705.         return p.getLatencySamples() / p.getSampleRate();

  706.     }

  707. 

  708.     NSTimeInterval getTailTime() override       { return getAudioProcessor().getTailLengthSeconds(); }

  709. 

  710.     //==============================================================================

  711.     bool getCurrentPosition (CurrentPositionInfo& info) override

  712.     {

  713.         bool musicContextCallSucceeded = false;

  714.         bool transportStateCallSucceeded = false;

  715. 

  716.         info = lastAudioHead;

  717.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  718.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  719. 

  720.         switch (lastTimeStamp.mSMPTETime.mType)

  721.         {

  722.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24; break;

  723.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25; break;

  724.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop; break;

  725.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30; break;

  726.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997; break;

  727.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  728.             default:                        info.frameRate = AudioPlayHead::fpsUnknown; break;

  729.         }

  730. 

  731.         double num;

  732.         NSInteger den;

  733.         NSInteger outDeltaSampleOffsetToNextBeat;

  734.         double outCurrentMeasureDownBeat, bpm;

  735.         double ppqPosition;

  736. 

  737.         if (hostMusicalContextCallback != nullptr)

  738.         {

  739.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  740. 

  741.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  742.             {

  743.                 musicContextCallSucceeded = true;

  744. 

  745.                 info.timeSigNumerator   = (int) num;

  746.                 info.timeSigDenominator = (int) den;

  747.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  748.                 info.bpm = bpm;

  749.                 info.ppqPosition = ppqPosition;

  750.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  751.             }

  752.         }

  753. 

  754.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  755.         AUHostTransportStateFlags flags;

  756. 

  757.         if (hostTransportStateCallback != nullptr)

  758.         {

  759.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  760. 

  761.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  762.             {

  763.                 transportStateCallSucceeded = true;

  764. 

  765.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  766.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  767.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  768.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  769.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  770.                 info.ppqLoopStart   = outCycleStartBeat;

  771.                 info.ppqLoopEnd     = outCycleEndBeat;

  772.             }

  773.         }

  774. 

  775.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  776.             lastAudioHead = info;

  777. 

  778.         return true;

  779.     }

  780. 

  781. private:

  782.     //==============================================================================

  783.     struct BusBuffer

  784.     {

  785.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  786.             : auBus (bus), bufferList (nullptr),

  787.               maxFrames (maxFramesPerBuffer),

  788.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  789.               isInterleaved ([[auBus format] isInterleaved])

  790.         {

  791.             alloc();

  792.         }

  793. 

  794.         //==============================================================================

  795.         void alloc()

  796.         {

  797.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  798.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  799.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  800.             jassert (bytes > 0);

  801. 

  802.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  803.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  804. 

  805.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  806.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  807.         }

  808. 

  809.         void dealloc()

  810.         {

  811.             bufferList = nullptr;

  812.             bufferListStorage.free();

  813.             scratchBuffer.setSize (0, 0);

  814.         }

  815. 

  816.         //==============================================================================

  817.         int numChannels() const noexcept                { return numberOfChannels; }

  818.         bool interleaved() const noexcept               { return isInterleaved; }

  819.         AudioBufferList* get() const noexcept           { return bufferList; }

  820. 

  821.         //==============================================================================

  822.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  823.         {

  824.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  825.             const bool isCompatible = isCompatibleWith (other);

  826. 

  827.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  828. 

  829.             for (int i = 0; i < numBuffers; ++i)

  830.             {

  831.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  832.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  833.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  834.                                                               : scratchBuffer.getWritePointer (i));

  835.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  836.             }

  837.         }

  838. 

  839.         //==============================================================================

  840.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  841.         {

  842.             if (other == nullptr)

  843.                 return false;

  844. 

  845.             if (other->mNumberBuffers > 0)

  846.             {

  847.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  848.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  849.                                                                              : other->mNumberBuffers);

  850. 

  851.                 return otherInterleaved == isInterleaved

  852.                     && numberOfChannels == otherChannels;

  853.             }

  854. 

  855.             return numberOfChannels == 0;

  856.         }

  857. 

  858.     private:

  859.         AUAudioUnitBus* auBus;

  860.         HeapBlock<char> bufferListStorage;

  861.         AudioBufferList* bufferList;

  862.         int maxFrames, numberOfChannels;

  863.         bool isInterleaved;

  864.         AudioSampleBuffer scratchBuffer;

  865.     };

  866. 

  867.     //==============================================================================

  868.     void addAudioUnitBusses (bool isInput)

  869.     {

  870.         ScopedPointer<NSMutableArray<AUAudioUnitBus*> > array = [[NSMutableArray<AUAudioUnitBus*> alloc] init];

  871.         AudioProcessor& processor = getAudioProcessor();

  872.         const int n = processor.getBusCount (isInput);

  873. 

  874.         for (int i = 0; i < n; ++i)

  875.         {

  876.             ScopedPointer<AUAudioUnitBus> audioUnitBus;

  877. 

  878.             {

  879.                 ScopedPointer<AVAudioFormat> defaultFormat = [[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  880.                                                                                                             channels: static_cast<AVAudioChannelCount> (processor.getChannelCountOfBus (isInput, i))];

  881. 

  882.                 audioUnitBus = [[AUAudioUnitBus alloc] initWithFormat: defaultFormat

  883.                                                                 error: nullptr];

  884.             }

  885. 

  886.             [array addObject: audioUnitBus];

  887.         }

  888. 

  889.         (isInput ? inputBusses : outputBusses) = [[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  890.                                                                                         busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  891.                                                                                          busses: array];

  892.     }

  893. 

  894.     void addParameters()

  895.     {

  896.         ScopedPointer<NSMutableArray<AUParameterNode*> > params = [[NSMutableArray<AUParameterNode*> alloc] init];

  897. 

  898.         paramObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  899.         paramProvider = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  900. 

  901.         overviewParams = [[NSMutableArray<NSNumber*> alloc] init];

  902. 

  903.         auto& processor = getAudioProcessor();

  904.         const int n = processor.getNumParameters();

  905. 

  906.        #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  907.         // check if all parameters are managed?

  908.         usingManagedParameter = (processor.getParameters().size() == processor.getNumParameters());

  909.        #endif

  910. 

  911.         for (int idx = 0; idx < n; ++idx)

  912.         {

  913.             const String identifier (idx);

  914.             const String name = processor.getParameterName (idx);

  915. 

  916.             AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  917.                                                       | kAudioUnitParameterFlag_IsReadable

  918.                                                       | kAudioUnitParameterFlag_HasCFNameString

  919.                                                       | kAudioUnitParameterFlag_ValuesHaveStrings);

  920. 

  921.            #if JucePlugin_AUHighResolutionParameters

  922.             flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  923.            #endif

  924. 

  925.             // set whether the param is automatable (unnamed parameters aren't allowed to be automated)

  926.             if (name.isEmpty() || ! processor.isParameterAutomatable (idx))

  927.                 flags |= kAudioUnitParameterFlag_NonRealTime;

  928. 

  929.             if (processor.isMetaParameter (idx))

  930.                 flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  931. 

  932.            #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  933.             AUParameterAddress address = static_cast<AUParameterAddress> (idx);

  934.            #else

  935.             AUParameterAddress address = generateAUParameterAddressForIndex (idx);

  936. 

  937.             // Consider yourself very unlucky if you hit this assertion. The hash code of your

  938.             // parameter ids are not unique.

  939.             jassert (! paramMap.contains (static_cast<int64> (address)));

  940. 

  941.             paramAddresses.add (address);

  942.             paramMap.set (static_cast<int64> (address), idx);

  943.           #endif

  944. 

  945.             // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  946. 

  947.             ScopedPointer<AUParameter> param = [[AUParameterTree createParameterWithIdentifier: juceStringToNS (identifier)

  948.                                                                                           name: juceStringToNS (name)

  949.                                                                                        address: address

  950.                                                                                            min: 0.0f

  951.                                                                                            max: 1.0f

  952.                                                                                           unit: kAudioUnitParameterUnit_Generic

  953.                                                                                       unitName: nullptr

  954.                                                                                          flags: flags

  955.                                                                                   valueStrings: nullptr

  956.                                                                            dependentParameters: nullptr] retain];

  957. 

  958.             [params addObject: param];

  959.             [overviewParams addObject: [NSNumber numberWithUnsignedLongLong:address]];

  960.         }

  961. 

  962.         // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  963.         paramTree = [[AUParameterTree createTreeWithChildren: params] retain];

  964. 

  965.         [paramTree setImplementorValueObserver: paramObserver];

  966.         [paramTree setImplementorValueProvider: paramProvider];

  967. 

  968.         if (processor.hasEditor())

  969.         {

  970.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  971.             editorObserverToken = [paramTree tokenByAddingParameterObserver: editorParamObserver];

  972.         }

  973.     }

  974. 

  975.     void addPresets()

  976.     {

  977.         factoryPresets = [[NSMutableArray<AUAudioUnitPreset*> alloc] init];

  978. 

  979.         const int n = getAudioProcessor().getNumPrograms();

  980. 

  981.         for (int idx = 0; idx < n; ++idx)

  982.         {

  983.             String name = getAudioProcessor().getProgramName (idx);

  984. 

  985.             ScopedPointer<AUAudioUnitPreset> preset = [[AUAudioUnitPreset alloc] init];

  986.             [preset setName: juceStringToNS (name)];

  987.             [preset setNumber: static_cast<NSInteger> (idx)];

  988. 

  989.             [factoryPresets addObject: preset];

  990.         }

  991.     }

  992. 

  993.     //==============================================================================

  994.     void allocateBusBuffer (bool isInput)

  995.     {

  996.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  997.         busBuffers.clear();

  998. 

  999.         const int n = getAudioProcessor().getBusCount (isInput);

  1000.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1001. 

  1002.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1003.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses : outputBusses) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1004.                                            static_cast<int> (maxFrames)));

  1005.     }

  1006. 

  1007.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1008.     {

  1009.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1010.         {

  1011.             switch (event->head.eventType)

  1012.             {

  1013.                 case AURenderEventMIDI:

  1014.                 {

  1015.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1016.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1017.                 }

  1018.                 break;

  1019. 

  1020.                 case AURenderEventParameter:

  1021.                 case AURenderEventParameterRamp:

  1022.                 {

  1023.                     const AUParameterEvent& paramEvent = event->parameter;

  1024.                     const int idx = getJuceParameterIndexForAUAddress (paramEvent.parameterAddress);

  1025. 

  1026.                     if (isPositiveAndBelow (idx, numParams))

  1027.                         getAudioProcessor().setParameter (idx, paramEvent.value);

  1028.                 }

  1029.                 break;

  1030. 

  1031.                 default:

  1032.                     break;

  1033.             }

  1034.         }

  1035.     }

  1036. 

  1037.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1038.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1039.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1040.     {

  1041.         auto& processor = getAudioProcessor();

  1042.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1043. 

  1044.         // process params

  1045.         const int numParams = processor.getNumParameters();

  1046.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1047. 

  1048.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1049.         {

  1050.             lastTimeStamp = *timestamp;

  1051. 

  1052.             const int numInputBuses  = inBusBuffers. size();

  1053.             const int numOutputBuses = outBusBuffers.size();

  1054. 

  1055.             // prepare buffers

  1056.             {

  1057.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1058.                 {

  1059.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1060.                      const bool canUseDirectOutput =

  1061.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1062. 

  1063.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1064.                 }

  1065. 

  1066.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1067.                 {

  1068.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1069.                     busBuffer.prepare (frameCount, busIdx < numOutputBuses ? outBusBuffers[busIdx]->get() : nullptr);

  1070.                 }

  1071. 

  1072.                 audioBuffer.reset();

  1073.             }

  1074. 

  1075.             // pull inputs

  1076.             {

  1077.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1078.                 {

  1079.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1080.                     AudioBufferList* buffer = busBuffer.get();

  1081. 

  1082.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1083.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1084. 

  1085.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1086.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1087.                 }

  1088.             }

  1089. 

  1090.             // set buffer pointer to minimize copying

  1091.             {

  1092.                 int chIdx = 0;

  1093. 

  1094.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1095.                 {

  1096.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1097.                     AudioBufferList* buffer = busBuffer.get();

  1098. 

  1099.                     const bool interleaved = busBuffer.interleaved();

  1100.                     const int numChannels = busBuffer.numChannels();

  1101. 

  1102.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1103. 

  1104.                     for (int ch = 0; ch < numChannels; ++ch)

  1105.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1106.                 }

  1107. 

  1108.                 // use input pointers on remaining channels

  1109. 

  1110.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1111.                 {

  1112.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1113. 

  1114.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1115.                     AudioBufferList* buffer = busBuffer.get();

  1116. 

  1117.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1118.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1119.                 }

  1120.             }

  1121. 

  1122.             // copy input

  1123.             {

  1124.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1125.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1126. 

  1127.                 // clear remaining channels

  1128.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1129.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1130.             }

  1131. 

  1132.             // process audio

  1133.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1134.             midiMessages.clear();

  1135.         }

  1136. 

  1137.         // copy back

  1138.         audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1139.                          mapper.get (false, (int) outputBusNumber));

  1140. 

  1141.         return noErr;

  1142.     }

  1143. 

  1144.     void processBlock (AudioSampleBuffer& buffer, MidiBuffer& midiBuffer) noexcept

  1145.     {

  1146.         auto& processor = getAudioProcessor();

  1147.         const ScopedLock sl (processor.getCallbackLock());

  1148. 

  1149.         if (processor.isSuspended())

  1150.             buffer.clear();

  1151.         else if ([au shouldBypassEffect])

  1152.             processor.processBlockBypassed (buffer, midiBuffer);

  1153.         else

  1154.             processor.processBlock (buffer, midiBuffer);

  1155.     }

  1156. 

  1157.     //==============================================================================

  1158.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1159.     {

  1160.         if (param != nullptr)

  1161.         {

  1162.             const int idx = getJuceParameterIndexForAUAddress ([param address]);

  1163.             auto& processor = getAudioProcessor();

  1164. 

  1165.             if (isPositiveAndBelow (idx, processor.getNumParameters()))

  1166.                 processor.setParameter (idx, value);

  1167.         }

  1168.     }

  1169. 

  1170.     AUValue getValue (AUParameter* param)

  1171.     {

  1172.         if (param != nullptr)

  1173.         {

  1174.             const int idx = getJuceParameterIndexForAUAddress ([param address]);

  1175.             auto& processor = getAudioProcessor();

  1176. 

  1177.             if (isPositiveAndBelow (idx, processor.getNumParameters()))

  1178.                 return processor.getParameter (idx);

  1179.         }

  1180. 

  1181.         return 0;

  1182.     }

  1183. 

  1184.     void valueChangedForObserver(AUParameterAddress, AUValue)

  1185.     {

  1186.         // this will have already been handled bny valueChangedFromHost

  1187.     }

  1188. 

  1189.     //==============================================================================

  1190.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1191.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept     { return static_cast<AUParameterAddress> (paramIndex); }

  1192.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept    { return static_cast<int> (address); }

  1193.    #else

  1194.     AUParameterAddress generateAUParameterAddressForIndex (int paramIndex) const

  1195.     {

  1196.         auto& processor = getAudioProcessor();

  1197.         const int n = processor.getNumParameters();

  1198. 

  1199.         if (isPositiveAndBelow (paramIndex, n))

  1200.         {

  1201.             const String& juceParamID = processor.getParameterID (paramIndex);

  1202.             return usingManagedParameter ? static_cast<AUParameterAddress> (juceParamID.hashCode64())

  1203.                                          : static_cast<AUParameterAddress> (juceParamID.getIntValue());

  1204.         }

  1205. 

  1206.         return static_cast<AUParameterAddress> (-1);

  1207.     }

  1208. 

  1209.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1210.     {

  1211.         return usingManagedParameter ? paramAddresses.getReference (paramIndex)

  1212.                                      : static_cast<AUParameterAddress> (paramIndex);

  1213.     }

  1214. 

  1215.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1216.     {

  1217.         return usingManagedParameter ? paramMap[static_cast<int64> (address)]

  1218.                                      : static_cast<int> (address);

  1219.     }

  1220.    #endif

  1221. 

  1222.     //==============================================================================

  1223.     static const double kDefaultSampleRate;

  1224. 

  1225.     AudioProcessorHolder::Ptr processorHolder;

  1226. 

  1227.     int totalInChannels, totalOutChannels;

  1228. 

  1229.     ScopedPointer<AUAudioUnitBusArray> inputBusses;

  1230.     ScopedPointer<AUAudioUnitBusArray> outputBusses;

  1231. 

  1232.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1233.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1234. 

  1235.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1236.     bool usingManagedParameter;

  1237.     Array<AUParameterAddress> paramAddresses;

  1238.     HashMap<int64, int> paramMap;

  1239.    #endif

  1240. 

  1241.     // to avoid recursion on parameter changes, we need to add an

  1242.     // editor observer to do the parameter changes

  1243.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1244.     AUParameterObserverToken editorObserverToken;

  1245. 

  1246.     ScopedPointer<AUParameterTree> paramTree;

  1247.     ScopedPointer<NSMutableArray<NSNumber*> > overviewParams;

  1248.     ScopedPointer<NSMutableArray<NSNumber*> > channelCapabilities;

  1249. 

  1250.     ScopedPointer<NSMutableArray<AUAudioUnitPreset*> > factoryPresets;

  1251. 

  1252.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1253. 

  1254.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1255.     AudioUnitHelpers::ChannelRemapper mapper;

  1256. 

  1257.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1258.     MidiBuffer midiMessages;

  1259. 

  1260.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1261.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1262. 

  1263.     AudioTimeStamp lastTimeStamp;

  1264.     CurrentPositionInfo lastAudioHead;

  1265. };

  1266. 

  1267. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1268. 

  1269. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1270. {

  1271.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1272.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1273. }

  1274. 

  1275. //==============================================================================

  1276. class JuceAUViewController

  1277. {

  1278. public:

  1279. 

  1280.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1281.         : myself (p), processorHolder (nullptr), preferredSize (1.0f, 1.0f)

  1282.     {

  1283.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1284. 

  1285.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1286.         initialiseJuce_GUI();

  1287.     }

  1288. 

  1289.     ~JuceAUViewController()

  1290.     {

  1291.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1292.     }

  1293. 

  1294.     //==============================================================================

  1295.     void loadView()

  1296.     {

  1297.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1298. 

  1299.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1300.         {

  1301.             processorHolder = new AudioProcessorHolder (p);

  1302.             auto& processor = getAudioProcessor();

  1303. 

  1304.             if (processor.hasEditor())

  1305.             {

  1306.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1307.                 {

  1308.                     preferredSize = editor->getBounds();

  1309. 

  1310.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1311.                     [myself setView: view];

  1312. 

  1313.                     editor->setVisible (true);

  1314.                     editor->addToDesktop (0, view);

  1315.                 }

  1316.             }

  1317.         }

  1318.     }

  1319. 

  1320.     void viewDidLayoutSubviews()

  1321.     {

  1322.         if (processorHolder != nullptr && [myself view] != nullptr)

  1323.         {

  1324.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1325.             {

  1326.                 editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1327. 

  1328.                 if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1329.                 {

  1330.                    #if JUCE_IOS

  1331.                     [peerView setNeedsDisplay];

  1332.                    #else

  1333.                     [peerView setNeedsDisplay: YES];

  1334.                    #endif

  1335.                 }

  1336.             }

  1337.         }

  1338.     }

  1339. 

  1340.     CGSize getPreferredContentSize() const

  1341.     {

  1342.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1343.                            static_cast<float> (preferredSize.getHeight()));

  1344.     }

  1345. 

  1346.     //==============================================================================

  1347.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1348.     {

  1349.         AUAudioUnit* retval = nil;

  1350. 

  1351.         if (! MessageManager::getInstance()->isThisTheMessageThread())

  1352.         {

  1353.             WaitableEvent creationEvent;

  1354. 

  1355.             // AUv3 headers say that we may block this thread and that the message thread is guaranteed

  1356.             // to be unblocked

  1357.             struct AUCreator  : public CallbackMessage

  1358.             {

  1359.                 JuceAUViewController& owner;

  1360.                 AudioComponentDescription pDescr;

  1361.                 NSError** pError;

  1362.                 AUAudioUnit*& outAU;

  1363.                 WaitableEvent& e;

  1364. 

  1365.                 AUCreator (JuceAUViewController& parent, const AudioComponentDescription& paramDescr, NSError** paramError,

  1366.                            AUAudioUnit*& outputAU, WaitableEvent& event)

  1367.                     : owner (parent), pDescr (paramDescr), pError (paramError), outAU (outputAU), e (event)

  1368.                 {}

  1369. 

  1370.                 void messageCallback() override

  1371.                 {

  1372.                     outAU = owner.createAudioUnitOnMessageThread (pDescr, pError);

  1373.                     e.signal();

  1374.                 }

  1375.             };

  1376. 

  1377.             (new AUCreator (*this, descr, error, retval, creationEvent))->post();

  1378.             creationEvent.wait (-1);

  1379.         }

  1380.         else

  1381.             retval = createAudioUnitOnMessageThread (descr, error);

  1382. 

  1383.         return [retval autorelease];

  1384.     }

  1385. 

  1386. private:

  1387.     //==============================================================================

  1388.     AUViewController<AUAudioUnitFactory>* myself;

  1389.     AudioProcessorHolder::Ptr processorHolder;

  1390.     Rectangle<int> preferredSize;

  1391. 

  1392.     //==============================================================================

  1393.     AUAudioUnit* createAudioUnitOnMessageThread (const AudioComponentDescription& descr, NSError** error)

  1394.     {

  1395.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1396. 

  1397.         [myself view];  // this will call [view load] and ensure that the AudioProcessor has been instantiated

  1398. 

  1399.         if (processorHolder == nullptr)

  1400.             return nullptr;

  1401. 

  1402.         return (new JuceAudioUnitv3 (processorHolder, descr, 0, error))->getAudioUnit();

  1403.     }

  1404. 

  1405.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder; }

  1406. };

  1407. 

  1408. //==============================================================================

  1409. // necessary glue code

  1410. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  1411. @end

  1412. 

  1413. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  1414. {

  1415.     ScopedPointer<JuceAUViewController> cpp;

  1416. }

  1417. 

  1418. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp = new JuceAUViewController (self); return self;}

  1419. - (void) loadView               { cpp->loadView(); }

  1420. - (AUAudioUnit *)createAudioUnitWithComponentDescription:(AudioComponentDescription)desc error:(NSError **)error { return cpp->createAudioUnit (desc, error); }

  1421. - (CGSize) preferredContentSize { return cpp->getPreferredContentSize(); }

  1422. - (void)viewDidLayoutSubviews   { return cpp->viewDidLayoutSubviews(); }

  1423. @end

  1424. 

  1425. #pragma clang diagnostic pop

  1426. #endif