DISTRHO
/
DPF-Plugins
mirror of https://github.com/DISTRHO/DPF-Plugins
1
0
Fork 0
Code Releases 8 Activity
Collection of DPF-based plugins for packaging
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
131 Commits
1 Branch
86MB
Tree: c7c5ffa5ab
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'c7c5ffa5ab'
${ noResults }
DPF-Plugins/dpf/cmake/DPF-plugin.cmake

675 lines
23KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     else()

  157.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  158.     endif()

  159.   endforeach()

  160. endfunction()

  161. 

  162. # ------------------------------------------------------------------------------

  163. # DPF private functions (prefixed with `dpf__`)

  164. # ------------------------------------------------------------------------------

  165. 

  166. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  167. #       to the output directory.

  168. #

  169. 

  170. # dpf__build_jack

  171. # ------------------------------------------------------------------------------

  172. #

  173. # Add build rules for a JACK program.

  174. #

  175. function(dpf__build_jack NAME DGL_LIBRARY)

  176.   dpf__create_dummy_source_list(_no_srcs)

  177. 

  178.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  179.   dpf__add_plugin_main("${NAME}-jack" "jack")

  180.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  181.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  182.   set_target_properties("${NAME}-jack" PROPERTIES

  183.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  184.     OUTPUT_NAME "${NAME}")

  185. 

  186.   # Note: libjack will be linked at runtime

  187.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  188.     target_link_libraries("${NAME}-jack" PRIVATE "dl")

  189.   endif()

  190. 

  191.   # for RtAudio native fallback

  192.   if(APPLE)

  193.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  194.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  195.     target_link_libraries("${NAME}-jack" PRIVATE "${APPLE_COREAUDIO_FRAMEWORK}" "${APPLE_COREFOUNDATION_FRAMEWORK}")

  196.   endif()

  197. endfunction()

  198. 

  199. # dpf__build_ladspa

  200. # ------------------------------------------------------------------------------

  201. #

  202. # Add build rules for a DSSI plugin.

  203. #

  204. function(dpf__build_ladspa NAME)

  205.   dpf__create_dummy_source_list(_no_srcs)

  206. 

  207.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  208.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  209.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  210.   set_target_properties("${NAME}-ladspa" PROPERTIES

  211.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  212.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  213.     OUTPUT_NAME "${NAME}-ladspa"

  214.     PREFIX "")

  215. endfunction()

  216. 

  217. # dpf__build_dssi

  218. # ------------------------------------------------------------------------------

  219. #

  220. # Add build rules for a DSSI plugin.

  221. #

  222. function(dpf__build_dssi NAME DGL_LIBRARY)

  223.   find_package(PkgConfig)

  224.   pkg_check_modules(LIBLO "liblo")

  225.   if(NOT LIBLO_FOUND)

  226.     dpf__warn_once_only(missing_liblo

  227.       "liblo is not found, skipping the `dssi` plugin targets")

  228.     return()

  229.   endif()

  230. 

  231.   link_directories(${LIBLO_LIBRARY_DIRS})

  232. 

  233.   dpf__create_dummy_source_list(_no_srcs)

  234. 

  235.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  236.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  237.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  238.   set_target_properties("${NAME}-dssi" PROPERTIES

  239.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  240.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  241.     OUTPUT_NAME "${NAME}-dssi"

  242.     PREFIX "")

  243. 

  244.   if(DGL_LIBRARY)

  245.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  246.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  247.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  248.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  249.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  250.       OUTPUT_NAME "${NAME}_ui")

  251. 

  252.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  253.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  254.   endif()

  255. endfunction()

  256. 

  257. # dpf__build_lv2

  258. # ------------------------------------------------------------------------------

  259. #

  260. # Add build rules for a LV2 plugin.

  261. #

  262. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  263.   dpf__create_dummy_source_list(_no_srcs)

  264. 

  265.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  266.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  267.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  268.   set_target_properties("${NAME}-lv2" PROPERTIES

  269.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  270.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  271.     OUTPUT_NAME "${NAME}_dsp"

  272.     PREFIX "")

  273. 

  274.   if(DGL_LIBRARY)

  275.     if(MONOLITHIC)

  276.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  277.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  278.       set_target_properties("${NAME}-lv2" PROPERTIES

  279.         OUTPUT_NAME "${NAME}")

  280.     else()

  281.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  282.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  283.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  284.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  285.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  286.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  287.         OUTPUT_NAME "${NAME}_ui"

  288.         PREFIX "")

  289.     endif()

  290.   endif()

  291. 

  292.   dpf__add_lv2_ttl_generator()

  293.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  294. 

  295.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  296.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  297.     "$<TARGET_FILE:lv2_ttl_generator>"

  298.     "$<TARGET_FILE:${NAME}-lv2>"

  299.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  300.     DEPENDS lv2_ttl_generator)

  301. endfunction()

  302. 

  303. # dpf__build_vst2

  304. # ------------------------------------------------------------------------------

  305. #

  306. # Add build rules for a VST2 plugin.

  307. #

  308. function(dpf__build_vst2 NAME DGL_LIBRARY)

  309.   dpf__create_dummy_source_list(_no_srcs)

  310. 

  311.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  312.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  313.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  314.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  315.   set_target_properties("${NAME}-vst2" PROPERTIES

  316.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  317.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  318.     OUTPUT_NAME "${NAME}-vst2"

  319.     PREFIX "")

  320. endfunction()

  321. 

  322. # dpf__add_dgl_cairo

  323. # ------------------------------------------------------------------------------

  324. #

  325. # Add the Cairo variant of DGL, if not already available.

  326. #

  327. function(dpf__add_dgl_cairo)

  328.   if(TARGET dgl-cairo)

  329.     return()

  330.   endif()

  331. 

  332.   find_package(PkgConfig)

  333.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  334. 

  335.   link_directories(${CAIRO_LIBRARY_DIRS})

  336. 

  337.   dpf__add_static_library(dgl-cairo STATIC

  338.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  339.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  340.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  341.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  342.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  343.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  344.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  345.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  346.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  347.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  348.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  349.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  350.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  351.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  352.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  353.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  354.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  355.   if(NOT APPLE)

  356.     target_sources(dgl-cairo PRIVATE

  357.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  358.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  359.     #target_sources(dgl-opengl PRIVATE

  360.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  361.   endif()

  362.   target_include_directories(dgl-cairo PUBLIC

  363.     "${DPF_ROOT_DIR}/dgl")

  364.   target_include_directories(dgl-cairo PUBLIC

  365.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  366. 

  367.   dpf__add_dgl_system_libs()

  368.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  369. 

  370.   add_library(dgl-cairo-definitions INTERFACE)

  371.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  372. 

  373.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  374.   if(MINGW)

  375.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  376.   else()

  377.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  378.   endif()

  379.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  380. endfunction()

  381. 

  382. # dpf__add_dgl_opengl

  383. # ------------------------------------------------------------------------------

  384. #

  385. # Add the OpenGL variant of DGL, if not already available.

  386. #

  387. function(dpf__add_dgl_opengl)

  388.   if(TARGET dgl-opengl)

  389.     return()

  390.   endif()

  391. 

  392.   if(NOT OpenGL_GL_PREFERENCE)

  393.     set(OpenGL_GL_PREFERENCE "LEGACY")

  394.   endif()

  395. 

  396.   find_package(OpenGL REQUIRED)

  397. 

  398.   dpf__add_static_library(dgl-opengl STATIC

  399.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  400.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  401.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  402.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  403.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  404.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  405.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  406.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  407.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  408.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  409.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  410.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  411.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  412.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  413.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  414.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  415.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  416.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  417.   if(NOT APPLE)

  418.     target_sources(dgl-opengl PRIVATE

  419.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  420.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  421.     #target_sources(dgl-opengl PRIVATE

  422.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  423.   endif()

  424.   target_include_directories(dgl-opengl PUBLIC

  425.     "${DPF_ROOT_DIR}/dgl")

  426.   target_include_directories(dgl-opengl PUBLIC

  427.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  428. 

  429.   if(APPLE)

  430.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  431.   endif()

  432. 

  433.   dpf__add_dgl_system_libs()

  434.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  435. 

  436.   add_library(dgl-opengl-definitions INTERFACE)

  437.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  438. 

  439.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  440.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  441. endfunction()

  442. 

  443. # dpf__add_plugin_specific_ui_sources

  444. # ------------------------------------------------------------------------------

  445. #

  446. # Compile plugin-specific UI sources into the target designated by the given

  447. # name. There are some special considerations here:

  448. # - On most platforms, sources can be compiled only once, as part of DGL;

  449. # - On macOS, for any sources which define Objective-C interfaces, these must

  450. #   be recompiled for each plugin under a unique namespace. In this case, the

  451. #   name must be a plugin-specific identifier, and it will be used for computing

  452. #   the unique ID along with the project version.

  453. function(dpf__add_plugin_specific_ui_sources NAME)

  454.   if(APPLE)

  455.     target_sources("${NAME}" PRIVATE

  456.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  457.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  458.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  459.   endif()

  460. endfunction()

  461. 

  462. # dpf__add_dgl_system_libs

  463. # ------------------------------------------------------------------------------

  464. #

  465. # Find system libraries required by DGL and add them as an interface target.

  466. #

  467. function(dpf__add_dgl_system_libs)

  468.   if(TARGET dgl-system-libs)

  469.     return()

  470.   endif()

  471.   add_library(dgl-system-libs INTERFACE)

  472.   add_library(dgl-system-libs-definitions INTERFACE)

  473.   if(HAIKU)

  474.     target_link_libraries(dgl-system-libs INTERFACE "be")

  475.   elseif(WIN32)

  476.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  477.   elseif(APPLE)

  478.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  479.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  480.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  481.   else()

  482.     find_package(X11 REQUIRED)

  483.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  484.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  485.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  486.     if(X11_Xext_FOUND)

  487.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  488.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  489.     endif()

  490.     if(X11_XSync_FOUND)

  491.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  492.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  493.     endif()

  494.     if(X11_Xrandr_FOUND)

  495.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  496.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  497.     endif()

  498.     #if(X11_Xcursor_FOUND)

  499.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  500.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  501.     #endif()

  502.    endif()

  503. 

  504.    if(MSVC)

  505.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  506.      foreach(_gl_header "glext.h")

  507.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  508.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  509.        endif()

  510.      endforeach()

  511.      foreach(_khr_header "khrplatform.h")

  512.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  513.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  514.        endif()

  515.      endforeach()

  516.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  517.    endif()

  518. 

  519.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  520. endfunction()

  521. 

  522. # dpf__add_executable

  523. # ------------------------------------------------------------------------------

  524. #

  525. # Adds an executable target, and set some default properties on the target.

  526. #

  527. function(dpf__add_executable NAME)

  528.   add_executable("${NAME}" ${ARGN})

  529.   dpf__set_target_defaults("${NAME}")

  530.   if(MINGW)

  531.     target_link_libraries("${NAME}" PRIVATE "-static")

  532.   endif()

  533. endfunction()

  534. 

  535. # dpf__add_module

  536. # ------------------------------------------------------------------------------

  537. #

  538. # Adds a module target, and set some default properties on the target.

  539. #

  540. function(dpf__add_module NAME)

  541.   add_library("${NAME}" MODULE ${ARGN})

  542.   dpf__set_target_defaults("${NAME}")

  543.   if(MINGW)

  544.     target_link_libraries("${NAME}" PRIVATE "-static")

  545.   endif()

  546. endfunction()

  547. 

  548. # dpf__add_static_library

  549. # ------------------------------------------------------------------------------

  550. #

  551. # Adds a static library target, and set some default properties on the target.

  552. #

  553. function(dpf__add_static_library NAME)

  554.   add_library("${NAME}" STATIC ${ARGN})

  555.   dpf__set_target_defaults("${NAME}")

  556. endfunction()

  557. 

  558. # dpf__set_target_defaults

  559. # ------------------------------------------------------------------------------

  560. #

  561. # Set default properties which must apply to all DPF-defined targets.

  562. #

  563. function(dpf__set_target_defaults NAME)

  564.   set_target_properties("${NAME}" PROPERTIES

  565.     POSITION_INDEPENDENT_CODE TRUE

  566.     C_VISIBILITY_PRESET "hidden"

  567.     CXX_VISIBILITY_PRESET "hidden"

  568.     VISIBILITY_INLINES_HIDDEN TRUE)

  569.   if(WIN32)

  570.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  571.   endif()

  572.   if (MINGW)

  573.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  574.   endif()

  575.   if (MSVC)

  576.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  577.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  578.   endif()

  579. endfunction()

  580. 

  581. # dpf__add_plugin_main

  582. # ------------------------------------------------------------------------------

  583. #

  584. # Adds plugin code to the given target.

  585. #

  586. function(dpf__add_plugin_main NAME TARGET)

  587.   target_sources("${NAME}" PRIVATE

  588.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  589.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  590. endfunction()

  591. 

  592. # dpf__add_ui_main

  593. # ------------------------------------------------------------------------------

  594. #

  595. # Adds UI code to the given target (only if the target has UI).

  596. #

  597. function(dpf__add_ui_main NAME TARGET HAS_UI)

  598.   if(HAS_UI)

  599.     target_sources("${NAME}" PRIVATE

  600.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  601.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  602.   endif()

  603. endfunction()

  604. 

  605. # dpf__add_plugin_target_definition

  606. # ------------------------------------------------------------------------------

  607. #

  608. # Adds the plugins target macro definition.

  609. # This selects which entry file is compiled according to the target type.

  610. #

  611. function(dpf__add_plugin_target_definition NAME TARGET)

  612.   string(TOUPPER "${TARGET}" _upperTarget)

  613.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  614. endfunction()

  615. 

  616. # dpf__add_lv2_ttl_generator

  617. # ------------------------------------------------------------------------------

  618. #

  619. # Build the LV2 TTL generator.

  620. #

  621. function(dpf__add_lv2_ttl_generator)

  622.   if(TARGET lv2_ttl_generator)

  623.     return()

  624.   endif()

  625.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  626.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  627.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  628.   endif()

  629. endfunction()

  630. 

  631. # dpf__ensure_sources_non_empty

  632. # ------------------------------------------------------------------------------

  633. #

  634. # Ensure the given source list contains at least one file.

  635. # The function appends an empty source file to the list if necessary.

  636. # This is useful when CMake does not permit to add targets without sources.

  637. #

  638. function(dpf__ensure_sources_non_empty VAR)

  639.   if(NOT "" STREQUAL "${${VAR}}")

  640.     return()

  641.   endif()

  642.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  643.   if(NOT EXISTS "${_file}")

  644.     file(WRITE "${_file}" "")

  645.   endif()

  646.   set("${VAR}" "${_file}" PARENT_SCOPE)

  647. endfunction()

  648. 

  649. # dpf__create_dummy_source_list

  650. # ------------------------------------------------------------------------------

  651. #

  652. # Create a dummy source list which is equivalent to compiling nothing.

  653. # This is only for compatibility with older CMake versions, which refuse to add

  654. # targets without any sources.

  655. #

  656. macro(dpf__create_dummy_source_list VAR)

  657.   set("${VAR}")

  658.   if(CMAKE_VERSION VERSION_LESS "3.11")

  659.     dpf__ensure_sources_non_empty("${VAR}")

  660.   endif()

  661. endmacro()

  662. 

  663. # dpf__warn_once

  664. # ------------------------------------------------------------------------------

  665. #

  666. # Prints a warning message once only.

  667. #

  668. function(dpf__warn_once_only TOKEN MESSAGE)

  669.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  670.   if(NOT _warned)

  671.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  672.     message(WARNING "${MESSAGE}")

  673.   endif()

  674. endfunction()