DISTRHO
/
DISTRHO-Ports
mirror of https://github.com/DISTRHO/DISTRHO-Ports
1
0
Fork 0
Code Releases 5 Activity
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2 Commits
6 Branches
135MB
Tree: 49edfaaa68
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '49edfaaa68'
${ noResults }
DISTRHO-Ports/bin/cabbage/Effects/FrequencyShifter.csd

263 lines
9.7KB
Raw Blame History 

  1. ; FrequencyShifter.csd

  2. ; Iain McCurdy, 2013.

  3. ; 

  4. ; Frequency shifting using the hilbert filter

  5. ; 

  6. ; CONTROLS

  7. ; --------

  8. ; Input			--	Choose audio input: Live, sine tone or pink noise

  9. ; Polarity		--	3 options: 'Positive' = multiply 'Freq.' by 1, 'Negative' = multiply 'Freq.' by -1, 'Dual' = sum of 'Positive' and 'Negative' outputs

  10. ; Mix			--	Dry/Wet mix control

  11. ; Freq.			--	Principle frequency of the shifting frequency (before modulation by other controls)

  12. ; Mult.			--	multipler of shifting frequency. Can be useful for finer control of shifting frequency around zero.

  13. ; Feedback		--	Amount of frequency shifter that is fed back into its input

  14. ; Level			--	Output level

  15. ; Dual Mono / Stereo	--	'Dual Mono' = both channels treated in the same way. 'Stereo' = right channel 180 degrees out of phase with respect to the left

  16. ;				 Stereo mode most apparent if shifting frequency is close to zero

  17. ; zero freq		--	set 'Freq.' to zero

  18. ;  [LFO~]

  19. ; Modulate Frequency	--	Switch to activate LFO modulation  of shifting frequency

  20. ; Shape			--	Shape of the LFO: sine / triangle / square / random sample and hold / random splines

  21. ; Rate			--	Rate of LFO (in hertz)

  22. ; Min			--	Minimum frequency of the LFO modulation

  23. ; Max			--	Maximum frequency of the LFO modulation

  24. ; Pan Mod			--	Amount of panning modulation (strictly speaking, stereo balance modulation). Rate of modulation governed also by 'Rate'

  25. ; Sync LFO		--	Restart LFO. Can be useful if 'random spline' modulation becomes 'stuck' at a low frequency

  26. 

  27. 

  28. <Cabbage>

  29. form caption("Time Domain Frequency Shifter") size(500,180), pluginID("fshi")

  30. image                               bounds( 0,  0, 500,180), colour("darkslategrey"), outline("silver"), line(6), shape("rounded")

  31. label    bounds(22,  7, 60, 11), text("INPUT"), fontcolour("white")

  32. combobox bounds(10, 18, 65, 20), channel("input"), value(1), text("Live","Tone","Noise")

  33. label    bounds(14, 42, 60, 11), text("POLARITY"), fontcolour("white")

  34. combobox bounds(10, 53, 65, 20), channel("polarity"), value(1), text("Positive","Negative","Dual")

  35. rslider bounds( 75, 10, 70, 70), text("Mix"),      channel("mix"),   range(0, 1.00, 0.5),        colour("darkslategrey"), fontcolour("white), tracker("yellow")

  36. rslider bounds(145, 10, 70, 70), text("Freq."),    channel("freq"),  range(-4000, 4000, -50), colour("darkslategrey"), fontcolour("white), tracker("yellow")

  37. rslider bounds(215, 10, 70, 70), text("Mult."),     channel("mult"),  range(-1, 1.00, 0.1),       colour("darkslategrey"), fontcolour("white), tracker("yellow")

  38. rslider bounds(285, 10, 70, 70), text("Feedback"), channel("fback"), range(0, 0.75, 0.6),     colour("darkslategrey"), fontcolour("white), tracker("yellow")

  39. rslider bounds(355, 10, 70, 70), text("Level"),    channel("level"), range(0, 1.00, 1),          colour("darkslategrey"), fontcolour("white), tracker("yellow")

  40. 

  41. checkbox bounds(425, 20, 12, 12), channel("r1") fontcolour("white") colour(yellow) value(1)

  42. checkbox bounds(425, 32, 12, 12), channel("r2") fontcolour("white") colour(yellow) 

  43. label    bounds(438, 21, 60,  9), text("DUAL MONO"), fontcolour("white")

  44. label    bounds(438, 33, 60,  9), text("STEREO"), fontcolour("white")

  45. 

  46. button   bounds(425, 50, 65, 20), colour("Green"), text("Zero Freq", "Zero Freq"), channel("Zerofreq"), value(0)

  47. 

  48. line     bounds( 10, 90, 480, 2), colour("Grey")

  49. checkbox bounds( 10,100,150, 20), channel("ModOnOff") text("LFO Modulate Freq."), fontcolour("white") colour(lime) value(0)

  50. label    bounds( 30,127, 75, 11), text("SHAPE"), fontcolour("white")

  51. combobox bounds( 10,138, 85, 20), channel("LFOShape"), value(7), text("Sine","Triangle","Square","Saw Up","Saw Down","Rand.S&H","Rand.Spline")

  52. rslider bounds( 145,100, 70, 70), text("Rate"),     channel("LFORate"),  range(0, 30,  1.5, 0.5, 0.001), colour("lightslategrey"), fontcolour("white), tracker("yellow")

  53. rslider bounds( 215,100, 70, 70), text("Min"),      channel("LFOMin"),   range(-2000, 2000, -600),   colour("lightslategrey"), fontcolour("white), tracker("yellow")

  54. rslider bounds( 285,100, 70, 70), text("Max"),      channel("LFOMax"),   range(-2000, 2000,  600),   colour("lightslategrey"), fontcolour("white), tracker("yellow")

  55. rslider bounds( 355,100, 70, 70), text("Pan Mod."),   channel("PanSpread"),range(0, 1.00, 1),          colour("lightslategrey"), fontcolour("white), tracker("yellow")

  56. button   bounds(425,100, 65, 20), colour("Green"), text("Sync LFO", "Sync LFO"), channel("SyncLFO"), value(0)

  57. 

  58. </Cabbage>

  59. <CsoundSynthesizer>

  60. 

  61. <CsOptions>

  62. -d -n

  63. </CsOptions>

  64. 

  65. <CsInstruments>

  66. sr 	= 	44100

  67. ksmps 	= 	32

  68. nchnls 	= 	2

  69. 0dbfs 	= 	1

  70. 

  71. ;Iain McCurdy, 2012

  72. ;http://iainmccurdy.org/csound.html

  73. ;Frequency shifter effect based around the hilbert filter.

  74. 

  75. gisine		ftgen	0,0,4096,10,1			;A SINE WAVE SHAPE

  76. gicos		ftgen	0,0,4096,11,1			;A COSINE WAVE SHAPE

  77. gishapes	ftgen	0,0,8,-2,0,1,2,4,5

  78. 

  79. opcode	FreqShifter,a,akkkki

  80. 	adry,kmix,kfreq,kmult,kfback,ifn	xin			;READ IN INPUT ARGUMENTS

  81. 	iWet	ftgenonce	0,0,1024,-7,0,512,1,512,1	;RESCALING FUNCTION FOR WET LEVEL CONTROL

  82. 	iDry	ftgenonce	0,0,1024,-7,1,512,1,512,0	;RESCALING FUNCTION FOR DRY LEVEL CONTROL

  83. 	kWet	table	kmix, iWet, 1				;RESCALE WET LEVEL CONTROL ACCORDING TO FUNCTION TABLE giWet

  84. 	kDry	table	kmix, iDry, 1				;RESCALE DRY LEVEL CONTROL ACCORDING TO FUNCTION TABLE giWet

  85. 	aFS	init	0					;INITILISE FEEDBACK SIGNAL (FOR FIRST K-PASS)

  86. 	ain	=	adry + (aFS * kfback)			;ADD FEEDBACK SIGNAL TO INPUT (AMOUNT OF FEEDBACK CONTROLLED BY 'Feedback Gain' SLIDER)

  87. 	areal, aimag hilbert ain				;HILBERT OPCODE OUTPUTS TWO PHASE SHIFTED SIGNALS, EACH 90 OUT OF PHASE WITH EACH OTHER

  88. 	kfshift	=	kfreq*kmult

  89. 	;QUADRATURE OSCILLATORS. I.E. 90 OUT OF PHASE WITH RESPECT TO EACH OTHER

  90. 	;OUTUTS	OPCODE	AMPLITUDE | FREQ. | FUNCTION_TABLE | INITIAL_PHASE (OPTIONAL;DEFAULTS TO ZERO)

  91. 	asin 	oscili       1,    kfshift,     ifn,           0

  92. 	acos 	oscili       1,    kfshift,     ifn,           0.25	

  93. 	;RING MODULATE EACH SIGNAL USING THE QUADRATURE OSCILLATORS AS MODULATORS

  94. 	amod1	=		areal * acos

  95. 	amod2	=		aimag * asin	

  96. 	;UPSHIFTING OUTPUT

  97. 	aFS	= (amod1 - amod2)

  98. 	aout	sum	aFS*kWet, adry*kDry		;CREATE WET/DRY MIX

  99. 		xout	aout				;SEND AUDIO BACK TO CALLER INSTRUMENT

  100. endop

  101. 

  102. 

  103. opcode	CabbageRadio2,k,SS			; change opcode name and number is string variable inputs

  104. S1,S2	xin					; add string inputs for the required number of inputs 

  105. kon		=	0

  106. koff		=	0

  107. ksum		=	0

  108. ktrigsum	=	0

  109. #define READ_CHANGES(NAME)	#

  110. k$NAME	chnget	$NAME

  111. ksum	=	ksum + k$NAME

  112. kon$NAME	trigger	k$NAME,0.5,0

  113. ktrigsum	=	ktrigsum + kon$NAME#

  114. 

  115. #define WRITE_CHANGES(NAME'COUNT)	#

  116. if kon$NAME!=1 then

  117.  chnset	koff,$NAME

  118. else

  119.  kval	=	$COUNT

  120. endif#

  121. 

  122.  $READ_CHANGES(S1) 

  123.  $READ_CHANGES(S2)				; add macro expansions for the required number of radio buttons

  124. 

  125. if ktrigsum>0 then

  126. 

  127.  $WRITE_CHANGES(S1'1)

  128.  $WRITE_CHANGES(S2'2)				; add macro expansions for the required number of radio buttons

  129. 

  130. endif

  131. 

  132. kval	=	(ksum=0?0:kval)

  133. 	xout	kval

  134. endop

  135. 

  136. 

  137. instr	1

  138. kporttime	linseg	0,0.001,0.05

  139. koff	=	0

  140. kmix		chnget	"mix"			; read input widgets

  141. kfreq		chnget	"freq"

  142. kfreq		portk	kfreq,kporttime

  143. kmult		chnget	"mult"

  144. kmult		portk	kmult,kporttime

  145. kfback		chnget	"fback"

  146. klevel		chnget	"level"

  147. kpolarity	chnget	"polarity"

  148. kStereoMode	CabbageRadio2	"r1","r2"	; call UDO

  149. kZeroFreq	chnget	"Zerofreq"

  150. ktrig changed	kZeroFreq

  151. if ktrig=1 then

  152.  chnset	koff,"freq"

  153. endif

  154. kModOnOff	chnget	"ModOnOff"	

  155. kLFOShape        chnget	"LFOShape"        	

  156. kLFORate         chnget	"LFORate"         	

  157. kLFOMin          chnget	"LFOMin"          	

  158. kLFOMax          chnget	"LFOMax"          	

  159. kPanSpread	chnget	"PanSpread"		

  160. kSyncLFO	chnget	"SyncLFO"

  161. 

  162. 

  163. /* INPUT */

  164. kinput		chnget	"input"

  165. if kinput=1 then

  166.  a1,a2	ins

  167. elseif kinput=2 then

  168.  a1	oscils	0.2, 300, 0

  169.  a2	=	a1

  170. else

  171.  a1	pinkish	0.2

  172.  a2	pinkish	0.2

  173. endif

  174. 

  175. 

  176. 

  177. /* LFO */

  178. if kModOnOff=1 then

  179.  ktrig	changed	kLFOShape,kSyncLFO

  180.  if ktrig=1 then

  181.   reinit RESTART_LFO

  182.  endif

  183.  RESTART_LFO:

  184.  if i(kLFOShape)=6 then

  185.   kLFOFreq	randomh	kLFOMin,kLFOMax,kLFORate

  186.  elseif i(kLFOShape)=7 then				; random spline

  187.   ;kLFOFreq	randomi	kLFOMin,kLFOMax,kLFORate,1

  188.   ;kLFOFreq	portk	kLFOFreq,1/kLFORate

  189.   kLFOFreq	rspline	kLFOMin,kLFOMax,kLFORate,kLFORate*2

  190.  else

  191.   ishape	table	i(kLFOShape)-1,gishapes

  192.   kLFOFreq	lfo	1,kLFORate,ishape

  193.   kLFOFreq	scale	(kLFOFreq*0.5)+0.5,kLFOMin,kLFOMax

  194.  endif

  195.  rireturn

  196. endif

  197. 

  198.  

  199.  

  200. kfreq	=	kfreq+kLFOFreq

  201. 

  202. /* FREQUENCY SHIFTERS */

  203. ktrig	changed	kStereoMode

  204. if ktrig=1 then

  205.  reinit RESTART_FREQUENCY_SHIFTERS

  206. endif

  207. RESTART_FREQUENCY_SHIFTERS:

  208. if kpolarity=1 then						; polarity is positive...

  209.  a1	FreqShifter	a1,kmix,kfreq,kmult,kfback,gisine	

  210.  if i(kStereoMode)=2 then

  211.   a2	FreqShifter	a2,kmix,kfreq,kmult,kfback,gicos	; cosine version

  212.  else

  213.   a2	FreqShifter	a2,kmix,kfreq,kmult,kfback,gisine	

  214.  endif 

  215. elseif kpolarity=2 then						; polarity is negative...

  216.  a1	FreqShifter	a1,kmix,-kfreq,kmult,kfback,gisine	

  217.  if i(kStereoMode)=2 then

  218.   a2	FreqShifter	a2,kmix,-kfreq,kmult,kfback,gicos	; cosine version

  219.  else

  220.   a2	FreqShifter	a2,kmix,-kfreq,kmult,kfback,gisine	

  221.  endif

  222. else								; polarity is dual...

  223.  aa	FreqShifter	a1,kmix,kfreq,kmult,kfback,gisine	; positive

  224.  if i(kStereoMode)=2 then

  225.   ab	FreqShifter	a2,kmix,kfreq,kmult,kfback,gicos	; cosine version

  226.  else

  227.   ab	FreqShifter	a2,kmix,kfreq,kmult,kfback,gisine	

  228.  endif 

  229.  ac	FreqShifter	a1,kmix,-kfreq,kmult,kfback,gisine	; negative

  230.  if i(kStereoMode)=2 then

  231.   ad	FreqShifter	a2,kmix,-kfreq,kmult,kfback,gicos	; cosine version

  232.  else

  233.   ad	FreqShifter	a2,kmix,-kfreq,kmult,kfback,gisine	

  234.  endif

  235. rireturn

  236. 

  237.  a1	=		(aa+ac)*0.5				; sum positive and negative and attenuate

  238.  a2	=		(ab+ad)*0.5

  239. endif

  240. 

  241. 

  242. /* PANNING */

  243. if kModOnOff=1 then

  244.  kpan	randomi	0.5-(kPanSpread*0.5),0.5+(kPanSpread*0.5),kLFORate,1

  245.  kpan	portk	kpan,1/kLFORate

  246.  a1  =     a1 * sin(kpan*$M_PI_2)

  247.  a2  =     a2 * cos(kpan*$M_PI_2)

  248.  ;a1	=	a1*kpan

  249.  ;a2	=	a2*(1-kpan)

  250. endif

  251. 

  252. 

  253. 

  254. a1	=	a1 * klevel					; scale using level control

  255. a2	=	a2 * klevel

  256. 	outs	a1,a2

  257. endin

  258. 

  259. </CsInstruments>

  260. <CsScore>

  261. i 1 0 [60*60*24*7]

  262. </CsScore>

  263. </CsoundSynthesizer>