DISTRHO
/
JUCE
mirror of https://github.com/DISTRHO/JUCE
1
0
Fork 0
Code Releases 1 Activity
The JUCE cross-platform C++ framework, with DISTRHO/KXStudio specific changes
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
8746 Commits
11 Branches
450MB
Tree: 107ba1fd69
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '107ba1fd69'
${ noResults }
JUCE/modules/juce_audio_plugin_client/AU/juce_AUv3_Wrapper.mm

1792 lines
78KB
Raw Blame History 

  1. /*

  2.   ==============================================================================

  3. 

  4.    This file is part of the JUCE library.

  5.    Copyright (c) 2017 - ROLI Ltd.

  6. 

  7.    JUCE is an open source library subject to commercial or open-source

  8.    licensing.

  9. 

  10.    By using JUCE, you agree to the terms of both the JUCE 5 End-User License

  11.    Agreement and JUCE 5 Privacy Policy (both updated and effective as of the

  12.    27th April 2017).

  13. 

  14.    End User License Agreement: www.juce.com/juce-5-licence

  15.    Privacy Policy: www.juce.com/juce-5-privacy-policy

  16. 

  17.    Or: You may also use this code under the terms of the GPL v3 (see

  18.    www.gnu.org/licenses).

  19. 

  20.    JUCE IS PROVIDED "AS IS" WITHOUT ANY WARRANTY, AND ALL WARRANTIES, WHETHER

  21.    EXPRESSED OR IMPLIED, INCLUDING MERCHANTABILITY AND FITNESS FOR PURPOSE, ARE

  22.    DISCLAIMED.

  23. 

  24.   ==============================================================================

  25. */

  26. 

  27. #include "../../juce_core/system/juce_TargetPlatform.h"

  28. #include "../utility/juce_CheckSettingMacros.h"

  29. 

  30. #if JucePlugin_Build_AUv3

  31. 

  32. #import <CoreAudioKit/CoreAudioKit.h>

  33. #import <AudioToolbox/AudioToolbox.h>

  34. #import <AVFoundation/AVFoundation.h>

  35. 

  36. #if JUCE_MAC

  37.  #if (! defined MAC_OS_X_VERSION_MIN_REQUIRED) || (! defined MAC_OS_X_VERSION_10_11) || (MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_11)

  38.   #error AUv3 needs Deployment Target OS X 10.11 or higher to compile

  39.  #endif

  40.  #if (defined MAC_OS_X_VERSION_10_13) && (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_13)

  41.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  42.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  43.  #endif

  44. #endif

  45. 

  46. #if JUCE_IOS

  47.  #if (! defined __IPHONE_OS_VERSION_MIN_REQUIRED) || (! defined __IPHONE_9_0) || (__IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_9_0)

  48.   #error AUv3 needs Deployment Target iOS 9.0 or higher to compile

  49.  #endif

  50.  #if (defined __IPHONE_11_0) && (__IPHONE_OS_VERSION_MIN_REQUIRED >= __IPHONE_11_0)

  51.   #define JUCE_AUV3_MIDI_OUTPUT_SUPPORTED 1

  52.   #define JUCE_AUV3_VIEW_CONFIG_SUPPORTED 1

  53.  #endif

  54. #endif

  55. 

  56. #ifndef __OBJC2__

  57.  #error AUv3 needs Objective-C 2 support (compile with 64-bit)

  58. #endif

  59. 

  60. #define JUCE_CORE_INCLUDE_OBJC_HELPERS 1

  61. 

  62. #include "../utility/juce_IncludeSystemHeaders.h"

  63. #include "../utility/juce_IncludeModuleHeaders.h"

  64. #include "../../juce_graphics/native/juce_mac_CoreGraphicsHelpers.h"

  65. 

  66. #include "../../juce_audio_basics/native/juce_mac_CoreAudioLayouts.h"

  67. #include "../../juce_audio_processors/format_types/juce_AU_Shared.h"

  68. 

  69. #define JUCE_VIEWCONTROLLER_OBJC_NAME(x) JUCE_JOIN_MACRO (x, FactoryAUv3)

  70. 

  71. #if JUCE_IOS

  72.  #define JUCE_IOS_MAC_VIEW  UIView

  73. #else

  74.  #define JUCE_IOS_MAC_VIEW  NSView

  75. #endif

  76. 

  77. #define JUCE_AUDIOUNIT_OBJC_NAME(x) JUCE_JOIN_MACRO (x, AUv3)

  78. 

  79. #pragma clang diagnostic push

  80. #pragma clang diagnostic ignored "-Wnullability-completeness"

  81. 

  82. using namespace juce;

  83. 

  84. // TODO: use SFINAE to automatically generate this for all NSObjects

  85. template <> struct ContainerDeletePolicy<AUAudioUnitBusArray>                   { static void destroy (NSObject* o) { [o release]; } };

  86. template <> struct ContainerDeletePolicy<AUParameterTree>                       { static void destroy (NSObject* o) { [o release]; } };

  87. template <> struct ContainerDeletePolicy<NSMutableArray<AUParameterNode*>>      { static void destroy (NSObject* o) { [o release]; } };

  88. template <> struct ContainerDeletePolicy<AUParameter>                           { static void destroy (NSObject* o) { [o release]; } };

  89. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitBus*>>       { static void destroy (NSObject* o) { [o release]; } };

  90. template <> struct ContainerDeletePolicy<AUAudioUnitBus>                        { static void destroy (NSObject* o) { [o release]; } };

  91. template <> struct ContainerDeletePolicy<AVAudioFormat>                         { static void destroy (NSObject* o) { [o release]; } };

  92. template <> struct ContainerDeletePolicy<AVAudioPCMBuffer>                      { static void destroy (NSObject* o) { [o release]; } };

  93. template <> struct ContainerDeletePolicy<NSMutableArray<NSNumber*>>             { static void destroy (NSObject* o) { [o release]; } };

  94. template <> struct ContainerDeletePolicy<NSNumber>                              { static void destroy (NSObject* o) { [o release]; } };

  95. template <> struct ContainerDeletePolicy<NSMutableArray<AUAudioUnitPreset*>>    { static void destroy (NSObject* o) { [o release]; } };

  96. template <> struct ContainerDeletePolicy<AUAudioUnitPreset>                     { static void destroy (NSObject* o) { [o release]; } };

  97. 

  98. //==============================================================================

  99. struct AudioProcessorHolder  : public ReferenceCountedObject

  100. {

  101.     AudioProcessorHolder() {}

  102.     AudioProcessorHolder (AudioProcessor* p) : processor (p) {}

  103.     AudioProcessor& operator*() noexcept        { return *processor; }

  104.     AudioProcessor* operator->() noexcept       { return processor; }

  105.     AudioProcessor* get() noexcept              { return processor; }

  106. 

  107.     struct ViewConfig

  108.     {

  109.         double width;

  110.         double height;

  111.         bool hostHasMIDIController;

  112.     };

  113. 

  114.     ScopedPointer<ViewConfig> viewConfiguration;

  115. 

  116.     typedef ReferenceCountedObjectPtr<AudioProcessorHolder> Ptr;

  117. 

  118. private:

  119.     ScopedPointer<AudioProcessor> processor;

  120. 

  121.     AudioProcessorHolder& operator= (AudioProcessor*) = delete;

  122.     AudioProcessorHolder (AudioProcessorHolder&) = delete;

  123.     AudioProcessorHolder& operator= (AudioProcessorHolder&) = delete;

  124. };

  125. 

  126. //==============================================================================

  127. class JuceAudioUnitv3Base

  128. {

  129. public:

  130.     JuceAudioUnitv3Base (const AudioComponentDescription& descr,

  131.                          AudioComponentInstantiationOptions options,

  132.                          NSError** error)

  133.        #pragma clang diagnostic push

  134.        #pragma clang diagnostic ignored "-Wobjc-method-access"

  135.         : au ([audioUnitObjCClass.createInstance() initWithComponentDescription: descr

  136.                                                                         options: options

  137.                                                                           error: error

  138.                                                                       juceClass: this])

  139.        #pragma clang diagnostic pop

  140.     {}

  141. 

  142.     JuceAudioUnitv3Base (AUAudioUnit* audioUnit) : au (audioUnit)

  143.     {

  144.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  145.         initialiseJuce_GUI();

  146.     }

  147. 

  148.     virtual ~JuceAudioUnitv3Base() {}

  149. 

  150.     //==============================================================================

  151.     AUAudioUnit* getAudioUnit() noexcept                                   { return au; }

  152. 

  153.     //==============================================================================

  154.     virtual void reset()                                                   = 0;

  155. 

  156.     //==============================================================================

  157.     virtual AUAudioUnitPreset* getCurrentPreset()                          = 0;

  158.     virtual void setCurrentPreset(AUAudioUnitPreset*)                      = 0;

  159.     virtual NSArray<AUAudioUnitPreset*>* getFactoryPresets()               = 0;

  160. 

  161.     virtual NSDictionary<NSString*, id>* getFullState()

  162.     {

  163.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  164.         return ObjCMsgSendSuper<NSDictionary<NSString*, id>*> (&s, @selector (fullState));

  165.     }

  166. 

  167.     virtual void setFullState (NSDictionary<NSString*, id>* state)

  168.     {

  169.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  170.         ObjCMsgSendSuper<void, NSDictionary<NSString*, id>*> (&s, @selector (setFullState:), state);

  171.     }

  172. 

  173.     virtual AUParameterTree* getParameterTree()                            = 0;

  174.     virtual NSArray<NSNumber*>* parametersForOverviewWithCount (int)       = 0;

  175. 

  176.     //==============================================================================

  177.     virtual NSTimeInterval getLatency()                                    = 0;

  178.     virtual NSTimeInterval getTailTime()                                   = 0;

  179. 

  180.     //==============================================================================

  181.     virtual AUAudioUnitBusArray* getInputBusses()                          = 0;

  182.     virtual AUAudioUnitBusArray* getOutputBusses()                         = 0;

  183.     virtual NSArray<NSNumber*>* getChannelCapabilities()                   = 0;

  184.     virtual bool shouldChangeToFormat (AVAudioFormat*, AUAudioUnitBus*)    = 0;

  185. 

  186.     //==============================================================================

  187.     virtual int getVirtualMIDICableCount()                                 = 0;

  188.     virtual bool getSupportsMPE()                                          = 0;

  189.     virtual NSArray<NSString*>* getMIDIOutputNames()                       = 0;

  190. 

  191.     //==============================================================================

  192.     virtual AUInternalRenderBlock getInternalRenderBlock()                 = 0;

  193.     virtual bool getCanProcessInPlace()                                    { return false; }

  194.     virtual bool getRenderingOffline()                                     = 0;

  195.     virtual void setRenderingOffline (bool offline)                        = 0;

  196. 

  197.     //==============================================================================

  198.     virtual NSString* getContextName()      const                          = 0;

  199.     virtual void setContextName (NSString*)                                = 0;

  200. 

  201.     virtual bool allocateRenderResourcesAndReturnError (NSError **outError)

  202.     {

  203.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  204.         return (ObjCMsgSendSuper<BOOL, NSError**> (&s, @selector (allocateRenderResourcesAndReturnError:), outError) == YES);

  205.     }

  206. 

  207.     virtual void deallocateRenderResources()

  208.     {

  209.         objc_super s = { getAudioUnit(), [AUAudioUnit class] };

  210.         ObjCMsgSendSuper<void> (&s, @selector (deallocateRenderResources));

  211.     }

  212. 

  213.     //==============================================================================

  214.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  215.     virtual NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>*) = 0;

  216.     virtual void selectViewConfiguration (AUAudioUnitViewConfiguration*)   = 0;

  217.    #endif

  218. 

  219. private:

  220.     struct Class  : public ObjCClass<AUAudioUnit>

  221.     {

  222.         Class() : ObjCClass<AUAudioUnit> ("AUAudioUnit_")

  223.         {

  224.             addIvar<JuceAudioUnitv3Base*> ("cppObject");

  225. 

  226.            #pragma clang diagnostic push

  227.            #pragma clang diagnostic ignored "-Wundeclared-selector"

  228.             addMethod (@selector (initWithComponentDescription:options:error:juceClass:),

  229.                        initWithComponentDescriptionAndJuceClass, "@@:",

  230.                        @encode (AudioComponentDescription),

  231.                        @encode (AudioComponentInstantiationOptions), "^@@");

  232.            #pragma clang diagnostic pop

  233. 

  234.             addMethod (@selector (initWithComponentDescription:options:error:),

  235.                        initWithComponentDescription, "@@:",

  236.                        @encode (AudioComponentDescription),

  237.                        @encode (AudioComponentInstantiationOptions), "^@");

  238. 

  239.             addMethod (@selector (dealloc),                         dealloc,                        "v@:");

  240. 

  241.             //==============================================================================

  242.             addMethod (@selector (reset),                           reset,                          "v@:");

  243. 

  244.             //==============================================================================

  245.             addMethod (@selector (currentPreset),                   getCurrentPreset,               "@@:");

  246.             addMethod (@selector (setCurrentPreset:),               setCurrentPreset,               "v@:@");

  247.             addMethod (@selector (factoryPresets),                  getFactoryPresets,              "@@:");

  248.             addMethod (@selector (fullState),                       getFullState,                   "@@:");

  249.             addMethod (@selector (setFullState:),                   setFullState,                   "v@:@");

  250.             addMethod (@selector (parameterTree),                   getParameterTree,               "@@:");

  251.             addMethod (@selector (parametersForOverviewWithCount:), parametersForOverviewWithCount, "@@:", @encode (NSInteger));

  252. 

  253.             //==============================================================================

  254.             addMethod (@selector (latency),                         getLatency,                     @encode (NSTimeInterval), "@:");

  255.             addMethod (@selector (tailTime),                        getTailTime,                    @encode (NSTimeInterval),  "@:");

  256. 

  257.             //==============================================================================

  258.             addMethod (@selector (inputBusses),                     getInputBusses,                 "@@:");

  259.             addMethod (@selector (outputBusses),                    getOutputBusses,                "@@:");

  260.             addMethod (@selector (channelCapabilities),             getChannelCapabilities,         "@@:");

  261.             addMethod (@selector (shouldChangeToFormat:forBus:),    shouldChangeToFormat,           "B@:@@");

  262. 

  263.             //==============================================================================

  264.             addMethod (@selector (virtualMIDICableCount),           getVirtualMIDICableCount,       @encode (NSInteger), "@:");

  265.             addMethod (@selector (supportsMPE),                     getSupportsMPE,                 @encode (BOOL),      "@:");

  266. 

  267.            #if JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  268.             addMethod (@selector (MIDIOutputNames),                 getMIDIOutputNames,             "@@:");

  269.            #endif

  270. 

  271.             //==============================================================================

  272.             addMethod (@selector (internalRenderBlock),             getInternalRenderBlock,         @encode (AUInternalRenderBlock), "@:");

  273.             addMethod (@selector (canProcessInPlace),               getCanProcessInPlace,           @encode (BOOL), "@:");

  274.             addMethod (@selector (isRenderingOffline),              getRenderingOffline,            @encode (BOOL),  "@:");

  275.             addMethod (@selector (setRenderingOffline:),            setRenderingOffline,            "v@:", @encode (BOOL));

  276.             addMethod (@selector (allocateRenderResourcesAndReturnError:),  allocateRenderResourcesAndReturnError, "B@:^@");

  277.             addMethod (@selector (deallocateRenderResources),       deallocateRenderResources,      "v@:");

  278. 

  279.             //==============================================================================

  280.             addMethod (@selector (contextName),                     getContextName,                 "@@:");

  281.             addMethod (@selector (setContextName:),                  setContextName,                 "v@:@");

  282. 

  283.             //==============================================================================

  284.            #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  285.             addMethod (@selector (supportedViewConfigurations:),    getSupportedViewConfigurations, "@@:@");

  286.             addMethod (@selector (selectViewConfiguration:),        selectViewConfiguration,        "v@:@");

  287.            #endif

  288. 

  289.             registerClass();

  290.         }

  291. 

  292.         //==============================================================================

  293.         static JuceAudioUnitv3Base* _this (id self)                     { return getIvar<JuceAudioUnitv3Base*> (self, "cppObject"); }

  294.         static void setThis (id self, JuceAudioUnitv3Base* cpp)         { object_setInstanceVariable           (self, "cppObject", cpp); }

  295. 

  296.         //==============================================================================

  297.         static id initWithComponentDescription (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  298.         {

  299.             AUAudioUnit* self = _self;

  300. 

  301.             objc_super s = { self, [AUAudioUnit class] };

  302.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  303.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  304. 

  305.             JuceAudioUnitv3Base* juceAU = JuceAudioUnitv3Base::create (self, descr, options, error);

  306. 

  307.             setThis (self, juceAU);

  308.             return self;

  309.         }

  310. 

  311.         static id initWithComponentDescriptionAndJuceClass (id _self, SEL, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error, JuceAudioUnitv3Base* juceAU)

  312.         {

  313.             AUAudioUnit* self = _self;

  314. 

  315.             objc_super s = { self, [AUAudioUnit class] };

  316.             self = ObjCMsgSendSuper<AUAudioUnit*, AudioComponentDescription,

  317.                                     AudioComponentInstantiationOptions, NSError**> (&s, @selector(initWithComponentDescription:options:error:), descr, options, error);

  318. 

  319. 

  320.             setThis (self, juceAU);

  321.             return self;

  322.         }

  323. 

  324.         static void dealloc (id self, SEL)

  325.         {

  326.             if (! MessageManager::getInstance()->isThisTheMessageThread())

  327.             {

  328.                 WaitableEvent deletionEvent;

  329. 

  330.                 struct AUDeleter  : public CallbackMessage

  331.                 {

  332.                     AUDeleter (id selfToDelete, WaitableEvent& event)

  333.                         : parentSelf (selfToDelete), parentDeletionEvent (event)

  334.                     {

  335.                     }

  336. 

  337.                     void messageCallback() override

  338.                     {

  339.                         delete _this (parentSelf);

  340.                         parentDeletionEvent.signal();

  341.                     }

  342. 

  343.                     id parentSelf;

  344.                     WaitableEvent& parentDeletionEvent;

  345.                 };

  346. 

  347.                 (new AUDeleter (self, deletionEvent))->post();

  348.                 deletionEvent.wait (-1);

  349.             }

  350.             else

  351.             {

  352.                 delete _this (self);

  353.             }

  354.         }

  355. 

  356.         //==============================================================================

  357.         static void reset (id self, SEL)                                                            { _this (self)->reset(); }

  358. 

  359.         //==============================================================================

  360.         static AUAudioUnitPreset* getCurrentPreset (id self, SEL)                                   { return _this (self)->getCurrentPreset(); }

  361.         static void setCurrentPreset (id self, SEL, AUAudioUnitPreset* preset)                      { return _this (self)->setCurrentPreset (preset); }

  362.         static NSArray<AUAudioUnitPreset*>* getFactoryPresets (id self, SEL)                        { return _this (self)->getFactoryPresets(); }

  363.         static NSDictionary<NSString*, id>* getFullState (id self, SEL)                             { return _this (self)->getFullState(); }

  364.         static void setFullState (id self, SEL, NSDictionary<NSString *, id>* state)                { return _this (self)->setFullState (state); }

  365.         static AUParameterTree*     getParameterTree (id self, SEL)                                 { return _this (self)->getParameterTree(); }

  366.         static NSArray<NSNumber*>* parametersForOverviewWithCount (id self, SEL, NSInteger count)   { return _this (self)->parametersForOverviewWithCount (static_cast<int> (count)); }

  367. 

  368.         //==============================================================================

  369.         static NSTimeInterval getLatency (id self, SEL)                                             { return _this (self)->getLatency(); }

  370.         static NSTimeInterval getTailTime (id self, SEL)                                            { return _this (self)->getTailTime(); }

  371. 

  372.         //==============================================================================

  373.         static AUAudioUnitBusArray* getInputBusses   (id self, SEL)                                 { return _this (self)->getInputBusses(); }

  374.         static AUAudioUnitBusArray* getOutputBusses  (id self, SEL)                                 { return _this (self)->getOutputBusses(); }

  375.         static NSArray<NSNumber*>* getChannelCapabilities (id self, SEL)                            { return _this (self)->getChannelCapabilities(); }

  376.         static BOOL shouldChangeToFormat (id self, SEL, AVAudioFormat* format, AUAudioUnitBus* bus) { return _this (self)->shouldChangeToFormat (format, bus) ? YES : NO; }

  377. 

  378.         //==============================================================================

  379.         static NSInteger getVirtualMIDICableCount (id self, SEL)                                    { return _this (self)->getVirtualMIDICableCount(); }

  380.         static BOOL getSupportsMPE (id self, SEL)                                                   { return _this (self)->getSupportsMPE() ? YES : NO; }

  381.         static NSArray<NSString*>* getMIDIOutputNames (id self, SEL)                                { return _this (self)->getMIDIOutputNames(); }

  382. 

  383.         //==============================================================================

  384.         static AUInternalRenderBlock getInternalRenderBlock (id self, SEL)                          { return _this (self)->getInternalRenderBlock();  }

  385.         static BOOL getCanProcessInPlace (id self, SEL)                                             { return _this (self)->getCanProcessInPlace() ? YES : NO; }

  386.         static BOOL getRenderingOffline (id self, SEL)                                              { return _this (self)->getRenderingOffline() ? YES : NO; }

  387.         static void setRenderingOffline (id self, SEL, BOOL renderingOffline)                       { _this (self)->setRenderingOffline (renderingOffline); }

  388.         static BOOL allocateRenderResourcesAndReturnError (id self, SEL, NSError** error)           { return _this (self)->allocateRenderResourcesAndReturnError (error) ? YES : NO; }

  389.         static void deallocateRenderResources (id self, SEL)                                        { _this (self)->deallocateRenderResources(); }

  390. 

  391.         //==============================================================================

  392.         static NSString* getContextName (id self, SEL)                                              { return _this (self)->getContextName(); }

  393.         static void setContextName (id self, SEL, NSString* str)                                    { return _this (self)->setContextName (str); }

  394. 

  395.         //==============================================================================

  396.        #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  397.         static NSIndexSet* getSupportedViewConfigurations (id self, SEL, NSArray<AUAudioUnitViewConfiguration*>* configs) { return _this (self)->getSupportedViewConfigurations (configs); }

  398.         static void selectViewConfiguration (id self, SEL, AUAudioUnitViewConfiguration* config)    { _this (self)->selectViewConfiguration (config); }

  399.        #endif

  400.     };

  401. 

  402.     static JuceAudioUnitv3Base* create (AUAudioUnit*, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**);

  403. 

  404.     //==============================================================================

  405.     static Class audioUnitObjCClass;

  406. 

  407. protected:

  408.     AUAudioUnit* au;

  409. };

  410. 

  411. //==============================================================================

  412. JuceAudioUnitv3Base::Class JuceAudioUnitv3Base::audioUnitObjCClass;

  413. 

  414. //==============================================================================

  415. //=========================== The actual AudioUnit =============================

  416. //==============================================================================

  417. class JuceAudioUnitv3  : public JuceAudioUnitv3Base,

  418.                          public AudioProcessorListener,

  419.                          public AudioPlayHead

  420. {

  421. public:

  422.     JuceAudioUnitv3 (const AudioProcessorHolder::Ptr& processor,

  423.                      const AudioComponentDescription& descr,

  424.                      AudioComponentInstantiationOptions options,

  425.                      NSError** error)

  426.         : JuceAudioUnitv3Base (descr, options, error),

  427.           processorHolder (processor),

  428.           mapper (*processorHolder->get())

  429.     {

  430.         init();

  431.     }

  432. 

  433.     JuceAudioUnitv3 (AUAudioUnit* audioUnit, AudioComponentDescription, AudioComponentInstantiationOptions, NSError**)

  434.         : JuceAudioUnitv3Base (audioUnit),

  435.           processorHolder (new AudioProcessorHolder (createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))),

  436.           mapper (*processorHolder->get())

  437.     {

  438.         init();

  439.     }

  440. 

  441.     ~JuceAudioUnitv3()

  442.     {

  443.         auto& processor = getAudioProcessor();

  444.         processor.removeListener (this);

  445. 

  446.         removeEditor (processor);

  447. 

  448.         if (editorObserverToken != nullptr)

  449.         {

  450.             [paramTree removeParameterObserver: editorObserverToken];

  451.             editorObserverToken = nullptr;

  452.         }

  453.     }

  454. 

  455.     //==============================================================================

  456.     void init()

  457.     {

  458.         AudioProcessor& processor = getAudioProcessor();

  459.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  460. 

  461.        #ifdef JucePlugin_PreferredChannelConfigurations

  462.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  463.         const int numConfigs = sizeof (configs) / sizeof (short[2]);

  464. 

  465.         jassert (numConfigs > 0 && (configs[0][0] > 0 || configs[0][1] > 0));

  466.         processor.setPlayConfigDetails (configs[0][0], configs[0][1], kDefaultSampleRate, static_cast<int> (maxFrames));

  467. 

  468.         Array<AUChannelInfo> channelInfos;

  469. 

  470.         for (int i = 0; i < numConfigs; ++i)

  471.         {

  472.             AUChannelInfo channelInfo;

  473. 

  474.             channelInfo.inChannels  = configs[i][0];

  475.             channelInfo.outChannels = configs[i][1];

  476. 

  477.             channelInfos.add (channelInfo);

  478.         }

  479.        #else

  480.         Array<AUChannelInfo> channelInfos = AudioUnitHelpers::getAUChannelInfo (processor);

  481.        #endif

  482. 

  483.         processor.setPlayHead (this);

  484. 

  485.         totalInChannels  = processor.getTotalNumInputChannels();

  486.         totalOutChannels = processor.getTotalNumOutputChannels();

  487. 

  488.         {

  489.             channelCapabilities = [[NSMutableArray<NSNumber*> alloc] init];

  490. 

  491. 

  492.             for (int i = 0; i < channelInfos.size(); ++i)

  493.             {

  494.                 AUChannelInfo& info = channelInfos.getReference (i);

  495. 

  496.                 [channelCapabilities addObject: [NSNumber numberWithInteger: info.inChannels]];

  497.                 [channelCapabilities addObject: [NSNumber numberWithInteger: info.outChannels]];

  498.             }

  499.         }

  500. 

  501.         editorObserverToken = nullptr;

  502.         internalRenderBlock = CreateObjCBlock (this, &JuceAudioUnitv3::renderCallback);

  503. 

  504.         processor.setRateAndBufferSizeDetails (kDefaultSampleRate, static_cast<int> (maxFrames));

  505.         processor.prepareToPlay (kDefaultSampleRate, static_cast<int> (maxFrames));

  506.         processor.addListener (this);

  507. 

  508.         addParameters();

  509.         addPresets();

  510. 

  511.         addAudioUnitBusses (true);

  512.         addAudioUnitBusses (false);

  513.     }

  514. 

  515.     AudioProcessor& getAudioProcessor() const noexcept        { return **processorHolder; }

  516. 

  517.     //==============================================================================

  518.     void reset() override

  519.     {

  520.         midiMessages.clear();

  521.         lastTimeStamp.mSampleTime = std::numeric_limits<Float64>::max();

  522.     }

  523. 

  524.     //==============================================================================

  525.     AUAudioUnitPreset* getCurrentPreset() override

  526.     {

  527.         const int n = static_cast<int> ([factoryPresets count]);

  528.         const int idx = static_cast<int> (getAudioProcessor().getCurrentProgram());

  529. 

  530.         if (idx < n)

  531.             return [factoryPresets objectAtIndex:static_cast<unsigned int> (idx)];

  532. 

  533.         return nullptr;

  534.     }

  535. 

  536.     void setCurrentPreset(AUAudioUnitPreset* preset) override

  537.     {

  538.         const int n = static_cast<int> ([factoryPresets count]);

  539.         const int idx = static_cast<int> ([preset number]);

  540. 

  541.         if (isPositiveAndBelow (idx, n))

  542.             getAudioProcessor().setCurrentProgram (idx);

  543.     }

  544. 

  545.     NSArray<AUAudioUnitPreset*>* getFactoryPresets() override

  546.     {

  547.         return factoryPresets;

  548.     }

  549. 

  550.     NSDictionary<NSString*, id>* getFullState() override

  551.     {

  552.         NSMutableDictionary<NSString*, id>* retval = [[NSMutableDictionary<NSString*, id> alloc] init];

  553. 

  554.         {

  555.             NSDictionary<NSString*, id>* superRetval = JuceAudioUnitv3Base::getFullState();

  556. 

  557.             if (superRetval != nullptr)

  558.                 [retval addEntriesFromDictionary:superRetval];

  559.         }

  560. 

  561.         juce::MemoryBlock state;

  562.         getAudioProcessor().getCurrentProgramStateInformation (state);

  563. 

  564.         if (state.getSize() > 0)

  565.         {

  566.             NSData* ourState = [[NSData alloc] initWithBytes: state.getData()

  567.                                                       length: state.getSize()];

  568. 

  569.             NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  570. 

  571.             [retval setObject: ourState

  572.                        forKey: nsKey];

  573. 

  574.             [nsKey    release];

  575.             [ourState release];

  576.         }

  577. 

  578.         return [retval autorelease];

  579.     }

  580. 

  581.     void setFullState (NSDictionary<NSString*, id>* state) override

  582.     {

  583.         if (state == nullptr)

  584.             return;

  585. 

  586.         NSMutableDictionary<NSString*, id>* modifiedState = [[NSMutableDictionary<NSString*, id> alloc] init];

  587.         [modifiedState addEntriesFromDictionary: state];

  588. 

  589.         NSString* nsPresetKey = [[NSString alloc] initWithUTF8String: kAUPresetDataKey];

  590.         [modifiedState removeObjectForKey: nsPresetKey];

  591.         [nsPresetKey release];

  592. 

  593.         JuceAudioUnitv3Base::setFullState (modifiedState);

  594. 

  595.         NSString* nsKey = [[NSString alloc] initWithUTF8String: JUCE_STATE_DICTIONARY_KEY];

  596.         NSObject* obj = [modifiedState objectForKey: nsKey];

  597.         [nsKey release];

  598. 

  599.         if (obj != nullptr)

  600.         {

  601.             if ([obj isKindOfClass:[NSData class]])

  602.             {

  603.                 NSData* data = reinterpret_cast<NSData*> (obj);

  604.                 const int numBytes = static_cast<int> ([data length]);

  605.                 const juce::uint8* const rawBytes = reinterpret_cast< const juce::uint8* const> ([data bytes]);

  606. 

  607.                 if (numBytes > 0)

  608.                     getAudioProcessor().setCurrentProgramStateInformation (rawBytes, numBytes);

  609.             }

  610.         }

  611. 

  612.         [modifiedState release];

  613.     }

  614. 

  615.     AUParameterTree* getParameterTree() override

  616.     {

  617.         return paramTree;

  618.     }

  619. 

  620.     NSArray<NSNumber*>* parametersForOverviewWithCount (int count) override

  621.     {

  622.         const int n = static_cast<int> ([overviewParams count]);

  623. 

  624.         if (count >= n)

  625.             return overviewParams;

  626. 

  627.         NSMutableArray<NSNumber*>* retval = [[NSMutableArray<NSNumber*>alloc] initWithArray: overviewParams];

  628.         [retval removeObjectsInRange: NSMakeRange (static_cast<unsigned int> (count), static_cast<unsigned int> (n - count))];

  629. 

  630.         return [retval autorelease];

  631.     }

  632. 

  633.     //==============================================================================

  634.     NSTimeInterval getLatency() override

  635.     {

  636.         auto& p = getAudioProcessor();

  637.         return p.getLatencySamples() / p.getSampleRate();

  638.     }

  639. 

  640.     NSTimeInterval getTailTime() override

  641.     {

  642.         return getAudioProcessor().getTailLengthSeconds();

  643.     }

  644. 

  645.     //==============================================================================

  646.     AUAudioUnitBusArray* getInputBusses() override            { return inputBusses;  }

  647.     AUAudioUnitBusArray* getOutputBusses() override           { return outputBusses; }

  648.     NSArray<NSNumber*>* getChannelCapabilities() override     { return channelCapabilities; }

  649. 

  650.     bool shouldChangeToFormat (AVAudioFormat* format, AUAudioUnitBus* auBus) override

  651.     {

  652.         const bool isInput = ([auBus busType] == AUAudioUnitBusTypeInput);

  653.         const int busIdx = static_cast<int> ([auBus index]);

  654.         const int newNumChannels = static_cast<int> ([format channelCount]);

  655. 

  656.         AudioProcessor& processor = getAudioProcessor();

  657. 

  658.         if (AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx))

  659.         {

  660.           #ifdef JucePlugin_PreferredChannelConfigurations

  661.             ignoreUnused (bus);

  662. 

  663.             short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  664. 

  665.             if (! AudioUnitHelpers::isLayoutSupported (processor, isInput, busIdx, newNumChannels, configs))

  666.                 return false;

  667.           #else

  668.             const AVAudioChannelLayout* layout    = [format channelLayout];

  669.             const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  670. 

  671.             if (layoutTag != 0)

  672.             {

  673.                 AudioChannelSet newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  674. 

  675.                 if (newLayout.size() != newNumChannels)

  676.                     return false;

  677. 

  678.                 if (! bus->isLayoutSupported (newLayout))

  679.                     return false;

  680.             }

  681.             else

  682.             {

  683.                 if (! bus->isNumberOfChannelsSupported (newNumChannels))

  684.                     return false;

  685.             }

  686.            #endif

  687. 

  688.             return true;

  689.         }

  690. 

  691.         return false;

  692.     }

  693. 

  694.     //==============================================================================

  695.     int getVirtualMIDICableCount() override

  696.     {

  697.        #if JucePlugin_WantsMidiInput

  698.         return 1;

  699.        #else

  700.         return 0;

  701.        #endif

  702.     }

  703. 

  704.     bool getSupportsMPE() override

  705.     {

  706.         return getAudioProcessor().supportsMPE();

  707.     }

  708. 

  709.     NSArray<NSString*>* getMIDIOutputNames() override

  710.     {

  711.        #if JucePlugin_ProducesMidiOutput

  712.         return @[@"MIDI Out"];

  713.        #else

  714.         return @[];

  715.        #endif

  716.     }

  717. 

  718.     //==============================================================================

  719.     AUInternalRenderBlock getInternalRenderBlock() override   { return internalRenderBlock;  }

  720.     bool getRenderingOffline() override                       { return getAudioProcessor().isNonRealtime(); }

  721.     void setRenderingOffline (bool offline) override

  722.     {

  723.         auto& processor = getAudioProcessor();

  724.         auto isCurrentlyNonRealtime = processor.isNonRealtime();

  725. 

  726.         if (isCurrentlyNonRealtime != offline)

  727.         {

  728.             ScopedLock callbackLock (processor.getCallbackLock());

  729. 

  730.             processor.setNonRealtime (offline);

  731.             processor.prepareToPlay (processor.getSampleRate(), processor.getBlockSize());

  732.         }

  733.     }

  734. 

  735.     //==============================================================================

  736.     NSString* getContextName() const    override              { return juceStringToNS (contextName); }

  737.     void setContextName (NSString* str) override

  738.     {

  739.         if (str != nullptr)

  740.         {

  741.             AudioProcessor::TrackProperties props;

  742.             props.name = nsStringToJuce (str);

  743. 

  744.             getAudioProcessor().updateTrackProperties (props);

  745.         }

  746.     }

  747. 

  748.     //==============================================================================

  749.     bool allocateRenderResourcesAndReturnError (NSError **outError) override

  750.     {

  751.         AudioProcessor& processor = getAudioProcessor();

  752.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  753. 

  754.         if (! JuceAudioUnitv3Base::allocateRenderResourcesAndReturnError (outError))

  755.             return false;

  756. 

  757.         if (outError != nullptr)

  758.             *outError = nullptr;

  759. 

  760.         AudioProcessor::BusesLayout layouts;

  761.         for (int dir = 0; dir < 2; ++dir)

  762.         {

  763.             const bool isInput = (dir == 0);

  764.             const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  765.             Array<AudioChannelSet>& channelSets = (isInput ? layouts.inputBuses : layouts.outputBuses);

  766. 

  767.             AUAudioUnitBusArray* auBuses = (isInput ? [getAudioUnit() inputBusses] : [getAudioUnit() outputBusses]);

  768.             jassert ([auBuses count] == static_cast<NSUInteger> (n));

  769. 

  770.             for (int busIdx = 0; busIdx < n; ++busIdx)

  771.             {

  772.                 AudioProcessor::Bus* bus = processor.getBus (isInput, busIdx);

  773.                 AVAudioFormat* format = [[auBuses objectAtIndexedSubscript:static_cast<NSUInteger> (busIdx)] format];

  774. 

  775.                 AudioChannelSet newLayout;

  776.                 const AVAudioChannelLayout* layout    = [format channelLayout];

  777.                 const AudioChannelLayoutTag layoutTag = (layout != nullptr ? [layout layoutTag] : 0);

  778. 

  779.                 if (layoutTag != 0)

  780.                     newLayout = CoreAudioLayouts::fromCoreAudio (layoutTag);

  781.                 else

  782.                     newLayout = bus->supportedLayoutWithChannels (static_cast<int> ([format channelCount]));

  783. 

  784.                 if (newLayout.isDisabled())

  785.                     return false;

  786. 

  787.                 channelSets.add (newLayout);

  788.             }

  789.         }

  790. 

  791.        #ifdef JucePlugin_PreferredChannelConfigurations

  792.         short configs[][2] = {JucePlugin_PreferredChannelConfigurations};

  793. 

  794.         if (! AudioProcessor::containsLayout (layouts, configs))

  795.         {

  796.             if (outError != nullptr)

  797.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  798. 

  799.             return false;

  800.         }

  801.        #endif

  802. 

  803.         if (! AudioUnitHelpers::setBusesLayout (&getAudioProcessor(), layouts))

  804.         {

  805.             if (outError != nullptr)

  806.                 *outError = [NSError errorWithDomain:NSOSStatusErrorDomain code:kAudioUnitErr_FormatNotSupported userInfo:nullptr];

  807. 

  808.             return false;

  809.         }

  810. 

  811.         totalInChannels  = processor.getTotalNumInputChannels();

  812.         totalOutChannels = processor.getTotalNumOutputChannels();

  813. 

  814.         allocateBusBuffer (true);

  815.         allocateBusBuffer (false);

  816. 

  817.         mapper.alloc();

  818. 

  819.         audioBuffer.prepare (totalInChannels, totalOutChannels, static_cast<int> (maxFrames));

  820. 

  821.         double sampleRate = (jmax (AudioUnitHelpers::getBusCount (&processor, true), AudioUnitHelpers::getBusCount (&processor, false)) > 0 ?

  822.                              [[[([inputBusses count] > 0 ? inputBusses : outputBusses) objectAtIndexedSubscript: 0] format] sampleRate] : 44100.0);

  823. 

  824.         processor.setRateAndBufferSizeDetails (sampleRate, static_cast<int> (maxFrames));

  825.         processor.prepareToPlay (sampleRate, static_cast<int> (maxFrames));

  826. 

  827.         zeromem (&lastAudioHead, sizeof (lastAudioHead));

  828.         hostMusicalContextCallback = [getAudioUnit() musicalContextBlock];

  829.         hostTransportStateCallback = [getAudioUnit() transportStateBlock];

  830. 

  831.         reset();

  832. 

  833.         return true;

  834.     }

  835. 

  836.     void deallocateRenderResources() override

  837.     {

  838.         hostMusicalContextCallback = nullptr;

  839.         hostTransportStateCallback = nullptr;

  840. 

  841.         getAudioProcessor().releaseResources();

  842.         audioBuffer.release();

  843. 

  844.         inBusBuffers. clear();

  845.         outBusBuffers.clear();

  846. 

  847.         mapper.release();

  848. 

  849.         JuceAudioUnitv3Base::deallocateRenderResources();

  850.     }

  851. 

  852.     //==============================================================================

  853.    #if JUCE_AUV3_VIEW_CONFIG_SUPPORTED

  854.     NSIndexSet* getSupportedViewConfigurations (NSArray<AUAudioUnitViewConfiguration*>* configs) override

  855.     {

  856.         auto supportedViewIndecies = [[NSMutableIndexSet alloc] init];

  857.         auto n = [configs count];

  858. 

  859.         if (auto* editor = getAudioProcessor().createEditorIfNeeded())

  860.         {

  861.             // If you hit this assertion then your plug-in's editor is reporting that it doesn't support

  862.             // any host MIDI controller configurations!

  863.             jassert (editor->supportsHostMIDIControllerPresence (true) || editor->supportsHostMIDIControllerPresence (false));

  864. 

  865.             for (auto i = 0u; i < n; ++i)

  866.             {

  867.                 if (auto* viewConfiguration = [configs objectAtIndex:i])

  868.                 {

  869.                     if (editor->supportsHostMIDIControllerPresence ([viewConfiguration hostHasController] == YES))

  870.                     {

  871.                         auto* constrainer = editor->getConstrainer();

  872.                         auto height = (int) [viewConfiguration height];

  873.                         auto width  = (int) [viewConfiguration width];

  874. 

  875.                         if (height <= constrainer->getMaximumHeight() && height >= constrainer->getMinimumHeight()

  876.                          && width  <= constrainer->getMaximumWidth()  && width  >= constrainer->getMinimumWidth())

  877.                             [supportedViewIndecies addIndex: i];

  878.                     }

  879.                 }

  880.             }

  881.         }

  882. 

  883.         return [supportedViewIndecies autorelease];

  884.     }

  885. 

  886.     void selectViewConfiguration (AUAudioUnitViewConfiguration* config) override

  887.     {

  888.         processorHolder->viewConfiguration = new AudioProcessorHolder::ViewConfig { [config width], [config height], [config hostHasController] == YES };

  889.     }

  890.    #endif

  891. 

  892.     //==============================================================================

  893.     void audioProcessorChanged (AudioProcessor* processor) override

  894.     {

  895.         ignoreUnused (processor);

  896. 

  897.         [au willChangeValueForKey: @"allParameterValues"];

  898.         addPresets();

  899.         [au didChangeValueForKey: @"allParameterValues"];

  900.     }

  901. 

  902.     void audioProcessorParameterChanged (AudioProcessor*, int idx, float newValue) override

  903.     {

  904.         if (isPositiveAndBelow (idx, getAudioProcessor().getNumParameters()))

  905.         {

  906.             if (AUParameter* param = [paramTree parameterWithAddress: getAUParameterAddressForIndex (idx)])

  907.             {

  908.                 if (editorObserverToken != nullptr)

  909.                     [param setValue: newValue  originator: editorObserverToken];

  910.                 else

  911.                     [param setValue: newValue];

  912.             }

  913.         }

  914.     }

  915. 

  916.     //==============================================================================

  917.     bool getCurrentPosition (CurrentPositionInfo& info) override

  918.     {

  919.         bool musicContextCallSucceeded = false;

  920.         bool transportStateCallSucceeded = false;

  921. 

  922.         info = lastAudioHead;

  923.         info.timeInSamples = (int64) (lastTimeStamp.mSampleTime + 0.5);

  924.         info.timeInSeconds = info.timeInSamples / getAudioProcessor().getSampleRate();

  925. 

  926.         switch (lastTimeStamp.mSMPTETime.mType)

  927.         {

  928.             case kSMPTETimeType2398:        info.frameRate = AudioPlayHead::fps23976; break;

  929.             case kSMPTETimeType24:          info.frameRate = AudioPlayHead::fps24; break;

  930.             case kSMPTETimeType25:          info.frameRate = AudioPlayHead::fps25; break;

  931.             case kSMPTETimeType2997:        info.frameRate = AudioPlayHead::fps2997; break;

  932.             case kSMPTETimeType2997Drop:    info.frameRate = AudioPlayHead::fps2997drop; break;

  933.             case kSMPTETimeType30Drop:      info.frameRate = AudioPlayHead::fps30drop; break;

  934.             case kSMPTETimeType30:          info.frameRate = AudioPlayHead::fps30; break;

  935.             case kSMPTETimeType60Drop:      info.frameRate = AudioPlayHead::fps60drop; break;

  936.             case kSMPTETimeType60:          info.frameRate = AudioPlayHead::fps60; break;

  937.             default:                        info.frameRate = AudioPlayHead::fpsUnknown; break;

  938.         }

  939. 

  940.         double num;

  941.         NSInteger den;

  942.         NSInteger outDeltaSampleOffsetToNextBeat;

  943.         double outCurrentMeasureDownBeat, bpm;

  944.         double ppqPosition;

  945. 

  946.         if (hostMusicalContextCallback != nullptr)

  947.         {

  948.             AUHostMusicalContextBlock musicalContextCallback = hostMusicalContextCallback;

  949. 

  950.             if (musicalContextCallback (&bpm, &num, &den, &ppqPosition, &outDeltaSampleOffsetToNextBeat, &outCurrentMeasureDownBeat))

  951.             {

  952.                 musicContextCallSucceeded = true;

  953. 

  954.                 info.timeSigNumerator   = (int) num;

  955.                 info.timeSigDenominator = (int) den;

  956.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  957.                 info.bpm = bpm;

  958.                 info.ppqPosition = ppqPosition;

  959.                 info.ppqPositionOfLastBarStart = outCurrentMeasureDownBeat;

  960.             }

  961.         }

  962. 

  963.         double outCurrentSampleInTimeLine, outCycleStartBeat = 0, outCycleEndBeat = 0;

  964.         AUHostTransportStateFlags flags;

  965. 

  966.         if (hostTransportStateCallback != nullptr)

  967.         {

  968.             AUHostTransportStateBlock transportStateCallback = hostTransportStateCallback;

  969. 

  970.             if (transportStateCallback (&flags, &outCurrentSampleInTimeLine, &outCycleStartBeat, &outCycleEndBeat))

  971.             {

  972.                 transportStateCallSucceeded = true;

  973. 

  974.                 info.timeInSamples  = (int64) (outCurrentSampleInTimeLine + 0.5);

  975.                 info.timeInSeconds  = info.timeInSamples / getAudioProcessor().getSampleRate();

  976.                 info.isPlaying      = ((flags & AUHostTransportStateMoving) != 0);

  977.                 info.isLooping      = ((flags & AUHostTransportStateCycling) != 0);

  978.                 info.isRecording    = ((flags & AUHostTransportStateRecording) != 0);

  979.                 info.ppqLoopStart   = outCycleStartBeat;

  980.                 info.ppqLoopEnd     = outCycleEndBeat;

  981.             }

  982.         }

  983. 

  984.         if (musicContextCallSucceeded && transportStateCallSucceeded)

  985.             lastAudioHead = info;

  986. 

  987.         return true;

  988.     }

  989. 

  990.     //==============================================================================

  991.     static void removeEditor (AudioProcessor& processor)

  992.     {

  993.         ScopedLock editorLock (processor.getCallbackLock());

  994. 

  995.         if (AudioProcessorEditor* editor = processor.getActiveEditor())

  996.         {

  997.             processor.editorBeingDeleted (editor);

  998.             delete editor;

  999.         }

  1000.     }

  1001. 

  1002. private:

  1003.     //==============================================================================

  1004.     struct BusBuffer

  1005.     {

  1006.         BusBuffer (AUAudioUnitBus* bus, int maxFramesPerBuffer)

  1007.             : auBus (bus),

  1008.               maxFrames (maxFramesPerBuffer),

  1009.               numberOfChannels (static_cast<int> ([[auBus format] channelCount])),

  1010.               isInterleaved ([[auBus format] isInterleaved])

  1011.         {

  1012.             alloc();

  1013.         }

  1014. 

  1015.         //==============================================================================

  1016.         void alloc()

  1017.         {

  1018.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1019.             int bytes = static_cast<int> (sizeof (AudioBufferList))

  1020.                           + ((numBuffers - 1) * static_cast<int> (sizeof (::AudioBuffer)));

  1021.             jassert (bytes > 0);

  1022. 

  1023.             bufferListStorage.calloc (static_cast<size_t> (bytes));

  1024.             bufferList = reinterpret_cast<AudioBufferList*> (bufferListStorage.getData());

  1025. 

  1026.             const int bufferChannels = isInterleaved ? numberOfChannels : 1;

  1027.             scratchBuffer.setSize (numBuffers, bufferChannels * maxFrames);

  1028.         }

  1029. 

  1030.         void dealloc()

  1031.         {

  1032.             bufferList = nullptr;

  1033.             bufferListStorage.free();

  1034.             scratchBuffer.setSize (0, 0);

  1035.         }

  1036. 

  1037.         //==============================================================================

  1038.         int numChannels() const noexcept                { return numberOfChannels; }

  1039.         bool interleaved() const noexcept               { return isInterleaved; }

  1040.         AudioBufferList* get() const noexcept           { return bufferList; }

  1041. 

  1042.         //==============================================================================

  1043.         void prepare (UInt32 nFrames, const AudioBufferList* other = nullptr) noexcept

  1044.         {

  1045.             const int numBuffers = isInterleaved ? 1 : numberOfChannels;

  1046.             const bool isCompatible = isCompatibleWith (other);

  1047. 

  1048.             bufferList->mNumberBuffers = static_cast<UInt32> (numBuffers);

  1049. 

  1050.             for (int i = 0; i < numBuffers; ++i)

  1051.             {

  1052.                 const UInt32 bufferChannels = static_cast<UInt32> (isInterleaved ? numberOfChannels : 1);

  1053.                 bufferList->mBuffers[i].mNumberChannels = bufferChannels;

  1054.                 bufferList->mBuffers[i].mData = (isCompatible ? other->mBuffers[i].mData

  1055.                                                               : scratchBuffer.getWritePointer (i));

  1056.                 bufferList->mBuffers[i].mDataByteSize = nFrames * bufferChannels * sizeof (float);

  1057.             }

  1058.         }

  1059. 

  1060.         //==============================================================================

  1061.         bool isCompatibleWith (const AudioBufferList* other) const noexcept

  1062.         {

  1063.             if (other == nullptr)

  1064.                 return false;

  1065. 

  1066.             if (other->mNumberBuffers > 0)

  1067.             {

  1068.                 const bool otherInterleaved = AudioUnitHelpers::isAudioBufferInterleaved (*other);

  1069.                 const int otherChannels = static_cast<int> (otherInterleaved ? other->mBuffers[0].mNumberChannels

  1070.                                                                              : other->mNumberBuffers);

  1071. 

  1072.                 return otherInterleaved == isInterleaved

  1073.                     && numberOfChannels == otherChannels;

  1074.             }

  1075. 

  1076.             return numberOfChannels == 0;

  1077.         }

  1078. 

  1079.     private:

  1080.         AUAudioUnitBus* auBus;

  1081.         HeapBlock<char> bufferListStorage;

  1082.         AudioBufferList* bufferList = nullptr;

  1083.         int maxFrames, numberOfChannels;

  1084.         bool isInterleaved;

  1085.         AudioBuffer<float> scratchBuffer;

  1086.     };

  1087. 

  1088.     //==============================================================================

  1089.     void addAudioUnitBusses (bool isInput)

  1090.     {

  1091.         ScopedPointer<NSMutableArray<AUAudioUnitBus*>> array = [[NSMutableArray<AUAudioUnitBus*> alloc] init];

  1092.         AudioProcessor& processor = getAudioProcessor();

  1093.         const int n = AudioUnitHelpers::getBusCount (&processor, isInput);

  1094. 

  1095.         for (int i = 0; i < n; ++i)

  1096.         {

  1097.             ScopedPointer<AUAudioUnitBus> audioUnitBus;

  1098. 

  1099.             {

  1100.                 ScopedPointer<AVAudioFormat> defaultFormat = [[AVAudioFormat alloc] initStandardFormatWithSampleRate: kDefaultSampleRate

  1101.                                                                                                             channels: static_cast<AVAudioChannelCount> (processor.getChannelCountOfBus (isInput, i))];

  1102. 

  1103.                 audioUnitBus = [[AUAudioUnitBus alloc] initWithFormat: defaultFormat

  1104.                                                                 error: nullptr];

  1105.             }

  1106. 

  1107.             [array addObject: audioUnitBus];

  1108.         }

  1109. 

  1110.         (isInput ? inputBusses : outputBusses) = [[AUAudioUnitBusArray alloc] initWithAudioUnit: au

  1111.                                                                                         busType: (isInput ? AUAudioUnitBusTypeInput : AUAudioUnitBusTypeOutput)

  1112.                                                                                          busses: array];

  1113.     }

  1114. 

  1115.     // When parameters are discrete we need to use integer values.

  1116.     float getMaximumParameterValue (int parameterIndex)

  1117.     {

  1118.        #if JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1119.         ignoreUnused (parameterIndex);

  1120.         return 1.0f;

  1121.        #else

  1122.         auto& processor = getAudioProcessor();

  1123.         return processor.isParameterDiscrete (parameterIndex) ? (float) (processor.getParameterNumSteps (parameterIndex) - 1) : 1.0f;

  1124.        #endif

  1125.     }

  1126. 

  1127.     void addParameters()

  1128.     {

  1129.         ScopedPointer<NSMutableArray<AUParameterNode*>> params = [[NSMutableArray<AUParameterNode*> alloc] init];

  1130. 

  1131.         overviewParams = [[NSMutableArray<NSNumber*> alloc] init];

  1132. 

  1133.         auto& processor = getAudioProcessor();

  1134.         const int n = processor.getNumParameters();

  1135. 

  1136.        #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1137.         // check if all parameters are managed?

  1138.         usingManagedParameter = (processor.getParameters().size() == processor.getNumParameters());

  1139.        #endif

  1140. 

  1141.         for (int idx = 0; idx < n; ++idx)

  1142.         {

  1143.             const String identifier (idx);

  1144.             const String name = processor.getParameterName (idx);

  1145. 

  1146.             AudioUnitParameterUnit unit = kAudioUnitParameterUnit_Generic;

  1147.             AudioUnitParameterOptions flags = (UInt32) (kAudioUnitParameterFlag_IsWritable

  1148.                                                       | kAudioUnitParameterFlag_IsReadable

  1149.                                                       | kAudioUnitParameterFlag_HasCFNameString

  1150.                                                       | kAudioUnitParameterFlag_ValuesHaveStrings);

  1151. 

  1152.            #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1153.             flags |= (UInt32) kAudioUnitParameterFlag_IsHighResolution;

  1154.            #endif

  1155. 

  1156.             // set whether the param is automatable (unnamed parameters aren't allowed to be automated)

  1157.             if (name.isEmpty() || ! processor.isParameterAutomatable (idx))

  1158.                 flags |= kAudioUnitParameterFlag_NonRealTime;

  1159. 

  1160.             const bool isParameterDiscrete = processor.isParameterDiscrete (idx);

  1161. 

  1162.             if (! isParameterDiscrete)

  1163.                 flags |= kAudioUnitParameterFlag_CanRamp;

  1164. 

  1165.             if (processor.isMetaParameter (idx))

  1166.                 flags |= kAudioUnitParameterFlag_IsGlobalMeta;

  1167. 

  1168.             auto deleter = [](NSMutableArray* arr) { [arr release]; };

  1169.             std::unique_ptr<NSMutableArray, decltype (deleter)> valueStrings (nullptr, deleter);

  1170. 

  1171.             // is this a meter?

  1172.             if (((processor.getParameterCategory (idx) & 0xffff0000) >> 16) == 2)

  1173.             {

  1174.                 flags &= ~kAudioUnitParameterFlag_IsWritable;

  1175.                 flags |= kAudioUnitParameterFlag_MeterReadOnly | kAudioUnitParameterFlag_DisplayLogarithmic;

  1176.                 unit = kAudioUnitParameterUnit_LinearGain;

  1177.             }

  1178.             else

  1179.             {

  1180.                #if ! JUCE_FORCE_LEGACY_PARAMETER_AUTOMATION_TYPE

  1181.                 if (auto* param = processor.getParameters()[idx])

  1182.                 {

  1183.                     if (param->isDiscrete())

  1184.                     {

  1185.                         unit = param->isBoolean() ? kAudioUnitParameterUnit_Boolean : kAudioUnitParameterUnit_Indexed;

  1186.                         auto maxValue = getMaximumParameterValue (idx);

  1187.                         auto numSteps = param->getNumSteps();

  1188. 

  1189.                         // Some hosts can't handle the huge numbers of discrete parameter values created when

  1190.                         // using the default number of steps.

  1191.                         jassert (numSteps != AudioProcessor::getDefaultNumParameterSteps());

  1192. 

  1193.                         valueStrings.reset ([NSMutableArray new]);

  1194. 

  1195.                         for (int i = 0; i < numSteps; ++i)

  1196.                             [valueStrings.get() addObject: juceStringToNS (param->getText ((float) i / maxValue, 0))];

  1197.                     }

  1198.                 }

  1199.                #endif

  1200.             }

  1201. 

  1202.            #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1203.             AUParameterAddress address = static_cast<AUParameterAddress> (idx);

  1204.            #else

  1205.             AUParameterAddress address = generateAUParameterAddressForIndex (idx);

  1206. 

  1207.             // Consider yourself very unlucky if you hit this assertion. The hash codes of your

  1208.             // parameter ids are not unique.

  1209.             jassert (! paramMap.contains (static_cast<int64> (address)));

  1210. 

  1211.             paramAddresses.add (address);

  1212.             paramMap.set (static_cast<int64> (address), idx);

  1213.           #endif

  1214. 

  1215.             // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1216. 

  1217.             ScopedPointer<AUParameter> param = [[AUParameterTree createParameterWithIdentifier: juceStringToNS (identifier)

  1218.                                                                                           name: juceStringToNS (name)

  1219.                                                                                        address: address

  1220.                                                                                            min: 0.0f

  1221.                                                                                            max: getMaximumParameterValue (idx)

  1222.                                                                                           unit: unit

  1223.                                                                                       unitName: nullptr

  1224.                                                                                          flags: flags

  1225.                                                                                   valueStrings: valueStrings.get()

  1226.                                                                            dependentParameters: nullptr] retain];

  1227. 

  1228.             [param.get() setValue: processor.getParameterDefaultValue (idx)];

  1229. 

  1230.             [params addObject: param];

  1231.             [overviewParams addObject: [NSNumber numberWithUnsignedLongLong:address]];

  1232.         }

  1233. 

  1234.         // create methods in AUParameterTree return unretained objects (!) -> see Apple header AUAudioUnitImplementation.h

  1235.         paramTree = [[AUParameterTree createTreeWithChildren: params] retain];

  1236. 

  1237.         paramObserver           = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedFromHost);

  1238.         paramProvider           = CreateObjCBlock (this, &JuceAudioUnitv3::getValue);

  1239.         stringFromValueProvider = CreateObjCBlock (this, &JuceAudioUnitv3::stringFromValue);

  1240.         valueFromStringProvider = CreateObjCBlock (this, &JuceAudioUnitv3::valueFromString);

  1241. 

  1242.         [paramTree setImplementorValueObserver: paramObserver];

  1243.         [paramTree setImplementorValueProvider: paramProvider];

  1244.         [paramTree setImplementorStringFromValueCallback: stringFromValueProvider];

  1245.         [paramTree setImplementorValueFromStringCallback: valueFromStringProvider];

  1246. 

  1247.         if (processor.hasEditor())

  1248.         {

  1249.             editorParamObserver = CreateObjCBlock (this, &JuceAudioUnitv3::valueChangedForObserver);

  1250.             editorObserverToken = [paramTree tokenByAddingParameterObserver: editorParamObserver];

  1251.         }

  1252.     }

  1253. 

  1254.     void setAudioProcessorParameter (int index, float value)

  1255.     {

  1256.         if (auto* param = getAudioProcessor().getParameters()[index])

  1257.         {

  1258.             param->setValue (value);

  1259.             param->sendValueChangedMessageToListeners (value);

  1260.         }

  1261.         else if (isPositiveAndBelow (index, getAudioProcessor().getNumParameters()))

  1262.         {

  1263.             getAudioProcessor().setParameter (index, value);

  1264.         }

  1265.     }

  1266. 

  1267.     void addPresets()

  1268.     {

  1269.         factoryPresets = [[NSMutableArray<AUAudioUnitPreset*> alloc] init];

  1270. 

  1271.         const int n = getAudioProcessor().getNumPrograms();

  1272. 

  1273.         for (int idx = 0; idx < n; ++idx)

  1274.         {

  1275.             String name = getAudioProcessor().getProgramName (idx);

  1276. 

  1277.             ScopedPointer<AUAudioUnitPreset> preset = [[AUAudioUnitPreset alloc] init];

  1278.             [preset setName: juceStringToNS (name)];

  1279.             [preset setNumber: static_cast<NSInteger> (idx)];

  1280. 

  1281.             [factoryPresets addObject: preset];

  1282.         }

  1283.     }

  1284. 

  1285.     //==============================================================================

  1286.     void allocateBusBuffer (bool isInput)

  1287.     {

  1288.         OwnedArray<BusBuffer>& busBuffers = isInput ? inBusBuffers : outBusBuffers;

  1289.         busBuffers.clear();

  1290. 

  1291.         const int n = AudioUnitHelpers::getBusCount (&getAudioProcessor(), isInput);

  1292.         const AUAudioFrameCount maxFrames = [getAudioUnit() maximumFramesToRender];

  1293. 

  1294.         for (int busIdx = 0; busIdx < n; ++busIdx)

  1295.             busBuffers.add (new BusBuffer ([(isInput ? inputBusses : outputBusses) objectAtIndexedSubscript: static_cast<unsigned int> (busIdx)],

  1296.                                            static_cast<int> (maxFrames)));

  1297.     }

  1298. 

  1299.     //==============================================================================

  1300.     void processEvents (const AURenderEvent *__nullable realtimeEventListHead, int numParams, AUEventSampleTime startTime)

  1301.     {

  1302.         for (const AURenderEvent* event = realtimeEventListHead; event != nullptr; event = event->head.next)

  1303.         {

  1304.             switch (event->head.eventType)

  1305.             {

  1306.                 case AURenderEventMIDI:

  1307.                 {

  1308.                     const AUMIDIEvent& midiEvent = event->MIDI;

  1309.                     midiMessages.addEvent (midiEvent.data, midiEvent.length, static_cast<int> (midiEvent.eventSampleTime - startTime));

  1310.                 }

  1311.                 break;

  1312. 

  1313.                 case AURenderEventParameter:

  1314.                 case AURenderEventParameterRamp:

  1315.                 {

  1316.                     const AUParameterEvent& paramEvent = event->parameter;

  1317.                     const int idx = getJuceParameterIndexForAUAddress (paramEvent.parameterAddress);

  1318. 

  1319.                     setAudioProcessorParameter (idx, paramEvent.value);

  1320.                 }

  1321.                 break;

  1322. 

  1323.                 default:

  1324.                     break;

  1325.             }

  1326.         }

  1327.     }

  1328. 

  1329.     AUAudioUnitStatus renderCallback (AudioUnitRenderActionFlags* actionFlags, const AudioTimeStamp* timestamp, AUAudioFrameCount frameCount,

  1330.                                       NSInteger outputBusNumber, AudioBufferList* outputData, const AURenderEvent *__nullable realtimeEventListHead,

  1331.                                       AURenderPullInputBlock __nullable pullInputBlock)

  1332.     {

  1333.         auto& processor = getAudioProcessor();

  1334.         jassert (static_cast<int> (frameCount) <= getAudioProcessor().getBlockSize());

  1335. 

  1336.         // process params

  1337.         const int numParams = processor.getNumParameters();

  1338.         processEvents (realtimeEventListHead, numParams, static_cast<AUEventSampleTime> (timestamp->mSampleTime));

  1339. 

  1340.         if (lastTimeStamp.mSampleTime != timestamp->mSampleTime)

  1341.         {

  1342.             lastTimeStamp = *timestamp;

  1343. 

  1344.             const int numInputBuses  = inBusBuffers. size();

  1345.             const int numOutputBuses = outBusBuffers.size();

  1346. 

  1347.             // prepare buffers

  1348.             {

  1349.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1350.                 {

  1351.                      BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1352.                      const bool canUseDirectOutput =

  1353.                          (busIdx == outputBusNumber && outputData != nullptr && outputData->mNumberBuffers > 0);

  1354. 

  1355.                     busBuffer.prepare (frameCount, canUseDirectOutput ? outputData : nullptr);

  1356.                 }

  1357. 

  1358.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1359.                 {

  1360.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1361.                     busBuffer.prepare (frameCount, busIdx < numOutputBuses ? outBusBuffers[busIdx]->get() : nullptr);

  1362.                 }

  1363. 

  1364.                 audioBuffer.reset();

  1365.             }

  1366. 

  1367.             // pull inputs

  1368.             {

  1369.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1370.                 {

  1371.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1372.                     AudioBufferList* buffer = busBuffer.get();

  1373. 

  1374.                     if (pullInputBlock == nullptr || pullInputBlock (actionFlags, timestamp, frameCount, busIdx, buffer) != noErr)

  1375.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1376. 

  1377.                     if (actionFlags != nullptr && (*actionFlags & kAudioUnitRenderAction_OutputIsSilence) != 0)

  1378.                         AudioUnitHelpers::clearAudioBuffer (*buffer);

  1379.                 }

  1380.             }

  1381. 

  1382.             // set buffer pointer to minimize copying

  1383.             {

  1384.                 int chIdx = 0;

  1385. 

  1386.                 for (int busIdx = 0; busIdx < numOutputBuses; ++busIdx)

  1387.                 {

  1388.                     BusBuffer& busBuffer = *outBusBuffers[busIdx];

  1389.                     AudioBufferList* buffer = busBuffer.get();

  1390. 

  1391.                     const bool interleaved = busBuffer.interleaved();

  1392.                     const int numChannels = busBuffer.numChannels();

  1393. 

  1394.                     const int* outLayoutMap = mapper.get (false, busIdx);

  1395. 

  1396.                     for (int ch = 0; ch < numChannels; ++ch)

  1397.                         audioBuffer.setBuffer (chIdx++, interleaved ? nullptr : static_cast<float*> (buffer->mBuffers[outLayoutMap[ch]].mData));

  1398.                 }

  1399. 

  1400.                 // use input pointers on remaining channels

  1401. 

  1402.                 for (int busIdx = 0; chIdx < totalInChannels;)

  1403.                 {

  1404.                     const int channelOffset = processor.getOffsetInBusBufferForAbsoluteChannelIndex (true, chIdx, busIdx);

  1405. 

  1406.                     BusBuffer& busBuffer = *inBusBuffers[busIdx];

  1407.                     AudioBufferList* buffer = busBuffer.get();

  1408. 

  1409.                     const int* inLayoutMap = mapper.get (true, busIdx);

  1410.                     audioBuffer.setBuffer (chIdx++,  busBuffer.interleaved() ? nullptr : static_cast<float*> (buffer->mBuffers[inLayoutMap[channelOffset]].mData));

  1411.                 }

  1412.             }

  1413. 

  1414.             // copy input

  1415.             {

  1416.                 for (int busIdx = 0; busIdx < numInputBuses; ++busIdx)

  1417.                     audioBuffer.push (*inBusBuffers[busIdx]->get(), mapper.get (true, busIdx));

  1418. 

  1419.                 // clear remaining channels

  1420.                 for (int i = totalInChannels; i < totalOutChannels; ++i)

  1421.                     zeromem (audioBuffer.push(), sizeof (float) * frameCount);

  1422.             }

  1423. 

  1424.             // process audio

  1425.             processBlock (audioBuffer.getBuffer (frameCount), midiMessages);

  1426. 

  1427.             // send MIDI

  1428.            #if JucePlugin_ProducesMidiOutput && JUCE_AUV3_MIDI_OUTPUT_SUPPORTED

  1429.             auto midiOut = [au MIDIOutputEventBlock];

  1430.             MidiMessage msg;

  1431.             int samplePosition;

  1432. 

  1433.             for (MidiBuffer::Iterator it (midiMessages); it.getNextEvent (msg, samplePosition);)

  1434.                 midiOut (samplePosition, 0, msg.getRawDataSize(), msg.getRawData());

  1435.            #endif

  1436. 

  1437.             midiMessages.clear();

  1438.         }

  1439. 

  1440.         // copy back

  1441.         audioBuffer.pop (*outBusBuffers[(int) outputBusNumber]->get(),

  1442.                          mapper.get (false, (int) outputBusNumber));

  1443. 

  1444.         return noErr;

  1445.     }

  1446. 

  1447.     void processBlock (AudioBuffer<float>& buffer, MidiBuffer& midiBuffer) noexcept

  1448.     {

  1449.         auto& processor = getAudioProcessor();

  1450.         const ScopedLock sl (processor.getCallbackLock());

  1451. 

  1452.         if (processor.isSuspended())

  1453.             buffer.clear();

  1454.         else if ([au shouldBypassEffect])

  1455.             processor.processBlockBypassed (buffer, midiBuffer);

  1456.         else

  1457.             processor.processBlock (buffer, midiBuffer);

  1458.     }

  1459. 

  1460.     //==============================================================================

  1461.     void valueChangedFromHost (AUParameter* param, AUValue value)

  1462.     {

  1463.         if (param != nullptr)

  1464.         {

  1465.             int idx = getJuceParameterIndexForAUAddress ([param address]);

  1466.             auto normalisedValue = value / getMaximumParameterValue (idx);

  1467. 

  1468.             setAudioProcessorParameter (idx, normalisedValue);

  1469.         }

  1470.     }

  1471. 

  1472.     AUValue getValue (AUParameter* param)

  1473.     {

  1474.         if (param != nullptr)

  1475.         {

  1476.             const int idx = getJuceParameterIndexForAUAddress ([param address]);

  1477.             auto& processor = getAudioProcessor();

  1478. 

  1479.             if (isPositiveAndBelow (idx, processor.getNumParameters()))

  1480.                 return processor.getParameter (idx) * getMaximumParameterValue (idx);

  1481.         }

  1482. 

  1483.         return 0;

  1484.     }

  1485. 

  1486.     void valueChangedForObserver(AUParameterAddress, AUValue)

  1487.     {

  1488.         // this will have already been handled by valueChangedFromHost

  1489.     }

  1490. 

  1491.     NSString* stringFromValue (AUParameter* param, const AUValue* value)

  1492.     {

  1493.         String text;

  1494. 

  1495.         if (param != nullptr && value != nullptr)

  1496.         {

  1497.             const int idx = getJuceParameterIndexForAUAddress ([param address]);

  1498.             auto& processor = getAudioProcessor();

  1499. 

  1500.             if (auto* p = processor.getParameters()[idx])

  1501.                 text = p->getText (*value / getMaximumParameterValue (idx), 0);

  1502.             else

  1503.                 text = String (*value);

  1504.         }

  1505. 

  1506.         return juceStringToNS (text);

  1507.     }

  1508. 

  1509.     AUValue valueFromString (AUParameter* param, NSString* str)

  1510.     {

  1511.         if (param != nullptr && str != nullptr)

  1512.         {

  1513.             const int idx = getJuceParameterIndexForAUAddress ([param address]);

  1514.             auto& processor = getAudioProcessor();

  1515.             const String text (nsStringToJuce (str));

  1516. 

  1517.             if (auto* p = processor.getParameters()[idx])

  1518.                 return p->getValueForText (text) * getMaximumParameterValue (idx);

  1519.             else

  1520.                 return text.getFloatValue();

  1521.         }

  1522. 

  1523.         return 0;

  1524.     }

  1525. 

  1526.     //==============================================================================

  1527.    #if JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1528.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept     { return static_cast<AUParameterAddress> (paramIndex); }

  1529.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept    { return static_cast<int> (address); }

  1530.    #else

  1531.     AUParameterAddress generateAUParameterAddressForIndex (int paramIndex) const

  1532.     {

  1533.         auto& processor = getAudioProcessor();

  1534.         const int n = processor.getNumParameters();

  1535. 

  1536.         if (isPositiveAndBelow (paramIndex, n))

  1537.         {

  1538.             const String& juceParamID = processor.getParameterID (paramIndex);

  1539.             return usingManagedParameter ? static_cast<AUParameterAddress> (juceParamID.hashCode64())

  1540.                                          : static_cast<AUParameterAddress> (juceParamID.getIntValue());

  1541.         }

  1542. 

  1543.         return static_cast<AUParameterAddress> (-1);

  1544.     }

  1545. 

  1546.     inline AUParameterAddress getAUParameterAddressForIndex (int paramIndex) const noexcept

  1547.     {

  1548.         return usingManagedParameter ? paramAddresses.getReference (paramIndex)

  1549.                                      : static_cast<AUParameterAddress> (paramIndex);

  1550.     }

  1551. 

  1552.     inline int getJuceParameterIndexForAUAddress (AUParameterAddress address) const noexcept

  1553.     {

  1554.         return usingManagedParameter ? paramMap[static_cast<int64> (address)]

  1555.                                      : static_cast<int> (address);

  1556.     }

  1557.    #endif

  1558. 

  1559.     //==============================================================================

  1560.     static const double kDefaultSampleRate;

  1561. 

  1562.     AudioProcessorHolder::Ptr processorHolder;

  1563. 

  1564.     int totalInChannels, totalOutChannels;

  1565. 

  1566.     ScopedPointer<AUAudioUnitBusArray> inputBusses;

  1567.     ScopedPointer<AUAudioUnitBusArray> outputBusses;

  1568. 

  1569.     ObjCBlock<AUImplementorValueObserver> paramObserver;

  1570.     ObjCBlock<AUImplementorValueProvider> paramProvider;

  1571.     ObjCBlock<AUImplementorStringFromValueCallback> stringFromValueProvider;

  1572.     ObjCBlock<AUImplementorValueFromStringCallback> valueFromStringProvider;

  1573. 

  1574.    #if ! JUCE_FORCE_USE_LEGACY_PARAM_IDS

  1575.     bool usingManagedParameter;

  1576.     Array<AUParameterAddress> paramAddresses;

  1577.     HashMap<int64, int> paramMap;

  1578.    #endif

  1579. 

  1580.     // to avoid recursion on parameter changes, we need to add an

  1581.     // editor observer to do the parameter changes

  1582.     ObjCBlock<AUParameterObserver> editorParamObserver;

  1583.     AUParameterObserverToken editorObserverToken;

  1584. 

  1585.     ScopedPointer<AUParameterTree> paramTree;

  1586.     ScopedPointer<NSMutableArray<NSNumber*>> overviewParams;

  1587.     ScopedPointer<NSMutableArray<NSNumber*>> channelCapabilities;

  1588. 

  1589.     ScopedPointer<NSMutableArray<AUAudioUnitPreset*>> factoryPresets;

  1590. 

  1591.     ObjCBlock<AUInternalRenderBlock> internalRenderBlock;

  1592. 

  1593.     AudioUnitHelpers::CoreAudioBufferList audioBuffer;

  1594.     AudioUnitHelpers::ChannelRemapper mapper;

  1595. 

  1596.     OwnedArray<BusBuffer> inBusBuffers, outBusBuffers;

  1597.     MidiBuffer midiMessages;

  1598. 

  1599.     ObjCBlock<AUHostMusicalContextBlock> hostMusicalContextCallback;

  1600.     ObjCBlock<AUHostTransportStateBlock> hostTransportStateCallback;

  1601. 

  1602.     AudioTimeStamp lastTimeStamp;

  1603.     CurrentPositionInfo lastAudioHead;

  1604. 

  1605.     String contextName;

  1606. };

  1607. 

  1608. const double JuceAudioUnitv3::kDefaultSampleRate = 44100.0;

  1609. 

  1610. JuceAudioUnitv3Base* JuceAudioUnitv3Base::create (AUAudioUnit* audioUnit, AudioComponentDescription descr, AudioComponentInstantiationOptions options, NSError** error)

  1611. {

  1612.     PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1613.     return new JuceAudioUnitv3 (audioUnit, descr, options, error);

  1614. }

  1615. 

  1616. //==============================================================================

  1617. class JuceAUViewController

  1618. {

  1619. public:

  1620.     JuceAUViewController (AUViewController<AUAudioUnitFactory>* p)

  1621.         : myself (p)

  1622.     {

  1623.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1624. 

  1625.         PluginHostType::jucePlugInClientCurrentWrapperType = AudioProcessor::wrapperType_AudioUnitv3;

  1626.         initialiseJuce_GUI();

  1627.     }

  1628. 

  1629.     ~JuceAUViewController()

  1630.     {

  1631.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1632. 

  1633.         if (processorHolder != nullptr)

  1634.             JuceAudioUnitv3::removeEditor (getAudioProcessor());

  1635.     }

  1636. 

  1637.     //==============================================================================

  1638.     void loadView()

  1639.     {

  1640.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1641. 

  1642.         if (AudioProcessor* p = createPluginFilterOfType (AudioProcessor::wrapperType_AudioUnitv3))

  1643.         {

  1644.             processorHolder = new AudioProcessorHolder (p);

  1645.             auto& processor = getAudioProcessor();

  1646. 

  1647.             if (processor.hasEditor())

  1648.             {

  1649.                 if (AudioProcessorEditor* editor = processor.createEditorIfNeeded())

  1650.                 {

  1651.                     preferredSize = editor->getBounds();

  1652. 

  1653.                     JUCE_IOS_MAC_VIEW* view = [[[JUCE_IOS_MAC_VIEW alloc] initWithFrame: convertToCGRect (editor->getBounds())] autorelease];

  1654.                     [myself setView: view];

  1655. 

  1656.                     editor->setVisible (true);

  1657.                     editor->addToDesktop (0, view);

  1658.                 }

  1659.             }

  1660.         }

  1661.     }

  1662. 

  1663.     void viewDidLayoutSubviews()

  1664.     {

  1665.         if (processorHolder != nullptr && [myself view] != nullptr)

  1666.         {

  1667.             if (AudioProcessorEditor* editor = getAudioProcessor().getActiveEditor())

  1668.             {

  1669.                 if (processorHolder->viewConfiguration != nullptr)

  1670.                     editor->hostMIDIControllerIsAvailable (processorHolder->viewConfiguration->hostHasMIDIController);

  1671. 

  1672.                 editor->setBounds (convertToRectInt ([[myself view] bounds]));

  1673. 

  1674.                 if (JUCE_IOS_MAC_VIEW* peerView = [[[myself view] subviews] objectAtIndex: 0])

  1675.                 {

  1676.                    #if JUCE_IOS

  1677.                     [peerView setNeedsDisplay];

  1678.                    #else

  1679.                     [peerView setNeedsDisplay: YES];

  1680.                    #endif

  1681.                 }

  1682.             }

  1683.         }

  1684.     }

  1685. 

  1686.     void didReceiveMemoryWarning()

  1687.     {

  1688.         if (processorHolder != nullptr)

  1689.             if (auto* processor = processorHolder->get())

  1690.                 processor->memoryWarningReceived();

  1691.     }

  1692. 

  1693.     CGSize getPreferredContentSize() const

  1694.     {

  1695.         return CGSizeMake (static_cast<float> (preferredSize.getWidth()),

  1696.                            static_cast<float> (preferredSize.getHeight()));

  1697.     }

  1698. 

  1699.     //==============================================================================

  1700.     AUAudioUnit* createAudioUnit (const AudioComponentDescription& descr, NSError** error)

  1701.     {

  1702.         AUAudioUnit* retval = nil;

  1703. 

  1704.         if (! MessageManager::getInstance()->isThisTheMessageThread())

  1705.         {

  1706.             WaitableEvent creationEvent;

  1707. 

  1708.             // AUv3 headers say that we may block this thread and that the message thread is guaranteed

  1709.             // to be unblocked

  1710.             struct AUCreator  : public CallbackMessage

  1711.             {

  1712.                 JuceAUViewController& owner;

  1713.                 AudioComponentDescription pDescr;

  1714.                 NSError** pError;

  1715.                 AUAudioUnit*& outAU;

  1716.                 WaitableEvent& e;

  1717. 

  1718.                 AUCreator (JuceAUViewController& parent, const AudioComponentDescription& paramDescr, NSError** paramError,

  1719.                            AUAudioUnit*& outputAU, WaitableEvent& event)

  1720.                     : owner (parent), pDescr (paramDescr), pError (paramError), outAU (outputAU), e (event)

  1721.                 {}

  1722. 

  1723.                 void messageCallback() override

  1724.                 {

  1725.                     outAU = owner.createAudioUnitOnMessageThread (pDescr, pError);

  1726.                     e.signal();

  1727.                 }

  1728.             };

  1729. 

  1730.             (new AUCreator (*this, descr, error, retval, creationEvent))->post();

  1731.             creationEvent.wait (-1);

  1732.         }

  1733.         else

  1734.         {

  1735.             retval = createAudioUnitOnMessageThread (descr, error);

  1736.         }

  1737. 

  1738.         return [retval autorelease];

  1739.     }

  1740. 

  1741. private:

  1742.     //==============================================================================

  1743.     AUViewController<AUAudioUnitFactory>* myself;

  1744.     AudioProcessorHolder::Ptr processorHolder = nullptr;

  1745.     Rectangle<int> preferredSize { 1, 1 };

  1746. 

  1747.     //==============================================================================

  1748.     AUAudioUnit* createAudioUnitOnMessageThread (const AudioComponentDescription& descr, NSError** error)

  1749.     {

  1750.         jassert (MessageManager::getInstance()->isThisTheMessageThread());

  1751. 

  1752.         [myself view];  // this will call [view load] and ensure that the AudioProcessor has been instantiated

  1753. 

  1754.         if (processorHolder == nullptr)

  1755.             return nullptr;

  1756. 

  1757.         return (new JuceAudioUnitv3 (processorHolder, descr, 0, error))->getAudioUnit();

  1758.     }

  1759. 

  1760.     AudioProcessor& getAudioProcessor() const noexcept       { return **processorHolder; }

  1761. };

  1762. 

  1763. //==============================================================================

  1764. // necessary glue code

  1765. @interface JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix) : AUViewController<AUAudioUnitFactory>

  1766. @end

  1767. 

  1768. @implementation JUCE_VIEWCONTROLLER_OBJC_NAME (JucePlugin_AUExportPrefix)

  1769. {

  1770.     ScopedPointer<JuceAUViewController> cpp;

  1771. }

  1772. 

  1773. - (instancetype) initWithNibName: (nullable NSString*) nib bundle: (nullable NSBundle*) bndl { self = [super initWithNibName: nib bundle: bndl]; cpp = new JuceAUViewController (self); return self; }

  1774. - (void) loadView                { cpp->loadView(); }

  1775. - (AUAudioUnit *) createAudioUnitWithComponentDescription: (AudioComponentDescription) desc error: (NSError **) error { return cpp->createAudioUnit (desc, error); }

  1776. - (CGSize) preferredContentSize  { return cpp->getPreferredContentSize(); }

  1777. - (void) viewDidLayoutSubviews   { cpp->viewDidLayoutSubviews(); }

  1778. - (void) didReceiveMemoryWarning { cpp->didReceiveMemoryWarning(); }

  1779. @end

  1780. 

  1781. //==============================================================================

  1782. #if JUCE_IOS

  1783. bool JUCE_CALLTYPE juce_isInterAppAudioConnected() { return false; }

  1784. void JUCE_CALLTYPE juce_switchToHostApplication()  {}

  1785. #if JUCE_MODULE_AVAILABLE_juce_gui_basics

  1786. Image JUCE_CALLTYPE juce_getIAAHostIcon (int)      { return {}; }

  1787. #endif

  1788. #endif

  1789. 

  1790. #pragma clang diagnostic pop

  1791. #endif