DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
8978 Commits
11 Branches
450MB
Tree: 4229dc0a4f
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '4229dc0a4f'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

1873 lines
82KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2017 - ROLI Ltd.

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 5 End-User License

  11.    Agreement and JUCE 5 Privacy Policy (both updated and effective as of the

  12.    27th April 2017).

  13. 

  14.    End User License Agreement: www.juce.com/juce-5-licence

  15.    Privacy Policy: www.juce.com/juce-5-privacy-policy

  16. 

  17.    Or: You may also use this code under the terms of the GPL v3 (see

  18.    www.gnu.org/licenses).

  19. 

  20.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  21.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  22.    DISCLAIMED.

  23. 

  24.   ==============================================================================

  25. */

  26. 

  27. #include "../../juce_core/system/juce_TargetPlatform.h"

  28. #include "../utility/juce_CheckSettingMacros.h"

  29. 

  30. #if JucePlugin_Build_AUv3

  31. 

  32. #import <CoreAudioKit/CoreAudioKit.h>

  33. #import <AudioToolbox/AudioToolbox.h>

  34. #import <AVFoundation/AVFoundation.h>

  35. 

  36. #if JUCE_MAC

  37.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  38.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  39.  #endif

  40.  #if (defined MAC_OS_X_VERSION_10_13) && (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_13)

  41.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  42.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  43.  #endif

  44. #endif

  45. 

  46. #if JUCE_IOS

  47.  #if (! defined __IPHONE_OS_VERSION_MIN_REQUIRED) || (! defined __IPHONE_9_0) || (__IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_9_0)

  48.   #error AUv3 needs Deployment Target iOS 9.0 or higher to compile

  49.  #endif

  50.  #if (defined __IPHONE_11_0) && (__IPHONE_OS_VERSION_MIN_REQUIRED >= __IPHONE_11_0)

  51.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  52.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  53.  #endif

  54. #endif

  55. 

  56. #ifndef __OBJC2__

  57.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  58. #endif

  59. 

  60. #define JUCE_CORE_INCLUDE_OBJC_HELPERS 1

  61. 

  62. #include "../utility/juce_IncludeSystemHeaders.h"

  63. #include "../utility/juce_IncludeModuleHeaders.h"

  64. #include "../../juce_graphics/native/juce_mac_CoreGraphicsHelpers.h"

  65. 

  66. #include "../../juce_audio_basics/native/juce_mac_CoreAudioLayouts.h"

  67. #include "../../juce_audio_processors/format_types/juce_LegacyAudioParameter.cpp"

  68. #include "../../juce_audio_processors/format_types/juce_AU_Shared.h"

  69. 

  70. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  71. 

  72. #if JUCE_IOS

  73.  #define JUCE_IOS_MAC_VIEW  UIView

  74. #else

  75.  #define JUCE_IOS_MAC_VIEW  NSView

  76. #endif

  77. 

  78. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  79. 

  80. #pragma clang diagnostic push

  81. #pragma clang diagnostic ignored "-Wnullability-completeness"

  82. 

  83. using namespace juce;

  84. 

  85. // TODO: use SFINAE to automatically generate this for all NSObjects

  86. template <> struct ContainerDeletePolicy<AUAudioUnitBusArray>                   { static void destroy (NSObject* o) { [o release]; } };

  87. template <> struct ContainerDeletePolicy<AUParameterTree>                       { static void destroy (NSObject* o) { [o release]; } };

  88. template <> struct ContainerDeletePolicy<NSMutableArray<AUParameterNode*>>      { static void destroy (NSObject* o) { [o release]; } };

  89. template <> struct ContainerDeletePolicy<AUParameter>                           { static void destroy (NSObject* o) { [o release]; } };

  90. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitBus*>>       { static void destroy (NSObject* o) { [o release]; } };

  91. template <> struct ContainerDeletePolicy<AUAudioUnitBus>                        { static void destroy (NSObject* o) { [o release]; } };

  92. template <> struct ContainerDeletePolicy<AVAudioFormat>                         { static void destroy (NSObject* o) { [o release]; } };

  93. template <> struct ContainerDeletePolicy<AVAudioPCMBuffer>                      { static void destroy (NSObject* o) { [o release]; } };

  94. template <> struct ContainerDeletePolicy<NSMutableArray<NSNumber*>>             { static void destroy (NSObject* o) { [o release]; } };

  95. template <> struct ContainerDeletePolicy<NSNumber>                              { static void destroy (NSObject* o) { [o release]; } };

  96. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitPreset*>>    { static void destroy (NSObject* o) { [o release]; } };

  97. template <> struct ContainerDeletePolicy<AUAudioUnitPreset>                     { static void destroy (NSObject* o) { [o release]; } };

  98. 

  99. //==============================================================================

  100. struct AudioProcessorHolder  : public ReferenceCountedObject

  101. {

  102.     AudioProcessorHolder() {}

  103.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  104.     AudioProcessor& operator*() noexcept        { return *processor; }

  105.     AudioProcessor* operator->() noexcept       { return processor.get(); }

  106.     AudioProcessor* get() noexcept              { return processor.get(); }

  107. 

  108.     struct ViewConfig

  109.     {

  110.         double width;

  111.         double height;

  112.         bool hostHasMIDIController;

  113.     };

  114. 

  115.     ScopedPointer<ViewConfig> viewConfiguration;

  116. 

  117.     typedef ReferenceCountedObjectPtr<AudioProcessorHolder> Ptr;

  118. 

  119. private:

  120.     ScopedPointer<AudioProcessor> processor;

  121. 

  122.     AudioProcessorHolder& operator= (AudioProcessor*) = delete;

  123.     AudioProcessorHolder (AudioProcessorHolder&) = delete;

  124.     AudioProcessorHolder& operator= (AudioProcessorHolder&) = delete;

  125. };

  126. 

  127. //==============================================================================

  128. class JuceAudioUnitv3Base

  129. {

  130. public:

  131.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  132.                          AudioComponentInstantiationOptions options,

  133.                          NSError** error)

  134.        #pragma clang diagnostic push

  135.        #pragma clang diagnostic ignored "-Wobjc-method-access"

  136.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  137.                                                                         options: options

  138.                                                                           error: error

  139.                                                                       juceClass: this])

  140.        #pragma clang diagnostic pop

  141.     {}

  142. 

  143.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  144.     {

  145.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  146.         initialiseJuce_GUI();

  147.     }

  148. 

  149.     virtual ~JuceAudioUnitv3Base() {}

  150. 

  151.     //==============================================================================

  152.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  153. 

  154.     //==============================================================================

  155.     virtual void reset()                                                   = 0;

  156. 

  157.     //==============================================================================

  158.     virtual AUAudioUnitPreset* getCurrentPreset()                          = 0;

  159.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      = 0;

  160.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()               = 0;

  161. 

  162.     virtual NSDictionary<NSString*, id>* getFullState()

  163.     {

  164.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  165.         return ObjCMsgSendSuper<NSDictionary<NSString*, id>*> (&s, @selector (fullState));

  166.     }

  167. 

  168.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  169.     {

  170.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  171.         ObjCMsgSendSuper<void, NSDictionary<NSString*, id>*> (&s, @selector (setFullState:), state);

  172.     }

  173. 

  174.     virtual AUParameterTree* getParameterTree()                            = 0;

  175.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)       = 0;

  176. 

  177.     //==============================================================================

  178.     virtual NSTimeInterval getLatency()                                    = 0;

  179.     virtual NSTimeInterval getTailTime()                                   = 0;

  180. 

  181.     //==============================================================================

  182.     virtual AUAudioUnitBusArray* getInputBusses()                          = 0;

  183.     virtual AUAudioUnitBusArray* getOutputBusses()                         = 0;

  184.     virtual NSArray<NSNumber*>* getChannelCapabilities()                   = 0;

  185.     virtual bool shouldChangeToFormat (AVAudioFormat*, AUAudioUnitBus*)    = 0;

  186. 

  187.     //==============================================================================

  188.     virtual int getVirtualMIDICableCount()                                 = 0;

  189.     virtual bool getSupportsMPE()                                          = 0;

  190.     virtual NSArray<NSString*>* getMIDIOutputNames()                       = 0;

  191. 

  192.     //==============================================================================

  193.     virtual AUInternalRenderBlock getInternalRenderBlock()                 = 0;

  194.     virtual bool getCanProcessInPlace()                                    { return false; }

  195.     virtual bool getRenderingOffline()                                     = 0;

  196.     virtual void setRenderingOffline (bool offline)                        = 0;

  197. 

  198.     virtual bool getShouldBypassEffect()

  199.     {

  200.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  201.         return (ObjCMsgSendSuper<BOOL> (&s, @selector (shouldBypassEffect)) == YES);

  202.     }

  203. 

  204.     virtual void setShouldBypassEffect (bool shouldBypass)

  205.     {

  206.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  207.         ObjCMsgSendSuper<void, BOOL> (&s, @selector (setShouldBypassEffect:), shouldBypass ? YES : NO);

  208.     }

  209. 

  210.     //==============================================================================

  211.     virtual NSString* getContextName()      const                          = 0;

  212.     virtual void setContextName (NSString*)                                = 0;

  213. 

  214.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  215.     {

  216.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  217.         return (ObjCMsgSendSuper<BOOL, NSError**> (&s, @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  218.     }

  219. 

  220.     virtual void deallocateRenderResources()

  221.     {

  222.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  223.         ObjCMsgSendSuper<void> (&s, @selector (deallocateRenderResources));

  224.     }

  225. 

  226.     //==============================================================================

  227.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  228.     virtual NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>*) = 0;

  229.     virtual void selectViewConfiguration (AUAudioUnitViewConfiguration*)   = 0;

  230.    #endif

  231. 

  232. private:

  233.     struct Class  : public ObjCClass<AUAudioUnit>

  234.     {

  235.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  236.         {

  237.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  238. 

  239.            #pragma clang diagnostic push

  240.            #pragma clang diagnostic ignored "-Wundeclared-selector"

  241.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  242.                        initWithComponentDescriptionAndJuceClass, "@@:",

  243.                        @encode (AudioComponentDescription),

  244.                        @encode (AudioComponentInstantiationOptions), "^@@");

  245.            #pragma clang diagnostic pop

  246. 

  247.             addMethod (@selector (initWithComponentDescription:options:error:),

  248.                        initWithComponentDescription, "@@:",

  249.                        @encode (AudioComponentDescription),

  250.                        @encode (AudioComponentInstantiationOptions), "^@");

  251. 

  252.             addMethod (@selector (dealloc),                         dealloc,                        "v@:");

  253. 

  254.             //==============================================================================

  255.             addMethod (@selector (reset),                           reset,                          "v@:");

  256. 

  257.             //==============================================================================

  258.             addMethod (@selector (currentPreset),                   getCurrentPreset,               "@@:");

  259.             addMethod (@selector (setCurrentPreset:),               setCurrentPreset,               "v@:@");

  260.             addMethod (@selector (factoryPresets),                  getFactoryPresets,              "@@:");

  261.             addMethod (@selector (fullState),                       getFullState,                   "@@:");

  262.             addMethod (@selector (setFullState:),                   setFullState,                   "v@:@");

  263.             addMethod (@selector (parameterTree),                   getParameterTree,               "@@:");

  264.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  265. 

  266.             //==============================================================================

  267.             addMethod (@selector (latency),                         getLatency,                     @encode (NSTimeInterval), "@:");

  268.             addMethod (@selector (tailTime),                        getTailTime,                    @encode (NSTimeInterval),  "@:");

  269. 

  270.             //==============================================================================

  271.             addMethod (@selector (inputBusses),                     getInputBusses,                 "@@:");

  272.             addMethod (@selector (outputBusses),                    getOutputBusses,                "@@:");

  273.             addMethod (@selector (channelCapabilities),             getChannelCapabilities,         "@@:");

  274.             addMethod (@selector (shouldChangeToFormat:forBus:),    shouldChangeToFormat,           "B@:@@");

  275. 

  276.             //==============================================================================

  277.             addMethod (@selector (virtualMIDICableCount),           getVirtualMIDICableCount,       @encode (NSInteger), "@:");

  278.             addMethod (@selector (supportsMPE),                     getSupportsMPE,                 @encode (BOOL),      "@:");

  279. 

  280.            #if JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  281.             addMethod (@selector (MIDIOutputNames),                 getMIDIOutputNames,             "@@:");

  282.            #endif

  283. 

  284.             //==============================================================================

  285.             addMethod (@selector (internalRenderBlock),             getInternalRenderBlock,         @encode (AUInternalRenderBlock), "@:");

  286.             addMethod (@selector (canProcessInPlace),               getCanProcessInPlace,           @encode (BOOL), "@:");

  287.             addMethod (@selector (isRenderingOffline),              getRenderingOffline,            @encode (BOOL),  "@:");

  288.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  289.             addMethod (@selector (shouldBypassEffect),              getShouldBypassEffect,          @encode (BOOL),  "@:");

  290.             addMethod (@selector (setShouldBypassEffect:),          setShouldBypassEffect,          "v@:", @encode (BOOL));

  291.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "B@:^@");

  292.             addMethod (@selector (deallocateRenderResources),       deallocateRenderResources,      "v@:");

  293. 

  294.             //==============================================================================

  295.             addMethod (@selector (contextName),                     getContextName,                 "@@:");

  296.             addMethod (@selector (setContextName:),                  setContextName,                 "v@:@");

  297. 

  298.             //==============================================================================

  299.            #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  300.             addMethod (@selector (supportedViewConfigurations:),    getSupportedViewConfigurations, "@@:@");

  301.             addMethod (@selector (selectViewConfiguration:),        selectViewConfiguration,        "v@:@");

  302.            #endif

  303. 

  304.             registerClass();

  305.         }

  306. 

  307.         //==============================================================================

  308.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  309.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  310. 

  311.         //==============================================================================

  312.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  313.         {

  314.             AUAudioUnit* self = _self;

  315. 

  316.             objc_super s = { self, [AUAudioUnit class] };

  317.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  318.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  319. 

  320.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  321. 

  322.             setThis (self, juceAU);

  323.             return self;

  324.         }

  325. 

  326.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  327.         {

  328.             AUAudioUnit* self = _self;

  329. 

  330.             objc_super s = { self, [AUAudioUnit class] };

  331.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  332.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  333. 

  334. 

  335.             setThis (self, juceAU);

  336.             return self;

  337.         }

  338. 

  339.         static void dealloc (id self, SEL)

  340.         {

  341.             if (! MessageManager::getInstance()->isThisTheMessageThread())

  342.             {

  343.                 WaitableEvent deletionEvent;

  344. 

  345.                 struct AUDeleter  : public CallbackMessage

  346.                 {

  347.                     AUDeleter (id selfToDelete, WaitableEvent& event)

  348.                         : parentSelf (selfToDelete), parentDeletionEvent (event)

  349.                     {

  350.                     }

  351. 

  352.                     void messageCallback() override

  353.                     {

  354.                         delete _this (parentSelf);

  355.                         parentDeletionEvent.signal();

  356.                     }

  357. 

  358.                     id parentSelf;

  359.                     WaitableEvent& parentDeletionEvent;

  360.                 };

  361. 

  362.                 (new AUDeleter (self, deletionEvent))->post();

  363.                 deletionEvent.wait (-1);

  364.             }

  365.             else

  366.             {

  367.                 delete _this (self);

  368.             }

  369.         }

  370. 

  371.         //==============================================================================

  372.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  373. 

  374.         //==============================================================================

  375.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  376.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  377.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  378.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  379.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  380.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  381.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  382. 

  383.         //==============================================================================

  384.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  385.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  386. 

  387.         //==============================================================================

  388.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  389.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  390.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  391.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  392. 

  393.         //==============================================================================

  394.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  395.         static BOOL getSupportsMPE (id self, SEL)                                                   { return _this (self)->getSupportsMPE() ? YES : NO; }

  396.         static NSArray<NSString*>* getMIDIOutputNames (id self, SEL)                                { return _this (self)->getMIDIOutputNames(); }

  397. 

  398.         //==============================================================================

  399.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  400.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  401.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  402.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  403.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  404.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  405.         static BOOL getShouldBypassEffect (id self, SEL)                                            { return _this (self)->getShouldBypassEffect() ? YES : NO; }

  406.         static void setShouldBypassEffect (id self, SEL, BOOL shouldBypass)                         { _this (self)->setShouldBypassEffect (shouldBypass); }

  407. 

  408.         //==============================================================================

  409.         static NSString* getContextName (id self, SEL)                                              { return _this (self)->getContextName(); }

  410.         static void setContextName (id self, SEL, NSString* str)                                    { return _this (self)->setContextName (str); }

  411. 

  412.         //==============================================================================

  413.        #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  414.         static NSIndexSet* getSupportedViewConfigurations (id self, SEL, NSArray<AUAudioUnitViewConfiguration*>* configs) { return _this (self)->getSupportedViewConfigurations (configs); }

  415.         static void selectViewConfiguration (id self, SEL, AUAudioUnitViewConfiguration* config)    { _this (self)->selectViewConfiguration (config); }

  416.        #endif

  417.     };

  418. 

  419.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  420. 

  421.     //==============================================================================

  422.     static Class audioUnitObjCClass;

  423. 

  424. protected:

  425.     AUAudioUnit* au;

  426. };

  427. 

  428. //==============================================================================

  429. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  430. 

  431. //==============================================================================

  432. //=========================== The actual AudioUnit =============================

  433. //==============================================================================

  434. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  435.                          public AudioProcessorListener,

  436.                          public AudioPlayHead,

  437.                          private AudioProcessorParameter::Listener

  438. {

  439. public:

  440.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  441.                      const AudioComponentDescription& descr,

  442.                      AudioComponentInstantiationOptions options,

  443.                      NSError** error)

  444.         : JuceAudioUnitv3Base (descr, options, error),

  445.           processorHolder (processor),

  446.           mapper (*processorHolder->get())

  447.     {

  448.         init();

  449.     }

  450. 

  451.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  452.         : JuceAudioUnitv3Base (audioUnit),

  453.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  454.           mapper (*processorHolder->get())

  455.     {

  456.         init();

  457.     }

  458. 

  459.     ~JuceAudioUnitv3()

  460.     {

  461.         auto& processor = getAudioProcessor();

  462.         processor.removeListener (this);

  463. 

  464.         if (bypassParam != nullptr)

  465.             bypassParam->removeListener (this);

  466. 

  467.         removeEditor (processor);

  468. 

  469.         if (editorObserverToken != nullptr)

  470.         {

  471.             [paramTree.get() removeParameterObserver: editorObserverToken];

  472.             editorObserverToken = nullptr;

  473.         }

  474.     }

  475. 

  476.     //==============================================================================

  477.     void init()

  478.     {

  479.         inParameterChangedCallback = false;

  480. 

  481.         AudioProcessor& processor = getAudioProcessor();

  482.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  483. 

  484.        #ifdef JucePlugin_PreferredChannelConfigurations

  485.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  486.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  487. 

  488.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  489.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  490. 

  491.         Array<AUChannelInfo> channelInfos;

  492. 

  493.         for (int i = 0; i < numConfigs; ++i)

  494.         {

  495.             AUChannelInfo channelInfo;

  496. 

  497.             channelInfo.inChannels  = configs[i][0];

  498.             channelInfo.outChannels = configs[i][1];

  499. 

  500.             channelInfos.add (channelInfo);

  501.         }

  502.        #else

  503.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  504.        #endif

  505. 

  506.         processor.setPlayHead (this);

  507. 

  508.         totalInChannels  = processor.getTotalNumInputChannels();

  509.         totalOutChannels = processor.getTotalNumOutputChannels();

  510. 

  511.         {

  512.             channelCapabilities.reset ([[NSMutableArray<NSNumber*> alloc] init]);

  513. 

  514.             for (int i = 0; i < channelInfos.size(); ++i)

  515.             {

  516.                 AUChannelInfo& info = channelInfos.getReference (i);

  517. 

  518.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.inChannels]];

  519.                 [channelCapabilities.get() addObject: [NSNumber numberWithInteger: info.outChannels]];

  520.             }

  521.         }

  522. 

  523.         editorObserverToken = nullptr;

  524.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  525. 

  526.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  527.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  528.         processor.addListener (this);

  529. 

  530.         addParameters();

  531.         addPresets();

  532. 

  533.         addAudioUnitBusses (true);

  534.         addAudioUnitBusses (false);

  535.     }

  536. 

  537.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  538. 

  539.     //==============================================================================

  540.     void reset() override

  541.     {

  542.         midiMessages.clear();

  543.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  544.     }

  545. 

  546.     //==============================================================================

  547.     AUAudioUnitPreset* getCurrentPreset() override

  548.     {

  549.         const int n = static_cast<int> ([factoryPresets.get() count]);

  550.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  551. 

  552.         if (idx < n)

  553.             return [factoryPresets.get() objectAtIndex:static_cast<unsigned int> (idx)];

  554. 

  555.         return nullptr;

  556.     }

  557. 

  558.     void setCurrentPreset(AUAudioUnitPreset* preset) override

  559.     {

  560.         const int n = static_cast<int> ([factoryPresets.get() count]);

  561.         const int idx = static_cast<int> ([preset number]);

  562. 

  563.         if (isPositiveAndBelow (idx, n))

  564.             getAudioProcessor().setCurrentProgram (idx);

  565.     }

  566. 

  567.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override

  568.     {

  569.         return factoryPresets.get();

  570.     }

  571. 

  572.     NSDictionary<NSString*, id>* getFullState() override

  573.     {

  574.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  575. 

  576.         {

  577.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  578. 

  579.             if (superRetval != nullptr)

  580.                 [retval addEntriesFromDictionary:superRetval];

  581.         }

  582. 

  583.         juce::MemoryBlock state;

  584.         getAudioProcessor().getCurrentProgramStateInformation (state);

  585. 

  586.         if (state.getSize() > 0)

  587.         {

  588.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  589.                                                       length: state.getSize()];

  590. 

  591.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  592. 

  593.             [retval setObject: ourState

  594.                        forKey: nsKey];

  595. 

  596.             [nsKey    release];

  597.             [ourState release];

  598.         }

  599. 

  600.         return [retval autorelease];

  601.     }

  602. 

  603.     void setFullState (NSDictionary<NSString*, id>* state) override

  604.     {

  605.         if (state == nullptr)

  606.             return;

  607. 

  608.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  609.         [modifiedState addEntriesFromDictionary: state];

  610. 

  611.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  612.         [modifiedState removeObjectForKey: nsPresetKey];

  613.         [nsPresetKey release];

  614. 

  615.         JuceAudioUnitv3Base::setFullState (modifiedState);

  616. 

  617.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  618.         NSObject* obj = [modifiedState objectForKey: nsKey];

  619.         [nsKey release];

  620. 

  621.         if (obj != nullptr)

  622.         {

  623.             if ([obj isKindOfClass:[NSData class]])

  624.             {

  625.                 NSData* data = reinterpret_cast<NSData*> (obj);

  626.                 const int numBytes = static_cast<int> ([data length]);

  627.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  628. 

  629.                 if (numBytes > 0)

  630.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  631.             }

  632.         }

  633. 

  634.         [modifiedState release];

  635.     }

  636. 

  637.     AUParameterTree* getParameterTree() override

  638.     {

  639.         return paramTree.get();

  640.     }

  641. 

  642.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  643.     {

  644.         const int n = static_cast<int> ([overviewParams.get() count]);

  645. 

  646.         if (count >= n)

  647.             return overviewParams.get();

  648. 

  649.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams.get()];

  650.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  651. 

  652.         return [retval autorelease];

  653.     }

  654. 

  655.     //==============================================================================

  656.     NSTimeInterval getLatency() override

  657.     {

  658.         auto& p = getAudioProcessor();

  659.         return p.getLatencySamples() / p.getSampleRate();

  660.     }

  661. 

  662.     NSTimeInterval getTailTime() override

  663.     {

  664.         return getAudioProcessor().getTailLengthSeconds();

  665.     }

  666. 

  667.     //==============================================================================

  668.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses.get();  }

  669.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses.get(); }

  670.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities.get(); }

  671. 

  672.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  673.     {

  674.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  675.         const int busIdx = static_cast<int> ([auBus index]);

  676.         const int newNumChannels = static_cast<int> ([format channelCount]);

  677. 

  678.         AudioProcessor& processor = getAudioProcessor();

  679. 

  680.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  681.         {

  682.           #ifdef JucePlugin_PreferredChannelConfigurations

  683.             ignoreUnused (bus);

  684. 

  685.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  686. 

  687.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  688.                 return false;

  689.           #else

  690.             const AVAudioChannelLayout* layout    = [format channelLayout];

  691.             const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  692. 

  693.             if (layoutTag != 0)

  694.             {

  695.                 AudioChannelSet newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  696. 

  697.                 if (newLayout.size() != newNumChannels)

  698.                     return false;

  699. 

  700.                 if (! bus->isLayoutSupported (newLayout))

  701.                     return false;

  702.             }

  703.             else

  704.             {

  705.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  706.                     return false;

  707.             }

  708.            #endif

  709. 

  710.             return true;

  711.         }

  712. 

  713.         return false;

  714.     }

  715. 

  716.     //==============================================================================

  717.     int getVirtualMIDICableCount() override

  718.     {

  719.        #if JucePlugin_WantsMidiInput

  720.         return 1;

  721.        #else

  722.         return 0;

  723.        #endif

  724.     }

  725. 

  726.     bool getSupportsMPE() override

  727.     {

  728.         return getAudioProcessor().supportsMPE();

  729.     }

  730. 

  731.     NSArray<NSString*>* getMIDIOutputNames() override

  732.     {

  733.        #if JucePlugin_ProducesMidiOutput

  734.         return @[@"MIDI Out"];

  735.        #else

  736.         return @[];

  737.        #endif

  738.     }

  739. 

  740.     //==============================================================================

  741.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  742.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  743.     void setRenderingOffline (bool offline) override

  744.     {

  745.         auto& processor = getAudioProcessor();

  746.         auto isCurrentlyNonRealtime = processor.isNonRealtime();

  747. 

  748.         if (isCurrentlyNonRealtime != offline)

  749.         {

  750.             ScopedLock callbackLock (processor.getCallbackLock());

  751. 

  752.             processor.setNonRealtime (offline);

  753.             processor.prepareToPlay (processor.getSampleRate(), processor.getBlockSize());

  754.         }

  755.     }

  756. 

  757.     bool getShouldBypassEffect() override

  758.     {

  759.         if (bypassParam != nullptr)

  760.             return (bypassParam->getValue() != 0.0f);

  761. 

  762.         return JuceAudioUnitv3Base::getShouldBypassEffect();

  763.     }

  764. 

  765.     void setShouldBypassEffect (bool shouldBypass) override

  766.     {

  767.         if (bypassParam != nullptr)

  768.             bypassParam->setValue (shouldBypass ? 1.0f : 0.0f);

  769. 

  770.         JuceAudioUnitv3Base::setShouldBypassEffect (shouldBypass);

  771.     }

  772. 

  773.     //==============================================================================

  774.     NSString* getContextName() const    override              { return juceStringToNS (contextName); }

  775.     void setContextName (NSString* str) override

  776.     {

  777.         if (str != nullptr)

  778.         {

  779.             AudioProcessor::TrackProperties props;

  780.             props.name = nsStringToJuce (str);

  781. 

  782.             getAudioProcessor().updateTrackProperties (props);

  783.         }

  784.     }

  785. 

  786.     //==============================================================================

  787.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  788.     {

  789.         AudioProcessor& processor = getAudioProcessor();

  790.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  791. 

  792.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  793.             return false;

  794. 

  795.         if (outError != nullptr)

  796.             *outError = nullptr;

  797. 

  798.         AudioProcessor::BusesLayout layouts;

  799.         for (int dir = 0; dir < 2; ++dir)

  800.         {

  801.             const bool isInput = (dir == 0);

  802.             const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  803.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  804. 

  805.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  806.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  807. 

  808.             for (int busIdx = 0; busIdx < n; ++busIdx)

  809.             {

  810.                 AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx);

  811.                 AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  812. 

  813.                 AudioChannelSet newLayout;

  814.                 const AVAudioChannelLayout* layout    = [format channelLayout];

  815.                 const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  816. 

  817.                 if (layoutTag != 0)

  818.                     newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  819.                 else

  820.                     newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  821. 

  822.                 if (newLayout.isDisabled())

  823.                     return false;

  824. 

  825.                 channelSets.add (newLayout);

  826.             }

  827.         }

  828. 

  829.        #ifdef JucePlugin_PreferredChannelConfigurations

  830.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  831. 

  832.         if (! AudioProcessor::containsLayout (layouts, configs))

  833.         {

  834.             if (outError != nullptr)

  835.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  836. 

  837.             return false;

  838.         }

  839.        #endif

  840. 

  841.         if (! AudioUnitHelpers::setBusesLayout (&getAudioProcessor(), layouts))

  842.         {

  843.             if (outError != nullptr)

  844.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  845. 

  846.             return false;

  847.         }

  848. 

  849.         totalInChannels  = processor.getTotalNumInputChannels();

  850.         totalOutChannels = processor.getTotalNumOutputChannels();

  851. 

  852.         allocateBusBuffer (true);

  853.         allocateBusBuffer (false);

  854. 

  855.         mapper.alloc();

  856. 

  857.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  858. 

  859.         double sampleRate = (jmax (AudioUnitHelpers::getBusCount (&processor, true), AudioUnitHelpers::getBusCount (&processor, false)) > 0 ?

  860.                              [[[([inputBusses.get() count] > 0 ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: 0] format] sampleRate] : 44100.0);

  861. 

  862.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  863.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  864. 

  865.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  866.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  867.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  868. 

  869.         reset();

  870. 

  871.         return true;

  872.     }

  873. 

  874.     void deallocateRenderResources() override

  875.     {

  876.         hostMusicalContextCallback = nullptr;

  877.         hostTransportStateCallback = nullptr;

  878. 

  879.         getAudioProcessor().releaseResources();

  880.         audioBuffer.release();

  881. 

  882.         inBusBuffers. clear();

  883.         outBusBuffers.clear();

  884. 

  885.         mapper.release();

  886. 

  887.         JuceAudioUnitv3Base::deallocateRenderResources();

  888.     }

  889. 

  890.     //==============================================================================

  891.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  892.     NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>* configs) override

  893.     {

  894.         auto supportedViewIndecies = [[NSMutableIndexSet alloc] init];

  895.         auto n = [configs count];

  896. 

  897.         if (auto* editor = getAudioProcessor().createEditorIfNeeded())

  898.         {

  899.             // If you hit this assertion then your plug-in's editor is reporting that it doesn't support

  900.             // any host MIDI controller configurations!

  901.             jassert (editor->supportsHostMIDIControllerPresence (true) || editor->supportsHostMIDIControllerPresence (false));

  902. 

  903.             for (auto i = 0u; i < n; ++i)

  904.             {

  905.                 if (auto* viewConfiguration = [configs objectAtIndex:i])

  906.                 {

  907.                     if (editor->supportsHostMIDIControllerPresence ([viewConfiguration hostHasController] == YES))

  908.                     {

  909.                         auto* constrainer = editor->getConstrainer();

  910.                         auto height = (int) [viewConfiguration height];

  911.                         auto width  = (int) [viewConfiguration width];

  912. 

  913.                         if (height <= constrainer->getMaximumHeight() && height >= constrainer->getMinimumHeight()

  914.                          && width  <= constrainer->getMaximumWidth()  && width  >= constrainer->getMinimumWidth())

  915.                             [supportedViewIndecies addIndex: i];

  916.                     }

  917.                 }

  918.             }

  919.         }

  920. 

  921.         return [supportedViewIndecies autorelease];

  922.     }

  923. 

  924.     void selectViewConfiguration (AUAudioUnitViewConfiguration* config) override

  925.     {

  926.         processorHolder->viewConfiguration = new AudioProcessorHolder::ViewConfig { [config width], [config height], [config hostHasController] == YES };

  927.     }

  928.    #endif

  929. 

  930.     //==============================================================================

  931.     void audioProcessorChanged (AudioProcessor* processor) override

  932.     {

  933.         ignoreUnused (processor);

  934. 

  935.         [au willChangeValueForKey: @"allParameterValues"];

  936.         addPresets();

  937.         [au didChangeValueForKey: @"allParameterValues"];

  938.     }

  939. 

  940.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  941.     {

  942.         if (inParameterChangedCallback.get())

  943.         {

  944.             inParameterChangedCallback = false;

  945.             return;

  946.         }

  947. 

  948.         if (isPositiveAndBelow (idx, juceParameters.getNumParameters()))

  949.         {

  950.             if (AUParameter* param = [paramTree.get() parameterWithAddress: getAUParameterAddressForIndex (idx)])

  951.             {

  952.                 if (editorObserverToken != nullptr)

  953.                     [param setValue: newValue  originator: editorObserverToken];

  954.                 else

  955.                     [param setValue: newValue];

  956.             }

  957.         }

  958.     }

  959. 

  960.     //==============================================================================

  961.     bool getCurrentPosition (CurrentPositionInfo& info) override

  962.     {

  963.         bool musicContextCallSucceeded = false;

  964.         bool transportStateCallSucceeded = false;

  965. 

  966.         info = lastAudioHead;

  967.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  968.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  969. 

  970.         switch (lastTimeStamp.mSMPTETime.mType)

  971.         {

  972.             case kSMPTETimeType2398:        info.frameRate = AudioPlayHead::fps23976; break;

  973.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24; break;

  974.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25; break;

  975.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997; break;

  976.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  977.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop; break;

  978.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30; break;

  979.             case kSMPTETimeType60Drop:      info.frameRate = AudioPlayHead::fps60drop; break;

  980.             case kSMPTETimeType60:          info.frameRate = AudioPlayHead::fps60; break;

  981.             default:                        info.frameRate = AudioPlayHead::fpsUnknown; break;

  982.         }

  983. 

  984.         double num;

  985.         NSInteger den;

  986.         NSInteger outDeltaSampleOffsetToNextBeat;

  987.         double outCurrentMeasureDownBeat, bpm;

  988.         double ppqPosition;

  989. 

  990.         if (hostMusicalContextCallback != nullptr)

  991.         {

  992.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  993. 

  994.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  995.             {

  996.                 musicContextCallSucceeded = true;

  997. 

  998.                 info.timeSigNumerator   = (int) num;

  999.                 info.timeSigDenominator = (int) den;

  1000.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  1001.                 info.bpm = bpm;

  1002.                 info.ppqPosition = ppqPosition;

  1003.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  1004.             }

  1005.         }

  1006. 

  1007.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  1008.         AUHostTransportStateFlags flags;

  1009. 

  1010.         if (hostTransportStateCallback != nullptr)

  1011.         {

  1012.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  1013. 

  1014.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  1015.             {

  1016.                 transportStateCallSucceeded = true;

  1017. 

  1018.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  1019.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  1020.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  1021.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  1022.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  1023.                 info.ppqLoopStart   = outCycleStartBeat;

  1024.                 info.ppqLoopEnd     = outCycleEndBeat;

  1025.             }

  1026.         }

  1027. 

  1028.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  1029.             lastAudioHead = info;

  1030. 

  1031.         return true;

  1032.     }

  1033. 

  1034.     //==============================================================================

  1035.     static void removeEditor (AudioProcessor& processor)

  1036.     {

  1037.         ScopedLock editorLock (processor.getCallbackLock());

  1038. 

  1039.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  1040.         {

  1041.             processor.editorBeingDeleted (editor);

  1042.             delete editor;

  1043.         }

  1044.     }

  1045. 

  1046. private:

  1047.     //==============================================================================

  1048.     struct BusBuffer

  1049.     {

  1050.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  1051.             : auBus (bus),

  1052.               maxFrames (maxFramesPerBuffer),

  1053.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  1054.               isInterleaved ([[auBus format] isInterleaved])

  1055.         {

  1056.             alloc();

  1057.         }

  1058. 

  1059.         //==============================================================================

  1060.         void alloc()

  1061.         {

  1062.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1063.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  1064.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  1065.             jassert (bytes > 0);

  1066. 

  1067.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  1068.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  1069. 

  1070.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  1071.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  1072.         }

  1073. 

  1074.         void dealloc()

  1075.         {

  1076.             bufferList = nullptr;

  1077.             bufferListStorage.free();

  1078.             scratchBuffer.setSize (0, 0);

  1079.         }

  1080. 

  1081.         //==============================================================================

  1082.         int numChannels() const noexcept                { return numberOfChannels; }

  1083.         bool interleaved() const noexcept               { return isInterleaved; }

  1084.         AudioBufferList* get() const noexcept           { return bufferList; }

  1085. 

  1086.         //==============================================================================

  1087.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  1088.         {

  1089.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1090.             const bool isCompatible = isCompatibleWith (other);

  1091. 

  1092.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  1093. 

  1094.             for (int i = 0; i < numBuffers; ++i)

  1095.             {

  1096.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  1097.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  1098.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  1099.                                                               : scratchBuffer.getWritePointer (i));

  1100.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  1101.             }

  1102.         }

  1103. 

  1104.         //==============================================================================

  1105.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  1106.         {

  1107.             if (other == nullptr)

  1108.                 return false;

  1109. 

  1110.             if (other->mNumberBuffers > 0)

  1111.             {

  1112.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  1113.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  1114.                                                                              : other->mNumberBuffers);

  1115. 

  1116.                 return otherInterleaved == isInterleaved

  1117.                     && numberOfChannels == otherChannels;

  1118.             }

  1119. 

  1120.             return numberOfChannels == 0;

  1121.         }

  1122. 

  1123.     private:

  1124.         AUAudioUnitBus* auBus;

  1125.         HeapBlock<char> bufferListStorage;

  1126.         AudioBufferList* bufferList = nullptr;

  1127.         int maxFrames, numberOfChannels;

  1128.         bool isInterleaved;

  1129.         AudioBuffer<float> scratchBuffer;

  1130.     };

  1131. 

  1132.     //==============================================================================

  1133.     void addAudioUnitBusses (bool isInput)

  1134.     {

  1135.         ScopedPointer<NSMutableArray<AUAudioUnitBus*>> array ([[NSMutableArray<AUAudioUnitBus*> alloc] init]);

  1136.         AudioProcessor& processor = getAudioProcessor();

  1137.         const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  1138. 

  1139.         for (int i = 0; i < n; ++i)

  1140.         {

  1141.             ScopedPointer<AUAudioUnitBus> audioUnitBus;

  1142. 

  1143.             {

  1144.                 ScopedPointer<AVAudioFormat> defaultFormat ([[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  1145.                                                                                                            channels: static_cast<AVAudioChannelCount> (processor.getChannelCountOfBus (isInput, i))]);

  1146. 

  1147.                 audioUnitBus.reset ([[AUAudioUnitBus alloc] initWithFormat: defaultFormat.get()

  1148.                                                                      error: nullptr]);

  1149.             }

  1150. 

  1151.             [array.get() addObject: audioUnitBus.get()];

  1152.         }

  1153. 

  1154.         (isInput ? inputBusses : outputBusses).reset ([[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  1155.                                                                                              busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  1156.                                                                                               busses: array.get()]);

  1157.     }

  1158. 

  1159.     // When parameters are discrete we need to use integer values.

  1160.     float getMaximumParameterValue (AudioProcessorParameter* juceParam)

  1161.     {

  1162.        #if JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1163.         ignoreUnused (juceParam);

  1164.         return 1.0f;

  1165.        #else

  1166.         return juceParam->isDiscrete() ? (float) (juceParam->getNumSteps() - 1) : 1.0f;

  1167.        #endif

  1168.     }

  1169. 

  1170.     void addParameters()

  1171.     {

  1172.         ScopedPointer<NSMutableArray<AUParameterNode*>> params ([[NSMutableArray<AUParameterNode*> alloc] init]);

  1173. 

  1174.         overviewParams.reset ([[NSMutableArray<NSNumber*> alloc] init]);

  1175. 

  1176.         auto& processor = getAudioProcessor();

  1177.         juceParameters.update (processor, forceLegacyParamIDs);

  1178. 

  1179.         const int n = juceParameters.getNumParameters();

  1180. 

  1181.         for (int idx = 0; idx < n; ++idx)

  1182.         {

  1183.             auto* juceParam = juceParameters.getParamForIndex (idx);

  1184. 

  1185.             const String identifier (idx);

  1186.             const String name = juceParam->getName (512);

  1187. 

  1188.             AudioUnitParameterUnit unit = kAudioUnitParameterUnit_Generic;

  1189.             AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  1190.                                                       | kAudioUnitParameterFlag_IsReadable

  1191.                                                       | kAudioUnitParameterFlag_HasCFNameString

  1192.                                                       | kAudioUnitParameterFlag_ValuesHaveStrings);

  1193. 

  1194.             if (! forceLegacyParamIDs)

  1195.                 flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  1196. 

  1197.             // set whether the param is automatable (unnamed parameters aren't allowed to be automated)

  1198.             if (name.isEmpty() || ! juceParam->isAutomatable())

  1199.                 flags |= kAudioUnitParameterFlag_NonRealTime;

  1200. 

  1201.             const bool isParameterDiscrete = juceParam->isDiscrete();

  1202. 

  1203.             if (! isParameterDiscrete)

  1204.                 flags |= kAudioUnitParameterFlag_CanRamp;

  1205. 

  1206.             if (juceParam->isMetaParameter())

  1207.                 flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  1208. 

  1209.             auto deleter = [](NSMutableArray* arr) { [arr release]; };

  1210.             std::unique_ptr<NSMutableArray, decltype (deleter)> valueStrings (nullptr, deleter);

  1211. 

  1212.             // is this a meter?

  1213.             if (((juceParam->getCategory() & 0xffff0000) >> 16) == 2)

  1214.             {

  1215.                 flags &= ~kAudioUnitParameterFlag_IsWritable;

  1216.                 flags |= kAudioUnitParameterFlag_MeterReadOnly | kAudioUnitParameterFlag_DisplayLogarithmic;

  1217.                 unit = kAudioUnitParameterUnit_LinearGain;

  1218.             }

  1219.             else

  1220.             {

  1221.                 if (! forceLegacyParamIDs)

  1222.                 {

  1223.                     if (juceParam->isDiscrete())

  1224.                     {

  1225.                         unit = juceParam->isBoolean() ? kAudioUnitParameterUnit_Boolean : kAudioUnitParameterUnit_Indexed;

  1226.                         auto maxValue = getMaximumParameterValue (juceParam);

  1227.                         auto numSteps = juceParam->getNumSteps();

  1228. 

  1229.                         // Some hosts can't handle the huge numbers of discrete parameter values created when

  1230.                         // using the default number of steps.

  1231.                         jassert (numSteps != AudioProcessor::getDefaultNumParameterSteps());

  1232. 

  1233.                         valueStrings.reset ([NSMutableArray new]);

  1234. 

  1235.                         for (int i = 0; i < numSteps; ++i)

  1236.                             [valueStrings.get() addObject: juceStringToNS (juceParam->getText ((float) i / maxValue, 0))];

  1237.                     }

  1238.                 }

  1239.             }

  1240. 

  1241.             AUParameterAddress address = forceLegacyParamIDs ? static_cast<AUParameterAddress> (idx)

  1242.                                                              : generateAUParameterAddress (juceParam);

  1243. 

  1244.            #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1245.             // Consider yourself very unlucky if you hit this assertion. The hash codes of your

  1246.             // parameter ids are not unique.

  1247.             jassert (! paramMap.contains (static_cast<int64> (address)));

  1248. 

  1249.             paramAddresses.add (address);

  1250.             paramMap.set (static_cast<int64> (address), idx);

  1251.            #endif

  1252. 

  1253.             // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1254.             ScopedPointer<AUParameter> param ([[AUParameterTree createParameterWithIdentifier: juceStringToNS (identifier)

  1255.                                                                                          name: juceStringToNS (name)

  1256.                                                                                       address: address

  1257.                                                                                           min: 0.0f

  1258.                                                                                           max: getMaximumParameterValue (juceParam)

  1259.                                                                                          unit: unit

  1260.                                                                                      unitName: nullptr

  1261.                                                                                         flags: flags

  1262.                                                                                  valueStrings: valueStrings.get()

  1263.                                                                           dependentParameters: nullptr] retain]);

  1264. 

  1265.             [param.get() setValue: juceParam->getDefaultValue()];

  1266. 

  1267.             [params.get() addObject: param.get()];

  1268.             [overviewParams.get() addObject: [NSNumber numberWithUnsignedLongLong:address]];

  1269.         }

  1270. 

  1271.         // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1272.         paramTree.reset ([[AUParameterTree createTreeWithChildren: params.get()] retain]);

  1273. 

  1274.         paramObserver           = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  1275.         paramProvider           = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  1276.         stringFromValueProvider = CreateObjCBlock (this, &JuceAudioUnitv3::stringFromValue);

  1277.         valueFromStringProvider = CreateObjCBlock (this, &JuceAudioUnitv3::valueFromString);

  1278. 

  1279.         [paramTree.get() setImplementorValueObserver: paramObserver];

  1280.         [paramTree.get() setImplementorValueProvider: paramProvider];

  1281.         [paramTree.get() setImplementorStringFromValueCallback: stringFromValueProvider];

  1282.         [paramTree.get() setImplementorValueFromStringCallback: valueFromStringProvider];

  1283. 

  1284.         if (processor.hasEditor())

  1285.         {

  1286.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  1287.             editorObserverToken = [paramTree.get() tokenByAddingParameterObserver: editorParamObserver];

  1288.         }

  1289. 

  1290.         if ((bypassParam = processor.getBypassParameter()) != nullptr)

  1291.             bypassParam->addListener (this);

  1292.     }

  1293. 

  1294.     void setAudioProcessorParameter (AudioProcessorParameter* juceParam, float value)

  1295.     {

  1296.         if (value != juceParam->getValue())

  1297.         {

  1298.             juceParam->setValue (value);

  1299. 

  1300.             inParameterChangedCallback = true;

  1301.             juceParam->sendValueChangedMessageToListeners (value);

  1302.         }

  1303.     }

  1304. 

  1305.     void addPresets()

  1306.     {

  1307.         factoryPresets.reset ([[NSMutableArray<AUAudioUnitPreset*> alloc] init]);

  1308. 

  1309.         const int n = getAudioProcessor().getNumPrograms();

  1310. 

  1311.         for (int idx = 0; idx < n; ++idx)

  1312.         {

  1313.             String name = getAudioProcessor().getProgramName (idx);

  1314. 

  1315.             ScopedPointer<AUAudioUnitPreset> preset ([[AUAudioUnitPreset alloc] init]);

  1316.             [preset.get() setName: juceStringToNS (name)];

  1317.             [preset.get() setNumber: static_cast<NSInteger> (idx)];

  1318. 

  1319.             [factoryPresets.get() addObject: preset.get()];

  1320.         }

  1321.     }

  1322. 

  1323.     //==============================================================================

  1324.     void allocateBusBuffer (bool isInput)

  1325.     {

  1326.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  1327.         busBuffers.clear();

  1328. 

  1329.         const int n = AudioUnitHelpers::getBusCount (&getAudioProcessor(), isInput);

  1330.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1331. 

  1332.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1333.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses.get() : outputBusses.get()) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1334.                                            static_cast<int> (maxFrames)));

  1335.     }

  1336. 

  1337.     //==============================================================================

  1338.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1339.     {

  1340.         ignoreUnused (numParams);

  1341. 

  1342.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1343.         {

  1344.             switch (event->head.eventType)

  1345.             {

  1346.                 case AURenderEventMIDI:

  1347.                 {

  1348.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1349.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1350.                 }

  1351.                 break;

  1352. 

  1353.                 case AURenderEventParameter:

  1354.                 case AURenderEventParameterRamp:

  1355.                 {

  1356.                     const AUParameterEvent& paramEvent = event->parameter;

  1357. 

  1358.                     if (auto* p = getJuceParameterForAUAddress (paramEvent.parameterAddress))

  1359.                         setAudioProcessorParameter (p, paramEvent.value);

  1360.                 }

  1361.                 break;

  1362. 

  1363.                 default:

  1364.                     break;

  1365.             }

  1366.         }

  1367.     }

  1368. 

  1369.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1370.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1371.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1372.     {

  1373.         auto& processor = getAudioProcessor();

  1374.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1375. 

  1376.         // process params

  1377.         const int numParams = juceParameters.getNumParameters();

  1378.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1379. 

  1380.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1381.         {

  1382.             lastTimeStamp = *timestamp;

  1383. 

  1384.             const int numInputBuses  = inBusBuffers. size();

  1385.             const int numOutputBuses = outBusBuffers.size();

  1386. 

  1387.             // prepare buffers

  1388.             {

  1389.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1390.                 {

  1391.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1392.                      const bool canUseDirectOutput =

  1393.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1394. 

  1395.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1396.                 }

  1397. 

  1398.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1399.                 {

  1400.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1401.                     busBuffer.prepare (frameCount, busIdx < numOutputBuses ? outBusBuffers[busIdx]->get() : nullptr);

  1402.                 }

  1403. 

  1404.                 audioBuffer.reset();

  1405.             }

  1406. 

  1407.             // pull inputs

  1408.             {

  1409.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1410.                 {

  1411.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1412.                     AudioBufferList* buffer = busBuffer.get();

  1413. 

  1414.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1415.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1416. 

  1417.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1418.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1419.                 }

  1420.             }

  1421. 

  1422.             // set buffer pointer to minimize copying

  1423.             {

  1424.                 int chIdx = 0;

  1425. 

  1426.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1427.                 {

  1428.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1429.                     AudioBufferList* buffer = busBuffer.get();

  1430. 

  1431.                     const bool interleaved = busBuffer.interleaved();

  1432.                     const int numChannels = busBuffer.numChannels();

  1433. 

  1434.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1435. 

  1436.                     for (int ch = 0; ch < numChannels; ++ch)

  1437.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1438.                 }

  1439. 

  1440.                 // use input pointers on remaining channels

  1441. 

  1442.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1443.                 {

  1444.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1445. 

  1446.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1447.                     AudioBufferList* buffer = busBuffer.get();

  1448. 

  1449.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1450.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1451.                 }

  1452.             }

  1453. 

  1454.             // copy input

  1455.             {

  1456.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1457.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1458. 

  1459.                 // clear remaining channels

  1460.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1461.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1462.             }

  1463. 

  1464.             // process audio

  1465.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1466. 

  1467.             // send MIDI

  1468.            #if JucePlugin_ProducesMidiOutput && JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  1469.             auto midiOut = [au MIDIOutputEventBlock];

  1470.             MidiMessage msg;

  1471.             int samplePosition;

  1472. 

  1473.             for (MidiBuffer::Iterator it (midiMessages); it.getNextEvent (msg, samplePosition);)

  1474.                 midiOut (samplePosition, 0, msg.getRawDataSize(), msg.getRawData());

  1475.            #endif

  1476. 

  1477.             midiMessages.clear();

  1478.         }

  1479. 

  1480.         // copy back

  1481.         audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1482.                          mapper.get (false, (int) outputBusNumber));

  1483. 

  1484.         return noErr;

  1485.     }

  1486. 

  1487.     void processBlock (AudioBuffer<float>& buffer, MidiBuffer& midiBuffer) noexcept

  1488.     {

  1489.         auto& processor = getAudioProcessor();

  1490.         const ScopedLock sl (processor.getCallbackLock());

  1491. 

  1492.         if (processor.isSuspended())

  1493.             buffer.clear();

  1494.         else if (bypassParam != nullptr && [au shouldBypassEffect])

  1495.             processor.processBlockBypassed (buffer, midiBuffer);

  1496.         else

  1497.             processor.processBlock (buffer, midiBuffer);

  1498.     }

  1499. 

  1500.     //==============================================================================

  1501.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1502.     {

  1503.         if (param != nullptr)

  1504.         {

  1505.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1506.             {

  1507.                 auto normalisedValue = value / getMaximumParameterValue (p);

  1508.                 setAudioProcessorParameter (p, normalisedValue);

  1509.             }

  1510.         }

  1511.     }

  1512. 

  1513.     AUValue getValue (AUParameter* param)

  1514.     {

  1515.         if (param != nullptr)

  1516.         {

  1517.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1518.                 return p->getValue() * getMaximumParameterValue (p);

  1519.         }

  1520. 

  1521.         return 0;

  1522.     }

  1523. 

  1524.     void valueChangedForObserver (AUParameterAddress, AUValue)

  1525.     {

  1526.         // this will have already been handled by valueChangedFromHost

  1527.     }

  1528. 

  1529.     NSString* stringFromValue (AUParameter* param, const AUValue* value)

  1530.     {

  1531.         String text;

  1532. 

  1533.         if (param != nullptr && value != nullptr)

  1534.         {

  1535.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1536.             {

  1537.                 if (LegacyAudioParameter::isLegacy (p))

  1538.                     text = String (*value);

  1539.                 else

  1540.                     text = p->getText (*value / getMaximumParameterValue (p), 0);

  1541.             }

  1542.         }

  1543. 

  1544.         return juceStringToNS (text);

  1545.     }

  1546. 

  1547.     AUValue valueFromString (AUParameter* param, NSString* str)

  1548.     {

  1549.         if (param != nullptr && str != nullptr)

  1550.         {

  1551.             if (auto* p = getJuceParameterForAUAddress ([param address]))

  1552.             {

  1553.                 const String text (nsStringToJuce (str));

  1554. 

  1555.                 if (LegacyAudioParameter::isLegacy (p))

  1556.                     return text.getFloatValue();

  1557.                 else

  1558.                     return p->getValueForText (text) * getMaximumParameterValue (p);

  1559.             }

  1560.         }

  1561. 

  1562.         return 0;

  1563.     }

  1564. 

  1565.     //==============================================================================

  1566.     // this is only ever called for the bypass parameter

  1567.     void parameterValueChanged (int, float newValue) override

  1568.     {

  1569.         JuceAudioUnitv3Base::setShouldBypassEffect (newValue != 0.0f);

  1570.     }

  1571. 

  1572.     void parameterGestureChanged (int, bool) override {}

  1573.     //==============================================================================

  1574.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1575.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept     { return static_cast<AUParameterAddress> (paramIndex); }

  1576.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept    { return static_cast<int> (address); }

  1577.    #else

  1578.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1579.     {

  1580.         return juceParameters.isUsingManagedParameters() ? paramAddresses.getReference (paramIndex)

  1581.                                                          : static_cast<AUParameterAddress> (paramIndex);

  1582.     }

  1583. 

  1584.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1585.     {

  1586.         return juceParameters.isUsingManagedParameters() ? paramMap[static_cast<int64> (address)]

  1587.                                                          : static_cast<int> (address);

  1588.     }

  1589.    #endif

  1590. 

  1591.     AUParameterAddress generateAUParameterAddress (AudioProcessorParameter* param) const

  1592.     {

  1593.         const String& juceParamID = LegacyAudioParameter::getParamID (param, forceLegacyParamIDs);

  1594. 

  1595.         return juceParameters.isUsingManagedParameters() ? static_cast<AUParameterAddress> (juceParamID.hashCode64())

  1596.                                                          : static_cast<AUParameterAddress> (juceParamID.getIntValue());

  1597.     }

  1598. 

  1599.     AudioProcessorParameter* getJuceParameterForAUAddress (AUParameterAddress address) const noexcept

  1600.     {

  1601.         return juceParameters.getParamForIndex (getJuceParameterIndexForAUAddress (address));

  1602.     }

  1603. 

  1604.     //==============================================================================

  1605.     static const double kDefaultSampleRate;

  1606. 

  1607.     AudioProcessorHolder::Ptr processorHolder;

  1608. 

  1609.     int totalInChannels, totalOutChannels;

  1610. 

  1611.     ScopedPointer<AUAudioUnitBusArray> inputBusses;

  1612.     ScopedPointer<AUAudioUnitBusArray> outputBusses;

  1613. 

  1614.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1615.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1616.     ObjCBlock<AUImplementorStringFromValueCallback> stringFromValueProvider;

  1617.     ObjCBlock<AUImplementorValueFromStringCallback> valueFromStringProvider;

  1618. 

  1619.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1620.     Array<AUParameterAddress> paramAddresses;

  1621.     HashMap<int64, int> paramMap;

  1622.    #endif

  1623.     LegacyAudioParametersWrapper juceParameters;

  1624. 

  1625.     // to avoid recursion on parameter changes, we need to add an

  1626.     // editor observer to do the parameter changes

  1627.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1628.     AUParameterObserverToken editorObserverToken;

  1629. 

  1630.     ScopedPointer<AUParameterTree> paramTree;

  1631.     ScopedPointer<NSMutableArray<NSNumber*>> overviewParams;

  1632.     ScopedPointer<NSMutableArray<NSNumber*>> channelCapabilities;

  1633. 

  1634.     ScopedPointer<NSMutableArray<AUAudioUnitPreset*>> factoryPresets;

  1635. 

  1636.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1637. 

  1638.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1639.     AudioUnitHelpers::ChannelRemapper mapper;

  1640. 

  1641.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1642.     MidiBuffer midiMessages;

  1643. 

  1644.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1645.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1646. 

  1647.     AudioTimeStamp lastTimeStamp;

  1648.     CurrentPositionInfo lastAudioHead;

  1649. 

  1650.     String contextName;

  1651. 

  1652.     ThreadLocalValue<bool> inParameterChangedCallback;

  1653.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1654.     static constexpr bool forceLegacyParamIDs = true;

  1655.    #else

  1656.     static constexpr bool forceLegacyParamIDs = false;

  1657.    #endif

  1658.     AudioProcessorParameter* bypassParam = nullptr;

  1659. };

  1660. 

  1661. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1662. 

  1663. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1664. {

  1665.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1666.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1667. }

  1668. 

  1669. //==============================================================================

  1670. class JuceAUViewController

  1671. {

  1672. public:

  1673.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1674.         : myself (p)

  1675.     {

  1676.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1677. 

  1678.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1679.         initialiseJuce_GUI();

  1680.     }

  1681. 

  1682.     ~JuceAUViewController()

  1683.     {

  1684.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1685. 

  1686.         if (processorHolder != nullptr)

  1687.             JuceAudioUnitv3::removeEditor (getAudioProcessor());

  1688.     }

  1689. 

  1690.     //==============================================================================

  1691.     void loadView()

  1692.     {

  1693.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1694. 

  1695.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1696.         {

  1697.             processorHolder = new AudioProcessorHolder (p);

  1698.             auto& processor = getAudioProcessor();

  1699. 

  1700.             if (processor.hasEditor())

  1701.             {

  1702.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1703.                 {

  1704.                     preferredSize = editor->getBounds();

  1705. 

  1706.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1707.                     [myself setView: view];

  1708. 

  1709.                    #if JUCE_IOS

  1710.                     editor->setVisible (false);

  1711.                    #else

  1712.                     editor->setVisible (true);

  1713.                    #endif

  1714. 

  1715.                     editor->addToDesktop (0, view);

  1716. 

  1717.                    #if JUCE_IOS

  1718.                     if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1719.                         [peerView setContentMode: UIViewContentModeTop];

  1720.                    #endif

  1721.                 }

  1722.             }

  1723.         }

  1724.     }

  1725. 

  1726.     void viewDidLayoutSubviews()

  1727.     {

  1728.         if (processorHolder != nullptr && [myself view] != nullptr)

  1729.         {

  1730.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1731.             {

  1732.                 if (processorHolder->viewConfiguration != nullptr)

  1733.                     editor->hostMIDIControllerIsAvailable (processorHolder->viewConfiguration->hostHasMIDIController);

  1734. 

  1735.                 editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1736. 

  1737.                 if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1738.                 {

  1739.                    #if JUCE_IOS

  1740.                     [peerView setNeedsDisplay];

  1741.                    #else

  1742.                     [peerView setNeedsDisplay: YES];

  1743.                    #endif

  1744.                 }

  1745.             }

  1746.         }

  1747.     }

  1748. 

  1749.     void didReceiveMemoryWarning()

  1750.     {

  1751.         if (processorHolder != nullptr)

  1752.             if (auto* processor = processorHolder->get())

  1753.                 processor->memoryWarningReceived();

  1754.     }

  1755. 

  1756.     void viewDidAppear (bool)

  1757.     {

  1758.         if (processorHolder != nullptr)

  1759.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1760.                 editor->setVisible (true);

  1761.     }

  1762. 

  1763.     void viewDidDisappear (bool)

  1764.     {

  1765.         if (processorHolder != nullptr)

  1766.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1767.                 editor->setVisible (false);

  1768.     }

  1769. 

  1770.     CGSize getPreferredContentSize() const

  1771.     {

  1772.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1773.                            static_cast<float> (preferredSize.getHeight()));

  1774.     }

  1775. 

  1776.     //==============================================================================

  1777.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1778.     {

  1779.         AUAudioUnit* retval = nil;

  1780. 

  1781.         if (! MessageManager::getInstance()->isThisTheMessageThread())

  1782.         {

  1783.             WaitableEvent creationEvent;

  1784. 

  1785.             // AUv3 headers say that we may block this thread and that the message thread is guaranteed

  1786.             // to be unblocked

  1787.             struct AUCreator  : public CallbackMessage

  1788.             {

  1789.                 JuceAUViewController& owner;

  1790.                 AudioComponentDescription pDescr;

  1791.                 NSError** pError;

  1792.                 AUAudioUnit*& outAU;

  1793.                 WaitableEvent& e;

  1794. 

  1795.                 AUCreator (JuceAUViewController& parent, const AudioComponentDescription& paramDescr, NSError** paramError,

  1796.                            AUAudioUnit*& outputAU, WaitableEvent& event)

  1797.                     : owner (parent), pDescr (paramDescr), pError (paramError), outAU (outputAU), e (event)

  1798.                 {}

  1799. 

  1800.                 void messageCallback() override

  1801.                 {

  1802.                     outAU = owner.createAudioUnitOnMessageThread (pDescr, pError);

  1803.                     e.signal();

  1804.                 }

  1805.             };

  1806. 

  1807.             (new AUCreator (*this, descr, error, retval, creationEvent))->post();

  1808.             creationEvent.wait (-1);

  1809.         }

  1810.         else

  1811.         {

  1812.             retval = createAudioUnitOnMessageThread (descr, error);

  1813.         }

  1814. 

  1815.         return [retval autorelease];

  1816.     }

  1817. 

  1818. private:

  1819.     //==============================================================================

  1820.     AUViewController<AUAudioUnitFactory>* myself;

  1821.     AudioProcessorHolder::Ptr processorHolder = nullptr;

  1822.     Rectangle<int> preferredSize { 1, 1 };

  1823. 

  1824.     //==============================================================================

  1825.     AUAudioUnit* createAudioUnitOnMessageThread (const AudioComponentDescription& descr, NSError** error)

  1826.     {

  1827.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1828. 

  1829.         [myself view];  // this will call [view load] and ensure that the AudioProcessor has been instantiated

  1830. 

  1831.         if (processorHolder == nullptr)

  1832.             return nullptr;

  1833. 

  1834.         return (new JuceAudioUnitv3 (processorHolder, descr, 0, error))->getAudioUnit();

  1835.     }

  1836. 

  1837.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder; }

  1838. };

  1839. 

  1840. //==============================================================================

  1841. // necessary glue code

  1842. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  1843. @end

  1844. 

  1845. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  1846. {

  1847.     ScopedPointer<JuceAUViewController> cpp;

  1848. }

  1849. 

  1850. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp.reset (new JuceAUViewController (self)); return self; }

  1851. - (void) loadView                { cpp->loadView(); }

  1852. - (AUAudioUnit *) createAudioUnitWithComponentDescription: (AudioComponentDescription) desc error: (NSError **) error { return cpp->createAudioUnit (desc, error); }

  1853. - (CGSize) preferredContentSize  { return cpp->getPreferredContentSize(); }

  1854. - (void) viewDidLayoutSubviews   { cpp->viewDidLayoutSubviews(); }

  1855. - (void) didReceiveMemoryWarning { cpp->didReceiveMemoryWarning(); }

  1856. #if JUCE_IOS

  1857. - (void) viewDidAppear: (BOOL) animated { cpp->viewDidAppear (animated); [super viewDidAppear:animated]; }

  1858. - (void) viewDidDisappear: (BOOL) animated { cpp->viewDidDisappear (animated); [super viewDidDisappear:animated]; }

  1859. #endif

  1860. @end

  1861. 

  1862. //==============================================================================

  1863. #if JUCE_IOS

  1864. bool JUCE_CALLTYPE juce_isInterAppAudioConnected() { return false; }

  1865. void JUCE_CALLTYPE juce_switchToHostApplication()  {}

  1866. #if JUCE_MODULE_AVAILABLE_juce_gui_basics

  1867. Image JUCE_CALLTYPE juce_getIAAHostIcon (int)      { return {}; }

  1868. #endif

  1869. #endif

  1870. 

  1871. #pragma clang diagnostic pop

  1872. #endif