DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
7447 Commits
9 Branches
8.6GB
Tree: 433a82edee
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '433a82edee'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

1468 lines
65KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2017 - ROLI Ltd.

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 5 End-User License

  11.    Agreement and JUCE 5 Privacy Policy (both updated and effective as of the

  12.    27th April 2017).

  13. 

  14.    End User License Agreement: www.juce.com/juce-5-licence

  15.    Privacy Policy: www.juce.com/juce-5-privacy-policy

  16. 

  17.    Or: You may also use this code under the terms of the GPL v3 (see

  18.    www.gnu.org/licenses).

  19. 

  20.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  21.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  22.    DISCLAIMED.

  23. 

  24.   ==============================================================================

  25. */

  26. 

  27. #include "../../juce_core/system/juce_TargetPlatform.h"

  28. #include "../utility/juce_CheckSettingMacros.h"

  29. 

  30. #if JucePlugin_Build_AUv3

  31. 

  32. #import <CoreAudioKit/CoreAudioKit.h>

  33. #import <AudioToolbox/AudioToolbox.h>

  34. #import <AVFoundation/AVFoundation.h>

  35. 

  36. #if JUCE_MAC

  37.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  38.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  39.  #endif

  40. #endif

  41. 

  42. #if JUCE_IOS

  43.  #if (! defined __IPHONE_OS_VERSION_MIN_REQUIRED) || (! defined __IPHONE_9_0) || (__IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_9_0)

  44.   #error AUv3 needs Deployment Target iOS 9.0 or higher to compile

  45.  #endif

  46. #endif

  47. 

  48. #ifndef __OBJC2__

  49.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  50. #endif

  51. 

  52. #include "../utility/juce_IncludeSystemHeaders.h"

  53. #include "../utility/juce_IncludeModuleHeaders.h"

  54. #include "../../juce_core/native/juce_osx_ObjCHelpers.h"

  55. #include "../../juce_graphics/native/juce_mac_CoreGraphicsHelpers.h"

  56. 

  57. #include "../../juce_audio_processors/format_types/juce_AU_Shared.h"

  58. 

  59. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  60. 

  61. #if ! JUCE_COMPILER_SUPPORTS_VARIADIC_TEMPLATES

  62.  #error AUv3 wrapper requires variadic template support

  63. #endif

  64. 

  65. #if JUCE_IOS

  66.  #define JUCE_IOS_MAC_VIEW  UIView

  67. #else

  68.  #define JUCE_IOS_MAC_VIEW  NSView

  69. #endif

  70. 

  71. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  72. 

  73. #pragma clang diagnostic push

  74. #pragma clang diagnostic ignored "-Wnullability-completeness"

  75. 

  76. // TODO: ask Timur: use SFINAE to automatically generate this for all NSObjects

  77. template <> struct ContainerDeletePolicy<AUAudioUnitBusArray>                   { static void destroy (NSObject* o) { [o release]; } };

  78. template <> struct ContainerDeletePolicy<AUParameterTree>                       { static void destroy (NSObject* o) { [o release]; } };

  79. template <> struct ContainerDeletePolicy<NSMutableArray<AUParameterNode *> >    { static void destroy (NSObject* o) { [o release]; } };

  80. template <> struct ContainerDeletePolicy<AUParameter>                           { static void destroy (NSObject* o) { [o release]; } };

  81. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitBus*> >      { static void destroy (NSObject* o) { [o release]; } };

  82. template <> struct ContainerDeletePolicy<AUAudioUnitBus>                        { static void destroy (NSObject* o) { [o release]; } };

  83. template <> struct ContainerDeletePolicy<AVAudioFormat>                         { static void destroy (NSObject* o) { [o release]; } };

  84. template <> struct ContainerDeletePolicy<AVAudioPCMBuffer>                      { static void destroy (NSObject* o) { [o release]; } };

  85. template <> struct ContainerDeletePolicy<NSMutableArray<NSNumber*> >            { static void destroy (NSObject* o) { [o release]; } };

  86. template <> struct ContainerDeletePolicy<NSNumber>                              { static void destroy (NSObject* o) { [o release]; } };

  87. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitPreset*> >   { static void destroy (NSObject* o) { [o release]; } };

  88. template <> struct ContainerDeletePolicy<AUAudioUnitPreset>                     { static void destroy (NSObject* o) { [o release]; } };

  89. 

  90. //==============================================================================

  91. struct AudioProcessorHolder  : public ReferenceCountedObject

  92. {

  93.     AudioProcessorHolder() {}

  94.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  95.     AudioProcessor& operator*() noexcept        { return *processor; }

  96.     AudioProcessor* operator->() noexcept       { return processor; }

  97.     AudioProcessor* get() noexcept              { return processor; }

  98. 

  99.     typedef ReferenceCountedObjectPtr<AudioProcessorHolder> Ptr;

  100. 

  101. private:

  102.     ScopedPointer<AudioProcessor> processor;

  103. 

  104.     AudioProcessorHolder& operator= (AudioProcessor*) JUCE_DELETED_FUNCTION;

  105.     AudioProcessorHolder (AudioProcessorHolder&) JUCE_DELETED_FUNCTION;

  106.     AudioProcessorHolder& operator= (AudioProcessorHolder&) JUCE_DELETED_FUNCTION;

  107. };

  108. 

  109. //==============================================================================

  110. class JuceAudioUnitv3Base

  111. {

  112. public:

  113.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  114.                          AudioComponentInstantiationOptions options,

  115.                          NSError** error)

  116.        #pragma clang diagnostic push

  117.        #pragma clang diagnostic ignored "-Wobjc-method-access"

  118.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  119.                                                                         options: options

  120.                                                                           error: error

  121.                                                                       juceClass: this])

  122.        #pragma clang diagnostic pop

  123.     {

  124.     }

  125. 

  126.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  127.     {

  128.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  129.         initialiseJuce_GUI();

  130.     }

  131. 

  132.     virtual ~JuceAudioUnitv3Base() {}

  133. 

  134.     //==============================================================================

  135.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  136.     virtual int getVirtualMIDICableCount()                                 { return 0; }

  137.     virtual void reset()                                                   {}

  138.     virtual bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* bus)

  139.     {

  140.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  141.         return (ObjCMsgSendSuper<BOOL, AVAudioFormat*,AUAudioUnitBus* > (&s, @selector (shouldChangeToFormat:forBus:), format, bus) == YES);

  142.     }

  143. 

  144.     virtual AUAudioUnitPreset* getCurrentPreset()                          { return nullptr; }

  145.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      {}

  146.     virtual NSTimeInterval getLatency()                                    { return 0.0; }

  147.     virtual NSTimeInterval getTailTime()                                   { return 0.0; }

  148.     virtual bool getCanProcessInPlace()                                    { return false; }

  149.     virtual bool getRenderingOffline()                                     { return false; }

  150. 

  151.     //==============================================================================

  152.     virtual AUAudioUnitBusArray* getInputBusses()          = 0;

  153.     virtual AUAudioUnitBusArray* getOutputBusses()         = 0;

  154.     virtual AUParameterTree* getParameterTree()            = 0;

  155.     virtual AUInternalRenderBlock getInternalRenderBlock() = 0;

  156.     virtual void setRenderingOffline (bool offline)        = 0;

  157.     virtual NSArray<NSNumber*> *getChannelCapabilities()   = 0;

  158. 

  159.     //==============================================================================

  160.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)

  161.     {

  162.         return [NSArray<NSNumber*> array];

  163.     }

  164. 

  165.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()

  166.     {

  167.         return [NSArray<AUAudioUnitPreset*> array];

  168.     }

  169. 

  170.     virtual NSDictionary<NSString*, id>* getFullState()

  171.     {

  172.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  173.         return ObjCMsgSendSuper<NSDictionary<NSString*, id>*> (&s, @selector (fullState));

  174.     }

  175. 

  176.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  177.     {

  178.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  179.         ObjCMsgSendSuper<void, NSDictionary<NSString*, id>*> (&s, @selector (setFullState:), state);

  180.     }

  181. 

  182.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  183.     {

  184.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  185.         return (ObjCMsgSendSuper<BOOL, NSError**> (&s, @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  186.     }

  187. 

  188.     virtual void deallocateRenderResources()

  189.     {

  190.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  191.         ObjCMsgSendSuper<void> (&s, @selector (deallocateRenderResources));

  192.     }

  193. 

  194. private:

  195.     struct Class  : public ObjCClass<AUAudioUnit>

  196.     {

  197.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  198.         {

  199.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  200. 

  201.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  202.                        initWithComponentDescriptionAndJuceClass, "@@:",

  203.                        @encode (AudioComponentDescription),

  204.                        @encode (AudioComponentInstantiationOptions), "^@@");

  205. 

  206.             addMethod (@selector (initWithComponentDescription:options:error:),

  207.                        initWithComponentDescription, "@@:",

  208.                        @encode (AudioComponentDescription),

  209.                        @encode (AudioComponentInstantiationOptions), "^@");

  210. 

  211.             addMethod (@selector (dealloc),                                 dealloc,                               "v@:");

  212.             addMethod (@selector (inputBusses),                             getInputBusses,                        "@@:");

  213.             addMethod (@selector (outputBusses),                            getOutputBusses,                       "@@:");

  214.             addMethod (@selector (parameterTree),                           getParameterTree,                      "@@:");

  215.             addMethod (@selector (deallocateRenderResources),               deallocateRenderResources,             "v@:");

  216.             addMethod (@selector (reset),                                   reset,                                 "v@:");

  217.             addMethod (@selector (shouldChangeToFormat:forBus:),            shouldChangeToFormat,                  "B@:@@");

  218.             addMethod (@selector (factoryPresets),                          getFactoryPresets,                     "@@:");

  219.             addMethod (@selector (currentPreset),                           getCurrentPreset,                      "@@:");

  220.             addMethod (@selector (setCurrentPreset:),                       setCurrentPreset,                      "v@:@");

  221.             addMethod (@selector (fullState),                               getFullState,                          "@@:");

  222.             addMethod (@selector (setFullState:),                           setFullState,                          "v@:@");

  223.             addMethod (@selector (channelCapabilities),                     getChannelCapabilities,                "@@:");

  224.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "B@:^@");

  225. 

  226.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  227.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  228. 

  229. 

  230.             addMethod (@selector (internalRenderBlock),   getInternalRenderBlock,   @encode (AUInternalRenderBlock), "@:");

  231.             addMethod (@selector (virtualMIDICableCount), getVirtualMIDICableCount, @encode (NSInteger),             "@:");

  232.             addMethod (@selector (latency),               getLatency,               @encode (NSTimeInterval),        "@:");

  233.             addMethod (@selector (tailTime),              getTailTime,              @encode (NSTimeInterval),        "@:");

  234.             addMethod (@selector (canProcessInPlace),     getCanProcessInPlace,     @encode (BOOL),                  "@:");

  235.             addMethod (@selector (isRenderingOffline),    getRenderingOffline,      @encode (BOOL),                  "@:");

  236. 

  237.             registerClass();

  238.         }

  239. 

  240.         //==============================================================================

  241.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  242.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  243. 

  244.         //==============================================================================

  245.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  246.         {

  247.             AUAudioUnit* self = _self;

  248. 

  249.             objc_super s = { self, [AUAudioUnit class] };

  250.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  251.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  252. 

  253.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  254. 

  255.             setThis (self, juceAU);

  256.             return self;

  257.         }

  258. 

  259.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  260.         {

  261.             AUAudioUnit* self = _self;

  262. 

  263.             objc_super s = { self, [AUAudioUnit class] };

  264.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  265.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  266. 

  267. 

  268.             setThis (self, juceAU);

  269.             return self;

  270.         }

  271. 

  272.         static void dealloc (id self, SEL)                                                          { delete _this (self); }

  273.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  274.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  275.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  276.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  277.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  278.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  279.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  280.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  281.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  282.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  283.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  284.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  285.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  286.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  287.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  288.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  289.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  290.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  291.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  292.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  293.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  294.     };

  295. 

  296.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  297. 

  298.     //==============================================================================

  299.     static Class audioUnitObjCClass;

  300. 

  301. protected:

  302.     AUAudioUnit* au;

  303. };

  304. 

  305. //==============================================================================

  306. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  307. 

  308. //==============================================================================

  309. //=========================== The actual AudioUnit =============================

  310. //==============================================================================

  311. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  312.                          public AudioProcessorListener,

  313.                          public AudioPlayHead

  314. {

  315. public:

  316.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  317.                      const AudioComponentDescription& descr,

  318.                      AudioComponentInstantiationOptions options,

  319.                      NSError** error)

  320.         : JuceAudioUnitv3Base (descr, options, error),

  321.           processorHolder (processor),

  322.           mapper (*processorHolder->get())

  323.     {

  324.         init();

  325.     }

  326. 

  327.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  328.         : JuceAudioUnitv3Base (audioUnit),

  329.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  330.           mapper (*processorHolder->get())

  331.     {

  332.         init();

  333.     }

  334. 

  335.     ~JuceAudioUnitv3()

  336.     {

  337.         auto& processor = getAudioProcessor();

  338.         processor.removeListener (this);

  339. 

  340.         removeEditor (processor);

  341. 

  342.         if (editorObserverToken != nullptr)

  343.         {

  344.             [paramTree removeParameterObserver: editorObserverToken];

  345.             editorObserverToken = nullptr;

  346.         }

  347.     }

  348. 

  349.     //==============================================================================

  350.     void init()

  351.     {

  352.         AudioProcessor& processor = getAudioProcessor();

  353.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  354. 

  355.        #ifdef JucePlugin_PreferredChannelConfigurations

  356.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  357.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  358. 

  359.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  360.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  361. 

  362.         Array<AUChannelInfo> channelInfos;

  363. 

  364.         for (int i = 0; i < numConfigs; ++i)

  365.         {

  366.             AUChannelInfo channelInfo;

  367. 

  368.             channelInfo.inChannels  = configs[i][0];

  369.             channelInfo.outChannels = configs[i][1];

  370. 

  371.             channelInfos.add (channelInfo);

  372.         }

  373.        #else

  374.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  375.        #endif

  376. 

  377.         processor.setPlayHead (this);

  378. 

  379.         totalInChannels  = processor.getTotalNumInputChannels();

  380.         totalOutChannels = processor.getTotalNumOutputChannels();

  381. 

  382.         {

  383.             channelCapabilities = [[NSMutableArray<NSNumber*> alloc] init];

  384. 

  385. 

  386.             for (int i = 0; i < channelInfos.size(); ++i)

  387.             {

  388.                 AUChannelInfo& info = channelInfos.getReference (i);

  389. 

  390.                 [channelCapabilities addObject: [NSNumber numberWithInteger: info.inChannels]];

  391.                 [channelCapabilities addObject: [NSNumber numberWithInteger: info.outChannels]];

  392.             }

  393.         }

  394. 

  395.         editorObserverToken = nullptr;

  396.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  397. 

  398.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  399.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  400.         processor.addListener (this);

  401. 

  402.         addParameters();

  403.         addPresets();

  404. 

  405.         addAudioUnitBusses (true);

  406.         addAudioUnitBusses (false);

  407.     }

  408. 

  409.     //==============================================================================

  410.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  411.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses;  }

  412.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses; }

  413.     AUParameterTree*     getParameterTree() override          { return paramTree; }

  414.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  415.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override { return factoryPresets; }

  416.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  417.     void setRenderingOffline (bool offline) override          { getAudioProcessor().setNonRealtime (offline); }

  418.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities; }

  419. 

  420.     //==============================================================================

  421.     AUAudioUnitPreset* getCurrentPreset() override

  422.     {

  423.         const int n = static_cast<int> ([factoryPresets count]);

  424.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  425. 

  426.         if (idx < n)

  427.             return [factoryPresets objectAtIndex:static_cast<unsigned int> (idx)];

  428. 

  429.         return nullptr;

  430.     }

  431. 

  432.     void setCurrentPreset(AUAudioUnitPreset* preset) override

  433.     {

  434.         const int n = static_cast<int> ([factoryPresets count]);

  435.         const int idx = static_cast<int> ([preset number]);

  436. 

  437.         if (isPositiveAndBelow (idx, n))

  438.             getAudioProcessor().setCurrentProgram (idx);

  439.     }

  440. 

  441.     //==============================================================================

  442.     NSDictionary<NSString*, id>* getFullState() override

  443.     {

  444.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  445. 

  446.         {

  447.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  448. 

  449.             if (superRetval != nullptr)

  450.                 [retval addEntriesFromDictionary:superRetval];

  451.         }

  452. 

  453.         juce::MemoryBlock state;

  454.         getAudioProcessor().getCurrentProgramStateInformation (state);

  455. 

  456.         if (state.getSize() > 0)

  457.         {

  458.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  459.                                                       length: state.getSize()];

  460. 

  461.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  462. 

  463.             [retval setObject: ourState

  464.                        forKey: nsKey];

  465. 

  466.             [nsKey    release];

  467.             [ourState release];

  468.         }

  469. 

  470.         return [retval autorelease];

  471.     }

  472. 

  473.     void setFullState (NSDictionary<NSString*, id>* state) override

  474.     {

  475.         if (state == nullptr)

  476.             return;

  477. 

  478.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  479.         [modifiedState addEntriesFromDictionary: state];

  480. 

  481.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  482.         [modifiedState removeObjectForKey: nsPresetKey];

  483.         [nsPresetKey release];

  484. 

  485.         JuceAudioUnitv3Base::setFullState (modifiedState);

  486. 

  487.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  488.         NSObject* obj = [modifiedState objectForKey: nsKey];

  489.         [nsKey release];

  490. 

  491.         if (obj != nullptr)

  492.         {

  493.             if ([obj isKindOfClass:[NSData class]])

  494.             {

  495.                 NSData* data = reinterpret_cast<NSData*> (obj);

  496.                 const int numBytes = static_cast<int> ([data length]);

  497.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  498. 

  499.                 if (numBytes > 0)

  500.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  501.             }

  502.         }

  503. 

  504.         [modifiedState release];

  505.     }

  506. 

  507.     //==============================================================================

  508.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  509.     {

  510.         const int n = static_cast<int> ([overviewParams count]);

  511. 

  512.         if (count >= n)

  513.             return overviewParams;

  514. 

  515.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams];

  516.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  517. 

  518.         return [retval autorelease];

  519.     }

  520. 

  521.     int getVirtualMIDICableCount() override

  522.     {

  523.        #if JucePlugin_WantsMidiInput

  524.         return 1;

  525.        #else

  526.         return 0;

  527.        #endif

  528.     }

  529. 

  530.     //==============================================================================

  531.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  532.     {

  533.         AudioProcessor& processor = getAudioProcessor();

  534.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  535. 

  536.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  537.             return false;

  538. 

  539.         if (outError != nullptr)

  540.             *outError = nullptr;

  541. 

  542.         AudioProcessor::BusesLayout layouts;

  543.         for (int dir = 0; dir < 2; ++dir)

  544.         {

  545.             const bool isInput = (dir == 0);

  546.             const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  547.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  548. 

  549.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  550.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  551. 

  552.             for (int busIdx = 0; busIdx < n; ++busIdx)

  553.             {

  554.                 AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx);

  555.                 AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  556. 

  557.                 AudioChannelSet newLayout;

  558.                 const AVAudioChannelLayout* layout    = [format channelLayout];

  559.                 const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  560. 

  561.                 if (layoutTag != 0)

  562.                     newLayout = AudioUnitHelpers::CALayoutTagToChannelSet (layoutTag);

  563.                 else

  564.                     newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  565. 

  566.                 if (newLayout.isDisabled())

  567.                     return false;

  568. 

  569.                 channelSets.add (newLayout);

  570.             }

  571.         }

  572. 

  573.        #ifdef JucePlugin_PreferredChannelConfigurations

  574.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  575. 

  576.         if (! AudioProcessor::containsLayout (layouts, configs))

  577.         {

  578.             if (outError != nullptr)

  579.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  580. 

  581.             return false;

  582.         }

  583.        #endif

  584. 

  585.         if (! AudioUnitHelpers::setBusesLayout (&getAudioProcessor(), layouts))

  586.         {

  587.             if (outError != nullptr)

  588.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  589. 

  590.             return false;

  591.         }

  592. 

  593.         totalInChannels  = processor.getTotalNumInputChannels();

  594.         totalOutChannels = processor.getTotalNumOutputChannels();

  595. 

  596.         allocateBusBuffer (true);

  597.         allocateBusBuffer (false);

  598. 

  599.         mapper.alloc();

  600. 

  601.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  602. 

  603.         double sampleRate = (jmax (AudioUnitHelpers::getBusCount (&processor, true), AudioUnitHelpers::getBusCount (&processor, false)) > 0 ?

  604.                              [[[([inputBusses count] > 0 ? inputBusses : outputBusses) objectAtIndexedSubscript: 0] format] sampleRate] : 44100.0);

  605. 

  606.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  607.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  608. 

  609.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  610.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  611.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  612. 

  613.         reset();

  614. 

  615.         return true;

  616.     }

  617. 

  618.     void deallocateRenderResources() override

  619.     {

  620.         hostMusicalContextCallback = nullptr;

  621.         hostTransportStateCallback = nullptr;

  622. 

  623.         getAudioProcessor().releaseResources();

  624.         audioBuffer.release();

  625. 

  626.         inBusBuffers. clear();

  627.         outBusBuffers.clear();

  628. 

  629.         mapper.release();

  630. 

  631.         JuceAudioUnitv3Base::deallocateRenderResources();

  632.     }

  633. 

  634.     void reset() override

  635.     {

  636.         midiMessages.clear();

  637.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  638.     }

  639. 

  640.     //==============================================================================

  641.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  642.     {

  643.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  644.         const int busIdx = static_cast<int> ([auBus index]);

  645.         const int newNumChannels = static_cast<int> ([format channelCount]);

  646. 

  647.         AudioProcessor& processor = getAudioProcessor();

  648. 

  649.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  650.         {

  651.           #ifdef JucePlugin_PreferredChannelConfigurations

  652.             ignoreUnused (bus);

  653. 

  654.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  655. 

  656.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  657.                 return false;

  658.           #else

  659.             const AVAudioChannelLayout* layout    = [format channelLayout];

  660.             const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  661. 

  662.             if (layoutTag != 0)

  663.             {

  664.                 AudioChannelSet newLayout = AudioUnitHelpers::CALayoutTagToChannelSet (layoutTag);

  665. 

  666.                 if (newLayout.size() != newNumChannels)

  667.                     return false;

  668. 

  669.                 if (! bus->isLayoutSupported (newLayout))

  670.                     return false;

  671.             }

  672.             else

  673.             {

  674.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  675.                     return false;

  676.             }

  677.            #endif

  678. 

  679.             return true;

  680.         }

  681. 

  682.         return false;

  683.     }

  684. 

  685.     //==============================================================================

  686.     void audioProcessorChanged (AudioProcessor* processor) override

  687.     {

  688.         ignoreUnused (processor);

  689. 

  690.         [au willChangeValueForKey: @"allParameterValues"];

  691.         [au didChangeValueForKey: @"allParameterValues"];

  692.     }

  693. 

  694.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  695.     {

  696.         if (isPositiveAndBelow (idx, getAudioProcessor().getNumParameters()))

  697.         {

  698.             if (AUParameter* param = [paramTree parameterWithAddress: getAUParameterAddressForIndex (idx)])

  699.             {

  700.                 if (editorObserverToken != nullptr)

  701.                     [param setValue: newValue  originator: editorObserverToken];

  702.                 else

  703.                     [param setValue: newValue];

  704.             }

  705.         }

  706.     }

  707. 

  708.     //==============================================================================

  709.     NSTimeInterval getLatency() override

  710.     {

  711.         auto& p = getAudioProcessor();

  712.         return p.getLatencySamples() / p.getSampleRate();

  713.     }

  714. 

  715.     NSTimeInterval getTailTime() override       { return getAudioProcessor().getTailLengthSeconds(); }

  716. 

  717.     //==============================================================================

  718.     bool getCurrentPosition (CurrentPositionInfo& info) override

  719.     {

  720.         bool musicContextCallSucceeded = false;

  721.         bool transportStateCallSucceeded = false;

  722. 

  723.         info = lastAudioHead;

  724.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  725.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  726. 

  727.         switch (lastTimeStamp.mSMPTETime.mType)

  728.         {

  729.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24; break;

  730.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25; break;

  731.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997; break;

  732.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  733.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop; break;

  734.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30; break;

  735.             case kSMPTETimeType60Drop:      info.frameRate = AudioPlayHead::fps60drop; break;

  736.             case kSMPTETimeType60:          info.frameRate = AudioPlayHead::fps60; break;

  737.             default:                        info.frameRate = AudioPlayHead::fpsUnknown; break;

  738.         }

  739. 

  740.         double num;

  741.         NSInteger den;

  742.         NSInteger outDeltaSampleOffsetToNextBeat;

  743.         double outCurrentMeasureDownBeat, bpm;

  744.         double ppqPosition;

  745. 

  746.         if (hostMusicalContextCallback != nullptr)

  747.         {

  748.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  749. 

  750.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  751.             {

  752.                 musicContextCallSucceeded = true;

  753. 

  754.                 info.timeSigNumerator   = (int) num;

  755.                 info.timeSigDenominator = (int) den;

  756.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  757.                 info.bpm = bpm;

  758.                 info.ppqPosition = ppqPosition;

  759.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  760.             }

  761.         }

  762. 

  763.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  764.         AUHostTransportStateFlags flags;

  765. 

  766.         if (hostTransportStateCallback != nullptr)

  767.         {

  768.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  769. 

  770.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  771.             {

  772.                 transportStateCallSucceeded = true;

  773. 

  774.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  775.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  776.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  777.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  778.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  779.                 info.ppqLoopStart   = outCycleStartBeat;

  780.                 info.ppqLoopEnd     = outCycleEndBeat;

  781.             }

  782.         }

  783. 

  784.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  785.             lastAudioHead = info;

  786. 

  787.         return true;

  788.     }

  789. 

  790.     static void removeEditor (AudioProcessor& processor)

  791.     {

  792.         ScopedLock editorLock (processor.getCallbackLock());

  793. 

  794.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  795.         {

  796.             processor.editorBeingDeleted (editor);

  797.             delete editor;

  798.         }

  799.     }

  800. 

  801. private:

  802.     //==============================================================================

  803.     struct BusBuffer

  804.     {

  805.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  806.             : auBus (bus), bufferList (nullptr),

  807.               maxFrames (maxFramesPerBuffer),

  808.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  809.               isInterleaved ([[auBus format] isInterleaved])

  810.         {

  811.             alloc();

  812.         }

  813. 

  814.         //==============================================================================

  815.         void alloc()

  816.         {

  817.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  818.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  819.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  820.             jassert (bytes > 0);

  821. 

  822.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  823.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  824. 

  825.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  826.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  827.         }

  828. 

  829.         void dealloc()

  830.         {

  831.             bufferList = nullptr;

  832.             bufferListStorage.free();

  833.             scratchBuffer.setSize (0, 0);

  834.         }

  835. 

  836.         //==============================================================================

  837.         int numChannels() const noexcept                { return numberOfChannels; }

  838.         bool interleaved() const noexcept               { return isInterleaved; }

  839.         AudioBufferList* get() const noexcept           { return bufferList; }

  840. 

  841.         //==============================================================================

  842.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  843.         {

  844.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  845.             const bool isCompatible = isCompatibleWith (other);

  846. 

  847.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  848. 

  849.             for (int i = 0; i < numBuffers; ++i)

  850.             {

  851.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  852.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  853.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  854.                                                               : scratchBuffer.getWritePointer (i));

  855.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  856.             }

  857.         }

  858. 

  859.         //==============================================================================

  860.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  861.         {

  862.             if (other == nullptr)

  863.                 return false;

  864. 

  865.             if (other->mNumberBuffers > 0)

  866.             {

  867.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  868.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  869.                                                                              : other->mNumberBuffers);

  870. 

  871.                 return otherInterleaved == isInterleaved

  872.                     && numberOfChannels == otherChannels;

  873.             }

  874. 

  875.             return numberOfChannels == 0;

  876.         }

  877. 

  878.     private:

  879.         AUAudioUnitBus* auBus;

  880.         HeapBlock<char> bufferListStorage;

  881.         AudioBufferList* bufferList;

  882.         int maxFrames, numberOfChannels;

  883.         bool isInterleaved;

  884.         AudioSampleBuffer scratchBuffer;

  885.     };

  886. 

  887.     //==============================================================================

  888.     void addAudioUnitBusses (bool isInput)

  889.     {

  890.         ScopedPointer<NSMutableArray<AUAudioUnitBus*> > array = [[NSMutableArray<AUAudioUnitBus*> alloc] init];

  891.         AudioProcessor& processor = getAudioProcessor();

  892.         const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  893. 

  894.         for (int i = 0; i < n; ++i)

  895.         {

  896.             ScopedPointer<AUAudioUnitBus> audioUnitBus;

  897. 

  898.             {

  899.                 ScopedPointer<AVAudioFormat> defaultFormat = [[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  900.                                                                                                             channels: static_cast<AVAudioChannelCount> (processor.getChannelCountOfBus (isInput, i))];

  901. 

  902.                 audioUnitBus = [[AUAudioUnitBus alloc] initWithFormat: defaultFormat

  903.                                                                 error: nullptr];

  904.             }

  905. 

  906.             [array addObject: audioUnitBus];

  907.         }

  908. 

  909.         (isInput ? inputBusses : outputBusses) = [[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  910.                                                                                         busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  911.                                                                                          busses: array];

  912.     }

  913. 

  914.     void addParameters()

  915.     {

  916.         ScopedPointer<NSMutableArray<AUParameterNode*> > params = [[NSMutableArray<AUParameterNode*> alloc] init];

  917. 

  918.         paramObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  919.         paramProvider = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  920. 

  921.         overviewParams = [[NSMutableArray<NSNumber*> alloc] init];

  922. 

  923.         auto& processor = getAudioProcessor();

  924.         const int n = processor.getNumParameters();

  925. 

  926.        #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  927.         // check if all parameters are managed?

  928.         usingManagedParameter = (processor.getParameters().size() == processor.getNumParameters());

  929.        #endif

  930. 

  931.         for (int idx = 0; idx < n; ++idx)

  932.         {

  933.             const String identifier (idx);

  934.             const String name = processor.getParameterName (idx);

  935. 

  936.             AudioUnitParameterUnit unit = kAudioUnitParameterUnit_Generic;

  937.             AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  938.                                                       | kAudioUnitParameterFlag_IsReadable

  939.                                                       | kAudioUnitParameterFlag_HasCFNameString

  940.                                                       | kAudioUnitParameterFlag_ValuesHaveStrings);

  941. 

  942.            #if JucePlugin_AUHighResolutionParameters

  943.             flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  944.            #endif

  945. 

  946.             // set whether the param is automatable (unnamed parameters aren't allowed to be automated)

  947.             if (name.isEmpty() || ! processor.isParameterAutomatable (idx))

  948.                 flags |= kAudioUnitParameterFlag_NonRealTime;

  949. 

  950.             if (processor.isMetaParameter (idx))

  951.                 flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  952. 

  953.             // is this a meter?

  954.             if (((processor.getParameterCategory (idx) & 0xffff0000) >> 16) == 2)

  955.             {

  956.                 flags &= ~kAudioUnitParameterFlag_IsWritable;

  957.                 flags |= kAudioUnitParameterFlag_MeterReadOnly | kAudioUnitParameterFlag_DisplayLogarithmic;

  958.                 unit = kAudioUnitParameterUnit_LinearGain;

  959.             }

  960. 

  961.            #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  962.             AUParameterAddress address = static_cast<AUParameterAddress> (idx);

  963.            #else

  964.             AUParameterAddress address = generateAUParameterAddressForIndex (idx);

  965. 

  966.             // Consider yourself very unlucky if you hit this assertion. The hash code of your

  967.             // parameter ids are not unique.

  968.             jassert (! paramMap.contains (static_cast<int64> (address)));

  969. 

  970.             paramAddresses.add (address);

  971.             paramMap.set (static_cast<int64> (address), idx);

  972.           #endif

  973. 

  974.             // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  975. 

  976.             ScopedPointer<AUParameter> param = [[AUParameterTree createParameterWithIdentifier: juceStringToNS (identifier)

  977.                                                                                           name: juceStringToNS (name)

  978.                                                                                        address: address

  979.                                                                                            min: 0.0f

  980.                                                                                            max: 1.0f

  981.                                                                                           unit: unit

  982.                                                                                       unitName: nullptr

  983.                                                                                          flags: flags

  984.                                                                                   valueStrings: nullptr

  985.                                                                            dependentParameters: nullptr] retain];

  986. 

  987.             [params addObject: param];

  988.             [overviewParams addObject: [NSNumber numberWithUnsignedLongLong:address]];

  989.         }

  990. 

  991.         // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  992.         paramTree = [[AUParameterTree createTreeWithChildren: params] retain];

  993. 

  994.         [paramTree setImplementorValueObserver: paramObserver];

  995.         [paramTree setImplementorValueProvider: paramProvider];

  996. 

  997.         if (processor.hasEditor())

  998.         {

  999.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  1000.             editorObserverToken = [paramTree tokenByAddingParameterObserver: editorParamObserver];

  1001.         }

  1002.     }

  1003. 

  1004.     void addPresets()

  1005.     {

  1006.         factoryPresets = [[NSMutableArray<AUAudioUnitPreset*> alloc] init];

  1007. 

  1008.         const int n = getAudioProcessor().getNumPrograms();

  1009. 

  1010.         for (int idx = 0; idx < n; ++idx)

  1011.         {

  1012.             String name = getAudioProcessor().getProgramName (idx);

  1013. 

  1014.             ScopedPointer<AUAudioUnitPreset> preset = [[AUAudioUnitPreset alloc] init];

  1015.             [preset setName: juceStringToNS (name)];

  1016.             [preset setNumber: static_cast<NSInteger> (idx)];

  1017. 

  1018.             [factoryPresets addObject: preset];

  1019.         }

  1020.     }

  1021. 

  1022.     //==============================================================================

  1023.     void allocateBusBuffer (bool isInput)

  1024.     {

  1025.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  1026.         busBuffers.clear();

  1027. 

  1028.         const int n = AudioUnitHelpers::getBusCount (&getAudioProcessor(), isInput);

  1029.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1030. 

  1031.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1032.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses : outputBusses) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1033.                                            static_cast<int> (maxFrames)));

  1034.     }

  1035. 

  1036.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1037.     {

  1038.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1039.         {

  1040.             switch (event->head.eventType)

  1041.             {

  1042.                 case AURenderEventMIDI:

  1043.                 {

  1044.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1045.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1046.                 }

  1047.                 break;

  1048. 

  1049.                 case AURenderEventParameter:

  1050.                 case AURenderEventParameterRamp:

  1051.                 {

  1052.                     const AUParameterEvent& paramEvent = event->parameter;

  1053.                     const int idx = getJuceParameterIndexForAUAddress (paramEvent.parameterAddress);

  1054. 

  1055.                     if (isPositiveAndBelow (idx, numParams))

  1056.                         getAudioProcessor().setParameter (idx, paramEvent.value);

  1057.                 }

  1058.                 break;

  1059. 

  1060.                 default:

  1061.                     break;

  1062.             }

  1063.         }

  1064.     }

  1065. 

  1066.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1067.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1068.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1069.     {

  1070.         auto& processor = getAudioProcessor();

  1071.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1072. 

  1073.         // process params

  1074.         const int numParams = processor.getNumParameters();

  1075.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1076. 

  1077.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1078.         {

  1079.             lastTimeStamp = *timestamp;

  1080. 

  1081.             const int numInputBuses  = inBusBuffers. size();

  1082.             const int numOutputBuses = outBusBuffers.size();

  1083. 

  1084.             // prepare buffers

  1085.             {

  1086.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1087.                 {

  1088.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1089.                      const bool canUseDirectOutput =

  1090.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1091. 

  1092.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1093.                 }

  1094. 

  1095.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1096.                 {

  1097.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1098.                     busBuffer.prepare (frameCount, busIdx < numOutputBuses ? outBusBuffers[busIdx]->get() : nullptr);

  1099.                 }

  1100. 

  1101.                 audioBuffer.reset();

  1102.             }

  1103. 

  1104.             // pull inputs

  1105.             {

  1106.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1107.                 {

  1108.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1109.                     AudioBufferList* buffer = busBuffer.get();

  1110. 

  1111.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1112.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1113. 

  1114.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1115.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1116.                 }

  1117.             }

  1118. 

  1119.             // set buffer pointer to minimize copying

  1120.             {

  1121.                 int chIdx = 0;

  1122. 

  1123.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1124.                 {

  1125.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1126.                     AudioBufferList* buffer = busBuffer.get();

  1127. 

  1128.                     const bool interleaved = busBuffer.interleaved();

  1129.                     const int numChannels = busBuffer.numChannels();

  1130. 

  1131.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1132. 

  1133.                     for (int ch = 0; ch < numChannels; ++ch)

  1134.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1135.                 }

  1136. 

  1137.                 // use input pointers on remaining channels

  1138. 

  1139.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1140.                 {

  1141.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1142. 

  1143.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1144.                     AudioBufferList* buffer = busBuffer.get();

  1145. 

  1146.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1147.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1148.                 }

  1149.             }

  1150. 

  1151.             // copy input

  1152.             {

  1153.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1154.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1155. 

  1156.                 // clear remaining channels

  1157.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1158.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1159.             }

  1160. 

  1161.             // process audio

  1162.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1163.             midiMessages.clear();

  1164.         }

  1165. 

  1166.         // copy back

  1167.         audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1168.                          mapper.get (false, (int) outputBusNumber));

  1169. 

  1170.         return noErr;

  1171.     }

  1172. 

  1173.     void processBlock (AudioSampleBuffer& buffer, MidiBuffer& midiBuffer) noexcept

  1174.     {

  1175.         auto& processor = getAudioProcessor();

  1176.         const ScopedLock sl (processor.getCallbackLock());

  1177. 

  1178.         if (processor.isSuspended())

  1179.             buffer.clear();

  1180.         else if ([au shouldBypassEffect])

  1181.             processor.processBlockBypassed (buffer, midiBuffer);

  1182.         else

  1183.             processor.processBlock (buffer, midiBuffer);

  1184.     }

  1185. 

  1186.     //==============================================================================

  1187.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1188.     {

  1189.         if (param != nullptr)

  1190.         {

  1191.             const int idx = getJuceParameterIndexForAUAddress ([param address]);

  1192.             auto& processor = getAudioProcessor();

  1193. 

  1194.             if (isPositiveAndBelow (idx, processor.getNumParameters()))

  1195.                 processor.setParameter (idx, value);

  1196.         }

  1197.     }

  1198. 

  1199.     AUValue getValue (AUParameter* param)

  1200.     {

  1201.         if (param != nullptr)

  1202.         {

  1203.             const int idx = getJuceParameterIndexForAUAddress ([param address]);

  1204.             auto& processor = getAudioProcessor();

  1205. 

  1206.             if (isPositiveAndBelow (idx, processor.getNumParameters()))

  1207.                 return processor.getParameter (idx);

  1208.         }

  1209. 

  1210.         return 0;

  1211.     }

  1212. 

  1213.     void valueChangedForObserver(AUParameterAddress, AUValue)

  1214.     {

  1215.         // this will have already been handled bny valueChangedFromHost

  1216.     }

  1217. 

  1218.     //==============================================================================

  1219.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1220.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept     { return static_cast<AUParameterAddress> (paramIndex); }

  1221.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept    { return static_cast<int> (address); }

  1222.    #else

  1223.     AUParameterAddress generateAUParameterAddressForIndex (int paramIndex) const

  1224.     {

  1225.         auto& processor = getAudioProcessor();

  1226.         const int n = processor.getNumParameters();

  1227. 

  1228.         if (isPositiveAndBelow (paramIndex, n))

  1229.         {

  1230.             const String& juceParamID = processor.getParameterID (paramIndex);

  1231.             return usingManagedParameter ? static_cast<AUParameterAddress> (juceParamID.hashCode64())

  1232.                                          : static_cast<AUParameterAddress> (juceParamID.getIntValue());

  1233.         }

  1234. 

  1235.         return static_cast<AUParameterAddress> (-1);

  1236.     }

  1237. 

  1238.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1239.     {

  1240.         return usingManagedParameter ? paramAddresses.getReference (paramIndex)

  1241.                                      : static_cast<AUParameterAddress> (paramIndex);

  1242.     }

  1243. 

  1244.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1245.     {

  1246.         return usingManagedParameter ? paramMap[static_cast<int64> (address)]

  1247.                                      : static_cast<int> (address);

  1248.     }

  1249.    #endif

  1250. 

  1251.     //==============================================================================

  1252.     static const double kDefaultSampleRate;

  1253. 

  1254.     AudioProcessorHolder::Ptr processorHolder;

  1255. 

  1256.     int totalInChannels, totalOutChannels;

  1257. 

  1258.     ScopedPointer<AUAudioUnitBusArray> inputBusses;

  1259.     ScopedPointer<AUAudioUnitBusArray> outputBusses;

  1260. 

  1261.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1262.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1263. 

  1264.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1265.     bool usingManagedParameter;

  1266.     Array<AUParameterAddress> paramAddresses;

  1267.     HashMap<int64, int> paramMap;

  1268.    #endif

  1269. 

  1270.     // to avoid recursion on parameter changes, we need to add an

  1271.     // editor observer to do the parameter changes

  1272.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1273.     AUParameterObserverToken editorObserverToken;

  1274. 

  1275.     ScopedPointer<AUParameterTree> paramTree;

  1276.     ScopedPointer<NSMutableArray<NSNumber*> > overviewParams;

  1277.     ScopedPointer<NSMutableArray<NSNumber*> > channelCapabilities;

  1278. 

  1279.     ScopedPointer<NSMutableArray<AUAudioUnitPreset*> > factoryPresets;

  1280. 

  1281.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1282. 

  1283.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1284.     AudioUnitHelpers::ChannelRemapper mapper;

  1285. 

  1286.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1287.     MidiBuffer midiMessages;

  1288. 

  1289.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1290.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1291. 

  1292.     AudioTimeStamp lastTimeStamp;

  1293.     CurrentPositionInfo lastAudioHead;

  1294. };

  1295. 

  1296. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1297. 

  1298. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1299. {

  1300.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1301.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1302. }

  1303. 

  1304. //==============================================================================

  1305. class JuceAUViewController

  1306. {

  1307. public:

  1308. 

  1309.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1310.         : myself (p), processorHolder (nullptr), preferredSize (1.0f, 1.0f)

  1311.     {

  1312.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1313. 

  1314.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1315.         initialiseJuce_GUI();

  1316.     }

  1317. 

  1318.     ~JuceAUViewController()

  1319.     {

  1320.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1321. 

  1322.         if (processorHolder != nullptr)

  1323.             JuceAudioUnitv3::removeEditor (getAudioProcessor());

  1324.     }

  1325. 

  1326.     //==============================================================================

  1327.     void loadView()

  1328.     {

  1329.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1330. 

  1331.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1332.         {

  1333.             processorHolder = new AudioProcessorHolder (p);

  1334.             auto& processor = getAudioProcessor();

  1335. 

  1336.             if (processor.hasEditor())

  1337.             {

  1338.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1339.                 {

  1340.                     preferredSize = editor->getBounds();

  1341. 

  1342.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1343.                     [myself setView: view];

  1344. 

  1345.                     editor->setVisible (true);

  1346.                     editor->addToDesktop (0, view);

  1347.                 }

  1348.             }

  1349.         }

  1350.     }

  1351. 

  1352.     void viewDidLayoutSubviews()

  1353.     {

  1354.         if (processorHolder != nullptr && [myself view] != nullptr)

  1355.         {

  1356.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1357.             {

  1358.                 editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1359. 

  1360.                 if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1361.                 {

  1362.                    #if JUCE_IOS

  1363.                     [peerView setNeedsDisplay];

  1364.                    #else

  1365.                     [peerView setNeedsDisplay: YES];

  1366.                    #endif

  1367.                 }

  1368.             }

  1369.         }

  1370.     }

  1371. 

  1372.     CGSize getPreferredContentSize() const

  1373.     {

  1374.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1375.                            static_cast<float> (preferredSize.getHeight()));

  1376.     }

  1377. 

  1378.     //==============================================================================

  1379.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1380.     {

  1381.         AUAudioUnit* retval = nil;

  1382. 

  1383.         if (! MessageManager::getInstance()->isThisTheMessageThread())

  1384.         {

  1385.             WaitableEvent creationEvent;

  1386. 

  1387.             // AUv3 headers say that we may block this thread and that the message thread is guaranteed

  1388.             // to be unblocked

  1389.             struct AUCreator  : public CallbackMessage

  1390.             {

  1391.                 JuceAUViewController& owner;

  1392.                 AudioComponentDescription pDescr;

  1393.                 NSError** pError;

  1394.                 AUAudioUnit*& outAU;

  1395.                 WaitableEvent& e;

  1396. 

  1397.                 AUCreator (JuceAUViewController& parent, const AudioComponentDescription& paramDescr, NSError** paramError,

  1398.                            AUAudioUnit*& outputAU, WaitableEvent& event)

  1399.                     : owner (parent), pDescr (paramDescr), pError (paramError), outAU (outputAU), e (event)

  1400.                 {}

  1401. 

  1402.                 void messageCallback() override

  1403.                 {

  1404.                     outAU = owner.createAudioUnitOnMessageThread (pDescr, pError);

  1405.                     e.signal();

  1406.                 }

  1407.             };

  1408. 

  1409.             (new AUCreator (*this, descr, error, retval, creationEvent))->post();

  1410.             creationEvent.wait (-1);

  1411.         }

  1412.         else

  1413.             retval = createAudioUnitOnMessageThread (descr, error);

  1414. 

  1415.         return [retval autorelease];

  1416.     }

  1417. 

  1418. private:

  1419.     //==============================================================================

  1420.     AUViewController<AUAudioUnitFactory>* myself;

  1421.     AudioProcessorHolder::Ptr processorHolder;

  1422.     Rectangle<int> preferredSize;

  1423. 

  1424.     //==============================================================================

  1425.     AUAudioUnit* createAudioUnitOnMessageThread (const AudioComponentDescription& descr, NSError** error)

  1426.     {

  1427.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1428. 

  1429.         [myself view];  // this will call [view load] and ensure that the AudioProcessor has been instantiated

  1430. 

  1431.         if (processorHolder == nullptr)

  1432.             return nullptr;

  1433. 

  1434.         return (new JuceAudioUnitv3 (processorHolder, descr, 0, error))->getAudioUnit();

  1435.     }

  1436. 

  1437.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder; }

  1438. };

  1439. 

  1440. //==============================================================================

  1441. // necessary glue code

  1442. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  1443. @end

  1444. 

  1445. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  1446. {

  1447.     ScopedPointer<JuceAUViewController> cpp;

  1448. }

  1449. 

  1450. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp = new JuceAUViewController (self); return self;}

  1451. - (void) loadView               { cpp->loadView(); }

  1452. - (AUAudioUnit *)createAudioUnitWithComponentDescription:(AudioComponentDescription)desc error:(NSError **)error { return cpp->createAudioUnit (desc, error); }

  1453. - (CGSize) preferredContentSize { return cpp->getPreferredContentSize(); }

  1454. - (void)viewDidLayoutSubviews   { return cpp->viewDidLayoutSubviews(); }

  1455. @end

  1456. 

  1457. //==============================================================================

  1458. #if JUCE_IOS

  1459. bool JUCE_CALLTYPE juce_isInterAppAudioConnected() { return false; }

  1460. void JUCE_CALLTYPE juce_switchToHostApplication()  {}

  1461. #if JUCE_MODULE_AVAILABLE_juce_gui_basics

  1462. Image JUCE_CALLTYPE juce_getIAAHostIcon (int)      { return Image(); }

  1463. #endif

  1464. #endif

  1465. 

  1466. #pragma clang diagnostic pop

  1467. #endif