DISTRHO
/
DISTRHO-Ports-Extra
mirror of https://github.com/DISTRHO/DISTRHO-Ports-Extra
1
0
Fork 0
Code Releases 0 Activity
Extra "ports" of juce-based plugins using the distrho build system
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2 Commits
1 Branch
28MB
Tree: d45623e876
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'd45623e876'
${ noResults }
DISTRHO-Ports-Extra/bin/cabbage-extra/Synths/BreakBeatCutter.csd

269 lines
15KB
Raw Blame History 

  1. ;BreakBeatCutter.csd

  2. ;Iain McCurdy, 2013.

  3. 

  4. ; Break Beat Cut Up using the bbcut opcode with additional processing

  5. 

  6. ;==BBCUT==========================================================================================================================

  7. 'Sub-division' determines the note duration used as the base unit in  cut-ups. 

  8. For example a value of 8 represents quavers (eighth notes), 16 represents semiquavers (sixteenth notes) and so on.                                                   

  9. 

  10. 'Bar Length' represents the number of beats per bar. For example, a value of 4 represents a 4/4 bar and so on. 

  11. 

  12. 'Phrase' defines the number of bars that will elapse before the cutting up pattern restarts from the beginning.          

  13. 

  14. 'Stutter' is a separate cut-up process which occasionally will take a very short fragment of the input audio and repeat

  15. it many times. 

  16. 

  17. 'Stutter Speed' defines the duration of each stutter in relation to 'Sub-division'. 

  18. If subdivision is 8 (quavers / eighth notes) and 'Stutter Speed' is 2 then each stutter will be a semiquaver / sixteenth note.

  19. 

  20. 'Stutter Chance' defines the frequency of stutter moments. 

  21. The range for this parameter is 0 to 1. Zero means stuttering will be very unlikely, 1 means it will be very likely.       

  22. 'Repeats' defines the number of repeats that will be employed in normal cut-up events.                                     

  23. When processing non-rhythmical, unmetered material it may be be more interesting to employ non-whole numbers for parameters such as 'Sub-division', 'Phrase' and 'Stutter Speed'.                                                      

  24. ;========================================================================================================================

  25. 

  26. 

  27. 

  28. 

  29. ;==FILTER================================================================================================================

  30. Additionally in this example a randomly moving band-pass filter has been implemented. 

  31. 

  32. 'Filter Mix' crossfades between the unfiltered bbcut signal and the filtered bbcut signal.   

  33. 

  34. 'Cutoff Freq.' consists of two small sliders which determine the range from which random cutoff values are derived.       

  35. 

  36. 'Interpolate<=>S&H' fades continuously between an interpolated random function and a sample and hold type random function. 

  37. 

  38. 'Filter Div.' controls the frequency subdivision with which new random cutoff frequency values are generated - a value of '1' means that new values are generated once every bar.                                    

  39. ;========================================================================================================================

  40. 

  41. 

  42. 

  43. ;==WGUIDE================================================================================================================

  44. A waveguide effect can randomly and rhythmically cut into the audio stream

  45. 'Chance' defines the probability of this happening. 0=never 1=always

  46. The range of frequencies the effect will choose from is defined by the user as note values.

  47. Frequencies are quatised to adhere to equal temperament.

  48. ;========================================================================================================================

  49. 

  50. 

  51. 

  52. ;==SQUARE MOD. (Square wave ring modulation)=============================================================================

  53. This effect can similarly randomly and rhythmically cut into the audio stream using the 'chance' control

  54. The range of frequencies the modulator waveform can move between is defined as 'oct' values.

  55. ;========================================================================================================================

  56. 

  57. 

  58. ;==F.SHIFT (Frequency Shifter)===========================================================================================

  59. Similar to the above except using a frequency shifter effect.

  60. ;========================================================================================================================

  61. 

  62. <Cabbage>

  63. form          size(440,485), caption("Break Beat Cutter"), pluginID("bbct")

  64. 

  65. groupbox bounds( 0,  0,440,145), text("CUTTER"), plant("cutter"), FontColour(silver),colour(40,40,40){

  66. rslider bounds( 10, 25, 70, 70), colour("Tan"), tracker("Tan"), fontcolour("silver"), text("Sub-div."),       channel("subdiv"),  range(1,  512,  8, 1, 1)

  67. rslider bounds( 80, 25, 70, 70), colour("Tan"), tracker("Tan"), fontcolour("silver"), text("Bar Length"),     channel("barlen"),  range(1,   16,  2, 1, 1)

  68. rslider bounds(150, 25, 70, 70), colour("Tan"), tracker("Tan"), fontcolour("silver"), text("Phrase"),         channel("phrase"),  range(1, 512, 8, 1, 1)

  69. rslider bounds(220, 25, 70, 70), colour("Tan"), tracker("Tan"), fontcolour("silver"), text("Repeats"),        channel("repeats"), range(1, 32, 2, 1, 1)

  70. rslider bounds(290, 25, 70, 70), colour("Tan"), tracker("Tan"), fontcolour("silver"), text("Stut. Speed"),  channel("stutspd"), range(1, 32, 4, 1, 1)

  71. rslider bounds(360, 25, 70, 70), colour("Tan"), tracker("Tan"), fontcolour("silver"), text("Stut. Chance"), channel("stutchnc"), range(0, 1.00, 0.5)

  72. hslider bounds(  5, 95,425, 40), colour("Tan"), tracker("Tan"), fontcolour("silver"), textBox(1)    channel("BPM"), range(10,  500, 110,1,1)

  73. label   bounds(198,127, 25, 11), text("BPM"), FontColour("silver")

  74. }

  75. 

  76. 

  77. 

  78. groupbox bounds( 0,145,440,100), text("FILTER"), plant("filter"), FontColour(silver),colour(40,40,40){

  79. rslider bounds( 10, 25, 70, 70), colour(200,100,50,255), tracker(200,100,50,255), fontcolour("silver"), text("Mix"),    channel("FltMix"), range(0, 1.00, 0.6)

  80. rslider bounds( 80, 25, 70, 70), colour(200,100,50,255), tracker(200,100,50,255), fontcolour("silver"), text("Division"),    channel("fltdiv"), range(1, 16, 1,1,1)

  81. rslider bounds(150, 25, 70, 70), colour(200,100,50,255), tracker(200,100,50,255), fontcolour("silver"), text("Bandwidth"),    channel("bw"), range(0.1, 10, 1, 0.5, 0.001)

  82. hslider bounds(220, 25,140, 35), colour(200,100,50,255), tracker(200,100,50,255), fontcolour("silver"),    channel("cfmin"), range(50, 10000, 50  ,0.5,0.1)

  83. hslider bounds(220, 50,140, 35), colour(200,100,50,255), tracker(200,100,50,255), fontcolour("silver"),    channel("cfmax"), range(50, 10000, 10000,0.5,0.1)

  84. label   bounds(254, 77, 80, 12), text("Cutoff Freq."), FontColour("white")

  85. rslider bounds(360, 25, 70, 70), colour(200,100,50,255), tracker(200,100,50,255), fontcolour("silver"), text("Int./S&H"),    channel("i_h"), range(0, 1, 0)

  86. }

  87. 

  88. groupbox bounds( 0,245,220,100), text("WAVE GUIDE"), plant("waveguide"), FontColour(silver),colour(40,40,40){

  89. rslider bounds( 10, 25, 70, 70), colour(150,150,50,255), tracker(150,150,50,255), fontcolour("silver"), text("Chance"),    channel("WguideChnc"), range(0, 1.00, 0.2)

  90. hslider bounds( 80, 25,140, 35), colour(150,150,50,255), tracker(150,150,50,255), fontcolour("silver"),    channel("wguidemin"), range(22, 100, 50,1,1)

  91. hslider bounds( 80, 50,140, 35), colour(150,150,50,255), tracker(150,150,50,255), fontcolour("silver"),    channel("wguidemax"), range(22, 100, 70,1,1)

  92. label   bounds(108, 77, 85, 12), text("Pitch Range"), FontColour("white")

  93. }

  94. 

  95. groupbox bounds(220,245,220,100), text("SQUARE MOD."), plant("sqmod"), FontColour(silver),colour(40,40,40){

  96. rslider bounds( 10, 25, 70, 70), colour(200,150,200,255), tracker(200,150,200,255), fontcolour("silver"), text("Chance"),    channel("SqModChnc"), range(0, 1.00, 0.2)

  97. hslider bounds( 80, 25,140, 35), colour(200,150,200,255), tracker(200,150,200,255), fontcolour("silver"),    channel("sqmodmin"), range(1, 14.0,  6)

  98. hslider bounds( 80, 50,140, 35), colour(200,150,200,255), tracker(200,150,200,255), fontcolour("silver"),    channel("sqmodmax"), range(1, 14.0, 12)

  99. label   bounds(108, 77, 85, 12), text("Freq.Range"), FontColour("white")

  100. }

  101. 

  102. groupbox bounds(0,345,220,100), text("FREQUENCY SHIFT"), plant("fshift"), FontColour(silver),colour(40,40,40){

  103. rslider bounds( 10, 25, 70, 70), colour(250,110,250,255), tracker(250,110,250,255), fontcolour("silver"), text("Chance"),    channel("FshiftChnc"), range(0, 1.00, 0.2)

  104. hslider bounds( 80, 25,140, 35), colour(250,110,250,255), tracker(250,110,250,255), fontcolour("silver"),    channel("fshiftmin"), range(-4000, 4000,-1000)

  105. hslider bounds( 80, 50,140, 35), colour(250,110,250,255), tracker(250,110,250,255), fontcolour("silver"),    channel("fshiftmax"), range(-4000, 4000, 1000)

  106. label   bounds(108, 77, 85, 12), text("Freq.Range"), FontColour("white")

  107. }

  108. 

  109. groupbox bounds(220,345,220,100), text("OUTPUT"), plant("output"), FontColour(silver),colour(40,40,40){

  110. rslider bounds( 10, 25, 70, 70), colour("Tan"), tracker("Tan"), fontcolour("silver"), text("Gain"),        channel("gain"), range(0, 1, 0.75)

  111. rslider bounds( 80, 25, 70, 70), colour("Tan"), tracker("Tan"), fontcolour("silver"), text("Dry/Wet"),        channel("DryWet"), range(0, 1, 0.6)

  112. rslider bounds(150, 25, 70, 70), colour("Tan"), tracker("Tan"), fontcolour("silver"), text("Layers"),        channel("layers"), range(1, 20, 1,1,1)

  113. }

  114. label   bounds( 5,470, 200, 12), text("Author: Iain McCurdy |2013|"), FontColour("grey")

  115. </Cabbage>

  116. <CsoundSynthesizer>

  117. <CsOptions>

  118. -n -d

  119. </CsOptions>

  120. <CsInstruments>

  121. sr = 44100

  122. ksmps = 64

  123. nchnls = 2

  124. 0dbfs=1

  125. seed	0

  126. 

  127. gisine	ftgen	0,0,131072,10,1

  128. 

  129. opcode	BBCutIteration,aa,aaiiiiiiiii

  130.  aL,aR,iBPS, isubdiv,  ibarlen,  iphrase, irepeats, istutspd, istutchnc, icount, ilayers	xin

  131.  abbcutL		bbcutm	aL,   iBPS, isubdiv,  ibarlen,  iphrase, irepeats, istutspd, istutchnc

  132.  abbcutR		bbcutm	aR,   iBPS, isubdiv,  ibarlen,  iphrase, irepeats, istutspd, istutchnc

  133.  amixL	=	0

  134.  amixR	=	0

  135.  if icount<ilayers then

  136.    amixL,amixR	BBCutIteration	aL,aR, iBPS, isubdiv,  ibarlen,  iphrase, irepeats, istutspd, istutchnc, icount+1, ilayers

  137.  endif

  138.  xout	abbcutL+amixL,abbcutR+amixL

  139. endop

  140. 

  141. opcode	FreqShifter,a,aki

  142. 	ain,kfshift,ifn	xin					;READ IN INPUT ARGUMENTS

  143. 	areal, aimag hilbert ain				;HILBERT OPCODE OUTPUTS TWO PHASE SHIFTED SIGNALS, EACH 90 OUT OF PHASE WITH EACH OTHER

  144. 	asin 	oscili       1,    kfshift,     ifn,          0

  145. 	acos 	oscili       1,    kfshift,     ifn,          0.25	

  146. 	;RING MODULATE EACH SIGNAL USING THE QUADRATURE OSCILLATORS AS MODULATORS

  147. 	amod1	=		areal * acos

  148. 	amod2	=		aimag * asin	

  149. 	;UPSHIFTING OUTPUT

  150. 	aFS	= (amod1 - amod2)

  151. 		xout	aFS				;SEND AUDIO BACK TO CALLER INSTRUMENT

  152. endop

  153. 

  154. instr 1	; read widgets

  155.  gksubdiv 	chnget	"subdiv"

  156.  gkbarlen 	chnget	"barlen"

  157.  gkphrase 	chnget	"phrase"

  158.  gkrepeats	chnget	"repeats"

  159.  gkstutspd	chnget	"stutspd"

  160.  gkstutchnc	chnget	"stutchnc"

  161.  gkBPM    	chnget	"BPM"

  162.  gkfltdiv	chnget	"fltdiv"

  163.  gkDryWet    	chnget	"DryWet"

  164.  gkFltMix 	chnget	"FltMix"

  165.  gkbw     	chnget	"bw"

  166.  gkcfmin  	chnget	"cfmin"

  167.  gkcfmax  	chnget	"cfmax"

  168.  gki_h    	chnget	"i_h"

  169.  gklayers    	chnget	"layers"

  170.  gkgain		chnget	"gain"

  171.  konoff		chnget	"onoff"

  172. endin

  173. 

  174. instr	2

  175.  aL,aR ins

  176.  ;aL	diskin	"loop.wav",1,0,1

  177.  ;aR	=	aL

  178.  

  179.  kSwitch	changed		gkBPM, gkrepeats, gkphrase, gkstutspd, gkstutchnc, gkbarlen, gksubdiv, gkfltdiv, gklayers	;GENERATE A MOMENTARY '1' PULSE IN OUTPUT 'kSwitch' IF ANY OF THE SCANNED INPUT VARIABLES CHANGE. (OUTPUT 'kSwitch' IS NORMALLY ZERO)

  180.  if	kSwitch=1	then		;IF I-RATE VARIABLE CHANGE TRIGGER IS '1'...

  181.  	reinit	UPDATE			;BEGIN A REINITIALISATION PASS FROM LABEL 'UPDATE'

  182.  endif

  183.  UPDATE:

  184. 

  185.  kmetro	metro	i(gkBPM)/60

  186.  

  187.  ;OUTPUT		OPCODE	        INPUT |   BPM      | SUBDIVISION | BAR_LENGTH | PHRASE_LENGTH | NUM.OF_REPEATS | STUTTER_SPEED | STUTTER_CHANCE	

  188.  abbcutL,abbcutR	BBCutIteration	aL,aR, i(gkBPM)/60, i(gksubdiv),  i(gkbarlen),   i(gkphrase),    i(gkrepeats),   i(gkstutspd),   i(gkstutchnc),  1, i(gklayers)

  189.  

  190.  ;FILTER=================================================================================================================================================================

  191.  kfreq	=	(gkfltdiv)	;FREQUENCY WITH WHICH NEW FILTER CUTOFF VALUES ARE GENERATED			;LEFT CHANNE 

  192.  rireturn	;RETURN FROM REINITIALISATION PASS TO PERFORMANCE TIME PASSES

  193.  

  194.  kcf1h	randomh	gkcfmin, gkcfmax, kfreq		;SAMPLE AND HOLD RANDOM FREQUENCY VALUES					;LEFT CHANNEL

  195.  kcf1i	lineto		kcf1h, 1/kfreq		;INTERPOLATE VALUES								;LEFT CHANNEL

  196.  kcf1	ntrpol		kcf1i, kcf1h, gki_h   	;CROSSFADE BETWEEN INTERPOLATING AND SAMPLE AND HOLD TYPE RANDOM VALUES		;LEFT CHANNEL

  197.  abbFltL	resonz	abbcutL, kcf1, kcf1*gkbw, 2	;BAND-PASS FILTER								;LEFT CHANNEL

  198.  abbMixL	ntrpol	abbcutL, abbFltL, gkFltMix	;CROSSFADE BETWEEN UNFILTERED AND FILTER AUDIO SIGNAL				;LEFT CHANNEL

  199.  kcf2h	randomh	gkcfmin, gkcfmax, kfreq		;SAMPLE AND HOLD RANDOM FREQUENCY VALUES					;RIGHT CHANNEL

  200.  kcf2i	lineto		kcf2h, 1/kfreq		;INTERPOLATE VALUES                                                             ;RIGHT CHANNEL

  201.  kcf2	ntrpol		kcf2i, kcf2h, gki_h   	;CROSSFADE BETWEEN INTERPOLATING AND SAMPLE AND HOLD TYPE RANDOM VALUES		;RIGHT CHANNEL

  202.  abbFltR	resonz	abbcutR, kcf2, kcf2*gkbw, 2	;BAND-PASS FILTER								;RIGHT CHANNEL

  203.  abbMixR	ntrpol	abbcutR, abbFltR, gkFltMix	;CROSSFADE BETWEEN UNFILTERED AND FILTER AUDIO SIGNAL				;RIGHT CHANNEL

  204.  ;=======================================================================================================================================================================

  205. 

  206.  ;WGUIDE1================================================================================================================================================================

  207.  kchance	chnget	"WguideChnc"

  208.  kdice		trandom	kmetro,0,1

  209.  if kdice<kchance then

  210.   kwguidemin	chnget	"wguidemin"

  211.   kwguidemax	chnget	"wguidemax"

  212.   knum		randomh	kwguidemin,kwguidemax,gkBPM/60

  213.   afrq		interp	cpsmidinn(int(knum))

  214.   kfb		randomi	0.8,0.99,gkBPM/(60*4)

  215.   kcf		randomi	800,4000,gkBPM/60

  216.   abbMixL	wguide1	abbMixL*0.7,afrq,kcf,kfb

  217.   abbMixR	wguide1	abbMixR*0.7,afrq,kcf,kfb

  218.  endif  

  219.  ;=======================================================================================================================================================================

  220. 

  221.  ;SQUARE MOD==============================================================================================================================================================

  222.  kchance	chnget	"SqModChnc"

  223.  ksqmodmin	chnget	"sqmodmin"

  224.  ksqmodmax	chnget	"sqmodmax"

  225.  kDiceRoll	trandom	kmetro,0,1

  226.  if kDiceRoll<kchance then

  227.   kratei	randomi	ksqmodmin,ksqmodmax,gkBPM/60

  228.   krateh	randomh	ksqmodmin,ksqmodmax,gkBPM/60

  229.   kcross	randomi	0,1,gkBPM

  230.   kcross	=	kcross>0.5?1:0

  231.   krate		ntrpol	kratei,krateh,kcross

  232.   amod		lfo	1,cpsoct(krate),2

  233.   abbMixL	=	abbMixL*amod

  234.   abbMixR	=	abbMixR*amod

  235.  endif

  236.  ;=======================================================================================================================================================================

  237. 

  238.  ;FSHIFT=================================================================================================================================================================

  239.  kchance	chnget	"FshiftChnc"

  240.  kdice		trandom	kmetro,0,1

  241.  if kdice<kchance then

  242.   kfshiftmin	chnget	"fshiftmin"

  243.   kfshiftmax	chnget	"fshiftmax"

  244. ;  kfsfrq	randomh	kfshiftmin,kfshiftmax,gkBPM/60

  245.   kfsfrqi	randomi	kfshiftmin,kfshiftmax,gkBPM/60

  246.   kfsfrqh	randomh	kfshiftmin,kfshiftmax,gkBPM/60

  247.   kcross	randomi	0,1,gkBPM/2

  248.   kcross	=	kcross>0.5?1:0

  249.   kfsfrq	ntrpol	kfsfrqi,kfsfrqh,kcross

  250.   abbMixL	FreqShifter	abbMixL,kfsfrq,gisine

  251.   abbMixR	FreqShifter	abbMixR,kfsfrq,gisine

  252.  endif   

  253.  ;=======================================================================================================================================================================

  254.  

  255.  amixL	sum	aL*(1-gkDryWet), abbMixL*gkDryWet	;SUM AND MIX DRY SIGNAL AND BBCUT SIGNAL (LEFT CHANNEL)

  256.  amixR	sum	aR*(1-gkDryWet), abbMixR*gkDryWet	;SUM AND MIX DRY SIGNAL AND BBCUT SIGNAL (RIGHT CHANNEL)

  257. 

  258. 

  259. 

  260. 

  261.  outs	amixL*gkgain, amixR*gkgain			;SEND AUDIO TO OUTPUTS

  262. endin

  263. 

  264. </CsInstruments>  

  265. <CsScore>

  266. i1 0 36000

  267. i2 0 36000

  268. </CsScore>

  269. </CsoundSynthesizer>