DISTRHO
/
DISTRHO-Ports-Extra
mirror of https://github.com/DISTRHO/DISTRHO-Ports-Extra
1
0
Fork 0
Code Releases 0 Activity
Extra "ports" of juce-based plugins using the distrho build system
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2 Commits
1 Branch
28MB
Tree: d45623e876
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'd45623e876'
${ noResults }
DISTRHO-Ports-Extra/bin/cabbage-extra/Effects/ModulatingDelays.csd

233 lines
9.0KB
Raw Blame History 

  1. ; Modulating Delays -  randomly modulating delays

  2. 

  3. ; GATE (for gating the incoming signal)

  4. ; On Thrsh / Off Thrsh	-	thresholds at which the gate will open and close

  5. ; Rise Time		-	time it takes for the gate to ramp open

  6. ; Rel Time		-	time it takes for the gate to ramp closed

  7. 

  8. ; SETUP

  9. ; Pan Width		-	extent of the random panning effect (0 = all layers centred)

  10. ; Spread		-	spread of the delay times of the different layers (if only 1 layer is active this control isn't really useful)

  11. ;				 if 'spread' is zero, all layers' delay time modulated between  'Min Time' and 'Max Time'

  12. ; Layers		-	Number of layers of modualting delays

  13. 

  14. ; REVERB - there is a reverb effect within the each delay buffer

  15. ; Amount		-	amount of reverb signal added to the output of the delay buffer - within the delay buffer -, this will therefore be mixed into the feedback signal and fed back into to reverb also

  16. ; Time			-	reverb time

  17. ; Damping		-	damping of high frequencies within the delay effect

  18. ; ** CAUTION MUST BE TAKEN WHEN USING HIGH LEVELS OF DELAY FEEDBACK WITH A HIGH REVERB AMOUNT AS OVERLOADING CAN QUICKLY OCCUR **

  19. 

  20. ; OUTPUT

  21. ; Dry			-	level control for the dry (post gate) signal

  22. ; Wet			-	level control for the wet (delayed) signal

  23. 

  24. ; SLIDERS

  25. ; Min Time		-	Minimum delay time in the delay time random modulation

  26. ; Max Time		-	Maximum delay time in the delay time random modulation

  27. ; Min Rate		-	Minimum rate in the random modulation

  28. ; Max Rate		-	Maximum rate in the random modulation

  29. ; Min F.back		-	Minimum feedback value in the modulation of delay feedback values

  30. ; Max F.back		-	Maximum feedback value in the modulation of delay feedback values

  31. ; Min Tone		-	Minimum cutoff frequency in a randomly modulting low-pass filter within each delay buffer

  32. ; Max Tone		-	Maximum cutoff frequency in a randomly modulting low-pass filter within each delay buffer

  33. 

  34. 

  35. <Cabbage>

  36. form size(960, 340), caption("Modulating Delays"), pluginID("mdel")

  37. 

  38. label    bounds(200,  5, 80, 11), text("G A T E"), fontcolour("white")

  39. checkbox bounds( 10, 35,100, 20), text("Gate On/Off") channel("GateActive"), FontColour("White"), colour("lime")  value(1)

  40. rslider  bounds(100, 20, 60, 60), channel("OnThreshold"),  text("On Thrsh."),  range(0, 1, 0.05, 0.5, 0.001),  colour(30,30,30) trackercolour(100,100,100)

  41. rslider  bounds(160, 20, 60, 60), channel("OffThreshold"), text("Off Thrsh."), range(0, 1, 0.01, 0.5, 0.001),  colour(30,30,30) trackercolour(100,100,100)

  42. rslider  bounds(220, 20, 60, 60), channel("RiseTime"),     text("Rise Time"),  range(0, 10, 1, 0.5, 0.001),    colour(30,30,30) trackercolour(100,100,100)

  43. rslider  bounds(280, 20, 60, 60), channel("RelTime"),      text("Rel.Time"),   range(0, 10, 0.01, 0.5, 0.001), colour(30,30,30) trackercolour(100,100,100)

  44. checkbox bounds(340, 35, 90, 15), text("Gating") channel("gating"), FontColour("White"), colour("red")  value(0) shape(ellipse)

  45. 

  46. label    bounds(487,  5, 80, 11), text("S E T U P"), fontcolour("white")

  47. line     bounds(405, 25,  3, 50), colour("Grey")

  48. rslider  bounds(420, 20, 60, 60), channel("width"),  text("Pan Width"),range(0, 0.5, 0.5),         colour(100,100,100) trackercolour(100,100,100)

  49. rslider  bounds(480, 20, 60, 60), channel("spread"), text("Spread"),   range(0, 4, 1, 0.5, 0.001), colour(100,100,100) trackercolour(100,100,100)

  50. rslider  bounds(540, 20, 60, 60), channel("layers"), text("Layers"),   range(1, 22, 8,1,1),        colour(100,100,100) trackercolour(100,100,100)

  51. line     bounds(610, 25,  3, 50), colour("Grey")

  52. label    bounds(680,  5, 80, 11), text("R E V E R B"), fontcolour("white")

  53. rslider  bounds(620, 20, 60, 60), channel("RvbAmt"),  text("Amount"),   range(0, 0.2, 0.06,1,0.001), colour(100,100,100) trackercolour(100,100,100)

  54. rslider  bounds(680, 20, 60, 60), channel("RvbTime"), text("Time"),     range(0.01,10,    7),        colour(100,100,100) trackercolour(100,100,100)

  55. rslider  bounds(740, 20, 60, 60), channel("damping"), text("Damping"),  range(0, 1, 0.5),            colour(100,100,100) trackercolour(100,100,100)

  56. line     bounds(810, 25,  3, 50), colour("Grey")

  57. label    bounds(856,  5, 80, 11), text("O U T P U T"), fontcolour("white")

  58. rslider  bounds(825, 20, 60, 60), channel("dry"),    text("Dry"),      range(0, 4, 0, 0.5, 0.001), colour(160,160,160) trackercolour(160,160,160)

  59. rslider  bounds(885, 20, 60, 60), channel("wet"),    text("Wet"),      range(0, 4, 1, 0.5, 0.001), colour(160,160,160) trackercolour(160,160,160)

  60. 

  61. line     bounds(  0, 95,960, 3), colour("Grey")

  62. 

  63. hslider bounds(10,110, 940, 30), channel("MinTime"), text(Delay Time Minimum),     range(0.001, 10, 0.131, 0.5, 0.000001),colour("blue"),   trackercolour(blue)

  64. hslider bounds(10,130, 940, 30), channel("MaxTime"), text(Delay Time Maximum),     range(0.001, 10, 0.9, 0.5, 0.000001),  colour("blue"),   trackercolour(blue)

  65. hslider bounds(10,160, 940, 30), channel("MinRate"), text(Random Rate Minimum),    range(0.001, 10, 0.1, 0.5, 0.00001),   colour("red"),    trackercolour(red)

  66. hslider bounds(10,180, 940, 30), channel("MaxRate"), text(Random Rate Maximum),    range(0.001, 10, 0.2, 0.5, 0.00001),   colour("red"),    trackercolour(red)

  67. hslider bounds(10,210, 940, 30), channel("MinFB"),   text(Delay Feedback Minimum), range(0, 0.999, 0.95,1,0.001),         colour("yellow"), trackercolour(yellow)

  68. hslider bounds(10,230, 940, 30), channel("MaxFB"),   text(Delay Feedback Maximum), range(0, 0.999, 0.975,1,0.001),        colour("yellow"), trackercolour(yellow)

  69. hslider bounds(10,260, 940, 30), channel("MinTone"), text(Tone Cutoff Frequency Minimum), range(4, 14, 11),               colour(purple),   trackercolour(purple)

  70. hslider bounds(10,280, 940, 30), channel("MaxTone"), text(Tone Cutoff Frequency Maximum), range(4, 14, 14),               colour(purple),   trackercolour(purple)

  71. 

  72. label   bounds( 10,320, 200, 12), text("Author: Iain McCurdy |2013|"), FontColour("grey")

  73. 

  74. </Cabbage>

  75. 

  76. <CsoundSynthesizer>

  77. 

  78. <CsOptions>

  79. -n -d

  80. </CsOptions>

  81. 

  82. <CsInstruments>

  83. 

  84. sr = 44100

  85. ksmps = 16

  86. nchnls = 2

  87. 0dbfs=1

  88. 

  89. 

  90. opcode	DelayIteration,aa,aakkkkkkkkkkkKiii

  91.  aL,aR,kMinTime,kMaxTime,kMinRate,kMaxRate,kMinFB,kMaxFB,kwidth,kMinTone,kMaxTone,kRvbAmt,kRvbTime,kdamping,ispread,icount,ilayers	xin

  92. 

  93.  kdel		rspline	kMinTime,kMaxTime,kMinRate,kMaxRate

  94.  kdel		limit	kdel,0.001,10

  95.  adel		interp	kdel

  96.  kFB		rspline	kMinFB,kMaxFB,kMinRate,kMaxRate

  97.  kFB		limit	kFB,0,1

  98.  

  99.  iMaxDel	=	10

  100.  iws		=	4

  101.  aout1, aout2	init	0

  102. 

  103.  ktone		rspline	kMinTone, kMaxTone,kMinRate,kMaxRate

  104.  ktone		=	cpsoct(ktone)

  105.  

  106.  idelOS		random	0,ispread

  107.   

  108.  abuf		delayr	iMaxDel+idelOS

  109.  aout1		deltap3	adel+idelOS

  110.  arvb 		nreverb aout1, kRvbTime, kdamping

  111.  aout1		=	aout1 + arvb*kRvbAmt

  112.  aout1		dcblock2	aout1

  113.  aout1		tone	aout1,ktone

  114.  		delayw	aL + aout1*kFB

  115.  		

  116.  abuf		delayr	iMaxDel+idelOS

  117.  aout2		deltap3	adel+idelOS

  118.  arvb 		nreverb aout2, kRvbTime, kdamping

  119.  aout2		=	aout2 + arvb*kRvbAmt

  120.  aout2		dcblock2	aout2

  121.  aout2		tone	aout2,ktone

  122.  		delayw	aR + aout2*kFB

  123. 

  124.  kpan		rspline	0.5-kwidth,0.5+kwidth,kMinRate,kMaxRate

  125.  kpan		limit	kpan,0,1

  126.  apan		interp	kpan

  127.  aout1		=	aout1*(1-apan)

  128.  aout2		=	aout2*(apan)

  129.  amix1,amix2	init	0

  130.  

  131.  amix1	=	0

  132.  amix2	=	0

  133.  

  134.  if icount<ilayers then

  135.   amix1,amix2	DelayIteration	aL,aR,kMinTime,kMaxTime,kMinRate,kMaxRate,kMinFB,kMaxFB,kwidth,kMinTone,kMaxTone,kRvbAmt,kRvbTime,kdamping,ispread,icount+1,ilayers

  136.  endif

  137.  

  138. 		xout	aout1+amix1, aout2+amix2

  139. endop

  140. 

  141. opcode	SwitchPort, k, kki

  142. 	kin,kupport,idnport	xin

  143. 	kold			init	0

  144. 	kporttime		=	(kin<kold?idnport:kupport)

  145. 	kout			portk	kin, kporttime

  146. 	kold			=	kout

  147. 				xout	kout

  148. endop

  149. 

  150. 

  151. instr	1

  152.  kporttime	linseg	0,0.001,1

  153.  aL,aR	ins

  154.  ;aL,aR	diskin2	"Synthpad.wav",1,0,1

  155.  ;aL	diskin2	"loop.wav",1,0,1

  156.  ;aR	=	aL

  157.  

  158.  kMinTime	chnget	"MinTime"

  159.  kMaxTime	chnget	"MaxTime"

  160.  kMinTime	portk	kMinTime,kMinTime			

  161.  kMaxTime	portk	kMaxTime,kMaxTime			

  162.  kspread	chnget	"spread"

  163.  kMinRate	chnget	"MinRate"

  164.  kMaxRate	chnget	"MaxRate"

  165.  kMinFB		chnget	"MinFB"

  166.  kMaxFB		chnget	"MaxFB"

  167.  kwidth		chnget	"width"

  168.  kMinTone	chnget	"MinTone"

  169.  kMaxTone	chnget	"MaxTone"

  170.  kres		chnget	"res"

  171.  klayers	chnget	"layers"

  172.  klayers	init	1

  173.  

  174.  kdry		chnget	"dry"

  175.  kwet		chnget	"wet"

  176.  kGateActive	chnget	"GateActive"

  177.  kOnThreshold	chnget	"OnThreshold"

  178.  kOffThreshold	chnget	"OffThreshold"

  179.  kRiseTime	chnget	"RiseTime"

  180.  kRelTime	chnget	"RelTime"

  181. 

  182.  kRvbAmt	chnget	"RvbAmt"

  183.  kRvbTime	chnget	"RvbTime"

  184.  kdamping	chnget	"damping"

  185.  

  186.  /* GATE */

  187.  if kGateActive=1 then

  188.   krms	rms	(aL+aR)*0.5

  189.   kthreshold	init	i(kOnThreshold)

  190.   kon	=	1

  191.   koff	=	0

  192.   if krms>kthreshold then

  193.    kgate	=	1

  194.    kthreshold	=	kOnThreshold

  195.    		chnset	koff,"gating"

  196.   else

  197.    kgate	=	0

  198.    kthreshold	=	kOffThreshold

  199.    		chnset	kon,"gating"

  200.   endif    

  201.   kgate	SwitchPort	kgate,kRiseTime,0.1

  202.   kgate	expcurve	kgate,8

  203.   agate	interp	kgate

  204.   aL	=	aL * agate

  205.   aR	=	aR * agate

  206.  endif

  207.  ktrig	trigger	kGateActive,0.5,1

  208.  if ktrig=1 then

  209.   chnset	koff,"gating"

  210.  endif

  211. 

  212. 

  213.  /* REINITIALISING */

  214.  ktrig	changed	klayers,kspread

  215.  if ktrig=1 then

  216.   reinit UPDATE

  217.  endif

  218.  UPDATE:

  219.  

  220.  /* CALL THE UDO */

  221.  aout1,aout2	DelayIteration	aL,aR,kMinTime,kMaxTime,kMinRate,kMaxRate,kMinFB,kMaxFB,kwidth,kMinTone,kMaxTone,kRvbAmt,kRvbTime,kdamping,i(kspread),1,i(klayers)

  222.  rireturn

  223. 

  224.  		outs	(aout1 * kwet) + (aL * kdry), (aout2 * kwet) + (aR * kdry)

  225. endin

  226. 

  227. </CsInstruments>  

  228. 

  229. <CsScore>

  230. i 1 0 360000

  231. </CsScore>

  232. 

  233. </CsoundSynthesizer>