DISTRHO
/
DPF-Plugins
mirror of https://github.com/DISTRHO/DPF-Plugins
1
0
Fork 0
Code Releases 8 Activity
Collection of DPF-based plugins for packaging
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
173 Commits
1 Branch
299MB
Tree: e07df08cd8
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'e07df08cd8'
${ noResults }
DPF-Plugins/plugins/ProM/projectM/configure.ac

276 lines
8.2KB
Raw Blame History 

  1. AC_INIT([projectM], [3.1.13], [me@mish.dev], [projectM], [https://github.com/projectM-visualizer/projectm/])

  2. AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects tar-pax])

  3. 

  4. AX_IS_RELEASE([git-directory])

  5. AX_CHECK_ENABLE_DEBUG([no], [DEBUG])

  6. 

  7. m4_ifdef([AM_PROG_AR], [AM_PROG_AR])

  8. LT_INIT

  9. 

  10. # Check if we should disable rpath.

  11. #

  12. # For advanced users: In certain configurations, the rpath attributes

  13. # added by libtool cause problems as rpath will be preferred over

  14. # LD_LIBRARY_PATH. This does not seem to be a problem with

  15. # clang. When using --disable-rpath you will likely need to set

  16. # LD_LIBRARY_PATH if you are using libraries in non-system locations.

  17. # YMMV.

  18. #

  19. 

  20. DISABLE_RPATH

  21. 

  22. AC_PROG_CXX

  23. AC_LANG(C++)

  24. 

  25. AC_CONFIG_MACRO_DIRS([m4 m4/autoconf-archive])

  26. 

  27. dnl emscripten

  28. AC_ARG_ENABLE([emscripten],

  29. AS_HELP_STRING([--enable-emscripten], [Build for web with emscripten]),

  30. [], [enable_emscripten=no])

  31. AS_IF([test "x$enable_emscripten" = "xyes" || test "x$EMSCRIPTEN" = "xyes"], [

  32.   dnl Set up emscripten

  33.   m4_include([m4/emscripten.m4])

  34.   AC_DEFINE([EMSCRIPTEN], [1], [Define EMSCRIPTEN])

  35.   enable_threading=no

  36.   enable_gles=yes

  37.   enable_sdl=yes

  38. ], [

  39.   dnl Running in a normal OS (not emscripten)

  40.   AX_CHECK_GL

  41. 

  42.   # check OS if mac or linux

  43.   AC_CANONICAL_HOST

  44.   AC_MSG_CHECKING(Freedom)

  45.   case $host_os in

  46.   darwin*)

  47.     # OSX needs CoreFoundation

  48.     AC_MSG_RESULT(Apple hoarderware detected)

  49.     LIBS="$LIBS -framework CoreFoundation"

  50.     ;;

  51.   linux*)

  52.     # limux needs dl

  53.     AC_MSG_RESULT(GNU/LINUX detected)

  54.     LIBS="$LIBS -ldl"

  55.     ;;

  56.   *)

  57.     AC_MSG_RESULT(Unknown)

  58.     ;;

  59.   esac

  60. ])

  61. 

  62. 

  63. AC_CHECK_LIB(c, dlopen, LIBDL="", AC_CHECK_LIB(dl, dlopen, LIBDL="-ldl"))

  64. 

  65. AC_CHECK_FUNCS_ONCE([aligned_alloc posix_memalign])

  66. AC_CHECK_HEADERS_ONCE([fts.h])

  67. 

  68. AC_CONFIG_HEADERS([config.h])

  69. AC_CONFIG_FILES([

  70.   Makefile

  71.   src/Makefile

  72.   src/libprojectM/Makefile

  73.   src/libprojectM/Renderer/Makefile

  74.   src/libprojectM/NativePresetFactory/Makefile

  75.   src/libprojectM/MilkdropPresetFactory/Makefile

  76.   src/libprojectM/libprojectM.pc

  77.   src/NativePresets/Makefile

  78.   src/projectM-sdl/Makefile

  79.   src/projectM-emscripten/Makefile

  80.   src/projectM-qt/Makefile

  81.   src/projectM-pulseaudio/Makefile

  82.   src/projectM-jack/Makefile

  83.   src/projectM-test/Makefile

  84. ])

  85. 

  86. 

  87. # SDL

  88. AC_ARG_ENABLE([sdl], AS_HELP_STRING([--enable-sdl], [Build SDL2 application]), [], [enable_sdl=check])

  89. AS_IF([test "$enable_sdl" != "no"], [

  90.     PKG_CHECK_MODULES([SDL], [sdl2], [

  91.         m4_include([m4/sdl2.m4])

  92.         SDL_VERSION="2.0.5"

  93.         AS_IF([test "$TRAVIS"], [SDL_VERSION=2.0.2])  # travis has old SDL, we don't care

  94.         AS_IF([test "$EMSCRIPTEN"], [SDL_VERSION=2.0.0])  # emscripten has old SDL, we don't care

  95. 

  96.         # Check for libSDL >= $SDL_VERSION

  97.         AM_PATH_SDL2($SDL_VERSION,

  98.             [enable_sdl=yes],

  99.             [AS_IF([test "$enable_sdl" = "yes"], AC_MSG_ERROR([*** SDL version >= $SDL_VERSION not found!])); enable_sdl=no])

  100.     ],

  101.     [

  102.         # not found

  103.         AS_IF([test "$enable_sdl" = "yes"], AC_MSG_ERROR([*** libsdl2 not found!]))

  104.         enable_sdl=no

  105.     ])

  106. ])

  107. 

  108. 

  109. # Threading

  110. AC_ARG_ENABLE([threading],

  111. AS_HELP_STRING([--enable-threading], [multhreading]),

  112. [], [enable_threading=yes])

  113. AS_IF([test "x$enable_threading" = "xyes" && ! test "$EMSCRIPTEN"], [

  114.   m4_include([m4/autoconf-archive/ax_pthread.m4])

  115.   AX_PTHREAD([

  116.     AC_DEFINE([USE_THREADS], [1], [Define USE_THREADS])

  117.     LIBS="$LIBS $PTHREAD_LIBS $PTHREAD_CFLAGS"

  118.     CFLAGS="$CFLAGS $PTHREAD_CFLAGS"

  119.     CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"

  120.     echo "LIBS=$LIBS"

  121.   ], [

  122.     AC_MSG_ERROR([pthreads not found])

  123.   ])

  124. ])

  125. 

  126. AC_ARG_ENABLE([gles],

  127.   AS_HELP_STRING([--enable-gles], [OpenGL ES support]),

  128.   [], [enable_gles=no])

  129.   AS_IF([test "x$enable_gles" = "xyes"], [

  130.     AC_DEFINE([USE_GLES], [1], [Define USE_GLES])

  131. ])

  132. 

  133. dnl LLVM

  134. dnl unfortuately AX_LLVM macro seems to be out of date, so we're going to rely on the user to make sure LLVM is installed correctly

  135. AC_ARG_ENABLE([llvm],

  136.   AS_HELP_STRING([--enable-llvm],[Support for JIT using LLVM]),

  137.   [], [enable_llvm=no])

  138. AS_IF([test x"$enable_llvm" = "xyes"], [

  139.     AC_DEFINE([HAVE_LLVM], [1], [Define HAVE_LLVM])

  140.     CFLAGS="$CFLAGS -I$(llvm-config --includedir)"

  141.     CXXFLAGS="$CXXFLAGS -I$(llvm-config --includedir)"

  142.     LIBS="$LIBS $(llvm-config --libs)"

  143.     LDFLAGS="$LDFLAGS $(llvm-config --ldflags)"

  144. ])

  145. 

  146. dnl from https://stackoverflow.com/questions/30897170/ac-subst-does-not-expand-variable answer: https://stackoverflow.com/a/30960268

  147. dnl ptomato https://stackoverflow.com/users/172999/ptomato

  148. AC_SUBST([PACKAGE])

  149. AC_PROG_SED

  150. AC_CONFIG_FILES([src/libprojectM/config.inp.in])

  151. 

  152. AC_PREFIX_DEFAULT([/usr/local])

  153. 

  154. AC_PROG_MKDIR_P

  155. 

  156. AS_IF([echo ${host} | grep -Fq android], [],

  157.   [AX_CHECK_COMPILE_FLAG([-stdlib=libc++], [

  158.                         CXXFLAGS="$CXXFLAGS -stdlib=libc++"])

  159. ])

  160. 

  161. AX_CHECK_COMPILE_FLAG([-std=c++14], [

  162.                         CXXFLAGS="$CXXFLAGS -std=c++14"])

  163. 

  164. # Qt5

  165. AC_ARG_ENABLE([qt], AS_HELP_STRING([--enable-qt], [Enable Qt: needed for pulseaudio and jack GUIs]), [], [enable_qt=check])

  166. AS_IF([test "$enable_qt" != "no"],

  167.   [

  168.     case $host_os in

  169.       linux*)

  170.         PATH="$PATH:`pkg-config --variable=host_bins Qt5Core`"

  171.       ;;

  172.     esac

  173.     AX_HAVE_QT  # m4/qt.m4

  174. 

  175.     AS_IF([test "$have_qt" = "yes"], [

  176.         # we have at least qt5 if $have_qt is true

  177.         enable_qt=yes

  178.         export QT_SELECT=qt5

  179. 

  180.         # we depend on libQt5Gui and libQt5OpenGL

  181.         # https://github.com/projectM-visualizer/projectm/issues/271

  182.         LIBS="$LIBS -lQt5Gui -lQt5OpenGL"

  183.     ],

  184.     [AS_IF([test "$enable_qt" = "yes"],

  185.         [AC_MSG_ERROR(["Qt5 not found"])],

  186.         [enable_qt=no])]

  187. )])

  188. 

  189. 

  190. # Pulseaudio

  191. AC_ARG_ENABLE([pulseaudio], AS_HELP_STRING([--enable-pulseaudio], [Build Pulseaudio]), [], [enable_pulseaudio=check])

  192. AS_IF([test "$enable_pulseaudio" != "no"],

  193.     [PKG_CHECK_MODULES([libpulse],

  194.         [libpulse],

  195.         [

  196.             # still need qt

  197.             AS_IF([test "$enable_qt" = "yes"],

  198.                 [enable_pulseaudio=yes],

  199.                 [enable_pulseaudio="no (Qt required)"])

  200.         ],

  201.         [AS_IF([test "$enable_pulseaudio" = "yes"],

  202.             [AC_MSG_ERROR([libpulse required, but not found.])],

  203.             [enable_pulseaudio=no])])])

  204. 

  205. 

  206. # Jack

  207. AC_ARG_ENABLE([jack], AS_HELP_STRING([--enable-jack], [Build Jack]), [], [enable_jack=check])

  208. AS_IF([test "$enable_jack" != "no"],

  209.     [PKG_CHECK_MODULES([jack],

  210.     [jack],

  211.     [

  212.         # still need qt

  213.         AS_IF([test "$enable_qt" = "yes"],

  214.             [enable_jack=yes],

  215.             [enable_jack="no (Qt required)"])

  216.     ],

  217.     [AS_IF([test "$enable_jack" = "yes"],

  218.         [AC_MSG_ERROR([jack required, but not found.])],

  219.         [enable_jack=no])])])

  220. 

  221. 

  222. AM_CONDITIONAL([ENABLE_SDL], [test "x$enable_sdl" = "xyes"])

  223. AM_CONDITIONAL([ENABLE_QT], [test "x$enable_qt" = "xyes"])

  224. AM_CONDITIONAL([ENABLE_JACK], [test "x$enable_jack" = "xyes"])

  225. AM_CONDITIONAL([ENABLE_PULSEAUDIO], [test "x$enable_pulseaudio" = "xyes"])

  226. AM_CONDITIONAL([ENABLE_EMSCRIPTEN], [test "x$enable_emscripten" = "xyes"])

  227. 

  228. 

  229. my_CFLAGS="-Wall -Wchar-subscripts -Wformat-security -Wpointer-arith -Wshadow -Wsign-compare -Wtype-limits"

  230. #my_CFLAGS+="-fsanitize=address -fno-omit-frame-pointer "

  231. my_CFLAGS="${my_CFLAGS} -DDATADIR_PATH=\\\"\"\$(pkgdatadir)\\\"\""

  232. my_CFLAGS="${my_CFLAGS} -I\"\$(top_srcdir)/vendor\""  # provides glm headers

  233. my_CFLAGS="${my_CFLAGS} -DGL_SILENCE_DEPRECATION"

  234. AC_SUBST([my_CFLAGS])

  235. 

  236. 

  237. # glm (vendored, this should never fail; headers are in vendor/glm)

  238. AC_SUBST(CPPFLAGS, "$CPPFLAGS -I${srcdir}/vendor")

  239. AS_IF([test "x$enable_emscripten" != "xyes"], [

  240.     AC_CHECK_HEADER([glm/glm.hpp],, AC_MSG_ERROR(vendored libglm not found.))

  241. ])

  242. 

  243. 

  244. AC_OUTPUT

  245. 

  246. AC_MSG_RESULT([

  247. projectM v$VERSION

  248. =====

  249. 

  250. prefix:                 ${prefix}

  251. sysconfdir:             ${sysconfdir}

  252. libdir:                 ${libdir}

  253. includedir:             ${includedir}

  254. 

  255. compiler:               ${CC}

  256. cflags:                 ${CFLAGS} ${my_CFLAGS}

  257. cxxflags:               ${CXXFLAGS}

  258. libs:                   ${LIBS}

  259. ldflags:                ${LDFLAGS}

  260. 

  261. - - -

  262. 

  263. Applications:

  264. =====

  265. 

  266. libprojectM:            yes

  267. Threading:              ${enable_threading}

  268. SDL:                    ${enable_sdl}

  269. Qt:                     ${enable_qt}

  270. Pulseaudio:             ${enable_pulseaudio}

  271. Jack:                   ${enable_jack}

  272. OpenGLES:               ${enable_gles}

  273. Emscripten:             ${enable_emscripten}

  274. LLVM JIT:               ${enable_llvm}

  275. ])