DISTRHO
/
DPF-Plugins
mirror of https://github.com/DISTRHO/DPF-Plugins
1
0
Fork 0
Code Releases 8 Activity
Collection of DPF-based plugins for packaging
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
136 Commits
1 Branch
299MB
Tree: 0d54329998
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '0d54329998'
${ noResults }
DPF-Plugins/dpf/cmake/DPF-plugin.cmake

713 lines
25KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     else()

  157.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  158.     endif()

  159.   endforeach()

  160. endfunction()

  161. 

  162. # ------------------------------------------------------------------------------

  163. # DPF private functions (prefixed with `dpf__`)

  164. # ------------------------------------------------------------------------------

  165. 

  166. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  167. #       to the output directory.

  168. #

  169. 

  170. # dpf__build_jack

  171. # ------------------------------------------------------------------------------

  172. #

  173. # Add build rules for a JACK program.

  174. #

  175. function(dpf__build_jack NAME DGL_LIBRARY)

  176.   dpf__create_dummy_source_list(_no_srcs)

  177. 

  178.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  179.   dpf__add_plugin_main("${NAME}-jack" "jack")

  180.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  181.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  182.   set_target_properties("${NAME}-jack" PROPERTIES

  183.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  184.     OUTPUT_NAME "${NAME}")

  185. 

  186.   # Note: libjack will be linked at runtime

  187.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  188.     target_link_libraries("${NAME}-jack" PRIVATE "dl")

  189.   endif()

  190. 

  191.   # for RtAudio native fallback

  192.   if(APPLE)

  193.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  194.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  195.     target_link_libraries("${NAME}-jack" PRIVATE "${APPLE_COREAUDIO_FRAMEWORK}" "${APPLE_COREFOUNDATION_FRAMEWORK}")

  196.   endif()

  197. endfunction()

  198. 

  199. # dpf__build_ladspa

  200. # ------------------------------------------------------------------------------

  201. #

  202. # Add build rules for a DSSI plugin.

  203. #

  204. function(dpf__build_ladspa NAME)

  205.   dpf__create_dummy_source_list(_no_srcs)

  206. 

  207.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  208.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  209.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  210.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  211.   set_target_properties("${NAME}-ladspa" PROPERTIES

  212.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  213.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  214.     OUTPUT_NAME "${NAME}-ladspa"

  215.     PREFIX "")

  216. endfunction()

  217. 

  218. # dpf__build_dssi

  219. # ------------------------------------------------------------------------------

  220. #

  221. # Add build rules for a DSSI plugin.

  222. #

  223. function(dpf__build_dssi NAME DGL_LIBRARY)

  224.   find_package(PkgConfig)

  225.   pkg_check_modules(LIBLO "liblo")

  226.   if(NOT LIBLO_FOUND)

  227.     dpf__warn_once_only(missing_liblo

  228.       "liblo is not found, skipping the `dssi` plugin targets")

  229.     return()

  230.   endif()

  231. 

  232.   link_directories(${LIBLO_LIBRARY_DIRS})

  233. 

  234.   dpf__create_dummy_source_list(_no_srcs)

  235. 

  236.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  237.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  238.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  239.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  240.   set_target_properties("${NAME}-dssi" PROPERTIES

  241.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  242.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  243.     OUTPUT_NAME "${NAME}-dssi"

  244.     PREFIX "")

  245. 

  246.   if(DGL_LIBRARY)

  247.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  248.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  249.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  250.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  251.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  252.       OUTPUT_NAME "${NAME}_ui")

  253. 

  254.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  255.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  256.   endif()

  257. endfunction()

  258. 

  259. # dpf__build_lv2

  260. # ------------------------------------------------------------------------------

  261. #

  262. # Add build rules for a LV2 plugin.

  263. #

  264. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  265.   dpf__create_dummy_source_list(_no_srcs)

  266. 

  267.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  268.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  269.   if(DGL_LIBRARY AND MONOLITHIC)

  270.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  271.   else()

  272.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  273.   endif()

  274.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  275.   set_target_properties("${NAME}-lv2" PROPERTIES

  276.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  277.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  278.     OUTPUT_NAME "${NAME}_dsp"

  279.     PREFIX "")

  280. 

  281.   if(DGL_LIBRARY)

  282.     if(MONOLITHIC)

  283.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  284.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  285.       set_target_properties("${NAME}-lv2" PROPERTIES

  286.         OUTPUT_NAME "${NAME}")

  287.     else()

  288.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  289.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  290.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  291.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  292.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  293.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  294.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  295.         OUTPUT_NAME "${NAME}_ui"

  296.         PREFIX "")

  297.     endif()

  298.   endif()

  299. 

  300.   dpf__add_lv2_ttl_generator()

  301.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  302. 

  303.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  304.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  305.     "$<TARGET_FILE:lv2_ttl_generator>"

  306.     "$<TARGET_FILE:${NAME}-lv2>"

  307.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  308.     DEPENDS lv2_ttl_generator)

  309. endfunction()

  310. 

  311. # dpf__build_vst2

  312. # ------------------------------------------------------------------------------

  313. #

  314. # Add build rules for a VST2 plugin.

  315. #

  316. function(dpf__build_vst2 NAME DGL_LIBRARY)

  317.   dpf__create_dummy_source_list(_no_srcs)

  318. 

  319.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  320.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  321.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  322.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  323.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  324.   set_target_properties("${NAME}-vst2" PROPERTIES

  325.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  326.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  327.     OUTPUT_NAME "${NAME}-vst2"

  328.     PREFIX "")

  329.   if(APPLE)

  330.     set_target_properties("${NAME}-vst2" PROPERTIES

  331.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  332.       OUTPUT_NAME "${NAME}"

  333.       SUFFIX "")

  334.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  335.     configure_file("${DPF_ROOT_DIR}/utils/plugin.vst/Contents/Info.plist"

  336.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  337.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.vst/Contents/PkgInfo"

  338.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  339.   endif()

  340. endfunction()

  341. 

  342. # dpf__add_dgl_cairo

  343. # ------------------------------------------------------------------------------

  344. #

  345. # Add the Cairo variant of DGL, if not already available.

  346. #

  347. function(dpf__add_dgl_cairo)

  348.   if(TARGET dgl-cairo)

  349.     return()

  350.   endif()

  351. 

  352.   find_package(PkgConfig)

  353.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  354. 

  355.   link_directories(${CAIRO_LIBRARY_DIRS})

  356. 

  357.   dpf__add_static_library(dgl-cairo STATIC

  358.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  359.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  360.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  361.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  362.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  363.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  364.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  365.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  366.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  367.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  368.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  369.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  370.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  371.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  372.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  373.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  374.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  375.   if(NOT APPLE)

  376.     target_sources(dgl-cairo PRIVATE

  377.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  378.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  379.     #target_sources(dgl-opengl PRIVATE

  380.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  381.   endif()

  382.   target_include_directories(dgl-cairo PUBLIC

  383.     "${DPF_ROOT_DIR}/dgl")

  384.   target_include_directories(dgl-cairo PUBLIC

  385.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  386. 

  387.   dpf__add_dgl_system_libs()

  388.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  389. 

  390.   add_library(dgl-cairo-definitions INTERFACE)

  391.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  392. 

  393.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  394.   if(MINGW)

  395.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  396.   else()

  397.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  398.   endif()

  399.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  400. endfunction()

  401. 

  402. # dpf__add_dgl_opengl

  403. # ------------------------------------------------------------------------------

  404. #

  405. # Add the OpenGL variant of DGL, if not already available.

  406. #

  407. function(dpf__add_dgl_opengl)

  408.   if(TARGET dgl-opengl)

  409.     return()

  410.   endif()

  411. 

  412.   if(NOT OpenGL_GL_PREFERENCE)

  413.     set(OpenGL_GL_PREFERENCE "LEGACY")

  414.   endif()

  415. 

  416.   find_package(OpenGL REQUIRED)

  417. 

  418.   dpf__add_static_library(dgl-opengl STATIC

  419.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  420.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  421.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  422.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  423.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  424.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  425.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  426.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  427.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  428.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  429.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  430.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  431.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  432.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  433.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  434.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  435.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  436.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  437.   if(NOT APPLE)

  438.     target_sources(dgl-opengl PRIVATE

  439.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  440.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  441.     #target_sources(dgl-opengl PRIVATE

  442.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  443.   endif()

  444.   target_include_directories(dgl-opengl PUBLIC

  445.     "${DPF_ROOT_DIR}/dgl")

  446.   target_include_directories(dgl-opengl PUBLIC

  447.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  448. 

  449.   if(APPLE)

  450.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  451.   endif()

  452. 

  453.   dpf__add_dgl_system_libs()

  454.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  455. 

  456.   add_library(dgl-opengl-definitions INTERFACE)

  457.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  458. 

  459.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  460.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  461. endfunction()

  462. 

  463. # dpf__add_plugin_specific_ui_sources

  464. # ------------------------------------------------------------------------------

  465. #

  466. # Compile plugin-specific UI sources into the target designated by the given

  467. # name. There are some special considerations here:

  468. # - On most platforms, sources can be compiled only once, as part of DGL;

  469. # - On macOS, for any sources which define Objective-C interfaces, these must

  470. #   be recompiled for each plugin under a unique namespace. In this case, the

  471. #   name must be a plugin-specific identifier, and it will be used for computing

  472. #   the unique ID along with the project version.

  473. function(dpf__add_plugin_specific_ui_sources NAME)

  474.   if(APPLE)

  475.     target_sources("${NAME}" PRIVATE

  476.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  477.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  478.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  479.   endif()

  480. endfunction()

  481. 

  482. # dpf__add_dgl_system_libs

  483. # ------------------------------------------------------------------------------

  484. #

  485. # Find system libraries required by DGL and add them as an interface target.

  486. #

  487. function(dpf__add_dgl_system_libs)

  488.   if(TARGET dgl-system-libs)

  489.     return()

  490.   endif()

  491.   add_library(dgl-system-libs INTERFACE)

  492.   add_library(dgl-system-libs-definitions INTERFACE)

  493.   if(HAIKU)

  494.     target_link_libraries(dgl-system-libs INTERFACE "be")

  495.   elseif(WIN32)

  496.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  497.   elseif(APPLE)

  498.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  499.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  500.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  501.   else()

  502.     find_package(X11 REQUIRED)

  503.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  504.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  505.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  506.     if(X11_Xext_FOUND)

  507.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  508.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  509.     endif()

  510.     if(X11_XSync_FOUND)

  511.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  512.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  513.     endif()

  514.     if(X11_Xrandr_FOUND)

  515.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  516.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  517.     endif()

  518.     #if(X11_Xcursor_FOUND)

  519.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  520.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  521.     #endif()

  522.    endif()

  523. 

  524.    if(MSVC)

  525.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  526.      foreach(_gl_header "glext.h")

  527.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  528.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  529.        endif()

  530.      endforeach()

  531.      foreach(_khr_header "khrplatform.h")

  532.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  533.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  534.        endif()

  535.      endforeach()

  536.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  537.    endif()

  538. 

  539.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  540. endfunction()

  541. 

  542. # dpf__add_executable

  543. # ------------------------------------------------------------------------------

  544. #

  545. # Adds an executable target, and set some default properties on the target.

  546. #

  547. function(dpf__add_executable NAME)

  548.   add_executable("${NAME}" ${ARGN})

  549.   dpf__set_target_defaults("${NAME}")

  550.   if(MINGW)

  551.     target_link_libraries("${NAME}" PRIVATE "-static")

  552.   endif()

  553. endfunction()

  554. 

  555. # dpf__add_module

  556. # ------------------------------------------------------------------------------

  557. #

  558. # Adds a module target, and set some default properties on the target.

  559. #

  560. function(dpf__add_module NAME)

  561.   add_library("${NAME}" MODULE ${ARGN})

  562.   dpf__set_target_defaults("${NAME}")

  563.   if(MINGW)

  564.     target_link_libraries("${NAME}" PRIVATE "-static")

  565.   endif()

  566. endfunction()

  567. 

  568. # dpf__add_static_library

  569. # ------------------------------------------------------------------------------

  570. #

  571. # Adds a static library target, and set some default properties on the target.

  572. #

  573. function(dpf__add_static_library NAME)

  574.   add_library("${NAME}" STATIC ${ARGN})

  575.   dpf__set_target_defaults("${NAME}")

  576. endfunction()

  577. 

  578. # dpf__set_module_export_list

  579. # ------------------------------------------------------------------------------

  580. #

  581. # Applies a list of exported symbols to the module target.

  582. #

  583. function(dpf__set_module_export_list NAME EXPORTS)

  584.   if(WIN32)

  585.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  586.   elseif(APPLE)

  587.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  588.       "-Xlinker" "-exported_symbols_list"

  589.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  590.   else()

  591.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  592.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  593.   endif()

  594. endfunction()

  595. 

  596. # dpf__set_target_defaults

  597. # ------------------------------------------------------------------------------

  598. #

  599. # Set default properties which must apply to all DPF-defined targets.

  600. #

  601. function(dpf__set_target_defaults NAME)

  602.   set_target_properties("${NAME}" PROPERTIES

  603.     POSITION_INDEPENDENT_CODE TRUE

  604.     C_VISIBILITY_PRESET "hidden"

  605.     CXX_VISIBILITY_PRESET "hidden"

  606.     VISIBILITY_INLINES_HIDDEN TRUE)

  607.   if(WIN32)

  608.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  609.   endif()

  610.   if (MINGW)

  611.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  612.   endif()

  613.   if (MSVC)

  614.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  615.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  616.   endif()

  617. endfunction()

  618. 

  619. # dpf__add_plugin_main

  620. # ------------------------------------------------------------------------------

  621. #

  622. # Adds plugin code to the given target.

  623. #

  624. function(dpf__add_plugin_main NAME TARGET)

  625.   target_sources("${NAME}" PRIVATE

  626.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  627.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  628. endfunction()

  629. 

  630. # dpf__add_ui_main

  631. # ------------------------------------------------------------------------------

  632. #

  633. # Adds UI code to the given target (only if the target has UI).

  634. #

  635. function(dpf__add_ui_main NAME TARGET HAS_UI)

  636.   if(HAS_UI)

  637.     target_sources("${NAME}" PRIVATE

  638.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  639.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  640.   endif()

  641. endfunction()

  642. 

  643. # dpf__add_plugin_target_definition

  644. # ------------------------------------------------------------------------------

  645. #

  646. # Adds the plugins target macro definition.

  647. # This selects which entry file is compiled according to the target type.

  648. #

  649. function(dpf__add_plugin_target_definition NAME TARGET)

  650.   string(TOUPPER "${TARGET}" _upperTarget)

  651.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  652. endfunction()

  653. 

  654. # dpf__add_lv2_ttl_generator

  655. # ------------------------------------------------------------------------------

  656. #

  657. # Build the LV2 TTL generator.

  658. #

  659. function(dpf__add_lv2_ttl_generator)

  660.   if(TARGET lv2_ttl_generator)

  661.     return()

  662.   endif()

  663.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  664.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  665.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  666.   endif()

  667. endfunction()

  668. 

  669. # dpf__ensure_sources_non_empty

  670. # ------------------------------------------------------------------------------

  671. #

  672. # Ensure the given source list contains at least one file.

  673. # The function appends an empty source file to the list if necessary.

  674. # This is useful when CMake does not permit to add targets without sources.

  675. #

  676. function(dpf__ensure_sources_non_empty VAR)

  677.   if(NOT "" STREQUAL "${${VAR}}")

  678.     return()

  679.   endif()

  680.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  681.   if(NOT EXISTS "${_file}")

  682.     file(WRITE "${_file}" "")

  683.   endif()

  684.   set("${VAR}" "${_file}" PARENT_SCOPE)

  685. endfunction()

  686. 

  687. # dpf__create_dummy_source_list

  688. # ------------------------------------------------------------------------------

  689. #

  690. # Create a dummy source list which is equivalent to compiling nothing.

  691. # This is only for compatibility with older CMake versions, which refuse to add

  692. # targets without any sources.

  693. #

  694. macro(dpf__create_dummy_source_list VAR)

  695.   set("${VAR}")

  696.   if(CMAKE_VERSION VERSION_LESS "3.11")

  697.     dpf__ensure_sources_non_empty("${VAR}")

  698.   endif()

  699. endmacro()

  700. 

  701. # dpf__warn_once

  702. # ------------------------------------------------------------------------------

  703. #

  704. # Prints a warning message once only.

  705. #

  706. function(dpf__warn_once_only TOKEN MESSAGE)

  707.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  708.   if(NOT _warned)

  709.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  710.     message(WARNING "${MESSAGE}")

  711.   endif()

  712. endfunction()