The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

272 lines
10KB

  1. /*
  2. ==============================================================================
  3. This file is part of the JUCE library - "Jules' Utility Class Extensions"
  4. Copyright 2004-11 by Raw Material Software Ltd.
  5. ------------------------------------------------------------------------------
  6. JUCE can be redistributed and/or modified under the terms of the GNU General
  7. Public License (Version 2), as published by the Free Software Foundation.
  8. A copy of the license is included in the JUCE distribution, or can be found
  9. online at www.gnu.org/licenses.
  10. JUCE is distributed in the hope that it will be useful, but WITHOUT ANY
  11. WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12. A PARTICULAR PURPOSE. See the GNU General Public License for more details.
  13. ------------------------------------------------------------------------------
  14. To release a closed-source product which uses JUCE, commercial licenses are
  15. available: visit www.rawmaterialsoftware.com/juce for more information.
  16. ==============================================================================
  17. */
  18. #if JUCE_MAC
  19. struct FileChooserDelegateClass : public ObjCClass <NSObject>
  20. {
  21. FileChooserDelegateClass() : ObjCClass <NSObject> ("JUCEFileChooser_")
  22. {
  23. addIvar<StringArray*> ("filters");
  24. addMethod (@selector (dealloc), dealloc, "v@:");
  25. addMethod (@selector (panel:shouldShowFilename:), shouldShowFilename, "c@:@@");
  26. #if defined (MAC_OS_X_VERSION_10_6) && MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_6
  27. addProtocol (@protocol (NSOpenSavePanelDelegate));
  28. #endif
  29. registerClass();
  30. }
  31. static void setFilters (id self, StringArray* filters)
  32. {
  33. object_setInstanceVariable (self, "filters", filters);
  34. }
  35. private:
  36. static void dealloc (id self, SEL)
  37. {
  38. delete getIvar<StringArray*> (self, "filters");
  39. sendSuperclassMessage (self, @selector (dealloc));
  40. }
  41. static BOOL shouldShowFilename (id self, SEL, id /*sender*/, NSString* filename)
  42. {
  43. StringArray* const filters = getIvar<StringArray*> (self, "filters");
  44. const File f (nsStringToJuce (filename));
  45. for (int i = filters->size(); --i >= 0;)
  46. if (f.getFileName().matchesWildcard ((*filters)[i], true))
  47. return true;
  48. #if (! defined (MAC_OS_X_VERSION_10_7)) || MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_7
  49. NSError* error;
  50. NSString* name = [[NSWorkspace sharedWorkspace] typeOfFile: filename error: &error];
  51. if ([name isEqualToString: nsStringLiteral ("com.apple.alias-file")])
  52. {
  53. FSRef ref;
  54. FSPathMakeRef ((const UInt8*) [filename fileSystemRepresentation], &ref, nullptr);
  55. Boolean targetIsFolder = false, wasAliased = false;
  56. FSResolveAliasFileWithMountFlags (&ref, true, &targetIsFolder, &wasAliased, 0);
  57. return wasAliased && targetIsFolder;
  58. }
  59. #endif
  60. return f.isDirectory()
  61. && ! [[NSWorkspace sharedWorkspace] isFilePackageAtPath: filename];
  62. }
  63. };
  64. //==============================================================================
  65. class TemporaryMainMenuWithStandardCommands
  66. {
  67. public:
  68. TemporaryMainMenuWithStandardCommands()
  69. : oldMenu (MenuBarModel::getMacMainMenu()), oldAppleMenu (nullptr)
  70. {
  71. if (const PopupMenu* appleMenu = MenuBarModel::getMacExtraAppleItemsMenu())
  72. oldAppleMenu = new PopupMenu (*appleMenu);
  73. MenuBarModel::setMacMainMenu (nullptr);
  74. NSMenu* menu = [[NSMenu alloc] initWithTitle: nsStringLiteral ("Edit")];
  75. NSMenuItem* item;
  76. item = [[NSMenuItem alloc] initWithTitle: NSLocalizedString (nsStringLiteral ("Cut"), nil)
  77. action: @selector (cut:) keyEquivalent: nsStringLiteral ("x")];
  78. [menu addItem: item];
  79. [item release];
  80. item = [[NSMenuItem alloc] initWithTitle: NSLocalizedString (nsStringLiteral ("Copy"), nil)
  81. action: @selector (copy:) keyEquivalent: nsStringLiteral ("c")];
  82. [menu addItem: item];
  83. [item release];
  84. item = [[NSMenuItem alloc] initWithTitle: NSLocalizedString (nsStringLiteral ("Paste"), nil)
  85. action: @selector (paste:) keyEquivalent: nsStringLiteral ("v")];
  86. [menu addItem: item];
  87. [item release];
  88. item = [[NSApp mainMenu] addItemWithTitle: NSLocalizedString (nsStringLiteral ("Edit"), nil)
  89. action: nil keyEquivalent: nsEmptyString()];
  90. [[NSApp mainMenu] setSubmenu: menu forItem: item];
  91. [menu release];
  92. // use a dummy modal component so that apps can tell that something is currently modal.
  93. dummyModalComponent.enterModalState();
  94. }
  95. ~TemporaryMainMenuWithStandardCommands()
  96. {
  97. MenuBarModel::setMacMainMenu (oldMenu, oldAppleMenu);
  98. }
  99. private:
  100. MenuBarModel* oldMenu;
  101. ScopedPointer<PopupMenu> oldAppleMenu;
  102. // The OS view already plays an alert when clicking outside
  103. // the modal comp, so this override avoids adding extra
  104. // inappropriate noises when the cancel button is pressed.
  105. // This override is also important because it stops the base class
  106. // calling ModalComponentManager::bringToFront, which can get
  107. // recursive when file dialogs are involved
  108. class SilentDummyModalComp : public Component
  109. {
  110. public:
  111. SilentDummyModalComp() {}
  112. void inputAttemptWhenModal() {}
  113. };
  114. SilentDummyModalComp dummyModalComponent;
  115. };
  116. //==============================================================================
  117. void FileChooser::showPlatformDialog (Array<File>& results,
  118. const String& title,
  119. const File& currentFileOrDirectory,
  120. const String& filter,
  121. bool selectsDirectory,
  122. bool selectsFiles,
  123. bool isSaveDialogue,
  124. bool /*warnAboutOverwritingExistingFiles*/,
  125. bool selectMultipleFiles,
  126. FilePreviewComponent* /*extraInfoComponent*/)
  127. {
  128. JUCE_AUTORELEASEPOOL
  129. ScopedPointer<TemporaryMainMenuWithStandardCommands> tempMenu;
  130. if (JUCEApplication::isStandaloneApp())
  131. tempMenu = new TemporaryMainMenuWithStandardCommands();
  132. StringArray* filters = new StringArray();
  133. filters->addTokens (filter.replaceCharacters (",:", ";;"), ";", String::empty);
  134. filters->trim();
  135. filters->removeEmptyStrings();
  136. #if defined (MAC_OS_X_VERSION_10_6) && MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_6
  137. typedef NSObject<NSOpenSavePanelDelegate> DelegateType;
  138. #else
  139. typedef NSObject DelegateType;
  140. #endif
  141. static FileChooserDelegateClass cls;
  142. DelegateType* delegate = (DelegateType*) [[cls.createInstance() init] autorelease];
  143. FileChooserDelegateClass::setFilters (delegate, filters);
  144. NSSavePanel* panel = isSaveDialogue ? [NSSavePanel savePanel]
  145. : [NSOpenPanel openPanel];
  146. [panel setTitle: juceStringToNS (title)];
  147. if (! isSaveDialogue)
  148. {
  149. NSOpenPanel* openPanel = (NSOpenPanel*) panel;
  150. [openPanel setCanChooseDirectories: selectsDirectory];
  151. [openPanel setCanChooseFiles: selectsFiles];
  152. [openPanel setAllowsMultipleSelection: selectMultipleFiles];
  153. [openPanel setResolvesAliases: YES];
  154. }
  155. [panel setDelegate: delegate];
  156. if (isSaveDialogue || selectsDirectory)
  157. [panel setCanCreateDirectories: YES];
  158. String directory, filename;
  159. if (currentFileOrDirectory.isDirectory())
  160. {
  161. directory = currentFileOrDirectory.getFullPathName();
  162. }
  163. else
  164. {
  165. directory = currentFileOrDirectory.getParentDirectory().getFullPathName();
  166. filename = currentFileOrDirectory.getFileName();
  167. }
  168. #if defined (MAC_OS_X_VERSION_10_6) && (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_6)
  169. [panel setDirectoryURL: [NSURL fileURLWithPath: juceStringToNS (directory)]];
  170. [panel setNameFieldStringValue: juceStringToNS (filename)];
  171. if ([panel runModal] == NSOKButton)
  172. #else
  173. if ([panel runModalForDirectory: juceStringToNS (directory)
  174. file: juceStringToNS (filename)] == NSOKButton)
  175. #endif
  176. {
  177. if (isSaveDialogue)
  178. {
  179. results.add (File (nsStringToJuce ([[panel URL] path])));
  180. }
  181. else
  182. {
  183. NSOpenPanel* openPanel = (NSOpenPanel*) panel;
  184. NSArray* urls = [openPanel URLs];
  185. for (unsigned int i = 0; i < [urls count]; ++i)
  186. results.add (File (nsStringToJuce ([[urls objectAtIndex: i] path])));
  187. }
  188. }
  189. [panel setDelegate: nil];
  190. }
  191. bool FileChooser::isPlatformDialogAvailable()
  192. {
  193. return true;
  194. }
  195. #else
  196. //==============================================================================
  197. bool FileChooser::isPlatformDialogAvailable()
  198. {
  199. return false;
  200. }
  201. void FileChooser::showPlatformDialog (Array<File>& results,
  202. const String& title,
  203. const File& currentFileOrDirectory,
  204. const String& filter,
  205. bool selectsDirectory,
  206. bool selectsFiles,
  207. bool isSaveDialogue,
  208. bool warnAboutOverwritingExistingFiles,
  209. bool selectMultipleFiles,
  210. FilePreviewComponent* extraInfoComponent)
  211. {
  212. JUCE_AUTORELEASEPOOL
  213. jassertfalse; //there's no such thing in iOS
  214. }
  215. #endif