DISTRHO
/
DISTRHO-Ports-Extra
mirror of https://github.com/DISTRHO/DISTRHO-Ports-Extra
1
0
Fork 0
Code Releases 0 Activity
Extra "ports" of juce-based plugins using the distrho build system
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2 Commits
1 Branch
26MB
Tree: d45623e876
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'd45623e876'
${ noResults }
DISTRHO-Ports-Extra/bin/cabbage-extra/Effects/ConvolutionReverb.csd

167 lines
8.2KB
Raw Blame History 

  1. Convolution Reverb

  2. ------------------

  3. You are encouraged to experiment with different impulse files.

  4. You can find some here: http://www.openairlib.net/

  5. The one I reference in this example can be found here: http://www.iainmccurdy.org/CsoundRealtimeExamples/SourceMaterials/Stairwell.wav

  6. NOTE THAT ZERO LATENCY (or close to zero) CONV0LUTION WILL NOT BE POSSIBLE.

  7. 

  8. Instructions

  9. ------------

  10. 'Size Ratio' compresses the duration of the impulse file (provided that 'compressed' is chosen for 'resize' mode).

  11. 'Curve' defines the shape of an envelope applied to compressed impulse files using GEN16

  12. 	zero		=	straight line decaying

  13. 	positive vals. 	=	increasingly convex decaying

  14. 	negative vals	=	increasingly concave decaying

  15. Increase 'iplen' (must be a power of 2) if experiencing performance problems, or reduce it to reduce latency.

  16. 'Delay OS' fine tunes the delay applied to the dry signal. Normally this should be zero but adjust it to modify how the dry signal lines up with the convoluted signal.

  17. 

  18. <Cabbage>

  19. form caption("Convolution Reverb") size(505, 90), pluginID("Conv")

  20. image bounds(0, 0, 505, 90), colour(135, 30, 30,220), shape("rounded"), outline(255,255,150), line(4) 

  21. button  bounds( 10,  10, 90, 20),       text("forward","backward"),                            channel("FwdBwd"), value(0), fontcolour(250,250,250)

  22. label   bounds( 30,  30, 60, 12),       text("direction"), fontcolour(250,250,250)

  23. button  bounds( 10,  50, 90, 20),       text("normal","compressed"),                           channel("resize"), value(0), fontcolour(250,250,250)

  24. label   bounds( 35,  70, 60, 12),       text("resize"), fontcolour(250,250,250)

  25. rslider bounds(105, 11, 70, 70),        text("Size Ratio"),     colour(135, 30, 30), trackercolour(255,255,150), fontcolour(250,250,250),  channel("CompRat"),     range(0, 1.00, 1)

  26. rslider bounds(170, 11, 70, 70),        text("Curve"),          colour(135, 30, 30), trackercolour(255,255,150), fontcolour(250,250,250),  channel("Curve"),       range(-8.00, 8.00, 0)

  27. rslider bounds(235, 11, 70, 70),        text("In Skip"),        colour(135, 30, 30), trackercolour(255,255,150), fontcolour(250,250,250),  channel("skipsamples"), range(0, 1.00, 0)

  28. rslider bounds(300, 11, 70, 70),        text("Del.OS."),        colour(135, 30, 30), trackercolour(255,255,150), fontcolour(250,250,250),  channel("DelayOS"),     range(-1.00, 1.00, 0)

  29. rslider bounds(365, 11, 70, 70),        text("Mix"),            colour(135, 30, 30), trackercolour(255,255,150), fontcolour(250,250,250),  channel("mix"),         range(0, 1.00, 0.25)

  30. rslider bounds(430, 11, 70, 70),        text("Level"),          colour(135, 30, 30), trackercolour(255,255,150), fontcolour(250,250,250),  channel("level"),       range(0, 1.00, 0.4)

  31. }

  32. </Cabbage>

  33. 

  34. <CsoundSynthesizer>

  35. 

  36. <CsOptions>

  37. -d -n

  38. </CsOptions>

  39. 

  40. <CsInstruments>

  41. 

  42. sr 		= 	44100	;SAMPLE RATE

  43. ksmps 		= 	32	;NUMBER OF AUDIO SAMPLES IN EACH CONTROL CYCLE

  44. nchnls 		= 	2	;NUMBER OF CHANNELS (2=STEREO)

  45. 0dbfs		=	1

  46. 

  47. ;Author: Iain McCurdy (2012)

  48. 

  49. ; IMPULSE RESPONSES STORED AS STEREO GEN01 FUNCTION TABLES

  50. giImpulse     ftgen   1, 0, 262144, 1, "stairwell.wav", 0, 0, 0	;stereo file, duration 1.176s

  51. 

  52. ; reverse function table UDO

  53. opcode	tab_reverse,i,i

  54. ifn             xin

  55. iTabLen         =               nsamp(ifn)

  56. iTableRev       ftgen           ifn+100,0,-iTabLen,-2, 0

  57. icount          =               0

  58. loop:

  59. ival            table           iTabLen-icount-1, ifn

  60.                 tableiw         ival,icount,iTableRev

  61.                 loop_lt         icount,1,iTabLen,loop

  62.                 xout   	        iTableRev

  63. endop

  64. 

  65. ; compress function table UDO

  66. opcode	tab_compress,i,iii

  67. ifn,iCompRat,iCurve    xin

  68. iTabLen         =               nsamp(ifn)

  69. iTabLenComp     =               int(nsamp(ifn)*iCompRat)

  70. iTableComp      ftgen           ifn+200,0,-iTabLenComp,-2, 0

  71. iAmpScaleTab	ftgen		ifn+300,0,-iTabLenComp,-16, 1,iTabLenComp,iCurve,0

  72. icount          =               0

  73. loop:

  74. ival            table           icount, ifn

  75. iAmpScale	table		icount, iAmpScaleTab

  76.                 tableiw         ival*iAmpScale,icount,iTableComp

  77.                 loop_lt         icount,1,iTabLenComp,loop

  78.                 xout   	        iTableComp

  79. endop

  80. 

  81. ; compress reverse function table UDO

  82. opcode	tab_compress_rev,i,iii

  83. ifn,iCompRat,iCurve    xin

  84. iTabLen         =               nsamp(ifn)

  85. iTabLenComp     =               int(nsamp(ifn)*iCompRat)

  86. iTableComp      ftgen           ifn+400,0,-iTabLenComp,-2, 0

  87. iAmpScaleTab	ftgen		ifn+500,0,-iTabLenComp,-16, 1,iTabLenComp,iCurve,0

  88. icount          =               0

  89. loop:

  90. ival            table           icount, ifn

  91. iAmpScale	table		icount, iAmpScaleTab

  92.                 tableiw         ival*iAmpScale, iTabLenComp-icount-1,iTableComp

  93.                 loop_lt         icount,1,iTabLenComp,loop

  94.                 xout   	        iTableComp

  95. endop

  96. 

  97. instr	1	;CONVOLUTION REVERB INSTRUMENT

  98. 	kFwdBwd		chnget	"FwdBwd"

  99. 	kresize		chnget	"resize"

  100. 	kmix		chnget	"mix"

  101. 	klevel		chnget	"level"

  102. 	kCompRat	chnget	"CompRat"

  103. 	kCurve		chnget	"Curve"

  104. 	kskipsamples	chnget	"skipsamples"

  105. 	kDelayOS	chnget	"DelayOS"

  106. 	kCompRat       init	1 			;IF THIS IS LEFT UNINITIALISED A CRASH WILL OCCUR! 

  107. 	

  108. 	ainL,ainR	ins				;READ STEREO AUDIO INPUT

  109. 	;ainL,ainR	diskin2	"808loop.wav",1,0,1	;USE A SOUND FILE FOR TESTING

  110. 	ainMix		sum	ainL,ainR

  111. 	

  112. 	;CREATE REVERSED TABLES

  113. 	irev	tab_reverse	giImpulse

  114. 

  115. 	kSwitch	changed		kskipsamples,kFwdBwd,kDelayOS,kCompRat,kCurve	;GENERATE A MOMENTARY '1' PULSE IN OUTPUT 'kSwitch' IF ANY OF THE SCANNED INPUT VARIABLES CHANGE. (OUTPUT 'kSwitch' IS NORMALLY ZERO)

  116. 	if	kSwitch=1	then			;IF I-RATE VARIABLE IS CHANGED...

  117. 		reinit	UPDATE				;BEGIN A REINITIALISATION PASS IN ORDER TO EFFECT THIS CHANGE. BEGIN THIS PASS AT LABEL ENTITLED 'UPDATE' AND CONTINUE UNTIL rireturn OPCODE 

  118. 	endif						;END OF CONDITIONAL BRANCHING

  119. 	UPDATE:						;LABEL

  120. 	;CREATE COMPRESSED TABLES

  121. 	icomp	tab_compress	giImpulse,i(kCompRat),i(kCurve)

  122. 

  123. 	;CREATE COMPRESSED REVERSED TABLES

  124. 	icomprev	tab_compress_rev	giImpulse,i(kCompRat),i(kCurve)

  125. 

  126. 	iplen		=	1024				;BUFFER LENGTH (INCREASE IF EXPERIENCING PERFORMANCE PROBLEMS, REDUCE IN ORDER TO REDUCE LATENCY)

  127. 	itab		=	giImpulse			;DERIVE FUNCTION TABLE NUMBER OF CHOSEN TABLE FOR IMPULSE FILE

  128. 	iirlen		=	nsamp(itab)*0.5			;DERIVE THE LENGTH OF THE IMPULSE RESPONSE IN SAMPLES. DIVIDE BY 2 AS TABLE IS STEREO.

  129. 	iskipsamples	=	nsamp(itab)*0.5*i(kskipsamples)	;DERIVE INSKIP INTO IMPULSE FILE. DIVIDE BY 2 (MULTIPLY BY 0.5) AS ALL IMPULSE FILES ARE STEREO

  130. 	

  131. 	;FORWARDS REVERB

  132. 	if kFwdBwd==0&&kresize==0 then

  133. 	 aL,aR	ftconv	ainMix, itab, iplen,iskipsamples, iirlen		;CONVOLUTE INPUT SOUND

  134. 	 adelL	delay	ainL, abs((iplen/sr)+i(kDelayOS)) 	;DELAY THE INPUT SOUND ACCORDING TO THE BUFFER SIZE

  135. 	 adelR	delay	ainR, abs((iplen/sr)+i(kDelayOS)) 	;DELAY THE INPUT SOUND ACCORDING TO THE BUFFER SIZE

  136.         

  137.         ;BACKWARDS REVERB

  138.         elseif kFwdBwd==1&&kresize==0 then

  139. 	 aL,aR	ftconv	ainMix, irev, iplen, iskipsamples, iirlen				;CONVOLUTE INPUT SOUND

  140. 	 adelL	delay	ainL,abs((iplen/sr)+(iirlen/sr)-(iskipsamples/sr)+i(kDelayOS))	;DELAY THE INPUT SOUND ACCORDING TO THE BUFFER SIZE AND THE DURATION OF THE IMPULSE FILE

  141. 	 adelR	delay	ainR,abs((iplen/sr)+(iirlen/sr)-(iskipsamples/sr)+i(kDelayOS))	;DELAY THE INPUT SOUND ACCORDING TO THE BUFFER SIZE AND THE DURATION OF THE IMPULSE FILE

  142. 

  143. 	elseif kFwdBwd==0&&kresize==1 then

  144. 	 aL,aR	ftconv	ainMix, icomp, iplen,iskipsamples, iirlen*i(kCompRat)		;CONVOLUTE INPUT SOUND

  145. 	 adelL	delay	ainL, abs((iplen/sr)+i(kDelayOS)) 				;DELAY THE INPUT SOUND ACCORDING TO THE BUFFER SIZE

  146. 	 adelR	delay	ainR, abs((iplen/sr)+i(kDelayOS)) 				;DELAY THE INPUT SOUND ACCORDING TO THE BUFFER SIZE

  147. 

  148. 	elseif kFwdBwd==1&&kresize==1 then

  149. 	 aL,aR	ftconv	ainMix, icomprev, iplen, iskipsamples, iirlen*i(kCompRat)		;CONVOLUTE INPUT SOUND

  150. 	 adelL	delay	ainL,abs((iplen/sr)+((iirlen*i(kCompRat))/sr)-(iskipsamples/sr)+i(kDelayOS))	;DELAY THE INPUT SOUND ACCORDING TO THE BUFFER SIZE AND THE DURATION OF THE IMPULSE FILE

  151. 	 adelR	delay	ainR,abs((iplen/sr)+((iirlen*i(kCompRat))/sr)-(iskipsamples/sr)+i(kDelayOS))	;DELAY THE INPUT SOUND ACCORDING TO THE BUFFER SIZE AND THE DURATION OF THE IMPULSE FILE

  152. 	endif

  153. 

  154. 	; CREATE A DRY/WET MIX

  155. 	aMixL	ntrpol	adelL,aL*0.1,kmix

  156. 	aMixR	ntrpol	adelR,aR*0.1,kmix

  157.         	outs	aMixL*klevel,aMixR*klevel

  158. endin

  159. 		

  160. </CsInstruments>

  161. 

  162. <CsScore>

  163. i 1 0 3600	;INSTRUMENT 2 (CONVOLUTION INSTRUMENT) RUNS FOR 1 HOUR (AND KEEPS REAL-TIME PERFORMANCE GOING) 

  164. </CsScore>

  165. 

  166. </CsoundSynthesizer>