DISTRHO
/
DPF-Plugins
mirror of https://github.com/DISTRHO/DPF-Plugins
1
0
Fork 0
Code Releases 8 Activity
Collection of DPF-based plugins for packaging
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
191 Commits
1 Branch
86MB
Tree: f42469deb2
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'f42469deb2'
${ noResults }
DPF-Plugins/dpf/cmake/DPF-plugin.cmake

1279 lines
46KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - opengl (default)

  82. #          - opengl3

  83. #          - vulkan

  84. #          - webview

  85. #

  86. #   `FILES_COMMON` <file1>...<fileN>

  87. #       list of sources which are part of both DSP and UI

  88. #

  89. #   `FILES_DSP` <file1>...<fileN>

  90. #       list of sources which are part of the DSP

  91. #

  92. #   `FILES_UI` <file1>...<fileN>

  93. #       list of sources which are part of the UI

  94. #       empty indicates the plugin does not have UI

  95. #

  96. #   `MODGUI_CLASS_NAME`

  97. #       class name to use for modgui builds

  98. #

  99. #   `MONOLITHIC`

  100. #       build LV2 as a single binary for UI and DSP

  101. #

  102. #   `NO_SHARED_RESOURCES`

  103. #       do not build DPF shared resources (fonts, etc)

  104. #

  105. #   `USE_FILE_BROWSER`

  106. #       enable file browser dialog APIs

  107. #

  108. #   `USE_WEB_VIEW`

  109. #       enable web browser view APIs

  110. #

  111. function(dpf_add_plugin NAME)

  112.   set(options MONOLITHIC NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  113.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  114.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  115.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  116. 

  117.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  118.     set(_dpf_plugin_UI_TYPE "opengl")

  119.   endif()

  120. 

  121.   set(_dgl_library)

  122.   if(_dpf_plugin_FILES_UI)

  123.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  124.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  125.       set(_dgl_library dgl-cairo)

  126.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  127.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  128.       set(_dgl_library dgl-external)

  129.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  130.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  131.       set(_dgl_library dgl-opengl)

  132.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  133.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  134.       set(_dgl_library dgl-opengl3)

  135.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  136.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  137.       set(_dgl_library dgl-vulkan)

  138.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  139.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  140.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  141.       set(_dgl_library dgl-external)

  142.     else()

  143.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  144.     endif()

  145.   else()

  146.     set(_dpf_plugin_UI_TYPE "")

  147.   endif()

  148. 

  149.   set(_dgl_has_ui OFF)

  150.   if(_dgl_library)

  151.     set(_dgl_has_ui ON)

  152.   endif()

  153. 

  154.   ###

  155.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  156.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  157.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  158. 

  159.   ###

  160.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  161.   target_include_directories("${NAME}" PUBLIC

  162.     "${DPF_ROOT_DIR}/distrho")

  163. 

  164.   if(_dpf_plugin_USE_FILE_BROWSER)

  165.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  166.   endif()

  167. 

  168.   if(_dpf_plugin_USE_WEB_VIEW)

  169.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  170.   endif()

  171. 

  172.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  173.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  174.   endif()

  175. 

  176.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  177.     target_link_libraries("${NAME}" PRIVATE "dl")

  178.   endif()

  179. 

  180.   if(_dgl_library)

  181.     # make sure that all code will see DGL_* definitions

  182.     target_link_libraries("${NAME}" PUBLIC

  183.       "${_dgl_library}-definitions"

  184.       dgl-system-libs-definitions

  185.       dgl-system-libs)

  186.   endif()

  187. 

  188.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  189.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  190. 

  191.   if(_dgl_library)

  192.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  193.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  194.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  195.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  196.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  197.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  198.           OUTPUT_STRIP_TRAILING_WHITESPACE

  199.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  200.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  201.       endif()

  202.     endif()

  203.     # add the files containing C++17 or Objective-C classes

  204.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  205.   else()

  206.     add_library("${NAME}-ui" INTERFACE)

  207.   endif()

  208. 

  209.   ###

  210.   foreach(_target ${_dpf_plugin_TARGETS})

  211.     if(_target STREQUAL "jack")

  212.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  213.     elseif(_target STREQUAL "ladspa")

  214.       dpf__build_ladspa("${NAME}")

  215.     elseif(_target STREQUAL "dssi")

  216.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  217.     elseif(_target STREQUAL "lv2")

  218.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  219.     elseif(_target STREQUAL "vst2")

  220.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  221.     elseif(_target STREQUAL "vst3")

  222.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  223.     elseif(_target STREQUAL "clap")

  224.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  225.     elseif(_target STREQUAL "au")

  226.       if (APPLE)

  227.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  228.       endif()

  229.     elseif(_target STREQUAL "static")

  230.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  231.     else()

  232.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  233.     endif()

  234.   endforeach()

  235. endfunction()

  236. 

  237. # ------------------------------------------------------------------------------

  238. # DPF private functions (prefixed with `dpf__`)

  239. # ------------------------------------------------------------------------------

  240. 

  241. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  242. #       to the output directory.

  243. #

  244. 

  245. # dpf__build_jack

  246. # ------------------------------------------------------------------------------

  247. #

  248. # Add build rules for a JACK/Standalone program.

  249. #

  250. function(dpf__build_jack NAME HAS_UI)

  251.   dpf__create_dummy_source_list(_no_srcs)

  252. 

  253.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  254.   dpf__add_plugin_main("${NAME}-jack" "jack")

  255.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  256.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  257.   set_target_properties("${NAME}-jack" PROPERTIES

  258.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  259.     OUTPUT_NAME "${NAME}")

  260. 

  261.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  262.   target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  263. 

  264.   find_package(PkgConfig)

  265.   pkg_check_modules(SDL2 "sdl2")

  266.   if(SDL2_FOUND)

  267.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  268.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  269.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  270.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  271.   endif()

  272. 

  273.   if(APPLE OR WIN32)

  274.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  275.   else()

  276.     find_package(Threads)

  277.     pkg_check_modules(ALSA "alsa")

  278.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  279.     if(ALSA_FOUND)

  280.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  281.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  282.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  283.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  284.     endif()

  285.     if(PULSEAUDIO_FOUND)

  286.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  287.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  288.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  289.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  290.     endif()

  291.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  292.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  293.     endif()

  294.   endif()

  295. 

  296.   # for RtAudio native fallback

  297.   if(APPLE)

  298.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  299.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  300.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  301.     target_link_libraries("${NAME}-jack" PRIVATE

  302.       "${APPLE_COREAUDIO_FRAMEWORK}"

  303.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  304.       "${APPLE_COREMIDI_FRAMEWORK}")

  305.   elseif(WIN32)

  306.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  307.     if(HAS_UI AND MINGW)

  308.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  309.     endif()

  310.   endif()

  311. endfunction()

  312. 

  313. # dpf__build_ladspa

  314. # ------------------------------------------------------------------------------

  315. #

  316. # Add build rules for a LADSPA plugin.

  317. #

  318. function(dpf__build_ladspa NAME)

  319.   dpf__create_dummy_source_list(_no_srcs)

  320. 

  321.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  322.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  323.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  324.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  325.   set_target_properties("${NAME}-ladspa" PROPERTIES

  326.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  327.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  328.     OUTPUT_NAME "${NAME}-ladspa"

  329.     PREFIX "")

  330. endfunction()

  331. 

  332. # dpf__build_dssi

  333. # ------------------------------------------------------------------------------

  334. #

  335. # Add build rules for a DSSI plugin.

  336. #

  337. function(dpf__build_dssi NAME HAS_UI)

  338.   find_package(PkgConfig)

  339.   pkg_check_modules(LIBLO "liblo")

  340.   if(NOT LIBLO_FOUND)

  341.     dpf__warn_once_only(missing_liblo

  342.       "liblo is not found, skipping the `dssi` plugin targets")

  343.     return()

  344.   endif()

  345. 

  346.   dpf__create_dummy_source_list(_no_srcs)

  347. 

  348.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  349.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  350.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  351.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  352.   set_target_properties("${NAME}-dssi" PROPERTIES

  353.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  354.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  355.     OUTPUT_NAME "${NAME}-dssi"

  356.     PREFIX "")

  357. 

  358.   if(HAS_UI)

  359.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  360.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  361.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  362.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  363.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  364.       OUTPUT_NAME "${NAME}_ui")

  365. 

  366.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  367.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  368.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  369.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  370.   endif()

  371. endfunction()

  372. 

  373. # dpf__build_lv2

  374. # ------------------------------------------------------------------------------

  375. #

  376. # Add build rules for an LV2 plugin.

  377. #

  378. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  379.   dpf__create_dummy_source_list(_no_srcs)

  380. 

  381.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  382.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  383.   if(HAS_UI AND MONOLITHIC)

  384.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  385.   else()

  386.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  387.   endif()

  388.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  389.   set_target_properties("${NAME}-lv2" PROPERTIES

  390.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  391.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  392.     OUTPUT_NAME "${NAME}_dsp"

  393.     PREFIX "")

  394. 

  395.   if(HAS_UI)

  396.     if(MONOLITHIC)

  397.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  398.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  399.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  400.       set_target_properties("${NAME}-lv2" PROPERTIES

  401.         OUTPUT_NAME "${NAME}")

  402.     else()

  403.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  404.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  405.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  406.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  407.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  408.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  409.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  410.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  411.         OUTPUT_NAME "${NAME}_ui"

  412.         PREFIX "")

  413.     endif()

  414.   endif()

  415. 

  416.   dpf__add_lv2_ttl_generator()

  417.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  418. 

  419.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  420. 

  421.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  422.     COMMAND

  423.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  424.     "$<TARGET_FILE:lv2_ttl_generator>"

  425.     "$<TARGET_FILE:${NAME}-lv2>"

  426.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  427.     DEPENDS lv2_ttl_generator)

  428. endfunction()

  429. 

  430. # dpf__build_vst2

  431. # ------------------------------------------------------------------------------

  432. #

  433. # Add build rules for a VST2 plugin.

  434. #

  435. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  436.   dpf__create_dummy_source_list(_no_srcs)

  437. 

  438.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  439.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  440.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  441.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  442.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  443.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  444.   set_target_properties("${NAME}-vst2" PROPERTIES

  445.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  446.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  447.     OUTPUT_NAME "${NAME}-vst2"

  448.     PREFIX "")

  449.   if(APPLE)

  450.     set_target_properties("${NAME}-vst2" PROPERTIES

  451.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  452.       OUTPUT_NAME "${NAME}"

  453.       SUFFIX "")

  454.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  455.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  456.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  457.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  458.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  459.   endif()

  460. endfunction()

  461. 

  462. # dpf__determine_vst3_package_architecture

  463. # ------------------------------------------------------------------------------

  464. #

  465. # Determines the package architecture for a VST3 plugin target.

  466. #

  467. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  468.   # if set by variable, override the detection

  469.   if(DPF_VST3_ARCHITECTURE)

  470.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  471.     return()

  472.   endif()

  473. 

  474.   # not used on Apple, which supports universal binary

  475.   if(APPLE)

  476.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  477.     return()

  478.   endif()

  479. 

  480.   # identify the target processor (special case of MSVC, problematic sometimes)

  481.   if(MSVC)

  482.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  483.   else()

  484.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  485.   endif()

  486. 

  487.   # transform the processor name to a format that VST3 recognizes

  488.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  489.     set(vst3_package_arch "x86_64")

  490.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  491.     if(WIN32)

  492.       set(vst3_package_arch "x86")

  493.     else()

  494.       set(vst3_package_arch "i386")

  495.     endif()

  496.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*|ppc(64)?(le)?)$")

  497.     set(vst3_package_arch "${vst3_system_arch}")

  498.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  499.     set(vst3_package_arch "aarch64")

  500.   else()

  501.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  502.   endif()

  503. 

  504.   # TODO: the detections for Windows arm/arm64 when supported

  505. 

  506.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  507. endfunction()

  508. 

  509. # dpf__build_vst3

  510. # ------------------------------------------------------------------------------

  511. #

  512. # Add build rules for a VST3 plugin.

  513. #

  514. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  515.   dpf__determine_vst3_package_architecture(vst3_arch)

  516. 

  517.   dpf__create_dummy_source_list(_no_srcs)

  518. 

  519.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  520.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  521.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  522.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  523.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  524.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  525.   set_target_properties("${NAME}-vst3" PROPERTIES

  526.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  527.     OUTPUT_NAME "${NAME}"

  528.     PREFIX "")

  529. 

  530.   if(APPLE)

  531.     set_target_properties("${NAME}-vst3" PROPERTIES

  532.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  533.       SUFFIX "")

  534.   elseif(WIN32)

  535.     set_target_properties("${NAME}-vst3" PROPERTIES

  536.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  537.   else()

  538.     set_target_properties("${NAME}-vst3" PROPERTIES

  539.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  540.   endif()

  541. 

  542.   if(APPLE)

  543.     # Uses the same macOS bundle template as VST2

  544.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  545.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  546.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  547.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  548.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  549.   endif()

  550. endfunction()

  551. 

  552. # dpf__build_clap

  553. # ------------------------------------------------------------------------------

  554. #

  555. # Add build rules for a CLAP plugin.

  556. #

  557. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  558.   dpf__create_dummy_source_list(_no_srcs)

  559. 

  560.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  561.   dpf__add_plugin_main("${NAME}-clap" "clap")

  562.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  563.   dpf__set_module_export_list("${NAME}-clap" "clap")

  564.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  565.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  566.   set_target_properties("${NAME}-clap" PROPERTIES

  567.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  568.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  569.     OUTPUT_NAME "${NAME}"

  570.     PREFIX ""

  571.     SUFFIX ".clap")

  572. 

  573.   if(APPLE)

  574.     set_target_properties("${NAME}-clap" PROPERTIES

  575.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  576.       OUTPUT_NAME "${NAME}"

  577.       SUFFIX "")

  578.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  579.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  580.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  581.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  582.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  583.   endif()

  584. endfunction()

  585. 

  586. # dpf__build_au

  587. # ------------------------------------------------------------------------------

  588. #

  589. # Add build rules for an AUv2 plugin.

  590. #

  591. function(dpf__build_au NAME HAS_UI)

  592.   dpf__create_dummy_source_list(_no_srcs)

  593. 

  594.   dpf__add_module("${NAME}-au" ${_no_srcs})

  595.   dpf__add_plugin_main("${NAME}-au" "au")

  596.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  597.   dpf__set_module_export_list("${NAME}-au" "au")

  598.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  599.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  600.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  601.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  602.   target_link_libraries("${NAME}-au" PRIVATE

  603.     "${NAME}-dsp"

  604.     "${NAME}-ui"

  605.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  606.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  607.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  608.   set_target_properties("${NAME}-au" PROPERTIES

  609.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  610.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  611.     OUTPUT_NAME "${NAME}"

  612.     PREFIX ""

  613.     SUFFIX "")

  614. 

  615.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  616.   dpf__add_plugin_main("${NAME}-export" "export")

  617.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  618.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  619. 

  620.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  621. 

  622.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  623.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  624.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents"

  625.     DEPENDS "${NAME}-export")

  626. 

  627.   add_dependencies("${NAME}-au" "${NAME}-export")

  628. 

  629.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  630.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  631. endfunction()

  632. 

  633. # dpf__build_static

  634. # ------------------------------------------------------------------------------

  635. #

  636. # Add build rules for a static library.

  637. #

  638. function(dpf__build_static NAME HAS_UI)

  639.   dpf__create_dummy_source_list(_no_srcs)

  640. 

  641.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  642.   dpf__add_plugin_main("${NAME}-static" "static")

  643.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  644.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  645. 

  646.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  647.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  648.   foreach(src ${dsp_srcs})

  649.     target_sources("${NAME}-static" PRIVATE ${src})

  650.   endforeach()

  651.   foreach(src ${ui_srcs})

  652.     target_sources("${NAME}-static" PRIVATE ${src})

  653.   endforeach()

  654. 

  655.   set_target_properties("${NAME}-static" PROPERTIES

  656.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  657.     OUTPUT_NAME "${NAME}"

  658.     PREFIX "")

  659. endfunction()

  660. 

  661. # dpf__add_dgl_cairo

  662. # ------------------------------------------------------------------------------

  663. #

  664. # Add the Cairo variant of DGL, if not already available.

  665. #

  666. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER)

  667.   if(TARGET dgl-cairo)

  668.     return()

  669.   endif()

  670. 

  671.   find_package(PkgConfig)

  672.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  673. 

  674.   link_directories(${CAIRO_LIBRARY_DIRS})

  675. 

  676.   dpf__add_static_library(dgl-cairo STATIC

  677.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  678.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  679.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  680.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  681.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  682.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  683.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  684.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  685.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  686.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  687.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  688.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  689.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  690.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  691.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  692.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  693.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  694.   if(SHARED_RESOURCES)

  695.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  696.   else()

  697.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  698.   endif()

  699.   if(APPLE)

  700.     target_sources(dgl-cairo PRIVATE

  701.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  702.   else()

  703.     target_sources(dgl-cairo PRIVATE

  704.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  705.   endif()

  706.   target_include_directories(dgl-cairo PUBLIC

  707.     "${DPF_ROOT_DIR}/dgl")

  708.   target_include_directories(dgl-cairo PUBLIC

  709.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  710. 

  711.   if(USE_FILE_BROWSER)

  712.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  713.   endif()

  714. 

  715.   dpf__add_dgl_system_libs()

  716.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  717. 

  718.   add_library(dgl-cairo-definitions INTERFACE)

  719.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  720. 

  721.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  722.   if(MINGW)

  723.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  724.   else()

  725.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  726.   endif()

  727.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  728. endfunction()

  729. 

  730. # dpf__add_dgl_external

  731. # ------------------------------------------------------------------------------

  732. #

  733. # Add the external variant of DGL, if not already available.

  734. #

  735. function(dpf__add_dgl_external USE_FILE_BROWSER)

  736.   if(TARGET dgl-external)

  737.     return()

  738.   endif()

  739. 

  740.   dpf__add_static_library(dgl-external STATIC

  741.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  742.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  743.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  744.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  745.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  746.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  747.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  748.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  749.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  750.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  751.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  752.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  753.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  754.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  755.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  756.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  757.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  758. 

  759.   if(APPLE)

  760.     target_sources(dgl-external PRIVATE

  761.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  762.   else()

  763.     target_sources(dgl-external PRIVATE

  764.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  765.   endif()

  766.   target_include_directories(dgl-external PUBLIC

  767.     "${DPF_ROOT_DIR}/dgl")

  768.   target_include_directories(dgl-external PUBLIC

  769.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  770. 

  771.   if(USE_FILE_BROWSER)

  772.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  773.   endif()

  774. 

  775.   dpf__add_dgl_system_libs()

  776.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  777.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  778. 

  779.   add_library(dgl-external-definitions INTERFACE)

  780.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  781. 

  782.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  783.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  784. endfunction()

  785. 

  786. # dpf__add_dgl_opengl

  787. # ------------------------------------------------------------------------------

  788. #

  789. # Add the OpenGL variant of DGL, if not already available.

  790. #

  791. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER)

  792.   if(TARGET dgl-opengl)

  793.     return()

  794.   endif()

  795. 

  796.   if(NOT OpenGL_GL_PREFERENCE)

  797.     set(OpenGL_GL_PREFERENCE "LEGACY")

  798.   endif()

  799. 

  800.   find_package(OpenGL REQUIRED)

  801. 

  802.   dpf__add_static_library(dgl-opengl STATIC

  803.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  804.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  805.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  806.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  807.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  808.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  809.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  810.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  811.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  812.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  813.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  814.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  815.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  816.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  817.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  818.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  819.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  820.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  821.   if(SHARED_RESOURCES)

  822.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  823.   else()

  824.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  825.   endif()

  826.   if(APPLE)

  827.     target_sources(dgl-opengl PRIVATE

  828.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  829.   else()

  830.     target_sources(dgl-opengl PRIVATE

  831.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  832.   endif()

  833.   target_include_directories(dgl-opengl PUBLIC

  834.     "${DPF_ROOT_DIR}/dgl")

  835.   target_include_directories(dgl-opengl PUBLIC

  836.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  837. 

  838.   if(APPLE)

  839.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  840.   endif()

  841. 

  842.   if(USE_FILE_BROWSER)

  843.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  844.   endif()

  845. 

  846.   dpf__add_dgl_system_libs()

  847.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  848. 

  849.   add_library(dgl-opengl-definitions INTERFACE)

  850.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  851. 

  852.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  853.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  854. endfunction()

  855. 

  856. # dpf__add_dgl_opengl3

  857. # ------------------------------------------------------------------------------

  858. #

  859. # Add the OpenGL3 variant of DGL, if not already available.

  860. #

  861. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER)

  862.   if(TARGET dgl-opengl3)

  863.     return()

  864.   endif()

  865. 

  866.   if(NOT OpenGL_GL_PREFERENCE)

  867.     set(OpenGL_GL_PREFERENCE "LEGACY")

  868.   endif()

  869. 

  870.   find_package(OpenGL REQUIRED)

  871. 

  872.   dpf__add_static_library(dgl-opengl3 STATIC

  873.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  874.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  875.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  876.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  877.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  878.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  879.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  880.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  881.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  882.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  883.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  884.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  885.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  886.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  887.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  888.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  889.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  890.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  891.   if(SHARED_RESOURCES)

  892.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  893.   else()

  894.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  895.   endif()

  896.   if(APPLE)

  897.     target_sources(dgl-opengl3 PRIVATE

  898.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  899.   else()

  900.     target_sources(dgl-opengl3 PRIVATE

  901.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  902.   endif()

  903.   target_include_directories(dgl-opengl3 PUBLIC

  904.     "${DPF_ROOT_DIR}/dgl")

  905.   target_include_directories(dgl-opengl3 PUBLIC

  906.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  907. 

  908.   if(APPLE)

  909.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  910.   endif()

  911. 

  912.   if(USE_FILE_BROWSER)

  913.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  914.   endif()

  915. 

  916.   dpf__add_dgl_system_libs()

  917.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  918. 

  919.   add_library(dgl-opengl3-definitions INTERFACE)

  920.   target_compile_definitions(dgl-opengl3-definitions INTERFACE "DGL_USE_OPENGL3" "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  921. 

  922.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  923.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  924. endfunction()

  925. 

  926. # dpf__add_dgl_vulkan

  927. # ------------------------------------------------------------------------------

  928. #

  929. # Add the Vulkan variant of DGL, if not already available.

  930. #

  931. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER)

  932.   if(TARGET dgl-vulkan)

  933.     return()

  934.   endif()

  935. 

  936.   find_package(Vulkan REQUIRED)

  937. 

  938.   dpf__add_static_library(dgl-vulkan STATIC

  939.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  940.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  941.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  942.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  943.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  944.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  945.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  946.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  947.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  948.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  949.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  950.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  951.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  952.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  953.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  954.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  955.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  956.   if(NO_SHARED_RESOURCES)

  957.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  958.   else()

  959.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  960.   endif()

  961.   if(APPLE)

  962.     target_sources(dgl-vulkan PRIVATE

  963.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  964.   else()

  965.     target_sources(dgl-vulkan PRIVATE

  966.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  967.   endif()

  968.   target_include_directories(dgl-vulkan PUBLIC

  969.     "${DPF_ROOT_DIR}/dgl")

  970.   target_include_directories(dgl-vulkan PUBLIC

  971.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  972. 

  973.   if(APPLE)

  974.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  975.   endif()

  976. 

  977.   if(USE_FILE_BROWSER)

  978.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  979.   endif()

  980. 

  981.   dpf__add_dgl_system_libs()

  982.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  983. 

  984.   add_library(dgl-vulkan-definitions INTERFACE)

  985.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  986. 

  987.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  988.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  989. endfunction()

  990. 

  991. # dpf__add_plugin_specific_ui_sources

  992. # ------------------------------------------------------------------------------

  993. #

  994. # Compile system specific files

  995. #

  996. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  997.   if(APPLE)

  998.     target_sources("${NAME}" PRIVATE

  999.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1000.     if(USE_WEB_VIEW)

  1001.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1002.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1003.     endif()

  1004.   elseif(WIN32 AND USE_WEB_VIEW)

  1005.     target_sources("${NAME}" PRIVATE

  1006.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1007.     if (MSVC)

  1008.       set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1009.         PROPERTIES COMPILE_FLAGS /std:c++17)

  1010.     else()

  1011.       set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1012.         PROPERTIES COMPILE_FLAGS -std=gnu++17)

  1013.     endif()

  1014.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1015.   endif()

  1016. endfunction()

  1017. 

  1018. # dpf__add_dgl_system_libs

  1019. # ------------------------------------------------------------------------------

  1020. #

  1021. # Find system libraries required by DGL and add them as an interface target.

  1022. #

  1023. function(dpf__add_dgl_system_libs)

  1024.   if(TARGET dgl-system-libs)

  1025.     return()

  1026.   endif()

  1027.   add_library(dgl-system-libs INTERFACE)

  1028.   add_library(dgl-system-libs-definitions INTERFACE)

  1029.   if(APPLE)

  1030.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1031.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1032.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1033.   elseif(EMSCRIPTEN)

  1034.   elseif(HAIKU)

  1035.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1036.   elseif(WIN32)

  1037.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1038.   else()

  1039.     find_package(PkgConfig)

  1040.     pkg_check_modules(DBUS "dbus-1")

  1041.     if(DBUS_FOUND)

  1042.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1043.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1044.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1045.     endif()

  1046.     find_package(X11 REQUIRED)

  1047.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1048.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1049.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1050.     if(X11_Xcursor_FOUND)

  1051.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1052.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1053.     endif()

  1054.     if(X11_Xext_FOUND)

  1055.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1056.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1057.     endif()

  1058.     if(X11_Xrandr_FOUND)

  1059.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1060.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1061.     endif()

  1062.     if(X11_XSync_FOUND)

  1063.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1064.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1065.     endif()

  1066.    endif()

  1067. 

  1068.    if(MSVC)

  1069.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1070.      foreach(_gl_header "glext.h")

  1071.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1072.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1073.        endif()

  1074.      endforeach()

  1075.      foreach(_khr_header "khrplatform.h")

  1076.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1077.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1078.        endif()

  1079.      endforeach()

  1080.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1081.    endif()

  1082. 

  1083.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1084. endfunction()

  1085. 

  1086. # dpf__add_executable

  1087. # ------------------------------------------------------------------------------

  1088. #

  1089. # Adds an executable target, and set some default properties on the target.

  1090. #

  1091. function(dpf__add_executable NAME)

  1092.   add_executable("${NAME}" ${ARGN})

  1093.   dpf__set_target_defaults("${NAME}")

  1094.   if(MINGW)

  1095.     target_link_libraries("${NAME}" PRIVATE "-static")

  1096.   endif()

  1097. endfunction()

  1098. 

  1099. # dpf__add_module

  1100. # ------------------------------------------------------------------------------

  1101. #

  1102. # Adds a module target, and set some default properties on the target.

  1103. #

  1104. function(dpf__add_module NAME)

  1105.   add_library("${NAME}" MODULE ${ARGN})

  1106.   dpf__set_target_defaults("${NAME}")

  1107.   if(APPLE)

  1108.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1109.   elseif(MINGW)

  1110.     target_link_libraries("${NAME}" PRIVATE "-static")

  1111.   endif()

  1112. endfunction()

  1113. 

  1114. # dpf__add_static_library

  1115. # ------------------------------------------------------------------------------

  1116. #

  1117. # Adds a static library target, and set some default properties on the target.

  1118. #

  1119. function(dpf__add_static_library NAME)

  1120.   add_library("${NAME}" STATIC ${ARGN})

  1121.   dpf__set_target_defaults("${NAME}")

  1122. endfunction()

  1123. 

  1124. # dpf__set_module_export_list

  1125. # ------------------------------------------------------------------------------

  1126. #

  1127. # Applies a list of exported symbols to the module target.

  1128. #

  1129. function(dpf__set_module_export_list NAME EXPORTS)

  1130.   if(WIN32)

  1131.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1132.   elseif(APPLE)

  1133.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1134.       "-Xlinker" "-exported_symbols_list"

  1135.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1136.   else()

  1137.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1138.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1139.   endif()

  1140. endfunction()

  1141. 

  1142. # dpf__set_target_defaults

  1143. # ------------------------------------------------------------------------------

  1144. #

  1145. # Set default properties which must apply to all DPF-defined targets.

  1146. #

  1147. function(dpf__set_target_defaults NAME)

  1148.   set_target_properties("${NAME}" PROPERTIES

  1149.     POSITION_INDEPENDENT_CODE TRUE

  1150.     C_VISIBILITY_PRESET "hidden"

  1151.     CXX_VISIBILITY_PRESET "hidden"

  1152.     VISIBILITY_INLINES_HIDDEN TRUE)

  1153.   if(WIN32)

  1154.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1155.   endif()

  1156.   if (MINGW)

  1157.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1158.   endif()

  1159.   if (MSVC)

  1160.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1161.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1162.   endif()

  1163.   if (CMAKE_COMPILER_IS_GNUCXX)

  1164.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1165.   endif()

  1166.   if ((NOT APPLE) AND (NOT MSVC))

  1167.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1168.   endif()

  1169. endfunction()

  1170. 

  1171. # dpf__add_plugin_main

  1172. # ------------------------------------------------------------------------------

  1173. #

  1174. # Adds plugin code to the given target.

  1175. #

  1176. function(dpf__add_plugin_main NAME TARGET)

  1177.   target_sources("${NAME}" PRIVATE

  1178.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1179.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1180. endfunction()

  1181. 

  1182. # dpf__add_ui_main

  1183. # ------------------------------------------------------------------------------

  1184. #

  1185. # Adds UI code to the given target (only if the target has UI).

  1186. #

  1187. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1188.   if(HAS_UI)

  1189.     target_sources("${NAME}" PRIVATE

  1190.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1191.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1192.   endif()

  1193. endfunction()

  1194. 

  1195. # dpf__add_plugin_target_definition

  1196. # ------------------------------------------------------------------------------

  1197. #

  1198. # Adds the plugins target macro definition.

  1199. # This selects which entry file is compiled according to the target type.

  1200. #

  1201. function(dpf__add_plugin_target_definition NAME TARGET)

  1202.   string(TOUPPER "${TARGET}" _upperTarget)

  1203.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1204. endfunction()

  1205. 

  1206. # dpf__add_lv2_ttl_generator

  1207. # ------------------------------------------------------------------------------

  1208. #

  1209. # Build the LV2 TTL generator.

  1210. #

  1211. function(dpf__add_lv2_ttl_generator)

  1212.   if(TARGET lv2_ttl_generator)

  1213.     return()

  1214.   endif()

  1215.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1216.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1217.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1218.   endif()

  1219. endfunction()

  1220. 

  1221. # dpf__ensure_sources_non_empty

  1222. # ------------------------------------------------------------------------------

  1223. #

  1224. # Ensure the given source list contains at least one file.

  1225. # The function appends an empty source file to the list if necessary.

  1226. # This is useful when CMake does not permit to add targets without sources.

  1227. #

  1228. function(dpf__ensure_sources_non_empty VAR)

  1229.   if(NOT "" STREQUAL "${${VAR}}")

  1230.     return()

  1231.   endif()

  1232.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1233.   if(NOT EXISTS "${_file}")

  1234.     file(WRITE "${_file}" "")

  1235.   endif()

  1236.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1237. endfunction()

  1238. 

  1239. # dpf__create_dummy_source_list

  1240. # ------------------------------------------------------------------------------

  1241. #

  1242. # Create a dummy source list which is equivalent to compiling nothing.

  1243. # This is only for compatibility with older CMake versions, which refuse to add

  1244. # targets without any sources.

  1245. #

  1246. macro(dpf__create_dummy_source_list VAR)

  1247.   set("${VAR}")

  1248.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1249.     dpf__ensure_sources_non_empty("${VAR}")

  1250.   endif()

  1251. endmacro()

  1252. 

  1253. # dpf__target_link_directories

  1254. # ------------------------------------------------------------------------------

  1255. #

  1256. # Call `target_link_directories` if cmake >= 3.13,

  1257. # otherwise fallback to global `link_directories`.

  1258. #

  1259. macro(dpf__target_link_directories NAME DIRS)

  1260.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1261.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1262.   else()

  1263.     link_directories(${DIRS})

  1264.   endif()

  1265. endmacro()

  1266. 

  1267. # dpf__warn_once

  1268. # ------------------------------------------------------------------------------

  1269. #

  1270. # Prints a warning message once only.

  1271. #

  1272. function(dpf__warn_once_only TOKEN MESSAGE)

  1273.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1274.   if(NOT _warned)

  1275.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1276.     message(WARNING "${MESSAGE}")

  1277.   endif()

  1278. endfunction()