DISTRHO
/
DPF-Plugins
mirror of https://github.com/DISTRHO/DPF-Plugins
1
0
Fork 0
Code Releases 8 Activity
Collection of DPF-based plugins for packaging
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
133 Commits
1 Branch
97MB
Tree: 5c201852b6
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '5c201852b6'
${ noResults }
DPF-Plugins/plugins/ProM/projectM/CMakeLists.txt

272 lines
12KB
Raw Blame History 

  1. cmake_minimum_required(VERSION 3.14 FATAL_ERROR)

  2. 

  3. if(CMAKE_VERSION VERSION_LESS 3.19 AND CMAKE_GENERATOR STREQUAL "Xcode")

  4.     message(AUTHOR_WARNING "Using a CMake version before 3.19 with a recent Xcode SDK and the Xcode generator "

  5.             "will likely result in CMake failing to find the AppleClang compiler. Either upgrade CMake to at least "

  6.             "version 3.19 or use a different generator, e.g. \"Unix Makefiles\" or \"Ninja\".")

  7. endif()

  8. 

  9. include(CMakeDependentOption)

  10. include(CheckSymbolExists)

  11. 

  12. set(CMAKE_CXX_STANDARD 14)

  13. set(CMAKE_CXX_STANDARD_REQUIRED YES)

  14. set(CMAKE_POSITION_INDEPENDENT_CODE YES)

  15. 

  16. set_property(GLOBAL PROPERTY USE_FOLDERS ON)

  17. 

  18. option(ENABLE_DEBUG_POSTFIX "Add \"d\" after library names for debug builds" ON)

  19. if(ENABLE_DEBUG_POSTFIX)

  20.     set(CMAKE_DEBUG_POSTFIX d)

  21. endif()

  22. 

  23. # The API (SO) and detailed library versions for the shared library.

  24. set(PROJECTM_SO_VERSION "3")

  25. set(PROJECTM_LIB_VERSION "3.1.1")

  26. 

  27. project(projectm

  28.         LANGUAGES C CXX

  29.         VERSION 3.1.13

  30.         )

  31. 

  32. list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake")

  33. 

  34. set(PROJECTM_BIN_DIR "bin" CACHE STRING "Executable installation directory, relative to the install prefix.")

  35. set(PROJECTM_DATADIR_PATH "share/projectM" CACHE STRING "Default (absolute) path to the projectM data files (presets etc.)")

  36. set(PROJECTM_LIB_DIR "lib" CACHE STRING "Library installation directory, relative to the install prefix.")

  37. set(PROJECTM_INCLUDE_DIR "include" CACHE STRING "Header installation directory, relative to the install prefix.")

  38. 

  39. # Feature options, including dependencies.

  40. option(ENABLE_STATIC_LIB "Build and install libprojectM as a static library" ON)

  41. cmake_dependent_option(ENABLE_SHARED_LIB "Build and install libprojectM as a shared library" ON "NOT CMAKE_SYSTEM_NAME STREQUAL Windows" OFF)

  42. cmake_dependent_option(ENABLE_SHARED_LINKING "Link all built UI applications against the shared library." OFF "ENABLE_SHARED_LIB" OFF)

  43. option(ENABLE_DOXYGEN "Build and install Doxygen source code documentation in PROJECTM_DATADIR_PATH/docs." OFF)

  44. option(ENABLE_CXX_INTERFACE "Enable exporting all C++ symbols, not only the C API, in the shared library. Warning: This is not very portable." OFF)

  45. option(ENABLE_PRESETS "Build and install bundled presets" ON)

  46. option(ENABLE_NATIVE_PRESETS "Build and install native libraries written in C/C++" OFF)

  47. option(ENABLE_TESTING "Build and install the projectM test suite" OFF)

  48. option(ENABLE_EMSCRIPTEN "Build for web with emscripten" OFF)

  49. cmake_dependent_option(ENABLE_SDL "Enable SDL2 support" ON "NOT ENABLE_EMSCRIPTEN;NOT ENABLE_TESTING" ON)

  50. cmake_dependent_option(ENABLE_SDL_UI "Build the SDL2-based reference UI" ON "NOT ENABLE_EMSCRIPTEN" OFF)

  51. cmake_dependent_option(ENABLE_GLES "Enable OpenGL ES support" OFF "NOT ENABLE_EMSCRIPTEN" ON)

  52. cmake_dependent_option(ENABLE_THREADING "Enable multithreading support" ON "NOT ENABLE_EMSCRIPTEN;NOT CMAKE_SYSTEM_NAME STREQUAL Windows" OFF)

  53. cmake_dependent_option(ENABLE_PULSEAUDIO "Build PulseAudio-based Qt UI" OFF "NOT ENABLE_EMSCRIPTEN;CMAKE_SYSTEM_NAME STREQUAL Linux" OFF)

  54. cmake_dependent_option(ENABLE_JACK "Build JACK-based Qt and SDL UIs" OFF "NOT ENABLE_EMSCRIPTEN;CMAKE_SYSTEM_NAME STREQUAL Linux" OFF)

  55. cmake_dependent_option(ENABLE_QT "Build Qt UI library" OFF "NOT ENABLE_PULSEAUDIO;NOT ENABLE_JACK" ON)

  56. cmake_dependent_option(ENABLE_LLVM "Enable LLVM JIT support" OFF "NOT ENABLE_EMSCRIPTEN" OFF)

  57. cmake_dependent_option(ENABLE_LIBVISUAL "Build and install the projectM libvisual plug-in" OFF "NOT ENABLE_EMSCRIPTEN;CMAKE_SYSTEM_NAME STREQUAL Linux" OFF)

  58. 

  59. if(NOT ENABLE_STATIC_LIB AND NOT ENABLE_SHARED_LIB)

  60.     message(FATAL_ERROR "At least one of either ENABLE_STATIC_LIB or ENABLE_SHARED_LIB options must be set to ON.")

  61. endif()

  62. 

  63. if(ENABLE_DOXYGEN)

  64.     find_package(Doxygen REQUIRED)

  65. endif()

  66. 

  67. find_package(GLM)

  68. if(NOT TARGET GLM::GLM)

  69.     add_library(GLM::GLM INTERFACE IMPORTED)

  70.     set_target_properties(GLM::GLM PROPERTIES

  71.             INTERFACE_INCLUDE_DIRECTORIES "${CMAKE_SOURCE_DIR}/vendor"

  72.             )

  73. 

  74.     message(STATUS "GLM library not found, using bundled version.")

  75.     set(USE_SYSTEM_GLM OFF)

  76. else()

  77.     set(USE_SYSTEM_GLM ON)

  78. endif()

  79. 

  80. if(ENABLE_EMSCRIPTEN)

  81.     message(STATUS "${CMAKE_C_COMPILER}")

  82.     check_symbol_exists(__EMSCRIPTEN__ "" HAVE_EMSCRIPTEN)

  83.     if(NOT HAVE_EMSCRIPTEN)

  84.         message(FATAL_ERROR "You are not using an emscripten compiler.")

  85.     endif()

  86. endif()

  87. 

  88. if(ENABLE_SDL)

  89.     find_package(SDL2 REQUIRED)

  90. 

  91.     # Apply some fixes, as SDL2's CMake support is new and still a WiP.

  92.     include(SDL2Target)

  93. endif()

  94. 

  95. if(ENABLE_GLES)

  96.     # Might be implemented in the CMake OpenGL module.

  97.     # We may provide a find module in the future, and add support for CMake's own module later:

  98.     # https://gitlab.kitware.com/cmake/cmake/-/blob/3fc3b43933d0b486aa4eb5d63fc257475feff348/Modules/FindOpenGL.cmake#L520

  99.     message(FATAL_ERROR "GLES support is currently not implemented for CMake builds.")

  100.     find_package(GLES3 REQUIRED)

  101. else()

  102.     find_package(OpenGL REQUIRED)

  103.     set(PROJECTM_OPENGL_LIBRARIES OpenGL::GL)

  104.     # GLX is required by SOIL2 on platforms with the X Window System (e.g. most Linux distributions)

  105.     if(TARGET OpenGL::GLX)

  106.         list(APPEND PROJECTM_OPENGL_LIBRARIES OpenGL::GLX)

  107.     endif()

  108.     if(CMAKE_SYSTEM_NAME STREQUAL "Windows")

  109.         find_package(GLEW REQUIRED)

  110.         list(APPEND PROJECTM_OPENGL_LIBRARIES GLEW::glew)

  111.     endif()

  112. endif()

  113. 

  114. if(ENABLE_THREADING)

  115.     set(CMAKE_THREAD_PREFER_PTHREAD YES)

  116.     find_package(Threads REQUIRED)

  117.     if(NOT CMAKE_USE_PTHREADS_INIT)

  118.         message(FATAL_ERROR "Threading support requested - pthread support is required, but not available.")

  119.     endif()

  120.     set(USE_THREADS YES)

  121. endif()

  122. 

  123. if(ENABLE_LLVM)

  124.     find_package(LLVM REQUIRED)

  125.     if(LLVM_VERSION VERSION_LESS 10.0)

  126.         message(FATAL_ERROR "LLVM JIT support requires at least version 10.0, but only ${LLVM_VERSION} was found.")

  127.     endif()

  128.     set(HAVE_LLVM TRUE)

  129. else()

  130.     unset(HAVE_LLVM)

  131. endif()

  132. 

  133. if(ENABLE_PULSEAUDIO)

  134.     find_package(Pulseaudio REQUIRED)

  135. endif()

  136. 

  137. if(ENABLE_JACK)

  138.     find_package(JACK REQUIRED)

  139. endif()

  140. 

  141. if(ENABLE_PULSEAUDIO OR ENABLE_JACK)

  142.     set(QT_REQUIRED_COMPONENTS Gui Widgets OpenGL Xml)

  143.     if(DEFINED QT_VERSION)

  144.         find_package(Qt${QT_VERSION} REQUIRED COMPONENTS ${QT_REQUIRED_COMPONENTS})

  145.     else()

  146.         # Try to determine the Qt version available, starting with Qt6

  147.         message(STATUS "Determining Qt version. To use a specific version, set QT_VERSION to either 5 or 6.")

  148.         find_package(Qt6 QUIET COMPONENTS ${QT_REQUIRED_COMPONENTS})

  149.         if(TARGET Qt6::Core)

  150.             set(QT_VERSION 6)

  151.         else()

  152.             find_package(Qt5 QUIET COMPONENTS ${QT_REQUIRED_COMPONENTS})

  153.             if(TARGET Qt5::Core)

  154.                 set(QT_VERSION 5)

  155.             else()

  156.                 message(FATAL_ERROR "Could not find either Qt 5 or 6, one is required to build the PulseAudio or JACK UIs.")

  157.             endif()

  158.         endif()

  159.     endif()

  160. 

  161.     # OpenGLWidgets were put into their own component since Qt 6.

  162.     if(QT_VERSION EQUAL 6)

  163.         list(APPEND QT_REQUIRED_COMPONENTS OpenGLWidgets)

  164.         find_package(Qt6 REQUIRED COMPONENTS OpenGLWidgets)

  165.     endif()

  166. 

  167.     set(QT_LINK_TARGETS "")

  168.     foreach(component ${QT_REQUIRED_COMPONENTS})

  169.         list(APPEND QT_LINK_TARGETS Qt${QT_VERSION}::${component})

  170.     endforeach()

  171. endif()

  172. 

  173. if(ENABLE_LIBVISUAL)

  174.     find_package(libvisual REQUIRED)

  175.     set(PROJECTM_LIBVISUAL_DIR "${LIBVISUAL_PLUGINSBASEDIR}/actor" CACHE STRING "Installation directory for the libvisual plug-in library.")

  176. endif()

  177. 

  178. if(ENABLE_CXX_INTERFACE)

  179.     set(CMAKE_C_VISIBILITY_PRESET default)

  180.     set(CMAKE_CXX_VISIBILITY_PRESET default)

  181.     set(CMAKE_VISIBILITY_INLINES_HIDDEN OFF)

  182. else()

  183.     set(CMAKE_C_VISIBILITY_PRESET hidden)

  184.     set(CMAKE_CXX_VISIBILITY_PRESET hidden)

  185.     set(CMAKE_VISIBILITY_INLINES_HIDDEN ON)

  186. endif()

  187. 

  188. include(features.cmake)

  189. 

  190. add_subdirectory(presets)

  191. add_subdirectory(src)

  192. 

  193. message(STATUS "")

  194. message(STATUS "projectM v${PROJECT_VERSION}")

  195. message(STATUS "==============================================")

  196. message(STATUS "")

  197. message(STATUS "    prefix:                  ${CMAKE_INSTALL_PREFIX}")

  198. message(STATUS "    libdir:                  ${PROJECTM_LIB_DIR}")

  199. message(STATUS "    includedir:              ${PROJECTM_INCLUDE_DIR}")

  200. message(STATUS "    bindir:                  ${PROJECTM_BIN_DIR}")

  201. message(STATUS "    libvisual plugin dir:    ${PROJECTM_LIBVISUAL_DIR}")

  202. message(STATUS "")

  203. message(STATUS "    compiler:                ${CMAKE_CXX_COMPILER}")

  204. message(STATUS "    cflags:                  ${CMAKE_C_FLAGS}")

  205. message(STATUS "    cxxflags:                ${CMAKE_CXX_FLAGS}")

  206. message(STATUS "    ldflags:                 ${CMAKE_SHARED_LINKER_FLAGS}")

  207. message(STATUS "")

  208. message(STATUS "    DATADIR_PATH:            ${PROJECTM_DATADIR_PATH}")

  209. message(STATUS "")

  210. message(STATUS "Features:")

  211. message(STATUS "==============================================")

  212. message(STATUS "")

  213. message(STATUS "    Presets:                 ${ENABLE_PRESETS}")

  214. message(STATUS "    Native presets:          ${ENABLE_NATIVE_PRESETS}")

  215. message(STATUS "    Threading:               ${ENABLE_THREADING}")

  216. message(STATUS "    SDL2:                    ${ENABLE_SDL}")

  217. if(ENABLE_SDL)

  218.     message(STATUS "        SDL2 version:        ${SDL2_VERSION}")

  219. endif()

  220. message(STATUS "    OpenGLES:                ${ENABLE_GLES}")

  221. message(STATUS "    Emscripten:              ${ENABLE_EMSCRIPTEN}")

  222. message(STATUS "    LLVM JIT:                ${ENABLE_LLVM}")

  223. if(ENABLE_LLVM)

  224.     message(STATUS "        LLVM version:        ${LLVM_VERSION}")

  225. endif()

  226. message(STATUS "    Use system GLM:          ${USE_SYSTEM_GLM}")

  227. message(STATUS "    Link UI with shared lib: ${ENABLE_SHARED_LINKING}")

  228. message(STATUS "")

  229. message(STATUS "Targets and applications:")

  230. message(STATUS "==============================================")

  231. message(STATUS "")

  232. message(STATUS "    libprojectM static:      ${ENABLE_STATIC_LIB}")

  233. message(STATUS "    libprojectM shared:      ${ENABLE_SHARED_LIB}")

  234. message(STATUS "    SDL2 UI:                 ${ENABLE_SDL_UI}")

  235. message(STATUS "    Doxygen API docs:        ${ENABLE_DOXYGEN}")

  236. message(STATUS "    Tests:                   ${ENABLE_TESTING}")

  237. message(STATUS "    PulseAudio UI:           ${ENABLE_PULSEAUDIO}")

  238. if(ENABLE_PULSEAUDIO)

  239.     message(STATUS "        PulseAudio version:  ${PULSEAUDIO_VERSION}")

  240. endif()

  241. message(STATUS "    JACK UI:                 ${ENABLE_JACK}")

  242. if(ENABLE_JACK)

  243.     message(STATUS "        JACK version:        ${JACK_VERSION}")

  244. endif()

  245. if(ENABLE_PULSEAUDIO OR ENABLE_JACK)

  246.     message(STATUS "    Qt version:              ${Qt${QT_VERSION}_VERSION}")

  247. endif()

  248. message(STATUS "    libvisual plug-in:       ${ENABLE_LIBVISUAL}")

  249. message(STATUS "")

  250. 

  251. message(AUTHOR_WARNING

  252.         "The CMake build scripts for projectM are still in active development.\n"

  253.         "This means that build parameters, exported target names and other things can change "

  254.         "at any time until the new build system is officially documented and announced to be "

  255.         "fully supported.\n"

  256.         "DO NOT base any production work on it yet!\n"

  257.         )

  258. 

  259. if(ENABLE_CXX_INTERFACE)

  260.     message(AUTHOR_WARNING "This build is configured to export all C++ symbols in the shared library.\n"

  261.             "Using C++ STL types across library borders only works if all components were built "

  262.             "with the exact same toolchain and C++ language level, otherwise it will cause crashes.\n"

  263.             "Enabling this option will not export additional symbols in Windows DLL builds.\n"

  264.             "Only use this if you know what you're doing. You have been warned!"

  265.             )

  266. endif()

  267. 

  268. # Create CPack configuration

  269. set(CPACK_PACKAGE_NAME "projectM")

  270. set(CPACK_VERBATIM_VARIABLES YES)

  271. include(CPack)