DISTRHO
/
DISTRHO-Ports-Extra
mirror of https://github.com/DISTRHO/DISTRHO-Ports-Extra
1
0
Fork 0
Code Releases 0 Activity
Extra "ports" of juce-based plugins using the distrho build system
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2 Commits
1 Branch
28MB
Tree: d45623e876
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'd45623e876'
${ noResults }
DISTRHO-Ports-Extra/bin/cabbage-extra/Synths/StringFeedback.csd

189 lines
9.8KB
Raw Blame History 

  1. StringFeedback.csd - an emulation of a feeding back vibrating string

  2. ------------------

  3. 

  4. Amplifier

  5. ---------

  6. Feedback	-	signal that is fed back into the vibrating string model. If a particular note doesn't sound, boost this!

  7. Drive		-	overdrive level

  8. Sustain		-	sustain of the string vibrations. Inverse of damping.

  9. Bright		-	brightness of the signal (lowpass filtering). Uses keyboard tracking, value stated is a ratio of the fundemental of the note played.

  10. Cut		-	remove lower partials of the signal (highpass filtering). Uses keyboard tracking, value stated is a ratio of the fundemental of the note played.

  11. 

  12. Movement

  13. ---------

  14. Movement is a rough imitation of the effect of moving the vibrating string with respect to the location of the speaker. This is simply a modulating very short delay.

  15. Speed		-	speed of modulation (created using a random spline)

  16. 

  17. Pick-up

  18. -------

  19. Settings pertaining to the location of the pick-up along the length of the vibrating string

  20. Position	-	manual positioning of the pick-up. 0 or 1 = either end. 0.5 = half-way along the string's length.

  21. Auto		-	if this is active, manual positioning is ignored and the pick-up moves around randomly

  22. Speed		-	speed of random movement of the pick-up

  23. 

  24. Reverb

  25. ------

  26. Distance	-	Distance of the listener from the speaker (basically a dry/wet signal crossfader)

  27. Room		-	Room size

  28. 

  29. Output

  30. ------

  31. Release		-	ampllitude envelope release for the feedback signal

  32. Level		-	Level control (pre reverb so reverberation will always die away natuarally)

  33. 

  34. <Cabbage>

  35. form caption("String Feedback"), size(775, 205), pluginID("fbck"), colour("0,0,0")

  36. 

  37. groupbox bounds(  0,  0, 290, 90), text("Amplifier"), fontcolour(195,126, 0){

  38. rslider bounds(  5, 25, 60, 60), text("Feedback"),  colour(195,126,  0), FontColour(195,126,  0), channel("fback"),   range(0, 8, 0.8,0.5)

  39. rslider bounds( 60, 25, 60, 60), text("Drive"),   colour(195,126,  0), FontColour(195,126,  0), channel("drive"),   range(0, 1, 0.25)

  40. rslider bounds(115, 25, 60, 60), text("Sustain"), colour(195,126,  0), FontColour(195,126,  0), channel("sustain"),   range(0.0001, 1, 1, 0.5, 0.0001)

  41. rslider bounds(170, 25, 60, 60), text("Bright"),  colour(195,126,  0), FontColour(195,126,  0), channel("LPF"),   range(1, 32, 16)

  42. rslider bounds(225, 25, 60, 60), text("Cut"),     colour(195,126,  0), FontColour(195,126,  0), channel("HPF"),   range(0, 32, 1)

  43. }

  44. 

  45. groupbox bounds(290,  0,  70, 90), text("Movement"), fontcolour(195,126, 0){

  46. rslider bounds(295, 25, 60, 60), text("Speed"),   colour(195,126,  0), FontColour(195,126,  0), channel("speed"),   range(0.001,1, 0.1,0.5,0.0001)

  47. }

  48. 

  49. groupbox bounds(360,  0,170, 90), text("Pick-up"), fontcolour(195,126, 0){

  50. rslider bounds(365, 25, 60, 60), text("Position"),colour(195,126,  0), FontColour(195,126,  0), channel("PickPos"),   range(0, 1, 0.1)

  51. checkbox bounds(425, 25, 70, 15), text("Auto") channel("auto"), FontColour(195,126,  0), colour("orange")

  52. rslider bounds(465, 25, 60, 60), text("Speed"),colour(195,126,  0), FontColour(195,126,  0), channel("PickPosSpeed"),   range(0.001, 8, 1, 0.5,0.001)

  53. }

  54. 

  55. groupbox bounds(530,  0,120, 90), text("Reverb"), fontcolour(195,126, 0){

  56. rslider bounds(535, 25, 60, 60), text("Distance"),colour(195,126,  0), FontColour(195,126,  0), channel("distance"),   range(0, 1, 0.1)

  57. rslider bounds(590, 25, 60, 60), text("Room"),    colour(195,126,  0), FontColour(195,126,  0), channel("room"),   range(0.5,0.99, 0.85)

  58. }

  59. 

  60. groupbox bounds(650,  0,125, 90), text("Output"), fontcolour(195,126, 0){

  61. rslider bounds(655, 25, 60, 60), text("Release"), colour(195,126,  0), FontColour(195,126,  0), channel("rel"),   range(0.01, 8, 0.01, 0.5)

  62. rslider bounds(710, 25, 60, 60), text("Level"),   colour(195,126,  0), FontColour(195,126,  0), channel("level"),   range(0, 1, 0.5)

  63. }

  64. 

  65. keyboard bounds(0,  95,775,80)

  66. image bounds(5, 180, 420, 20), colour(75, 85, 90, 50), plant("credit"){

  67. label bounds(0.03, 0.1, .6, .7), text("Author: Iain McCurdy |2013|"), colour("white"), FontColour(195,126,  0)

  68. }

  69. 

  70. </Cabbage>

  71. 

  72. <CsoundSynthesizer>

  73. 

  74. <CsOptions>

  75. -dm0 -n -+rtmidi=null -M0

  76. </CsOptions>

  77. 

  78. 

  79. <CsInstruments>

  80. 

  81. sr 		= 	44100

  82. ksmps 		= 	4

  83. nchnls 		= 	2

  84. 0dbfs		=	1

  85. massign		0,1		; assign all midi to channel 1

  86. 		seed	0	; random number generators seeded from system clock

  87. 

  88. gasendL,gasendR,garvbL,garvbR	init	0	; initialise global variables to zero

  89. giscal	ftgen	0,0,1024,-16,1,1024,4,8		; amplitude scaling used in 'overdrive' mechanism

  90. gifbscl	ftgen	0,0,128,-27, 0,1, 36,1, 86,3, 127,3	; Feedback scaling function table. Higher notes need higher levels of feedback.

  91. 

  92. instr	1

  93. kporttime	linseg	0,0.001,0.05	; used to smooth GUI control movement

  94. iplk	=	0.1			; pluck position (largely irrelevant)

  95. iamp	=	1			; amplitude

  96. icps	cpsmidi				; midi note played (in cycles-per-second)

  97. inum	notnum				; midi note number

  98. ifbscl	table	inum, gifbscl		; Feedback scaling. Higher notes need higher levels of feedback. This scaling function is defined earlier in a function table.

  99. ksustain	chnget	"sustain"	; string sustain (inverse of damping). Higher values = more sustain

  100. krefl	=	1-ksustain		; string damping (derived from sustain value). Higher values = more damping. Range 0 - 1

  101. adel	init	0			; feedback signal from the modulating delay (initial value for the first pass)

  102. 

  103. ; pick-up position

  104. kauto	chnget	"auto"			; 'auto' checkbox button.

  105. if(kauto==0) then			; if 'auto' button is off pick-up position is set manually

  106.  kpick	chnget	"PickPos"		; 'Position' GUI knob

  107.  kpick	portk	kpick,kporttime		; smooth changes made to the value to prevent glitches

  108. else					; other 'Auto' pick-up position modulation mode is used

  109.  kPickposSpeed	chnget	"PickPosSpeed"	; pick-up position modulation 'Speed' GUI knob

  110.  kpick	rspline		0.01,0.99,kPickposSpeed,kPickposSpeed*2	; pick-up position created using a random spline method

  111.  kpick	limit	kpick,0.01,0.99		; contain possible values. (N.b. rspline will generate values beyond its given limits.)

  112. endif

  113. 

  114. irel	chnget	"rel"			; feedback signal release time

  115. aInRel	linsegr	1,irel,0		; feedback signal release envelope

  116. adust	dust		0.1,1		; generate a sparse crackle signal. This is used to help keep the string vibrating.

  117. 

  118. kfback	chnget	"fback"			; 'Feedback' value from GUI knob

  119. asig 	repluck 	iplk, iamp, icps, kpick, krefl,( (adel*kfback*ifbscl) + ( (garvbL+garvbR) * 0.1) + adust) * aInRel	; vibrating string model

  120. 

  121. ; overdrive

  122. kDrive	chnget	"drive"			; overdrive value from GUI knob

  123. ktrig	changed	kDrive			; if 'Drive' knob is moved generate a trigger. Reinitialisation will be needed to refresh the 'clip' opcode.

  124. if(ktrig==1) then			; if 'Drive' knob has been moved...

  125.  reinit	UPDATE				; reinitialise from 'UPDATE' label

  126. endif					

  127. UPDATE:					; a label. Reinitialise from here.

  128. iClipLev	=	1-(i(kDrive)*0.9)	; clip level remapped from 0 to 1 remapped to 1 to 0.1.

  129. asig	clip	asig,0,iClipLev		; clip the audio signal

  130. igain	table	i(kDrive),giscal,1	; get amplitude compensation value according to the current 'Drive' setting

  131. asig	=	asig*igain		; compensate for gain loss

  132. rireturn

  133. 

  134. ; filtering

  135. kLPF	chnget	"LPF"			; Lowpass filter ('Bright') GUI knob. This is a ratio of the fundemental frequency so the final cutoff frequency will depend on the note played (keyboard tracking).

  136. kLPF	portk	kLPF,kporttime		; smooth changes

  137. kLPF	limit	icps*kLPF,20,sr/2	; derive cycles-per-second filter cutoff value (and protect against out of range values which would cause the filter to 'blow up')

  138. asig	butlp	asig, kLPF		; lowpass filter the signal

  139. kHPF	chnget	"HPF"			; same as the above but with a highpass filter. (Highpass filter called 'Cut' in GUI.)

  140. kHPF	portk	kHPF,kporttime

  141. kHPF	limit	icps*kHPF,1,sr/2

  142. asig	buthp	asig, kHPF

  143. 

  144. ; amplitude enveloping

  145. aAmpEnv	expsegr	0.001,.1,1,15,0.001	; amplitude envelope

  146. asig	=	asig*aAmpEnv		; apply amplitude envelope

  147. 

  148. ; delay (this controls how different harmonics are accentuated in the feedback process)

  149. kspeed	chnget	"speed"				; delay time modulation speed

  150. iDelMin	=	0.0001				; delay minimum...

  151. iDelMax	=	0.01				; ...and maximum. These could maybe be brought out as GUI controls

  152. kdeltim	rspline	iDelMin,iDelMax,kspeed,kspeed*2	; random spline for delay time (k-rate)

  153. kdeltim	limit	kdeltim,iDelMin,iDelMax		; limit value (n.b. rspline will generate values beyond its given minimum and maximum) 

  154. adeltim	interp	kdeltim				; interpolate to create a-rate verion for delay time (a-rate will give smoother results)

  155. adel	vdelay3	asig, adeltim*1000, 1000	; create modulating delay signal

  156. 

  157. ; stereo spatialisation - this gives the dry (unreverberated) signal some stereo width 

  158. kdelL	rspline	0.001, 0.01, 0.05, 0.1		; left channel spatialising delay

  159. kdelR	rspline	0.001, 0.01, 0.05, 0.1		; right channel spatialising delay

  160. kdelL	limit	kdelL,0.001, 0.01		; limit left channel delay times (n.b. rspline will generate values beyond its given minimum and maximum)

  161. kdelR	limit	kdelR,0.001, 0.01		; limit right channel delay times (n.b. rspline will generate values beyond its given minimum and maximum)

  162. adelL	interp	kdelL				; create a-rate of left channel delay time version using interpolation

  163. adelR   interp	kdelR				; create a-rate of right channel delay time version using interpolation

  164. aL	vdelay3	adel,adelL*1000,10		; delay signal left channel

  165. aR	vdelay3	adel,adelR*1000,10		; delay signal right channel

  166. 

  167. ; create reverb send signals (stereo)

  168. klevel	chnget	"level"				; level control (pre reverb input therefore allows reverb to die away naturally)

  169. gasendL	=	gasendL+(aL*klevel)		; left channel reverb send signal accumulated with audio from this note

  170. gasendR	=	gasendR+(aR*klevel)		; right channel reverb send signal accumulated with audio from this note

  171. endin

  172. 

  173. instr	Reverb

  174. kroom	chnget	"room"						; room size

  175. garvbL, garvbR	reverbsc	gasendL, gasendR, kroom, 7000	; apply reverb

  176. iDryLev	=	0.1						; dry signal level

  177. kRvbLev	chnget	"distance"					; reverb signal level

  178.  		outs		(garvbL*kRvbLev*0.2)+(gasendL*iDryLev*(1-kRvbLev)), (garvbR*kRvbLev*0.2)+(gasendR*iDryLev*(1-kRvbLev))

  179. 	clear	gasendL,gasendR

  180. endin

  181. 

  182. 

  183. </CsInstruments>

  184. 

  185. <CsScore>

  186. i "Reverb" 0 3600

  187. </CsScore>

  188. 

  189. </CsoundSynthesizer>