DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
13265 Commits
11 Branches
588MB
Tree: 2ba2bc9677
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '2ba2bc9677'
${ noResults }
JUCE/modules/juce_gui_basics/native/accessibility/juce_ios_Accessibility.mm

667 lines
33KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2022 - Raw Material Software Limited

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 7 End-User License

  11.    Agreement and JUCE Privacy Policy.

  12. 

  13.    End User License Agreement: www.juce.com/juce-7-licence

  14.    Privacy Policy: www.juce.com/juce-privacy-policy

  15. 

  16.    Or: You may also use this code under the terms of the GPL v3 (see

  17.    www.gnu.org/licenses).

  18. 

  19.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  20.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  21.    DISCLAIMED.

  22. 

  23.   ==============================================================================

  24. */

  25. 

  26. static void juceFreeAccessibilityPlatformSpecificData (UIAccessibilityElement* element)

  27. {

  28.     if (auto* container = juce::getIvar<UIAccessibilityElement*> (element, "container"))

  29.     {

  30.         object_setInstanceVariable (element, "container", nullptr);

  31.         object_setInstanceVariable (container, "handler", nullptr);

  32. 

  33.         [container release];

  34.     }

  35. }

  36. 

  37. namespace juce

  38. {

  39. 

  40. #define JUCE_NATIVE_ACCESSIBILITY_INCLUDED 1

  41. 

  42. template <typename> struct Signature;

  43. 

  44. template <typename Result, typename... Args>

  45. struct Signature<Result (Args...)> {};

  46. 

  47. // @selector isn't constexpr, so the 'sel' members are functions rather than static constexpr data members

  48. struct SignatureHasText                         : Signature<BOOL()>                                                              { static auto sel() { return @selector (hasText); } };

  49. struct SignatureSetSelectedTextRange            : Signature<void (UITextRange*)>                                                 { static auto sel() { return @selector (setSelectedTextRange:); } };

  50. struct SignatureSelectedTextRange               : Signature<UITextRange*()>                                                      { static auto sel() { return @selector (selectedTextRange); } };

  51. struct SignatureMarkedTextRange                 : Signature<UITextRange*()>                                                      { static auto sel() { return @selector (markedTextRange); } };

  52. struct SignatureSetMarkedTextSelectedRange      : Signature<void (NSString*, NSRange)>                                           { static auto sel() { return @selector (setMarkedText:selectedRange:); } };

  53. struct SignatureUnmarkText                      : Signature<void()>                                                              { static auto sel() { return @selector (unmarkText); } };

  54. struct SignatureMarkedTextStyle                 : Signature<NSDictionary<NSAttributedStringKey, id>*()>                          { static auto sel() { return @selector (markedTextStyle); } };

  55. struct SignatureSetMarkedTextStyle              : Signature<void (NSDictionary<NSAttributedStringKey, id>*)>                     { static auto sel() { return @selector (setMarkedTextStyle:); } };

  56. struct SignatureBeginningOfDocument             : Signature<UITextPosition*()>                                                   { static auto sel() { return @selector (beginningOfDocument); } };

  57. struct SignatureEndOfDocument                   : Signature<UITextPosition*()>                                                   { static auto sel() { return @selector (endOfDocument); } };

  58. struct SignatureTokenizer                       : Signature<id<UITextInputTokenizer>()>                                          { static auto sel() { return @selector (tokenizer); } };

  59. struct SignatureBaseWritingDirection            : Signature<NSWritingDirection (UITextPosition*, UITextStorageDirection)>        { static auto sel() { return @selector (baseWritingDirectionForPosition:inDirection:); } };

  60. struct SignatureCaretRectForPosition            : Signature<CGRect (UITextPosition*)>                                            { static auto sel() { return @selector (caretRectForPosition:); } };

  61. struct SignatureCharacterRangeByExtending       : Signature<UITextRange* (UITextPosition*, UITextLayoutDirection)>               { static auto sel() { return @selector (characterRangeByExtendingPosition:inDirection:); } };

  62. struct SignatureCharacterRangeAtPoint           : Signature<UITextRange* (CGPoint)>                                              { static auto sel() { return @selector (characterRangeAtPoint:); } };

  63. struct SignatureClosestPositionToPoint          : Signature<UITextPosition* (CGPoint)>                                           { static auto sel() { return @selector (closestPositionToPoint:); } };

  64. struct SignatureClosestPositionToPointInRange   : Signature<UITextPosition* (CGPoint, UITextRange*)>                             { static auto sel() { return @selector (closestPositionToPoint:withinRange:); } };

  65. struct SignatureComparePositionToPosition       : Signature<NSComparisonResult (UITextPosition*, UITextPosition*)>               { static auto sel() { return @selector (comparePosition:toPosition:); } };

  66. struct SignatureOffsetFromPositionToPosition    : Signature<NSInteger (UITextPosition*, UITextPosition*)>                        { static auto sel() { return @selector (offsetFromPosition:toPosition:); } };

  67. struct SignaturePositionFromPositionInDirection : Signature<UITextPosition* (UITextPosition*, UITextLayoutDirection, NSInteger)> { static auto sel() { return @selector (positionFromPosition:inDirection:offset:); } };

  68. struct SignaturePositionFromPositionOffset      : Signature<UITextPosition* (UITextPosition*, NSInteger)>                        { static auto sel() { return @selector (positionFromPosition:offset:); } };

  69. struct SignatureFirstRectForRange               : Signature<CGRect (UITextRange*)>                                               { static auto sel() { return @selector (firstRectForRange:); } };

  70. struct SignatureSelectionRectsForRange          : Signature<NSArray<UITextSelectionRect*>* (UITextRange*)>                       { static auto sel() { return @selector (selectionRectsForRange:); } };

  71. struct SignaturePositionWithinRange             : Signature<UITextPosition* (UITextRange*, UITextLayoutDirection)>               { static auto sel() { return @selector (positionWithinRange:farthestInDirection:); } };

  72. struct SignatureReplaceRangeWithText            : Signature<void (UITextRange*, NSString*)>                                      { static auto sel() { return @selector (replaceRange:withText:); } };

  73. struct SignatureSetBaseWritingDirection         : Signature<void (NSWritingDirection, UITextRange*)>                             { static auto sel() { return @selector (setBaseWritingDirection:forRange:); } };

  74. struct SignatureTextInRange                     : Signature<NSString* (UITextRange*)>                                            { static auto sel() { return @selector (textInRange:); } };

  75. struct SignatureTextRangeFromPosition           : Signature<UITextRange* (UITextPosition*, UITextPosition*)>                     { static auto sel() { return @selector (textRangeFromPosition:toPosition:); } };

  76. struct SignatureSetInputDelegate                : Signature<void (id)>                                                           { static auto sel() { return @selector (setInputDelegate:); } };

  77. struct SignatureInputDelegate                   : Signature<id()>                                                                { static auto sel() { return @selector (inputDelegate); } };

  78. struct SignatureKeyboardType                    : Signature<UIKeyboardType()>                                                    { static auto sel() { return @selector (keyboardType); } };

  79. struct SignatureAutocapitalizationType          : Signature<UITextAutocapitalizationType()>                                      { static auto sel() { return @selector (autocapitalizationType); } };

  80. struct SignatureAutocorrectionType              : Signature<UITextAutocorrectionType()>                                          { static auto sel() { return @selector (autocorrectionType); } };

  81. 

  82. //==============================================================================

  83. class AccessibilityHandler::AccessibilityNativeImpl

  84. {

  85. public:

  86.     explicit AccessibilityNativeImpl (AccessibilityHandler& handler)

  87.         : accessibilityElement (AccessibilityElement::create (handler))

  88.     {

  89.     }

  90. 

  91.     UIAccessibilityElement* getAccessibilityElement() const noexcept

  92.     {

  93.         return accessibilityElement.get();

  94.     }

  95. 

  96. private:

  97.     //==============================================================================

  98.     class AccessibilityContainer  : public AccessibleObjCClass<NSObject>

  99.     {

  100.     public:

  101.         AccessibilityContainer()

  102.             : AccessibleObjCClass ("JUCEUIAccessibilityContainer_")

  103.         {

  104.             addMethod (@selector (isAccessibilityElement), [] (id, SEL) { return false; });

  105. 

  106.             addMethod (@selector (accessibilityFrame), [] (id self, SEL)

  107.             {

  108.                 if (auto* handler = getHandler (self))

  109.                     return convertToCGRect (handler->getComponent().getScreenBounds());

  110. 

  111.                 return CGRectZero;

  112.             });

  113. 

  114.             addMethod (@selector (accessibilityElements), [] (id self, SEL) -> NSArray*

  115.             {

  116.                 if (auto* handler = getHandler (self))

  117.                     return getContainerAccessibilityElements (*handler);

  118. 

  119.                 return nil;

  120.             });

  121. 

  122.             if (@available (iOS 11.0, *))

  123.             {

  124.                 addMethod (@selector (accessibilityDataTableCellElementForRow:column:), [] (id self, SEL, NSUInteger row, NSUInteger column) -> id

  125.                 {

  126.                     if (auto* tableHandler = getEnclosingHandlerWithInterface (getHandler (self), &AccessibilityHandler::getTableInterface))

  127.                         if (auto* tableInterface = tableHandler->getTableInterface())

  128.                             if (auto* cellHandler = tableInterface->getCellHandler ((int) row, (int) column))

  129.                                 if (auto* parent = getAccessibleParent (cellHandler))

  130.                                     return static_cast<id> (parent->getNativeImplementation());

  131. 

  132.                     return nil;

  133.                 });

  134. 

  135.                 addMethod (@selector (accessibilityRowCount),                           getAccessibilityRowCount);

  136.                 addMethod (@selector (accessibilityColumnCount),                        getAccessibilityColumnCount);

  137. 

  138.                 addMethod (@selector (accessibilityHeaderElementsForColumn:), [] (id self, SEL, NSUInteger column) -> NSArray*

  139.                 {

  140.                     if (auto* tableHandler = getEnclosingHandlerWithInterface (getHandler (self), &AccessibilityHandler::getTableInterface))

  141.                     {

  142.                         if (auto* tableInterface = tableHandler->getTableInterface())

  143.                         {

  144.                             if (auto* header = tableInterface->getHeaderHandler())

  145.                             {

  146.                                 if (isPositiveAndBelow (column, header->getChildren().size()))

  147.                                 {

  148.                                     auto* result = [NSMutableArray new];

  149.                                     [result addObject: static_cast<id> (header->getChildren()[(size_t) column]->getNativeImplementation())];

  150.                                     return result;

  151.                                 }

  152.                             }

  153.                         }

  154.                     }

  155. 

  156.                     return nullptr;

  157.                 });

  158. 

  159.                 addProtocol (@protocol (UIAccessibilityContainerDataTable));

  160. 

  161.                 addMethod (@selector (accessibilityContainerType), [] (id self, SEL) -> NSInteger

  162.                 {

  163.                     if (auto* handler = getHandler (self))

  164.                     {

  165.                         if (handler->getTableInterface() != nullptr)

  166.                         {

  167.                             if (@available (iOS 11.0, *))

  168.                                 return UIAccessibilityContainerTypeDataTable;

  169. 

  170.                             return 1; // UIAccessibilityContainerTypeDataTable

  171.                         }

  172. 

  173.                         const auto handlerRole = handler->getRole();

  174. 

  175.                         if (handlerRole == AccessibilityRole::popupMenu

  176.                             || handlerRole == AccessibilityRole::list

  177.                             || handlerRole == AccessibilityRole::tree)

  178.                         {

  179.                             if (@available (iOS 11.0, *))

  180.                                 return UIAccessibilityContainerTypeList;

  181. 

  182.                             return 2; // UIAccessibilityContainerTypeList

  183.                         }

  184.                     }

  185. 

  186.                     if (@available (iOS 11.0, *))

  187.                         return UIAccessibilityContainerTypeNone;

  188. 

  189.                     return 0; // UIAccessibilityContainerTypeNone

  190.                 });

  191.             }

  192. 

  193.             registerClass();

  194.         }

  195. 

  196.     private:

  197.         static const AccessibilityHandler* getAccessibleParent (const AccessibilityHandler* h)

  198.         {

  199.             if (h == nullptr)

  200.                 return nullptr;

  201. 

  202.             if ([static_cast<id> (h->getNativeImplementation()) isAccessibilityElement])

  203.                 return h;

  204. 

  205.             return getAccessibleParent (h->getParent());

  206.         }

  207. 

  208.         static AccessibilityHandler* getHandler (id self)

  209.         {

  210.             return getIvar<AccessibilityHandler*> (self, "handler");

  211.         }

  212.     };

  213. 

  214.     //==============================================================================

  215.     class AccessibilityElement  : public AccessibleObjCClass<UIAccessibilityElement>

  216.     {

  217.         template <typename Func, typename... Items>

  218.         static constexpr void forEach (Func&& func, Items&&... items)

  219.         {

  220.             (void) std::initializer_list<int> { ((void) func (std::forward<Items> (items)), 0)... };

  221.         }

  222. 

  223.     public:

  224.         enum class Type  { defaultElement, textElement };

  225. 

  226.         static Holder create (AccessibilityHandler& handler)

  227.         {

  228.             static AccessibilityElement cls     { Type::defaultElement };

  229.             static AccessibilityElement textCls { Type::textElement };

  230. 

  231.             id instance = (hasEditableText (handler) ? textCls : cls).createInstance();

  232. 

  233.             Holder element ([instance initWithAccessibilityContainer: static_cast<id> (handler.getComponent().getWindowHandle())]);

  234.             object_setInstanceVariable (element.get(), "handler", &handler);

  235.             return element;

  236.         }

  237. 

  238.         AccessibilityElement (Type elementType)

  239.         {

  240.             addMethod (@selector (isAccessibilityElement), [] (id self, SEL)

  241.             {

  242.                 auto* handler = getHandler (self);

  243. 

  244.                 const auto hasAccessiblePropertiesOrIsTableCell = [] (auto& handlerRef)

  245.                 {

  246.                     const auto isTableCell = [&]

  247.                     {

  248.                         if (auto* tableHandler = getEnclosingHandlerWithInterface (&handlerRef, &AccessibilityHandler::getTableInterface))

  249.                         {

  250.                             if (auto* tableInterface = tableHandler->getTableInterface())

  251.                             {

  252.                                 return tableInterface->getRowSpan    (handlerRef).hasValue()

  253.                                     && tableInterface->getColumnSpan (handlerRef).hasValue();

  254.                             }

  255.                         }

  256. 

  257.                         return false;

  258.                     };

  259. 

  260.                     return handlerRef.getTitle().isNotEmpty()

  261.                         || handlerRef.getHelp().isNotEmpty()

  262.                         || handlerRef.getTextInterface()  != nullptr

  263.                         || handlerRef.getValueInterface() != nullptr

  264.                         || isTableCell();

  265.                 };

  266. 

  267.                 return handler != nullptr

  268.                     && ! handler->isIgnored()

  269.                     && handler->getRole() != AccessibilityRole::window

  270.                     && hasAccessiblePropertiesOrIsTableCell (*handler);

  271.             });

  272. 

  273.             addMethod (@selector (accessibilityContainer), [] (id self, SEL) -> id

  274.             {

  275.                 if (auto* handler = getHandler (self))

  276.                 {

  277.                     if (handler->getComponent().isOnDesktop())

  278.                         return static_cast<id> (handler->getComponent().getWindowHandle());

  279. 

  280.                     if (! handler->getChildren().empty())

  281.                     {

  282.                         if (UIAccessibilityElement* container = getContainer (self))

  283.                             return container;

  284. 

  285.                         static AccessibilityContainer cls;

  286. 

  287.                         id container = cls.createInstance();

  288. 

  289.                         object_setInstanceVariable (container, "handler", handler);

  290.                         object_setInstanceVariable (self, "container", container);

  291. 

  292.                         return container;

  293.                     }

  294. 

  295.                     if (auto* parent = handler->getParent())

  296.                         return [static_cast<id> (parent->getNativeImplementation()) accessibilityContainer];

  297.                 }

  298. 

  299.                 return nil;

  300.             });

  301. 

  302.             addMethod (@selector (accessibilityFrame), [] (id self, SEL)

  303.             {

  304.                 if (auto* handler = getHandler (self))

  305.                     return convertToCGRect (handler->getComponent().getScreenBounds());

  306. 

  307.                 return CGRectZero;

  308.             });

  309. 

  310.             addMethod (@selector (accessibilityTraits), [] (id self, SEL)

  311.             {

  312.                 auto traits = UIAccessibilityTraits{};

  313. 

  314.                 if (auto* handler = getHandler (self))

  315.                 {

  316.                     traits |= [&handler]

  317.                     {

  318.                         switch (handler->getRole())

  319.                         {

  320.                             case AccessibilityRole::button:

  321.                             case AccessibilityRole::toggleButton:

  322.                             case AccessibilityRole::radioButton:

  323.                             case AccessibilityRole::comboBox:      return UIAccessibilityTraitButton;

  324. 

  325.                             case AccessibilityRole::label:

  326.                             case AccessibilityRole::staticText:    return UIAccessibilityTraitStaticText;

  327. 

  328.                             case AccessibilityRole::image:         return UIAccessibilityTraitImage;

  329.                             case AccessibilityRole::tableHeader:   return UIAccessibilityTraitHeader;

  330.                             case AccessibilityRole::hyperlink:     return UIAccessibilityTraitLink;

  331.                             case AccessibilityRole::ignored:       return UIAccessibilityTraitNotEnabled;

  332. 

  333.                             case AccessibilityRole::editableText:  return UIAccessibilityTraitKeyboardKey;

  334. 

  335.                             case AccessibilityRole::slider:

  336.                             case AccessibilityRole::menuItem:

  337.                             case AccessibilityRole::menuBar:

  338.                             case AccessibilityRole::popupMenu:

  339.                             case AccessibilityRole::table:

  340.                             case AccessibilityRole::column:

  341.                             case AccessibilityRole::row:

  342.                             case AccessibilityRole::cell:

  343.                             case AccessibilityRole::list:

  344.                             case AccessibilityRole::listItem:

  345.                             case AccessibilityRole::tree:

  346.                             case AccessibilityRole::treeItem:

  347.                             case AccessibilityRole::progressBar:

  348.                             case AccessibilityRole::group:

  349.                             case AccessibilityRole::dialogWindow:

  350.                             case AccessibilityRole::window:

  351.                             case AccessibilityRole::scrollBar:

  352.                             case AccessibilityRole::tooltip:

  353.                             case AccessibilityRole::splashScreen:

  354.                             case AccessibilityRole::unspecified:   break;

  355.                         }

  356. 

  357.                         return UIAccessibilityTraitNone;

  358.                     }();

  359. 

  360.                     const auto state = handler->getCurrentState();

  361. 

  362.                     if (state.isSelected() || state.isChecked())

  363.                         traits |= UIAccessibilityTraitSelected;

  364. 

  365.                     if (auto* valueInterface = getValueInterface (self))

  366.                         if (! valueInterface->isReadOnly() && valueInterface->getRange().isValid())

  367.                             traits |= UIAccessibilityTraitAdjustable;

  368.                 }

  369. 

  370.                 return traits | sendSuperclassMessage<UIAccessibilityTraits> (self, @selector (accessibilityTraits));

  371.             });

  372. 

  373.             addMethod (@selector (accessibilityLabel), getAccessibilityTitle);

  374.             addMethod (@selector (accessibilityHint),  getAccessibilityHelp);

  375. 

  376.             addMethod (@selector (accessibilityValue), [] (id self, SEL) -> NSString*

  377.             {

  378.                 if (auto* handler = getHandler (self))

  379.                 {

  380.                     if (handler->getCurrentState().isCheckable())

  381.                         return handler->getCurrentState().isChecked() ? @"1" : @"0";

  382. 

  383.                     return (NSString*) getAccessibilityValueFromInterfaces (*handler);

  384.                 }

  385. 

  386.                 return nil;

  387.             });

  388. 

  389.             addMethod (@selector (setAccessibilityValue:), setAccessibilityValue);

  390. 

  391.             addMethod (@selector (accessibilityElementDidBecomeFocused), [] (id self, SEL)

  392.             {

  393.                 if (auto* handler = getHandler (self))

  394.                 {

  395.                     const WeakReference<Component> safeComponent (&handler->getComponent());

  396. 

  397.                     performActionIfSupported (self, AccessibilityActionType::focus);

  398. 

  399.                     if (safeComponent != nullptr)

  400.                         handler->grabFocus();

  401.                 }

  402.             });

  403. 

  404.             addMethod (@selector (accessibilityElementDidLoseFocus), [] (id self, SEL)

  405.             {

  406.                 if (auto* handler = getHandler (self))

  407.                     handler->giveAwayFocus();

  408.             });

  409. 

  410.             addMethod (@selector (accessibilityElementIsFocused), [] (id self, SEL) -> BOOL

  411.             {

  412.                 if (auto* handler = getHandler (self))

  413.                     return handler->hasFocus (false);

  414. 

  415.                 return NO;

  416.             });

  417. 

  418.             addMethod (@selector (accessibilityViewIsModal), getIsAccessibilityModal);

  419. 

  420.             addMethod (@selector (accessibilityActivate), [] (id self, SEL)

  421.             {

  422.                 if (auto* handler = getHandler (self))

  423.                 {

  424.                     // Occasionally VoiceOver sends accessibilityActivate to the wrong element, so we first query

  425.                     // which element it thinks has focus and forward the event on to that element if it differs

  426.                     id focusedElement = UIAccessibilityFocusedElement (UIAccessibilityNotificationVoiceOverIdentifier);

  427. 

  428.                     if (focusedElement != nullptr && ! [static_cast<id> (handler->getNativeImplementation()) isEqual: focusedElement])

  429.                         return [focusedElement accessibilityActivate];

  430. 

  431.                     if (handler->hasFocus (false))

  432.                         return accessibilityPerformPress (self, {});

  433.                 }

  434. 

  435.                 return NO;

  436.             });

  437. 

  438.             addMethod (@selector (accessibilityIncrement), accessibilityPerformIncrement);

  439.             addMethod (@selector (accessibilityDecrement), accessibilityPerformDecrement);

  440. 

  441.             addMethod (@selector (accessibilityPerformEscape), [] (id self, SEL)

  442.             {

  443.                 if (auto* handler = getHandler (self))

  444.                 {

  445.                     if (auto* modal = Component::getCurrentlyModalComponent())

  446.                     {

  447.                         if (auto* modalHandler = modal->getAccessibilityHandler())

  448.                         {

  449.                             if (modalHandler == handler || modalHandler->isParentOf (handler))

  450.                             {

  451.                                 modal->exitModalState (0);

  452.                                 return YES;

  453.                             }

  454.                         }

  455.                     }

  456.                 }

  457. 

  458.                 return NO;

  459.             });

  460. 

  461.             if (elementType == Type::textElement)

  462.             {

  463.                 addMethod (@selector (deleteBackward), [] (id, SEL) {});

  464.                 addMethod (@selector (insertText:), [] (id, SEL, NSString*) {});

  465. 

  466.                 forEach ([this] (auto signature) { addPassthroughMethodWithSignature (signature); },

  467.                          SignatureHasText{},

  468.                          SignatureSetSelectedTextRange{},

  469.                          SignatureSelectedTextRange{},

  470.                          SignatureMarkedTextRange{},

  471.                          SignatureSetMarkedTextSelectedRange{},

  472.                          SignatureUnmarkText{},

  473.                          SignatureMarkedTextStyle{},

  474.                          SignatureSetMarkedTextStyle{},

  475.                          SignatureBeginningOfDocument{},

  476.                          SignatureEndOfDocument{},

  477.                          SignatureTokenizer{},

  478.                          SignatureBaseWritingDirection{},

  479.                          SignatureCaretRectForPosition{},

  480.                          SignatureCharacterRangeByExtending{},

  481.                          SignatureCharacterRangeAtPoint{},

  482.                          SignatureClosestPositionToPoint{},

  483.                          SignatureClosestPositionToPointInRange{},

  484.                          SignatureComparePositionToPosition{},

  485.                          SignatureOffsetFromPositionToPosition{},

  486.                          SignaturePositionFromPositionInDirection{},

  487.                          SignaturePositionFromPositionOffset{},

  488.                          SignatureFirstRectForRange{},

  489.                          SignatureSelectionRectsForRange{},

  490.                          SignaturePositionWithinRange{},

  491.                          SignatureReplaceRangeWithText{},

  492.                          SignatureSetBaseWritingDirection{},

  493.                          SignatureTextInRange{},

  494.                          SignatureTextRangeFromPosition{},

  495.                          SignatureSetInputDelegate{},

  496.                          SignatureInputDelegate{},

  497.                          SignatureKeyboardType{},

  498.                          SignatureAutocapitalizationType{},

  499.                          SignatureAutocorrectionType{});

  500. 

  501.                 addProtocol (@protocol (UITextInput));

  502.             }

  503. 

  504.             if (@available (iOS 11.0, *))

  505.             {

  506.                 addMethod (@selector (accessibilityRowRange),                           getAccessibilityRowIndexRange);

  507.                 addMethod (@selector (accessibilityColumnRange),                        getAccessibilityColumnIndexRange);

  508.                 addProtocol (@protocol (UIAccessibilityContainerDataTableCell));

  509.             }

  510. 

  511.             addIvar<UIAccessibilityElement*> ("container");

  512. 

  513.             registerClass();

  514.         }

  515. 

  516.     private:

  517.         template <typename Result>

  518.         static auto getResult (NSInvocation* invocation, detail::Tag<Result>)

  519.         {

  520.             Result result{};

  521.             [invocation getReturnValue: &result];

  522.             return result;

  523.         }

  524. 

  525.         static void getResult (NSInvocation*, detail::Tag<void>) {}

  526. 

  527.         template <typename HasSelector, typename Result, typename... Args>

  528.         auto makePassthroughCallback (HasSelector, Signature<Result (Args...)>)

  529.         {

  530.             return [] (id self, SEL, Args... args) -> Result

  531.             {

  532.                 if (auto* input = getPeerTextInput (self))

  533.                 {

  534.                     const auto s = detail::makeCompileTimeStr (@encode (Result), @encode (id), @encode (SEL), @encode (Args)...);

  535.                     const auto signature = [NSMethodSignature signatureWithObjCTypes: s.data()];

  536.                     const auto invocation = [NSInvocation invocationWithMethodSignature: signature];

  537.                     invocation.selector = HasSelector::sel();

  538. 

  539.                     // Indices 0 and 1 are 'id self' and 'SEL _cmd' respectively

  540.                     auto counter = 2;

  541.                     forEach ([&] (auto& arg) { [invocation setArgument: &arg atIndex: counter++]; }, args...);

  542. 

  543.                     [invocation invokeWithTarget: input];

  544. 

  545.                     return getResult (invocation, detail::Tag<Result>{});

  546.                 }

  547. 

  548.                 jassertfalse;

  549.                 return {};

  550.             };

  551.         }

  552. 

  553.         template <typename Signature>

  554.         void addPassthroughMethodWithSignature (Signature signature)

  555.         {

  556.             addMethod (Signature::sel(), makePassthroughCallback (signature, signature));

  557.         }

  558. 

  559.         static UIAccessibilityElement* getContainer (id self)

  560.         {

  561.             return getIvar<UIAccessibilityElement*> (self, "container");

  562.         }

  563. 

  564.         static UIViewComponentPeer* getPeer (id self)

  565.         {

  566.             if (auto* handler = getHandler (self))

  567.                 return static_cast<UIViewComponentPeer*> (handler->getComponent().getPeer());

  568. 

  569.             return nil;

  570.         }

  571. 

  572.         static JuceTextView* getPeerTextInput (id self)

  573.         {

  574.             if (auto* peer = getPeer (self))

  575.                 return peer->hiddenTextInput.get();

  576. 

  577.             return nil;

  578.         }

  579. 

  580.         //==============================================================================

  581.         JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityElement)

  582.     };

  583. 

  584.     //==============================================================================

  585.     AccessibilityElement::Holder accessibilityElement;

  586. 

  587.     //==============================================================================

  588.     JUCE_DECLARE_NON_COPYABLE_WITH_LEAK_DETECTOR (AccessibilityNativeImpl)

  589. };

  590. 

  591. //==============================================================================

  592. AccessibilityNativeHandle* AccessibilityHandler::getNativeImplementation() const

  593. {

  594.     return (AccessibilityNativeHandle*) nativeImpl->getAccessibilityElement();

  595. }

  596. 

  597. static bool areAnyAccessibilityClientsActive()

  598. {

  599.     return UIAccessibilityIsVoiceOverRunning();

  600. }

  601. 

  602. static void sendAccessibilityEvent (UIAccessibilityNotifications notification, id argument)

  603. {

  604.     if (! areAnyAccessibilityClientsActive())

  605.         return;

  606. 

  607.     jassert (notification != UIAccessibilityNotifications{});

  608. 

  609.     UIAccessibilityPostNotification (notification, argument);

  610. }

  611. 

  612. void notifyAccessibilityEventInternal (const AccessibilityHandler& handler, InternalAccessibilityEvent eventType)

  613. {

  614.     auto notification = [eventType]

  615.     {

  616.         switch (eventType)

  617.         {

  618.             case InternalAccessibilityEvent::elementCreated:

  619.             case InternalAccessibilityEvent::elementDestroyed:

  620.             case InternalAccessibilityEvent::elementMovedOrResized:

  621.             case InternalAccessibilityEvent::focusChanged:           return UIAccessibilityLayoutChangedNotification;

  622. 

  623.             case InternalAccessibilityEvent::windowOpened:

  624.             case InternalAccessibilityEvent::windowClosed:           return UIAccessibilityScreenChangedNotification;

  625.         }

  626. 

  627.         return UIAccessibilityNotifications{};

  628.     }();

  629. 

  630.     if (notification != UIAccessibilityNotifications{})

  631.     {

  632.         const bool moveToHandler = (eventType == InternalAccessibilityEvent::focusChanged && handler.hasFocus (false));

  633. 

  634.         sendAccessibilityEvent (notification,

  635.                                 moveToHandler ? static_cast<id> (handler.getNativeImplementation()) : nil);

  636.     }

  637. }

  638. 

  639. void AccessibilityHandler::notifyAccessibilityEvent (AccessibilityEvent eventType) const

  640. {

  641.     auto notification = [eventType]

  642.     {

  643.         switch (eventType)

  644.         {

  645.             case AccessibilityEvent::textSelectionChanged:

  646.             case AccessibilityEvent::rowSelectionChanged:

  647.             case AccessibilityEvent::textChanged:

  648.             case AccessibilityEvent::valueChanged:

  649.             case AccessibilityEvent::titleChanged:          break;

  650. 

  651.             case AccessibilityEvent::structureChanged:      return UIAccessibilityLayoutChangedNotification;

  652.         }

  653. 

  654.         return UIAccessibilityNotifications{};

  655.     }();

  656. 

  657.     if (notification != UIAccessibilityNotifications{})

  658.         sendAccessibilityEvent (notification, static_cast<id> (getNativeImplementation()));

  659. }

  660. 

  661. void AccessibilityHandler::postAnnouncement (const String& announcementString, AnnouncementPriority)

  662. {

  663.     sendAccessibilityEvent (UIAccessibilityAnnouncementNotification, juceStringToNS (announcementString));

  664. }

  665. 

  666. } // namespace juce